arch/tile/kernel/mcount_64.S

   1 /*
   2  * Copyright 2012 Tilera Corporation. All Rights Reserved.
   3  *
   4  *   This program is free software; you can redistribute it and/or
   5  *   modify it under the terms of the GNU General Public License
   6  *   as published by the Free Software Foundation, version 2.
   7  *
   8  *   This program is distributed in the hope that it will be useful, but
   9  *   WITHOUT ANY WARRANTY; without even the implied warranty of
  10  *   MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or
  11  *   NON INFRINGEMENT.  See the GNU General Public License for
  12  *   more details.
  13  *
  14  * TILE-Gx specific __mcount support
  15  */
  16
  17 #include <linux/linkage.h>
  18 #include <asm/ftrace.h>
  19
  20 #define REGSIZE 8
  21
  22         .text
  23         .global __mcount
  24
  25         .macro  MCOUNT_SAVE_REGS
  26         addli   sp, sp, -REGSIZE
  27         {
  28          st     sp, lr
  29          addli  r29, sp, - (12 * REGSIZE)
  30         }
  31         {
  32          addli  sp, sp, - (13 * REGSIZE)
  33          st     r29, sp
  34         }
  35         addli   r29, r29, REGSIZE
  36         { st    r29, r0; addli  r29, r29, REGSIZE }
  37         { st    r29, r1; addli  r29, r29, REGSIZE }
  38         { st    r29, r2; addli  r29, r29, REGSIZE }
  39         { st    r29, r3; addli  r29, r29, REGSIZE }
  40         { st    r29, r4; addli  r29, r29, REGSIZE }
  41         { st    r29, r5; addli  r29, r29, REGSIZE }
  42         { st    r29, r6; addli  r29, r29, REGSIZE }
  43         { st    r29, r7; addli  r29, r29, REGSIZE }
  44         { st    r29, r8; addli  r29, r29, REGSIZE }
  45         { st    r29, r9; addli  r29, r29, REGSIZE }
  46         { st    r29, r10; addli r29, r29, REGSIZE }
  47         .endm
  48
  49         .macro  MCOUNT_RESTORE_REGS
  50         addli   r29, sp, (2 * REGSIZE)
  51         { ld    r0, r29; addli  r29, r29, REGSIZE }
  52         { ld    r1, r29; addli  r29, r29, REGSIZE }
  53         { ld    r2, r29; addli  r29, r29, REGSIZE }
  54         { ld    r3, r29; addli  r29, r29, REGSIZE }
  55         { ld    r4, r29; addli  r29, r29, REGSIZE }
  56         { ld    r5, r29; addli  r29, r29, REGSIZE }
  57         { ld    r6, r29; addli  r29, r29, REGSIZE }
  58         { ld    r7, r29; addli  r29, r29, REGSIZE }
  59         { ld    r8, r29; addli  r29, r29, REGSIZE }
  60         { ld    r9, r29; addli  r29, r29, REGSIZE }
  61         { ld    r10, r29; addli lr, sp, (13 * REGSIZE) }
  62         { ld    lr, lr;  addli  sp, sp, (14 * REGSIZE) }
  63         .endm
  64
  65         .macro  RETURN_BACK
  66         { move  r12, lr; move   lr, r10 }
  67         jrp     r12
  68         .endm
  69
  70 #ifdef CONFIG_DYNAMIC_FTRACE
  71
  72         .align  64
  73 STD_ENTRY(__mcount)
  74 __mcount:
  75         j       ftrace_stub
  76 STD_ENDPROC(__mcount)
  77
  78         .align  64
  79 STD_ENTRY(ftrace_caller)
  80         MCOUNT_SAVE_REGS
  81
  82         /* arg1: self return address */
  83         /* arg2: parent's return address */
  84         { move  r0, lr; move    r1, r10 }
  85
  86         .global ftrace_call
  87 ftrace_call:
  88         /*
  89          * a placeholder for the call to a real tracing function, i.e.
  90          * ftrace_trace_function()
  91          */
  92         nop
  93
  94 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  95         .global ftrace_graph_call
  96 ftrace_graph_call:
  97         /*
  98          * a placeholder for the call to a real tracing function, i.e.
  99          * ftrace_graph_caller()
 100          */
 101         nop
 102 #endif
 103         MCOUNT_RESTORE_REGS
 104         .global ftrace_stub
 105 ftrace_stub:
 106         RETURN_BACK
 107 STD_ENDPROC(ftrace_caller)
 108
 109 #else /* ! CONFIG_DYNAMIC_FTRACE */
 110
 111         .align  64
 112 STD_ENTRY(__mcount)
 113         {
 114          moveli r11, hw2_last(ftrace_trace_function)
 115          moveli r13, hw2_last(ftrace_stub)
 116         }
 117         {
 118          shl16insli     r11, r11, hw1(ftrace_trace_function)
 119          shl16insli     r13, r13, hw1(ftrace_stub)
 120         }
 121         {
 122          shl16insli     r11, r11, hw0(ftrace_trace_function)
 123          shl16insli     r13, r13, hw0(ftrace_stub)
 124         }
 125
 126         ld      r11, r11
 127         sub     r14, r13, r11
 128         bnez    r14, static_trace
 129
 130 #ifdef  CONFIG_FUNCTION_GRAPH_TRACER
 131         moveli  r15, hw2_last(ftrace_graph_return)
 132         shl16insli      r15, r15, hw1(ftrace_graph_return)
 133         shl16insli      r15, r15, hw0(ftrace_graph_return)
 134         ld      r15, r15
 135         sub     r15, r15, r13
 136         bnez    r15, ftrace_graph_caller
 137
 138         {
 139          moveli r16, hw2_last(ftrace_graph_entry)
 140          moveli r17, hw2_last(ftrace_graph_entry_stub)
 141         }
 142         {
 143          shl16insli     r16, r16, hw1(ftrace_graph_entry)
 144          shl16insli     r17, r17, hw1(ftrace_graph_entry_stub)
 145         }
 146         {
 147          shl16insli     r16, r16, hw0(ftrace_graph_entry)
 148          shl16insli     r17, r17, hw0(ftrace_graph_entry_stub)
 149         }
 150         ld      r16, r16
 151         sub     r17, r16, r17
 152         bnez    r17, ftrace_graph_caller
 153
 154 #endif
 155         RETURN_BACK
 156
 157 static_trace:
 158         MCOUNT_SAVE_REGS
 159
 160         /* arg1: self return address */
 161         /* arg2: parent's return address */
 162         { move  r0, lr; move    r1, r10 }
 163
 164         /* call ftrace_trace_function() */
 165         jalr    r11
 166
 167         MCOUNT_RESTORE_REGS
 168
 169         .global ftrace_stub
 170 ftrace_stub:
 171         RETURN_BACK
 172 STD_ENDPROC(__mcount)
 173
 174 #endif  /* ! CONFIG_DYNAMIC_FTRACE */
 175
 176 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 177
 178 STD_ENTRY(ftrace_graph_caller)
 179 ftrace_graph_caller:
 180 #ifndef CONFIG_DYNAMIC_FTRACE
 181         MCOUNT_SAVE_REGS
 182 #endif
 183
 184         /* arg1: Get the location of the parent's return address */
 185         addi    r0, sp, 12 * REGSIZE
 186         /* arg2: Get self return address */
 187         move    r1, lr
 188
 189         jal prepare_ftrace_return
 190
 191         MCOUNT_RESTORE_REGS
 192         RETURN_BACK
 193 STD_ENDPROC(ftrace_graph_caller)
 194
 195         .global return_to_handler
 196 return_to_handler:
 197         MCOUNT_SAVE_REGS
 198
 199         jal     ftrace_return_to_handler
 200         /* restore the real parent address */
 201         move    r11, r0
 202
 203         MCOUNT_RESTORE_REGS
 204         jr      r11
 205
 206 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */