arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36 #include <asm/context_tracking.h>
  37
  38 /*
  39  * System calls.
  40  */
  41         .section        ".toc","aw"
  42 SYS_CALL_TABLE:
  43         .tc sys_call_table[TC],sys_call_table
  44
  45 /* This value is used to mark exception frames on the stack. */
  46 exception_marker:
  47         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  48
  49         .section        ".text"
  50         .align 7
  51
  52 #undef SHOW_SYSCALLS
  53
  54         .globl system_call_common
  55 system_call_common:
  56         andi.   r10,r12,MSR_PR
  57         mr      r10,r1
  58         addi    r1,r1,-INT_FRAME_SIZE
  59         beq-    1f
  60         ld      r1,PACAKSAVE(r13)
  61 1:      std     r10,0(r1)
  62         std     r11,_NIP(r1)
  63         std     r12,_MSR(r1)
  64         std     r0,GPR0(r1)
  65         std     r10,GPR1(r1)
  66         beq     2f                      /* if from kernel mode */
  67         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  68 2:      std     r2,GPR2(r1)
  69         std     r3,GPR3(r1)
  70         mfcr    r2
  71         std     r4,GPR4(r1)
  72         std     r5,GPR5(r1)
  73         std     r6,GPR6(r1)
  74         std     r7,GPR7(r1)
  75         std     r8,GPR8(r1)
  76         li      r11,0
  77         std     r11,GPR9(r1)
  78         std     r11,GPR10(r1)
  79         std     r11,GPR11(r1)
  80         std     r11,GPR12(r1)
  81         std     r11,_XER(r1)
  82         std     r11,_CTR(r1)
  83         std     r9,GPR13(r1)
  84         mflr    r10
  85         /*
  86          * This clears CR0.SO (bit 28), which is the error indication on
  87          * return from this system call.
  88          */
  89         rldimi  r2,r11,28,(63-28)
  90         li      r11,0xc01
  91         std     r10,_LINK(r1)
  92         std     r11,_TRAP(r1)
  93         std     r3,ORIG_GPR3(r1)
  94         std     r2,_CCR(r1)
  95         ld      r2,PACATOC(r13)
  96         addi    r9,r1,STACK_FRAME_OVERHEAD
  97         ld      r11,exception_marker@toc(r2)
  98         std     r11,-16(r9)             /* "regshere" marker */
  99 #if defined(CONFIG_VIRT_CPU_ACCOUNTING_NATIVE) && defined(CONFIG_PPC_SPLPAR)
 100 BEGIN_FW_FTR_SECTION
 101         beq     33f
 102         /* if from user, see if there are any DTL entries to process */
 103         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 104         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 105         addi    r10,r10,LPPACA_DTLIDX
 106         LDX_BE  r10,0,r10               /* get log write index */
 107         cmpd    cr1,r11,r10
 108         beq+    cr1,33f
 109         bl      accumulate_stolen_time
 110         REST_GPR(0,r1)
 111         REST_4GPRS(3,r1)
 112         REST_2GPRS(7,r1)
 113         addi    r9,r1,STACK_FRAME_OVERHEAD
 114 33:
 115 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 116 #endif /* CONFIG_VIRT_CPU_ACCOUNTING_NATIVE && CONFIG_PPC_SPLPAR */
 117
 118         /*
 119          * A syscall should always be called with interrupts enabled
 120          * so we just unconditionally hard-enable here. When some kind
 121          * of irq tracing is used, we additionally check that condition
 122          * is correct
 123          */
 124 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 125         lbz     r10,PACASOFTIRQEN(r13)
 126         xori    r10,r10,1
 127 1:      tdnei   r10,0
 128         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 129 #endif
 130
 131 #ifdef CONFIG_PPC_BOOK3E
 132         wrteei  1
 133 #else
 134         ld      r11,PACAKMSR(r13)
 135         ori     r11,r11,MSR_EE
 136         mtmsrd  r11,1
 137 #endif /* CONFIG_PPC_BOOK3E */
 138
 139         /* We do need to set SOFTE in the stack frame or the return
 140          * from interrupt will be painful
 141          */
 142         li      r10,1
 143         std     r10,SOFTE(r1)
 144
 145 #ifdef SHOW_SYSCALLS
 146         bl      do_show_syscall
 147         REST_GPR(0,r1)
 148         REST_4GPRS(3,r1)
 149         REST_2GPRS(7,r1)
 150         addi    r9,r1,STACK_FRAME_OVERHEAD
 151 #endif
 152         CURRENT_THREAD_INFO(r11, r1)
 153         ld      r10,TI_FLAGS(r11)
 154         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 155         bne     syscall_dotrace
 156 .Lsyscall_dotrace_cont:
 157         cmpldi  0,r0,NR_syscalls
 158         bge-    syscall_enosys
 159
 160 system_call:                    /* label this so stack traces look sane */
 161 /*
 162  * Need to vector to 32 Bit or default sys_call_table here,
 163  * based on caller's run-mode / personality.
 164  */
 165         ld      r11,SYS_CALL_TABLE@toc(2)
 166         andi.   r10,r10,_TIF_32BIT
 167         beq     15f
 168         addi    r11,r11,8       /* use 32-bit syscall entries */
 169         clrldi  r3,r3,32
 170         clrldi  r4,r4,32
 171         clrldi  r5,r5,32
 172         clrldi  r6,r6,32
 173         clrldi  r7,r7,32
 174         clrldi  r8,r8,32
 175 15:
 176         slwi    r0,r0,4
 177         ldx     r12,r11,r0      /* Fetch system call handler [ptr] */
 178         mtctr   r12
 179         bctrl                   /* Call handler */
 180
 181 syscall_exit:
 182         std     r3,RESULT(r1)
 183 #ifdef SHOW_SYSCALLS
 184         bl      do_show_syscall_exit
 185         ld      r3,RESULT(r1)
 186 #endif
 187         CURRENT_THREAD_INFO(r12, r1)
 188
 189         ld      r8,_MSR(r1)
 190 #ifdef CONFIG_PPC_BOOK3S
 191         /* No MSR:RI on BookE */
 192         andi.   r10,r8,MSR_RI
 193         beq-    unrecov_restore
 194 #endif
 195         /*
 196          * Disable interrupts so current_thread_info()->flags can't change,
 197          * and so that we don't get interrupted after loading SRR0/1.
 198          */
 199 #ifdef CONFIG_PPC_BOOK3E
 200         wrteei  0
 201 #else
 202         ld      r10,PACAKMSR(r13)
 203         /*
 204          * For performance reasons we clear RI the same time that we
 205          * clear EE. We only need to clear RI just before we restore r13
 206          * below, but batching it with EE saves us one expensive mtmsrd call.
 207          * We have to be careful to restore RI if we branch anywhere from
 208          * here (eg syscall_exit_work).
 209          */
 210         li      r9,MSR_RI
 211         andc    r11,r10,r9
 212         mtmsrd  r11,1
 213 #endif /* CONFIG_PPC_BOOK3E */
 214
 215         ld      r9,TI_FLAGS(r12)
 216         li      r11,-_LAST_ERRNO
 217         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 218         bne-    syscall_exit_work
 219         cmpld   r3,r11
 220         ld      r5,_CCR(r1)
 221         bge-    syscall_error
 222 .Lsyscall_error_cont:
 223         ld      r7,_NIP(r1)
 224 BEGIN_FTR_SECTION
 225         stdcx.  r0,0,r1                 /* to clear the reservation */
 226 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 227         andi.   r6,r8,MSR_PR
 228         ld      r4,_LINK(r1)
 229
 230         beq-    1f
 231         ACCOUNT_CPU_USER_EXIT(r11, r12)
 232         HMT_MEDIUM_LOW_HAS_PPR
 233         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 234 1:      ld      r2,GPR2(r1)
 235         ld      r1,GPR1(r1)
 236         mtlr    r4
 237         mtcr    r5
 238         mtspr   SPRN_SRR0,r7
 239         mtspr   SPRN_SRR1,r8
 240         RFI
 241         b       .       /* prevent speculative execution */
 242
 243 syscall_error:
 244         oris    r5,r5,0x1000    /* Set SO bit in CR */
 245         neg     r3,r3
 246         std     r5,_CCR(r1)
 247         b       .Lsyscall_error_cont
 248
 249 /* Traced system call support */
 250 syscall_dotrace:
 251         bl      save_nvgprs
 252         addi    r3,r1,STACK_FRAME_OVERHEAD
 253         bl      do_syscall_trace_enter
 254         /*
 255          * Restore argument registers possibly just changed.
 256          * We use the return value of do_syscall_trace_enter
 257          * for the call number to look up in the table (r0).
 258          */
 259         mr      r0,r3
 260         ld      r3,GPR3(r1)
 261         ld      r4,GPR4(r1)
 262         ld      r5,GPR5(r1)
 263         ld      r6,GPR6(r1)
 264         ld      r7,GPR7(r1)
 265         ld      r8,GPR8(r1)
 266         addi    r9,r1,STACK_FRAME_OVERHEAD
 267         CURRENT_THREAD_INFO(r10, r1)
 268         ld      r10,TI_FLAGS(r10)
 269         b       .Lsyscall_dotrace_cont
 270
 271 syscall_enosys:
 272         li      r3,-ENOSYS
 273         b       syscall_exit
 274
 275 syscall_exit_work:
 276 #ifdef CONFIG_PPC_BOOK3S
 277         mtmsrd  r10,1           /* Restore RI */
 278 #endif
 279         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 280          If TIF_NOERROR is set, just save r3 as it is. */
 281
 282         andi.   r0,r9,_TIF_RESTOREALL
 283         beq+    0f
 284         REST_NVGPRS(r1)
 285         b       2f
 286 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 287         blt+    1f
 288         andi.   r0,r9,_TIF_NOERROR
 289         bne-    1f
 290         ld      r5,_CCR(r1)
 291         neg     r3,r3
 292         oris    r5,r5,0x1000    /* Set SO bit in CR */
 293         std     r5,_CCR(r1)
 294 1:      std     r3,GPR3(r1)
 295 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 296         beq     4f
 297
 298         /* Clear per-syscall TIF flags if any are set.  */
 299
 300         li      r11,_TIF_PERSYSCALL_MASK
 301         addi    r12,r12,TI_FLAGS
 302 3:      ldarx   r10,0,r12
 303         andc    r10,r10,r11
 304         stdcx.  r10,0,r12
 305         bne-    3b
 306         subi    r12,r12,TI_FLAGS
 307
 308 4:      /* Anything else left to do? */
 309         SET_DEFAULT_THREAD_PPR(r3, r10)         /* Set thread.ppr = 3 */
 310         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 311         beq     ret_from_except_lite
 312
 313         /* Re-enable interrupts */
 314 #ifdef CONFIG_PPC_BOOK3E
 315         wrteei  1
 316 #else
 317         ld      r10,PACAKMSR(r13)
 318         ori     r10,r10,MSR_EE
 319         mtmsrd  r10,1
 320 #endif /* CONFIG_PPC_BOOK3E */
 321
 322         bl      save_nvgprs
 323         addi    r3,r1,STACK_FRAME_OVERHEAD
 324         bl      do_syscall_trace_leave
 325         b       ret_from_except
 326
 327 /* Save non-volatile GPRs, if not already saved. */
 328 _GLOBAL(save_nvgprs)
 329         ld      r11,_TRAP(r1)
 330         andi.   r0,r11,1
 331         beqlr-
 332         SAVE_NVGPRS(r1)
 333         clrrdi  r0,r11,1
 334         std     r0,_TRAP(r1)
 335         blr
 336
 337
 338 /*
 339  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 340  * and thus put the process into the stopped state where we might
 341  * want to examine its user state with ptrace.  Therefore we need
 342  * to save all the nonvolatile registers (r14 - r31) before calling
 343  * the C code.  Similarly, fork, vfork and clone need the full
 344  * register state on the stack so that it can be copied to the child.
 345  */
 346
 347 _GLOBAL(ppc_fork)
 348         bl      save_nvgprs
 349         bl      sys_fork
 350         b       syscall_exit
 351
 352 _GLOBAL(ppc_vfork)
 353         bl      save_nvgprs
 354         bl      sys_vfork
 355         b       syscall_exit
 356
 357 _GLOBAL(ppc_clone)
 358         bl      save_nvgprs
 359         bl      sys_clone
 360         b       syscall_exit
 361
 362 _GLOBAL(ppc32_swapcontext)
 363         bl      save_nvgprs
 364         bl      compat_sys_swapcontext
 365         b       syscall_exit
 366
 367 _GLOBAL(ppc64_swapcontext)
 368         bl      save_nvgprs
 369         bl      sys_swapcontext
 370         b       syscall_exit
 371
 372 _GLOBAL(ret_from_fork)
 373         bl      schedule_tail
 374         REST_NVGPRS(r1)
 375         li      r3,0
 376         b       syscall_exit
 377
 378 _GLOBAL(ret_from_kernel_thread)
 379         bl      schedule_tail
 380         REST_NVGPRS(r1)
 381         mtlr    r14
 382         mr      r3,r15
 383 #if defined(_CALL_ELF) && _CALL_ELF == 2
 384         mr      r12,r14
 385 #endif
 386         blrl
 387         li      r3,0
 388         b       syscall_exit
 389
 390 /*
 391  * This routine switches between two different tasks.  The process
 392  * state of one is saved on its kernel stack.  Then the state
 393  * of the other is restored from its kernel stack.  The memory
 394  * management hardware is updated to the second process's state.
 395  * Finally, we can return to the second process, via ret_from_except.
 396  * On entry, r3 points to the THREAD for the current task, r4
 397  * points to the THREAD for the new task.
 398  *
 399  * Note: there are two ways to get to the "going out" portion
 400  * of this code; either by coming in via the entry (_switch)
 401  * or via "fork" which must set up an environment equivalent
 402  * to the "_switch" path.  If you change this you'll have to change
 403  * the fork code also.
 404  *
 405  * The code which creates the new task context is in 'copy_thread'
 406  * in arch/powerpc/kernel/process.c
 407  */
 408         .align  7
 409 _GLOBAL(_switch)
 410         mflr    r0
 411         std     r0,16(r1)
 412         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 413         /* r3-r13 are caller saved -- Cort */
 414         SAVE_8GPRS(14, r1)
 415         SAVE_10GPRS(22, r1)
 416         mflr    r20             /* Return to switch caller */
 417         mfmsr   r22
 418         li      r0, MSR_FP
 419 #ifdef CONFIG_VSX
 420 BEGIN_FTR_SECTION
 421         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 422 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 423 #endif /* CONFIG_VSX */
 424 #ifdef CONFIG_ALTIVEC
 425 BEGIN_FTR_SECTION
 426         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 427         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 428         std     r24,THREAD_VRSAVE(r3)
 429 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 430 #endif /* CONFIG_ALTIVEC */
 431 #ifdef CONFIG_PPC64
 432 BEGIN_FTR_SECTION
 433         mfspr   r25,SPRN_DSCR
 434         std     r25,THREAD_DSCR(r3)
 435 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 436 #endif
 437         and.    r0,r0,r22
 438         beq+    1f
 439         andc    r22,r22,r0
 440         MTMSRD(r22)
 441         isync
 442 1:      std     r20,_NIP(r1)
 443         mfcr    r23
 444         std     r23,_CCR(r1)
 445         std     r1,KSP(r3)      /* Set old stack pointer */
 446
 447 #ifdef CONFIG_PPC_BOOK3S_64
 448 BEGIN_FTR_SECTION
 449         /* Event based branch registers */
 450         mfspr   r0, SPRN_BESCR
 451         std     r0, THREAD_BESCR(r3)
 452         mfspr   r0, SPRN_EBBHR
 453         std     r0, THREAD_EBBHR(r3)
 454         mfspr   r0, SPRN_EBBRR
 455         std     r0, THREAD_EBBRR(r3)
 456 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 457 #endif
 458
 459 #ifdef CONFIG_SMP
 460         /* We need a sync somewhere here to make sure that if the
 461          * previous task gets rescheduled on another CPU, it sees all
 462          * stores it has performed on this one.
 463          */
 464         sync
 465 #endif /* CONFIG_SMP */
 466
 467         /*
 468          * If we optimise away the clear of the reservation in system
 469          * calls because we know the CPU tracks the address of the
 470          * reservation, then we need to clear it here to cover the
 471          * case that the kernel context switch path has no larx
 472          * instructions.
 473          */
 474 BEGIN_FTR_SECTION
 475         ldarx   r6,0,r1
 476 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 477
 478 #ifdef CONFIG_PPC_BOOK3S
 479 /* Cancel all explict user streams as they will have no use after context
 480  * switch and will stop the HW from creating streams itself
 481  */
 482         DCBT_STOP_ALL_STREAM_IDS(r6)
 483 #endif
 484
 485         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 486         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 487
 488         ld      r8,KSP(r4)      /* new stack pointer */
 489 #ifdef CONFIG_PPC_BOOK3S
 490 BEGIN_FTR_SECTION
 491   BEGIN_FTR_SECTION_NESTED(95)
 492         clrrdi  r6,r8,28        /* get its ESID */
 493         clrrdi  r9,r1,28        /* get current sp ESID */
 494   FTR_SECTION_ELSE_NESTED(95)
 495         clrrdi  r6,r8,40        /* get its 1T ESID */
 496         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 497   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 498 FTR_SECTION_ELSE
 499         b       2f
 500 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 501         clrldi. r0,r6,2         /* is new ESID c00000000? */
 502         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 503         cror    eq,4*cr1+eq,eq
 504         beq     2f              /* if yes, don't slbie it */
 505
 506         /* Bolt in the new stack SLB entry */
 507         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 508         oris    r0,r6,(SLB_ESID_V)@h
 509         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 510 BEGIN_FTR_SECTION
 511         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 512         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 513         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 514 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 515
 516         /* Update the last bolted SLB.  No write barriers are needed
 517          * here, provided we only update the current CPU's SLB shadow
 518          * buffer.
 519          */
 520         ld      r9,PACA_SLBSHADOWPTR(r13)
 521         li      r12,0
 522         std     r12,SLBSHADOW_STACKESID(r9)     /* Clear ESID */
 523         li      r12,SLBSHADOW_STACKVSID
 524         STDX_BE r7,r12,r9                       /* Save VSID */
 525         li      r12,SLBSHADOW_STACKESID
 526         STDX_BE r0,r12,r9                       /* Save ESID */
 527
 528         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 529          * we have 1TB segments, the only CPUs known to have the errata
 530          * only support less than 1TB of system memory and we'll never
 531          * actually hit this code path.
 532          */
 533
 534         slbie   r6
 535         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 536         slbmte  r7,r0
 537         isync
 538 2:
 539 #endif /* !CONFIG_PPC_BOOK3S */
 540
 541         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 542         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 543            because we don't need to leave the 288-byte ABI gap at the
 544            top of the kernel stack. */
 545         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 546
 547         mr      r1,r8           /* start using new stack pointer */
 548         std     r7,PACAKSAVE(r13)
 549
 550 #ifdef CONFIG_PPC_BOOK3S_64
 551 BEGIN_FTR_SECTION
 552         /* Event based branch registers */
 553         ld      r0, THREAD_BESCR(r4)
 554         mtspr   SPRN_BESCR, r0
 555         ld      r0, THREAD_EBBHR(r4)
 556         mtspr   SPRN_EBBHR, r0
 557         ld      r0, THREAD_EBBRR(r4)
 558         mtspr   SPRN_EBBRR, r0
 559
 560         ld      r0,THREAD_TAR(r4)
 561         mtspr   SPRN_TAR,r0
 562 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 563 #endif
 564
 565 #ifdef CONFIG_ALTIVEC
 566 BEGIN_FTR_SECTION
 567         ld      r0,THREAD_VRSAVE(r4)
 568         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 569 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 570 #endif /* CONFIG_ALTIVEC */
 571 #ifdef CONFIG_PPC64
 572 BEGIN_FTR_SECTION
 573         lwz     r6,THREAD_DSCR_INHERIT(r4)
 574         ld      r0,THREAD_DSCR(r4)
 575         cmpwi   r6,0
 576         bne     1f
 577         ld      r0,PACA_DSCR(r13)
 578 1:
 579 BEGIN_FTR_SECTION_NESTED(70)
 580         mfspr   r8, SPRN_FSCR
 581         rldimi  r8, r6, FSCR_DSCR_LG, (63 - FSCR_DSCR_LG)
 582         mtspr   SPRN_FSCR, r8
 583 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_207S, CPU_FTR_ARCH_207S, 70)
 584         cmpd    r0,r25
 585         beq     2f
 586         mtspr   SPRN_DSCR,r0
 587 2:
 588 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 589 #endif
 590
 591         ld      r6,_CCR(r1)
 592         mtcrf   0xFF,r6
 593
 594         /* r3-r13 are destroyed -- Cort */
 595         REST_8GPRS(14, r1)
 596         REST_10GPRS(22, r1)
 597
 598         /* convert old thread to its task_struct for return value */
 599         addi    r3,r3,-THREAD
 600         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 601         mtlr    r7
 602         addi    r1,r1,SWITCH_FRAME_SIZE
 603         blr
 604
 605         .align  7
 606 _GLOBAL(ret_from_except)
 607         ld      r11,_TRAP(r1)
 608         andi.   r0,r11,1
 609         bne     ret_from_except_lite
 610         REST_NVGPRS(r1)
 611
 612 _GLOBAL(ret_from_except_lite)
 613         /*
 614          * Disable interrupts so that current_thread_info()->flags
 615          * can't change between when we test it and when we return
 616          * from the interrupt.
 617          */
 618 #ifdef CONFIG_PPC_BOOK3E
 619         wrteei  0
 620 #else
 621         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 622         mtmsrd  r10,1             /* Update machine state */
 623 #endif /* CONFIG_PPC_BOOK3E */
 624
 625         CURRENT_THREAD_INFO(r9, r1)
 626         ld      r3,_MSR(r1)
 627 #ifdef CONFIG_PPC_BOOK3E
 628         ld      r10,PACACURRENT(r13)
 629 #endif /* CONFIG_PPC_BOOK3E */
 630         ld      r4,TI_FLAGS(r9)
 631         andi.   r3,r3,MSR_PR
 632         beq     resume_kernel
 633 #ifdef CONFIG_PPC_BOOK3E
 634         lwz     r3,(THREAD+THREAD_DBCR0)(r10)
 635 #endif /* CONFIG_PPC_BOOK3E */
 636
 637         /* Check current_thread_info()->flags */
 638         andi.   r0,r4,_TIF_USER_WORK_MASK
 639 #ifdef CONFIG_PPC_BOOK3E
 640         bne     1f
 641         /*
 642          * Check to see if the dbcr0 register is set up to debug.
 643          * Use the internal debug mode bit to do this.
 644          */
 645         andis.  r0,r3,DBCR0_IDM@h
 646         beq     restore
 647         mfmsr   r0
 648         rlwinm  r0,r0,0,~MSR_DE /* Clear MSR.DE */
 649         mtmsr   r0
 650         mtspr   SPRN_DBCR0,r3
 651         li      r10, -1
 652         mtspr   SPRN_DBSR,r10
 653         b       restore
 654 #else
 655         beq     restore
 656 #endif
 657 1:      andi.   r0,r4,_TIF_NEED_RESCHED
 658         beq     2f
 659         bl      restore_interrupts
 660         SCHEDULE_USER
 661         b       ret_from_except_lite
 662 2:
 663 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 664         andi.   r0,r4,_TIF_USER_WORK_MASK & ~_TIF_RESTORE_TM
 665         bne     3f              /* only restore TM if nothing else to do */
 666         addi    r3,r1,STACK_FRAME_OVERHEAD
 667         bl      restore_tm_state
 668         b       restore
 669 3:
 670 #endif
 671         bl      save_nvgprs
 672         bl      restore_interrupts
 673         addi    r3,r1,STACK_FRAME_OVERHEAD
 674         bl      do_notify_resume
 675         b       ret_from_except
 676
 677 resume_kernel:
 678         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 679         andis.  r8,r4,_TIF_EMULATE_STACK_STORE@h
 680         beq+    1f
 681
 682         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 683
 684         lwz     r3,GPR1(r1)
 685         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 686         mr      r4,r1                   /* src:  current exception frame */
 687         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 688
 689         /* Copy from the original to the trampoline. */
 690         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 691         li      r6,0                    /* start offset: 0 */
 692         mtctr   r5
 693 2:      ldx     r0,r6,r4
 694         stdx    r0,r6,r3
 695         addi    r6,r6,8
 696         bdnz    2b
 697
 698         /* Do real store operation to complete stwu */
 699         lwz     r5,GPR1(r1)
 700         std     r8,0(r5)
 701
 702         /* Clear _TIF_EMULATE_STACK_STORE flag */
 703         lis     r11,_TIF_EMULATE_STACK_STORE@h
 704         addi    r5,r9,TI_FLAGS
 705 0:      ldarx   r4,0,r5
 706         andc    r4,r4,r11
 707         stdcx.  r4,0,r5
 708         bne-    0b
 709 1:
 710
 711 #ifdef CONFIG_PREEMPT
 712         /* Check if we need to preempt */
 713         andi.   r0,r4,_TIF_NEED_RESCHED
 714         beq+    restore
 715         /* Check that preempt_count() == 0 and interrupts are enabled */
 716         lwz     r8,TI_PREEMPT(r9)
 717         cmpwi   cr1,r8,0
 718         ld      r0,SOFTE(r1)
 719         cmpdi   r0,0
 720         crandc  eq,cr1*4+eq,eq
 721         bne     restore
 722
 723         /*
 724          * Here we are preempting the current task. We want to make
 725          * sure we are soft-disabled first and reconcile irq state.
 726          */
 727         RECONCILE_IRQ_STATE(r3,r4)
 728 1:      bl      preempt_schedule_irq
 729
 730         /* Re-test flags and eventually loop */
 731         CURRENT_THREAD_INFO(r9, r1)
 732         ld      r4,TI_FLAGS(r9)
 733         andi.   r0,r4,_TIF_NEED_RESCHED
 734         bne     1b
 735
 736         /*
 737          * arch_local_irq_restore() from preempt_schedule_irq above may
 738          * enable hard interrupt but we really should disable interrupts
 739          * when we return from the interrupt, and so that we don't get
 740          * interrupted after loading SRR0/1.
 741          */
 742 #ifdef CONFIG_PPC_BOOK3E
 743         wrteei  0
 744 #else
 745         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 746         mtmsrd  r10,1             /* Update machine state */
 747 #endif /* CONFIG_PPC_BOOK3E */
 748 #endif /* CONFIG_PREEMPT */
 749
 750         .globl  fast_exc_return_irq
 751 fast_exc_return_irq:
 752 restore:
 753         /*
 754          * This is the main kernel exit path. First we check if we
 755          * are about to re-enable interrupts
 756          */
 757         ld      r5,SOFTE(r1)
 758         lbz     r6,PACASOFTIRQEN(r13)
 759         cmpwi   cr0,r5,0
 760         beq     restore_irq_off
 761
 762         /* We are enabling, were we already enabled ? Yes, just return */
 763         cmpwi   cr0,r6,1
 764         beq     cr0,do_restore
 765
 766         /*
 767          * We are about to soft-enable interrupts (we are hard disabled
 768          * at this point). We check if there's anything that needs to
 769          * be replayed first.
 770          */
 771         lbz     r0,PACAIRQHAPPENED(r13)
 772         cmpwi   cr0,r0,0
 773         bne-    restore_check_irq_replay
 774
 775         /*
 776          * Get here when nothing happened while soft-disabled, just
 777          * soft-enable and move-on. We will hard-enable as a side
 778          * effect of rfi
 779          */
 780 restore_no_replay:
 781         TRACE_ENABLE_INTS
 782         li      r0,1
 783         stb     r0,PACASOFTIRQEN(r13);
 784
 785         /*
 786          * Final return path. BookE is handled in a different file
 787          */
 788 do_restore:
 789 #ifdef CONFIG_PPC_BOOK3E
 790         b       exception_return_book3e
 791 #else
 792         /*
 793          * Clear the reservation. If we know the CPU tracks the address of
 794          * the reservation then we can potentially save some cycles and use
 795          * a larx. On POWER6 and POWER7 this is significantly faster.
 796          */
 797 BEGIN_FTR_SECTION
 798         stdcx.  r0,0,r1         /* to clear the reservation */
 799 FTR_SECTION_ELSE
 800         ldarx   r4,0,r1
 801 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 802
 803         /*
 804          * Some code path such as load_up_fpu or altivec return directly
 805          * here. They run entirely hard disabled and do not alter the
 806          * interrupt state. They also don't use lwarx/stwcx. and thus
 807          * are known not to leave dangling reservations.
 808          */
 809         .globl  fast_exception_return
 810 fast_exception_return:
 811         ld      r3,_MSR(r1)
 812         ld      r4,_CTR(r1)
 813         ld      r0,_LINK(r1)
 814         mtctr   r4
 815         mtlr    r0
 816         ld      r4,_XER(r1)
 817         mtspr   SPRN_XER,r4
 818
 819         REST_8GPRS(5, r1)
 820
 821         andi.   r0,r3,MSR_RI
 822         beq-    unrecov_restore
 823
 824         /* Load PPR from thread struct before we clear MSR:RI */
 825 BEGIN_FTR_SECTION
 826         ld      r2,PACACURRENT(r13)
 827         ld      r2,TASKTHREADPPR(r2)
 828 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 829
 830         /*
 831          * Clear RI before restoring r13.  If we are returning to
 832          * userspace and we take an exception after restoring r13,
 833          * we end up corrupting the userspace r13 value.
 834          */
 835         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 836         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 837         mtmsrd  r4,1
 838
 839 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 840         /* TM debug */
 841         std     r3, PACATMSCRATCH(r13) /* Stash returned-to MSR */
 842 #endif
 843         /*
 844          * r13 is our per cpu area, only restore it if we are returning to
 845          * userspace the value stored in the stack frame may belong to
 846          * another CPU.
 847          */
 848         andi.   r0,r3,MSR_PR
 849         beq     1f
 850 BEGIN_FTR_SECTION
 851         mtspr   SPRN_PPR,r2     /* Restore PPR */
 852 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 853         ACCOUNT_CPU_USER_EXIT(r2, r4)
 854         REST_GPR(13, r1)
 855 1:
 856         mtspr   SPRN_SRR1,r3
 857
 858         ld      r2,_CCR(r1)
 859         mtcrf   0xFF,r2
 860         ld      r2,_NIP(r1)
 861         mtspr   SPRN_SRR0,r2
 862
 863         ld      r0,GPR0(r1)
 864         ld      r2,GPR2(r1)
 865         ld      r3,GPR3(r1)
 866         ld      r4,GPR4(r1)
 867         ld      r1,GPR1(r1)
 868
 869         rfid
 870         b       .       /* prevent speculative execution */
 871
 872 #endif /* CONFIG_PPC_BOOK3E */
 873
 874         /*
 875          * We are returning to a context with interrupts soft disabled.
 876          *
 877          * However, we may also about to hard enable, so we need to
 878          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 879          * or that bit can get out of sync and bad things will happen
 880          */
 881 restore_irq_off:
 882         ld      r3,_MSR(r1)
 883         lbz     r7,PACAIRQHAPPENED(r13)
 884         andi.   r0,r3,MSR_EE
 885         beq     1f
 886         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 887         stb     r7,PACAIRQHAPPENED(r13)
 888 1:      li      r0,0
 889         stb     r0,PACASOFTIRQEN(r13);
 890         TRACE_DISABLE_INTS
 891         b       do_restore
 892
 893         /*
 894          * Something did happen, check if a re-emit is needed
 895          * (this also clears paca->irq_happened)
 896          */
 897 restore_check_irq_replay:
 898         /* XXX: We could implement a fast path here where we check
 899          * for irq_happened being just 0x01, in which case we can
 900          * clear it and return. That means that we would potentially
 901          * miss a decrementer having wrapped all the way around.
 902          *
 903          * Still, this might be useful for things like hash_page
 904          */
 905         bl      __check_irq_replay
 906         cmpwi   cr0,r3,0
 907         beq     restore_no_replay
 908
 909         /*
 910          * We need to re-emit an interrupt. We do so by re-using our
 911          * existing exception frame. We first change the trap value,
 912          * but we need to ensure we preserve the low nibble of it
 913          */
 914         ld      r4,_TRAP(r1)
 915         clrldi  r4,r4,60
 916         or      r4,r4,r3
 917         std     r4,_TRAP(r1)
 918
 919         /*
 920          * Then find the right handler and call it. Interrupts are
 921          * still soft-disabled and we keep them that way.
 922         */
 923         cmpwi   cr0,r3,0x500
 924         bne     1f
 925         addi    r3,r1,STACK_FRAME_OVERHEAD;
 926         bl      do_IRQ
 927         b       ret_from_except
 928 1:      cmpwi   cr0,r3,0x900
 929         bne     1f
 930         addi    r3,r1,STACK_FRAME_OVERHEAD;
 931         bl      timer_interrupt
 932         b       ret_from_except
 933 #ifdef CONFIG_PPC_DOORBELL
 934 1:
 935 #ifdef CONFIG_PPC_BOOK3E
 936         cmpwi   cr0,r3,0x280
 937 #else
 938         BEGIN_FTR_SECTION
 939                 cmpwi   cr0,r3,0xe80
 940         FTR_SECTION_ELSE
 941                 cmpwi   cr0,r3,0xa00
 942         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 943 #endif /* CONFIG_PPC_BOOK3E */
 944         bne     1f
 945         addi    r3,r1,STACK_FRAME_OVERHEAD;
 946         bl      doorbell_exception
 947         b       ret_from_except
 948 #endif /* CONFIG_PPC_DOORBELL */
 949 1:      b       ret_from_except /* What else to do here ? */
 950
 951 unrecov_restore:
 952         addi    r3,r1,STACK_FRAME_OVERHEAD
 953         bl      unrecoverable_exception
 954         b       unrecov_restore
 955
 956 #ifdef CONFIG_PPC_RTAS
 957 /*
 958  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 959  * called with the MMU off.
 960  *
 961  * In addition, we need to be in 32b mode, at least for now.
 962  *
 963  * Note: r3 is an input parameter to rtas, so don't trash it...
 964  */
 965 _GLOBAL(enter_rtas)
 966         mflr    r0
 967         std     r0,16(r1)
 968         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 969
 970         /* Because RTAS is running in 32b mode, it clobbers the high order half
 971          * of all registers that it saves.  We therefore save those registers
 972          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 973          */
 974         SAVE_GPR(2, r1)                 /* Save the TOC */
 975         SAVE_GPR(13, r1)                /* Save paca */
 976         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 977         SAVE_10GPRS(22, r1)             /* ditto */
 978
 979         mfcr    r4
 980         std     r4,_CCR(r1)
 981         mfctr   r5
 982         std     r5,_CTR(r1)
 983         mfspr   r6,SPRN_XER
 984         std     r6,_XER(r1)
 985         mfdar   r7
 986         std     r7,_DAR(r1)
 987         mfdsisr r8
 988         std     r8,_DSISR(r1)
 989
 990         /* Temporary workaround to clear CR until RTAS can be modified to
 991          * ignore all bits.
 992          */
 993         li      r0,0
 994         mtcr    r0
 995
 996 #ifdef CONFIG_BUG
 997         /* There is no way it is acceptable to get here with interrupts enabled,
 998          * check it with the asm equivalent of WARN_ON
 999          */
1000         lbz     r0,PACASOFTIRQEN(r13)
1001 1:      tdnei   r0,0
1002         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
1003 #endif
1004
1005         /* Hard-disable interrupts */
1006         mfmsr   r6
1007         rldicl  r7,r6,48,1
1008         rotldi  r7,r7,16
1009         mtmsrd  r7,1
1010
1011         /* Unfortunately, the stack pointer and the MSR are also clobbered,
1012          * so they are saved in the PACA which allows us to restore
1013          * our original state after RTAS returns.
1014          */
1015         std     r1,PACAR1(r13)
1016         std     r6,PACASAVEDMSR(r13)
1017
1018         /* Setup our real return addr */
1019         LOAD_REG_ADDR(r4,rtas_return_loc)
1020         clrldi  r4,r4,2                 /* convert to realmode address */
1021         mtlr    r4
1022
1023         li      r0,0
1024         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
1025         andc    r0,r6,r0
1026
1027         li      r9,1
1028         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
1029         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI|MSR_LE
1030         andc    r6,r0,r9
1031         sync                            /* disable interrupts so SRR0/1 */
1032         mtmsrd  r0                      /* don't get trashed */
1033
1034         LOAD_REG_ADDR(r4, rtas)
1035         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
1036         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
1037
1038         mtspr   SPRN_SRR0,r5
1039         mtspr   SPRN_SRR1,r6
1040         rfid
1041         b       .       /* prevent speculative execution */
1042
1043 rtas_return_loc:
1044         FIXUP_ENDIAN
1045
1046         /* relocation is off at this point */
1047         GET_PACA(r4)
1048         clrldi  r4,r4,2                 /* convert to realmode address */
1049
1050         bcl     20,31,$+4
1051 0:      mflr    r3
1052         ld      r3,(1f-0b)(r3)          /* get &rtas_restore_regs */
1053
1054         mfmsr   r6
1055         li      r0,MSR_RI
1056         andc    r6,r6,r0
1057         sync
1058         mtmsrd  r6
1059
1060         ld      r1,PACAR1(r4)           /* Restore our SP */
1061         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
1062
1063         mtspr   SPRN_SRR0,r3
1064         mtspr   SPRN_SRR1,r4
1065         rfid
1066         b       .       /* prevent speculative execution */
1067
1068         .align  3
1069 1:      .llong  rtas_restore_regs
1070
1071 rtas_restore_regs:
1072         /* relocation is on at this point */
1073         REST_GPR(2, r1)                 /* Restore the TOC */
1074         REST_GPR(13, r1)                /* Restore paca */
1075         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
1076         REST_10GPRS(22, r1)             /* ditto */
1077
1078         GET_PACA(r13)
1079
1080         ld      r4,_CCR(r1)
1081         mtcr    r4
1082         ld      r5,_CTR(r1)
1083         mtctr   r5
1084         ld      r6,_XER(r1)
1085         mtspr   SPRN_XER,r6
1086         ld      r7,_DAR(r1)
1087         mtdar   r7
1088         ld      r8,_DSISR(r1)
1089         mtdsisr r8
1090
1091         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
1092         ld      r0,16(r1)               /* get return address */
1093
1094         mtlr    r0
1095         blr                             /* return to caller */
1096
1097 #endif /* CONFIG_PPC_RTAS */
1098
1099 _GLOBAL(enter_prom)
1100         mflr    r0
1101         std     r0,16(r1)
1102         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
1103
1104         /* Because PROM is running in 32b mode, it clobbers the high order half
1105          * of all registers that it saves.  We therefore save those registers
1106          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1107          */
1108         SAVE_GPR(2, r1)
1109         SAVE_GPR(13, r1)
1110         SAVE_8GPRS(14, r1)
1111         SAVE_10GPRS(22, r1)
1112         mfcr    r10
1113         mfmsr   r11
1114         std     r10,_CCR(r1)
1115         std     r11,_MSR(r1)
1116
1117         /* Put PROM address in SRR0 */
1118         mtsrr0  r4
1119
1120         /* Setup our trampoline return addr in LR */
1121         bcl     20,31,$+4
1122 0:      mflr    r4
1123         addi    r4,r4,(1f - 0b)
1124         mtlr    r4
1125
1126         /* Prepare a 32-bit mode big endian MSR
1127          */
1128 #ifdef CONFIG_PPC_BOOK3E
1129         rlwinm  r11,r11,0,1,31
1130         mtsrr1  r11
1131         rfi
1132 #else /* CONFIG_PPC_BOOK3E */
1133         LOAD_REG_IMMEDIATE(r12, MSR_SF | MSR_ISF | MSR_LE)
1134         andc    r11,r11,r12
1135         mtsrr1  r11
1136         rfid
1137 #endif /* CONFIG_PPC_BOOK3E */
1138
1139 1:      /* Return from OF */
1140         FIXUP_ENDIAN
1141
1142         /* Just make sure that r1 top 32 bits didn't get
1143          * corrupt by OF
1144          */
1145         rldicl  r1,r1,0,32
1146
1147         /* Restore the MSR (back to 64 bits) */
1148         ld      r0,_MSR(r1)
1149         MTMSRD(r0)
1150         isync
1151
1152         /* Restore other registers */
1153         REST_GPR(2, r1)
1154         REST_GPR(13, r1)
1155         REST_8GPRS(14, r1)
1156         REST_10GPRS(22, r1)
1157         ld      r4,_CCR(r1)
1158         mtcr    r4
1159
1160         addi    r1,r1,PROM_FRAME_SIZE
1161         ld      r0,16(r1)
1162         mtlr    r0
1163         blr
1164
1165 #ifdef CONFIG_FUNCTION_TRACER
1166 #ifdef CONFIG_DYNAMIC_FTRACE
1167 _GLOBAL(mcount)
1168 _GLOBAL(_mcount)
1169         blr
1170
1171 _GLOBAL_TOC(ftrace_caller)
1172         /* Taken from output of objdump from lib64/glibc */
1173         mflr    r3
1174         ld      r11, 0(r1)
1175         stdu    r1, -112(r1)
1176         std     r3, 128(r1)
1177         ld      r4, 16(r11)
1178         subi    r3, r3, MCOUNT_INSN_SIZE
1179 .globl ftrace_call
1180 ftrace_call:
1181         bl      ftrace_stub
1182         nop
1183 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1184 .globl ftrace_graph_call
1185 ftrace_graph_call:
1186         b       ftrace_graph_stub
1187 _GLOBAL(ftrace_graph_stub)
1188 #endif
1189         ld      r0, 128(r1)
1190         mtlr    r0
1191         addi    r1, r1, 112
1192 _GLOBAL(ftrace_stub)
1193         blr
1194 #else
1195 _GLOBAL_TOC(_mcount)
1196         /* Taken from output of objdump from lib64/glibc */
1197         mflr    r3
1198         ld      r11, 0(r1)
1199         stdu    r1, -112(r1)
1200         std     r3, 128(r1)
1201         ld      r4, 16(r11)
1202
1203         subi    r3, r3, MCOUNT_INSN_SIZE
1204         LOAD_REG_ADDR(r5,ftrace_trace_function)
1205         ld      r5,0(r5)
1206         ld      r5,0(r5)
1207         mtctr   r5
1208         bctrl
1209         nop
1210
1211
1212 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1213         b       ftrace_graph_caller
1214 #endif
1215         ld      r0, 128(r1)
1216         mtlr    r0
1217         addi    r1, r1, 112
1218 _GLOBAL(ftrace_stub)
1219         blr
1220
1221 #endif /* CONFIG_DYNAMIC_FTRACE */
1222
1223 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1224 _GLOBAL(ftrace_graph_caller)
1225         /* load r4 with local address */
1226         ld      r4, 128(r1)
1227         subi    r4, r4, MCOUNT_INSN_SIZE
1228
1229         /* get the parent address */
1230         ld      r11, 112(r1)
1231         addi    r3, r11, 16
1232
1233         bl      prepare_ftrace_return
1234         nop
1235
1236         ld      r0, 128(r1)
1237         mtlr    r0
1238         addi    r1, r1, 112
1239         blr
1240
1241 _GLOBAL(return_to_handler)
1242         /* need to save return values */
1243         std     r4,  -24(r1)
1244         std     r3,  -16(r1)
1245         std     r31, -8(r1)
1246         mr      r31, r1
1247         stdu    r1, -112(r1)
1248
1249         bl      ftrace_return_to_handler
1250         nop
1251
1252         /* return value has real return address */
1253         mtlr    r3
1254
1255         ld      r1, 0(r1)
1256         ld      r4,  -24(r1)
1257         ld      r3,  -16(r1)
1258         ld      r31, -8(r1)
1259
1260         /* Jump back to real return address */
1261         blr
1262
1263 _GLOBAL(mod_return_to_handler)
1264         /* need to save return values */
1265         std     r4,  -32(r1)
1266         std     r3,  -24(r1)
1267         /* save TOC */
1268         std     r2,  -16(r1)
1269         std     r31, -8(r1)
1270         mr      r31, r1
1271         stdu    r1, -112(r1)
1272
1273         /*
1274          * We are in a module using the module's TOC.
1275          * Switch to our TOC to run inside the core kernel.
1276          */
1277         ld      r2, PACATOC(r13)
1278
1279         bl      ftrace_return_to_handler
1280         nop
1281
1282         /* return value has real return address */
1283         mtlr    r3
1284
1285         ld      r1, 0(r1)
1286         ld      r4,  -32(r1)
1287         ld      r3,  -24(r1)
1288         ld      r2,  -16(r1)
1289         ld      r31, -8(r1)
1290
1291         /* Jump back to real return address */
1292         blr
1293 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1294 #endif /* CONFIG_FUNCTION_TRACER */