arch/arm64/kernel/head.S

   1 /*
   2  * Low-level CPU initialisation
   3  * Based on arch/arm/kernel/head.S
   4  *
   5  * Copyright (C) 1994-2002 Russell King
   6  * Copyright (C) 2003-2012 ARM Ltd.
   7  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   8  *              Will Deacon <will.deacon@arm.com>
   9  *
  10  * This program is free software; you can redistribute it and/or modify
  11  * it under the terms of the GNU General Public License version 2 as
  12  * published by the Free Software Foundation.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21  */
  22
  23 #include <linux/linkage.h>
  24 #include <linux/init.h>
  25 #include <linux/irqchip/arm-gic-v3.h>
  26
  27 #include <asm/assembler.h>
  28 #include <asm/ptrace.h>
  29 #include <asm/asm-offsets.h>
  30 #include <asm/cache.h>
  31 #include <asm/cputype.h>
  32 #include <asm/kernel-pgtable.h>
  33 #include <asm/kvm_arm.h>
  34 #include <asm/memory.h>
  35 #include <asm/pgtable-hwdef.h>
  36 #include <asm/pgtable.h>
  37 #include <asm/page.h>
  38 #include <asm/sysreg.h>
  39 #include <asm/thread_info.h>
  40 #include <asm/virt.h>
  41
  42 #define __PHYS_OFFSET   (KERNEL_START - TEXT_OFFSET)
  43
  44 #if (TEXT_OFFSET & 0xfff) != 0
  45 #error TEXT_OFFSET must be at least 4KB aligned
  46 #elif (PAGE_OFFSET & 0x1fffff) != 0
  47 #error PAGE_OFFSET must be at least 2MB aligned
  48 #elif TEXT_OFFSET > 0x1fffff
  49 #error TEXT_OFFSET must be less than 2MB
  50 #endif
  51
  52 #define KERNEL_START    _text
  53 #define KERNEL_END      _end
  54
  55 /*
  56  * Kernel startup entry point.
  57  * ---------------------------
  58  *
  59  * The requirements are:
  60  *   MMU = off, D-cache = off, I-cache = on or off,
  61  *   x0 = physical address to the FDT blob.
  62  *
  63  * This code is mostly position independent so you call this at
  64  * __pa(PAGE_OFFSET + TEXT_OFFSET).
  65  *
  66  * Note that the callee-saved registers are used for storing variables
  67  * that are useful before the MMU is enabled. The allocations are described
  68  * in the entry routines.
  69  */
  70         __HEAD
  71
  72         /*
  73          * DO NOT MODIFY. Image header expected by Linux boot-loaders.
  74          */
  75 #ifdef CONFIG_EFI
  76 efi_head:
  77         /*
  78          * This add instruction has no meaningful effect except that
  79          * its opcode forms the magic "MZ" signature required by UEFI.
  80          */
  81         add     x13, x18, #0x16
  82         b       stext
  83 #else
  84         b       stext                           // branch to kernel start, magic
  85         .long   0                               // reserved
  86 #endif
  87         .quad   _kernel_offset_le               // Image load offset from start of RAM, little-endian
  88         .quad   _kernel_size_le                 // Effective size of kernel image, little-endian
  89         .quad   _kernel_flags_le                // Informative flags, little-endian
  90         .quad   0                               // reserved
  91         .quad   0                               // reserved
  92         .quad   0                               // reserved
  93         .byte   0x41                            // Magic number, "ARM\x64"
  94         .byte   0x52
  95         .byte   0x4d
  96         .byte   0x64
  97 #ifdef CONFIG_EFI
  98         .long   pe_header - efi_head            // Offset to the PE header.
  99 #else
 100         .word   0                               // reserved
 101 #endif
 102
 103 #ifdef CONFIG_EFI
 104         .globl  __efistub_stext_offset
 105         .set    __efistub_stext_offset, stext - efi_head
 106         .align 3
 107 pe_header:
 108         .ascii  "PE"
 109         .short  0
 110 coff_header:
 111         .short  0xaa64                          // AArch64
 112         .short  2                               // nr_sections
 113         .long   0                               // TimeDateStamp
 114         .long   0                               // PointerToSymbolTable
 115         .long   1                               // NumberOfSymbols
 116         .short  section_table - optional_header // SizeOfOptionalHeader
 117         .short  0x206                           // Characteristics.
 118                                                 // IMAGE_FILE_DEBUG_STRIPPED |
 119                                                 // IMAGE_FILE_EXECUTABLE_IMAGE |
 120                                                 // IMAGE_FILE_LINE_NUMS_STRIPPED
 121 optional_header:
 122         .short  0x20b                           // PE32+ format
 123         .byte   0x02                            // MajorLinkerVersion
 124         .byte   0x14                            // MinorLinkerVersion
 125         .long   _end - stext                    // SizeOfCode
 126         .long   0                               // SizeOfInitializedData
 127         .long   0                               // SizeOfUninitializedData
 128         .long   __efistub_entry - efi_head      // AddressOfEntryPoint
 129         .long   __efistub_stext_offset          // BaseOfCode
 130
 131 extra_header_fields:
 132         .quad   0                               // ImageBase
 133         .long   0x1000                          // SectionAlignment
 134         .long   PECOFF_FILE_ALIGNMENT           // FileAlignment
 135         .short  0                               // MajorOperatingSystemVersion
 136         .short  0                               // MinorOperatingSystemVersion
 137         .short  0                               // MajorImageVersion
 138         .short  0                               // MinorImageVersion
 139         .short  0                               // MajorSubsystemVersion
 140         .short  0                               // MinorSubsystemVersion
 141         .long   0                               // Win32VersionValue
 142
 143         .long   _end - efi_head                 // SizeOfImage
 144
 145         // Everything before the kernel image is considered part of the header
 146         .long   __efistub_stext_offset          // SizeOfHeaders
 147         .long   0                               // CheckSum
 148         .short  0xa                             // Subsystem (EFI application)
 149         .short  0                               // DllCharacteristics
 150         .quad   0                               // SizeOfStackReserve
 151         .quad   0                               // SizeOfStackCommit
 152         .quad   0                               // SizeOfHeapReserve
 153         .quad   0                               // SizeOfHeapCommit
 154         .long   0                               // LoaderFlags
 155         .long   0x6                             // NumberOfRvaAndSizes
 156
 157         .quad   0                               // ExportTable
 158         .quad   0                               // ImportTable
 159         .quad   0                               // ResourceTable
 160         .quad   0                               // ExceptionTable
 161         .quad   0                               // CertificationTable
 162         .quad   0                               // BaseRelocationTable
 163
 164         // Section table
 165 section_table:
 166
 167         /*
 168          * The EFI application loader requires a relocation section
 169          * because EFI applications must be relocatable.  This is a
 170          * dummy section as far as we are concerned.
 171          */
 172         .ascii  ".reloc"
 173         .byte   0
 174         .byte   0                       // end of 0 padding of section name
 175         .long   0
 176         .long   0
 177         .long   0                       // SizeOfRawData
 178         .long   0                       // PointerToRawData
 179         .long   0                       // PointerToRelocations
 180         .long   0                       // PointerToLineNumbers
 181         .short  0                       // NumberOfRelocations
 182         .short  0                       // NumberOfLineNumbers
 183         .long   0x42100040              // Characteristics (section flags)
 184
 185
 186         .ascii  ".text"
 187         .byte   0
 188         .byte   0
 189         .byte   0                       // end of 0 padding of section name
 190         .long   _end - stext            // VirtualSize
 191         .long   __efistub_stext_offset  // VirtualAddress
 192         .long   _edata - stext          // SizeOfRawData
 193         .long   __efistub_stext_offset  // PointerToRawData
 194
 195         .long   0               // PointerToRelocations (0 for executables)
 196         .long   0               // PointerToLineNumbers (0 for executables)
 197         .short  0               // NumberOfRelocations  (0 for executables)
 198         .short  0               // NumberOfLineNumbers  (0 for executables)
 199         .long   0xe0500020      // Characteristics (section flags)
 200
 201         /*
 202          * EFI will load stext onwards at the 4k section alignment
 203          * described in the PE/COFF header. To ensure that instruction
 204          * sequences using an adrp and a :lo12: immediate will function
 205          * correctly at this alignment, we must ensure that stext is
 206          * placed at a 4k boundary in the Image to begin with.
 207          */
 208         .align 12
 209 #endif
 210
 211 ENTRY(stext)
 212         bl      preserve_boot_args
 213         bl      el2_setup                       // Drop to EL1, w20=cpu_boot_mode
 214         adrp    x24, __PHYS_OFFSET
 215         bl      set_cpu_boot_mode_flag
 216         bl      __create_page_tables            // x25=TTBR0, x26=TTBR1
 217         /*
 218          * The following calls CPU setup code, see arch/arm64/mm/proc.S for
 219          * details.
 220          * On return, the CPU will be ready for the MMU to be turned on and
 221          * the TCR will have been set.
 222          */
 223         ldr     x27, =__mmap_switched           // address to jump to after
 224                                                 // MMU has been enabled
 225         adr_l   lr, __enable_mmu                // return (PIC) address
 226         b       __cpu_setup                     // initialise processor
 227 ENDPROC(stext)
 228
 229 /*
 230  * Preserve the arguments passed by the bootloader in x0 .. x3
 231  */
 232 preserve_boot_args:
 233         mov     x21, x0                         // x21=FDT
 234
 235         adr_l   x0, boot_args                   // record the contents of
 236         stp     x21, x1, [x0]                   // x0 .. x3 at kernel entry
 237         stp     x2, x3, [x0, #16]
 238
 239         dmb     sy                              // needed before dc ivac with
 240                                                 // MMU off
 241
 242         add     x1, x0, #0x20                   // 4 x 8 bytes
 243         b       __inval_cache_range             // tail call
 244 ENDPROC(preserve_boot_args)
 245
 246 /*
 247  * Macro to create a table entry to the next page.
 248  *
 249  *      tbl:    page table address
 250  *      virt:   virtual address
 251  *      shift:  #imm page table shift
 252  *      ptrs:   #imm pointers per table page
 253  *
 254  * Preserves:   virt
 255  * Corrupts:    tmp1, tmp2
 256  * Returns:     tbl -> next level table page address
 257  */
 258         .macro  create_table_entry, tbl, virt, shift, ptrs, tmp1, tmp2
 259         lsr     \tmp1, \virt, #\shift
 260         and     \tmp1, \tmp1, #\ptrs - 1        // table index
 261         add     \tmp2, \tbl, #PAGE_SIZE
 262         orr     \tmp2, \tmp2, #PMD_TYPE_TABLE   // address of next table and entry type
 263         str     \tmp2, [\tbl, \tmp1, lsl #3]
 264         add     \tbl, \tbl, #PAGE_SIZE          // next level table page
 265         .endm
 266
 267 /*
 268  * Macro to populate the PGD (and possibily PUD) for the corresponding
 269  * block entry in the next level (tbl) for the given virtual address.
 270  *
 271  * Preserves:   tbl, next, virt
 272  * Corrupts:    tmp1, tmp2
 273  */
 274         .macro  create_pgd_entry, tbl, virt, tmp1, tmp2
 275         create_table_entry \tbl, \virt, PGDIR_SHIFT, PTRS_PER_PGD, \tmp1, \tmp2
 276 #if SWAPPER_PGTABLE_LEVELS > 3
 277         create_table_entry \tbl, \virt, PUD_SHIFT, PTRS_PER_PUD, \tmp1, \tmp2
 278 #endif
 279 #if SWAPPER_PGTABLE_LEVELS > 2
 280         create_table_entry \tbl, \virt, SWAPPER_TABLE_SHIFT, PTRS_PER_PTE, \tmp1, \tmp2
 281 #endif
 282         .endm
 283
 284 /*
 285  * Macro to populate block entries in the page table for the start..end
 286  * virtual range (inclusive).
 287  *
 288  * Preserves:   tbl, flags
 289  * Corrupts:    phys, start, end, pstate
 290  */
 291         .macro  create_block_map, tbl, flags, phys, start, end
 292         lsr     \phys, \phys, #SWAPPER_BLOCK_SHIFT
 293         lsr     \start, \start, #SWAPPER_BLOCK_SHIFT
 294         and     \start, \start, #PTRS_PER_PTE - 1       // table index
 295         orr     \phys, \flags, \phys, lsl #SWAPPER_BLOCK_SHIFT  // table entry
 296         lsr     \end, \end, #SWAPPER_BLOCK_SHIFT
 297         and     \end, \end, #PTRS_PER_PTE - 1           // table end index
 298 9999:   str     \phys, [\tbl, \start, lsl #3]           // store the entry
 299         add     \start, \start, #1                      // next entry
 300         add     \phys, \phys, #SWAPPER_BLOCK_SIZE               // next block
 301         cmp     \start, \end
 302         b.ls    9999b
 303         .endm
 304
 305 /*
 306  * Setup the initial page tables. We only setup the barest amount which is
 307  * required to get the kernel running. The following sections are required:
 308  *   - identity mapping to enable the MMU (low address, TTBR0)
 309  *   - first few MB of the kernel linear mapping to jump to once the MMU has
 310  *     been enabled
 311  */
 312 __create_page_tables:
 313         adrp    x25, idmap_pg_dir
 314         adrp    x26, swapper_pg_dir
 315         mov     x27, lr
 316
 317         /*
 318          * Invalidate the idmap and swapper page tables to avoid potential
 319          * dirty cache lines being evicted.
 320          */
 321         mov     x0, x25
 322         add     x1, x26, #SWAPPER_DIR_SIZE
 323         bl      __inval_cache_range
 324
 325         /*
 326          * Clear the idmap and swapper page tables.
 327          */
 328         mov     x0, x25
 329         add     x6, x26, #SWAPPER_DIR_SIZE
 330 1:      stp     xzr, xzr, [x0], #16
 331         stp     xzr, xzr, [x0], #16
 332         stp     xzr, xzr, [x0], #16
 333         stp     xzr, xzr, [x0], #16
 334         cmp     x0, x6
 335         b.lo    1b
 336
 337         ldr     x7, =SWAPPER_MM_MMUFLAGS
 338
 339         /*
 340          * Create the identity mapping.
 341          */
 342         mov     x0, x25                         // idmap_pg_dir
 343         adrp    x3, __idmap_text_start          // __pa(__idmap_text_start)
 344
 345 #ifndef CONFIG_ARM64_VA_BITS_48
 346 #define EXTRA_SHIFT     (PGDIR_SHIFT + PAGE_SHIFT - 3)
 347 #define EXTRA_PTRS      (1 << (48 - EXTRA_SHIFT))
 348
 349         /*
 350          * If VA_BITS < 48, it may be too small to allow for an ID mapping to be
 351          * created that covers system RAM if that is located sufficiently high
 352          * in the physical address space. So for the ID map, use an extended
 353          * virtual range in that case, by configuring an additional translation
 354          * level.
 355          * First, we have to verify our assumption that the current value of
 356          * VA_BITS was chosen such that all translation levels are fully
 357          * utilised, and that lowering T0SZ will always result in an additional
 358          * translation level to be configured.
 359          */
 360 #if VA_BITS != EXTRA_SHIFT
 361 #error "Mismatch between VA_BITS and page size/number of translation levels"
 362 #endif
 363
 364         /*
 365          * Calculate the maximum allowed value for TCR_EL1.T0SZ so that the
 366          * entire ID map region can be mapped. As T0SZ == (64 - #bits used),
 367          * this number conveniently equals the number of leading zeroes in
 368          * the physical address of __idmap_text_end.
 369          */
 370         adrp    x5, __idmap_text_end
 371         clz     x5, x5
 372         cmp     x5, TCR_T0SZ(VA_BITS)   // default T0SZ small enough?
 373         b.ge    1f                      // .. then skip additional level
 374
 375         adr_l   x6, idmap_t0sz
 376         str     x5, [x6]
 377         dmb     sy
 378         dc      ivac, x6                // Invalidate potentially stale cache line
 379
 380         create_table_entry x0, x3, EXTRA_SHIFT, EXTRA_PTRS, x5, x6
 381 1:
 382 #endif
 383
 384         create_pgd_entry x0, x3, x5, x6
 385         mov     x5, x3                          // __pa(__idmap_text_start)
 386         adr_l   x6, __idmap_text_end            // __pa(__idmap_text_end)
 387         create_block_map x0, x7, x3, x5, x6
 388
 389         /*
 390          * Map the kernel image (starting with PHYS_OFFSET).
 391          */
 392         mov     x0, x26                         // swapper_pg_dir
 393         mov     x5, #PAGE_OFFSET
 394         create_pgd_entry x0, x5, x3, x6
 395         ldr     x6, =KERNEL_END                 // __va(KERNEL_END)
 396         mov     x3, x24                         // phys offset
 397         create_block_map x0, x7, x3, x5, x6
 398
 399         /*
 400          * Since the page tables have been populated with non-cacheable
 401          * accesses (MMU disabled), invalidate the idmap and swapper page
 402          * tables again to remove any speculatively loaded cache lines.
 403          */
 404         mov     x0, x25
 405         add     x1, x26, #SWAPPER_DIR_SIZE
 406         dmb     sy
 407         bl      __inval_cache_range
 408
 409         mov     lr, x27
 410         ret
 411 ENDPROC(__create_page_tables)
 412         .ltorg
 413
 414 /*
 415  * The following fragment of code is executed with the MMU enabled.
 416  */
 417         .set    initial_sp, init_thread_union + THREAD_START_SP
 418 __mmap_switched:
 419         // Clear BSS
 420         adr_l   x0, __bss_start
 421         mov     x1, xzr
 422         adr_l   x2, __bss_stop
 423         sub     x2, x2, x0
 424         bl      __pi_memset
 425
 426         adr_l   sp, initial_sp, x4
 427         mov     x4, sp
 428         and     x4, x4, #~(THREAD_SIZE - 1)
 429         msr     sp_el0, x4                      // Save thread_info
 430         str_l   x21, __fdt_pointer, x5          // Save FDT pointer
 431         str_l   x24, memstart_addr, x6          // Save PHYS_OFFSET
 432         mov     x29, #0
 433 #ifdef CONFIG_KASAN
 434         bl      kasan_early_init
 435 #endif
 436         b       start_kernel
 437 ENDPROC(__mmap_switched)
 438
 439 /*
 440  * end early head section, begin head code that is also used for
 441  * hotplug and needs to have the same protections as the text region
 442  */
 443         .section ".text","ax"
 444 /*
 445  * If we're fortunate enough to boot at EL2, ensure that the world is
 446  * sane before dropping to EL1.
 447  *
 448  * Returns either BOOT_CPU_MODE_EL1 or BOOT_CPU_MODE_EL2 in x20 if
 449  * booted in EL1 or EL2 respectively.
 450  */
 451 ENTRY(el2_setup)
 452         mrs     x0, CurrentEL
 453         cmp     x0, #CurrentEL_EL2
 454         b.ne    1f
 455         mrs     x0, sctlr_el2
 456 CPU_BE( orr     x0, x0, #(1 << 25)      )       // Set the EE bit for EL2
 457 CPU_LE( bic     x0, x0, #(1 << 25)      )       // Clear the EE bit for EL2
 458         msr     sctlr_el2, x0
 459         b       2f
 460 1:      mrs     x0, sctlr_el1
 461 CPU_BE( orr     x0, x0, #(3 << 24)      )       // Set the EE and E0E bits for EL1
 462 CPU_LE( bic     x0, x0, #(3 << 24)      )       // Clear the EE and E0E bits for EL1
 463         msr     sctlr_el1, x0
 464         mov     w20, #BOOT_CPU_MODE_EL1         // This cpu booted in EL1
 465         isb
 466         ret
 467
 468 2:
 469 #ifdef CONFIG_ARM64_VHE
 470         /*
 471          * Check for VHE being present. For the rest of the EL2 setup,
 472          * x2 being non-zero indicates that we do have VHE, and that the
 473          * kernel is intended to run at EL2.
 474          */
 475         mrs     x2, id_aa64mmfr1_el1
 476         ubfx    x2, x2, #8, #4
 477 #else
 478         mov     x2, xzr
 479 #endif
 480
 481         /* Hyp configuration. */
 482         mov     x0, #HCR_RW                     // 64-bit EL1
 483         cbz     x2, set_hcr
 484         orr     x0, x0, #HCR_TGE                // Enable Host Extensions
 485         orr     x0, x0, #HCR_E2H
 486 set_hcr:
 487         msr     hcr_el2, x0
 488         isb
 489
 490         /* Generic timers. */
 491         mrs     x0, cnthctl_el2
 492         orr     x0, x0, #3                      // Enable EL1 physical timers
 493         msr     cnthctl_el2, x0
 494         msr     cntvoff_el2, xzr                // Clear virtual offset
 495
 496 #ifdef CONFIG_ARM_GIC_V3
 497         /* GICv3 system register access */
 498         mrs     x0, id_aa64pfr0_el1
 499         ubfx    x0, x0, #24, #4
 500         cmp     x0, #1
 501         b.ne    3f
 502
 503         mrs_s   x0, ICC_SRE_EL2
 504         orr     x0, x0, #ICC_SRE_EL2_SRE        // Set ICC_SRE_EL2.SRE==1
 505         orr     x0, x0, #ICC_SRE_EL2_ENABLE     // Set ICC_SRE_EL2.Enable==1
 506         msr_s   ICC_SRE_EL2, x0
 507         isb                                     // Make sure SRE is now set
 508         mrs_s   x0, ICC_SRE_EL2                 // Read SRE back,
 509         tbz     x0, #0, 3f                      // and check that it sticks
 510         msr_s   ICH_HCR_EL2, xzr                // Reset ICC_HCR_EL2 to defaults
 511
 512 3:
 513 #endif
 514
 515         /* Populate ID registers. */
 516         mrs     x0, midr_el1
 517         mrs     x1, mpidr_el1
 518         msr     vpidr_el2, x0
 519         msr     vmpidr_el2, x1
 520
 521         /* sctlr_el1 */
 522         mov     x0, #0x0800                     // Set/clear RES{1,0} bits
 523 CPU_BE( movk    x0, #0x33d0, lsl #16    )       // Set EE and E0E on BE systems
 524 CPU_LE( movk    x0, #0x30d0, lsl #16    )       // Clear EE and E0E on LE systems
 525         msr     sctlr_el1, x0
 526
 527         /* Coprocessor traps. */
 528         mov     x0, #0x33ff
 529         msr     cptr_el2, x0                    // Disable copro. traps to EL2
 530
 531 #ifdef CONFIG_COMPAT
 532         msr     hstr_el2, xzr                   // Disable CP15 traps to EL2
 533 #endif
 534
 535         /* EL2 debug */
 536         mrs     x0, id_aa64dfr0_el1             // Check ID_AA64DFR0_EL1 PMUVer
 537         sbfx    x0, x0, #8, #4
 538         cmp     x0, #1
 539         b.lt    4f                              // Skip if no PMU present
 540         mrs     x0, pmcr_el0                    // Disable debug access traps
 541         ubfx    x0, x0, #11, #5                 // to EL2 and allow access to
 542         msr     mdcr_el2, x0                    // all PMU counters from EL1
 543 4:
 544
 545         /* Stage-2 translation */
 546         msr     vttbr_el2, xzr
 547
 548         cbz     x2, install_el2_stub
 549
 550         mov     w20, #BOOT_CPU_MODE_EL2         // This CPU booted in EL2
 551         isb
 552         ret
 553
 554 install_el2_stub:
 555         /* Hypervisor stub */
 556         adrp    x0, __hyp_stub_vectors
 557         add     x0, x0, #:lo12:__hyp_stub_vectors
 558         msr     vbar_el2, x0
 559
 560         /* spsr */
 561         mov     x0, #(PSR_F_BIT | PSR_I_BIT | PSR_A_BIT | PSR_D_BIT |\
 562                       PSR_MODE_EL1h)
 563         msr     spsr_el2, x0
 564         msr     elr_el2, lr
 565         mov     w20, #BOOT_CPU_MODE_EL2         // This CPU booted in EL2
 566         eret
 567 ENDPROC(el2_setup)
 568
 569 /*
 570  * Sets the __boot_cpu_mode flag depending on the CPU boot mode passed
 571  * in x20. See arch/arm64/include/asm/virt.h for more info.
 572  */
 573 ENTRY(set_cpu_boot_mode_flag)
 574         adr_l   x1, __boot_cpu_mode
 575         cmp     w20, #BOOT_CPU_MODE_EL2
 576         b.ne    1f
 577         add     x1, x1, #4
 578 1:      str     w20, [x1]                       // This CPU has booted in EL1
 579         dmb     sy
 580         dc      ivac, x1                        // Invalidate potentially stale cache line
 581         ret
 582 ENDPROC(set_cpu_boot_mode_flag)
 583
 584 /*
 585  * We need to find out the CPU boot mode long after boot, so we need to
 586  * store it in a writable variable.
 587  *
 588  * This is not in .bss, because we set it sufficiently early that the boot-time
 589  * zeroing of .bss would clobber it.
 590  */
 591         .pushsection    .data..cacheline_aligned
 592         .align  L1_CACHE_SHIFT
 593 ENTRY(__boot_cpu_mode)
 594         .long   BOOT_CPU_MODE_EL2
 595         .long   BOOT_CPU_MODE_EL1
 596         .popsection
 597
 598         /*
 599          * This provides a "holding pen" for platforms to hold all secondary
 600          * cores are held until we're ready for them to initialise.
 601          */
 602 ENTRY(secondary_holding_pen)
 603         bl      el2_setup                       // Drop to EL1, w20=cpu_boot_mode
 604         bl      set_cpu_boot_mode_flag
 605         mrs     x0, mpidr_el1
 606         ldr     x1, =MPIDR_HWID_BITMASK
 607         and     x0, x0, x1
 608         adr_l   x3, secondary_holding_pen_release
 609 pen:    ldr     x4, [x3]
 610         cmp     x4, x0
 611         b.eq    secondary_startup
 612         wfe
 613         b       pen
 614 ENDPROC(secondary_holding_pen)
 615
 616         /*
 617          * Secondary entry point that jumps straight into the kernel. Only to
 618          * be used where CPUs are brought online dynamically by the kernel.
 619          */
 620 ENTRY(secondary_entry)
 621         bl      el2_setup                       // Drop to EL1
 622         bl      set_cpu_boot_mode_flag
 623         b       secondary_startup
 624 ENDPROC(secondary_entry)
 625
 626 ENTRY(secondary_startup)
 627         /*
 628          * Common entry point for secondary CPUs.
 629          */
 630         adrp    x25, idmap_pg_dir
 631         adrp    x26, swapper_pg_dir
 632         bl      __cpu_setup                     // initialise processor
 633
 634         ldr     x21, =secondary_data
 635         ldr     x27, =__secondary_switched      // address to jump to after enabling the MMU
 636         b       __enable_mmu
 637 ENDPROC(secondary_startup)
 638
 639 ENTRY(__secondary_switched)
 640         ldr     x0, [x21]                       // get secondary_data.stack
 641         mov     sp, x0
 642         and     x0, x0, #~(THREAD_SIZE - 1)
 643         msr     sp_el0, x0                      // save thread_info
 644         mov     x29, #0
 645         b       secondary_start_kernel
 646 ENDPROC(__secondary_switched)
 647
 648 /*
 649  * Enable the MMU.
 650  *
 651  *  x0  = SCTLR_EL1 value for turning on the MMU.
 652  *  x27 = *virtual* address to jump to upon completion
 653  *
 654  * Other registers depend on the function called upon completion.
 655  *
 656  * Checks if the selected granule size is supported by the CPU.
 657  * If it isn't, park the CPU
 658  */
 659         .section        ".idmap.text", "ax"
 660 __enable_mmu:
 661         mrs     x1, ID_AA64MMFR0_EL1
 662         ubfx    x2, x1, #ID_AA64MMFR0_TGRAN_SHIFT, 4
 663         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED
 664         b.ne    __no_granule_support
 665         ldr     x5, =vectors
 666         msr     vbar_el1, x5
 667         msr     ttbr0_el1, x25                  // load TTBR0
 668         msr     ttbr1_el1, x26                  // load TTBR1
 669         isb
 670         msr     sctlr_el1, x0
 671         isb
 672         /*
 673          * Invalidate the local I-cache so that any instructions fetched
 674          * speculatively from the PoC are discarded, since they may have
 675          * been dynamically patched at the PoU.
 676          */
 677         ic      iallu
 678         dsb     nsh
 679         isb
 680         br      x27
 681 ENDPROC(__enable_mmu)
 682
 683 __no_granule_support:
 684         wfe
 685         b __no_granule_support
 686 ENDPROC(__no_granule_support)