arch/x86/entry/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  *
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  *
  10  * Some of this is documented in Documentation/x86/entry_64.txt
  11  *
  12  * A note on terminology:
  13  * - iret frame:        Architecture defined interrupt frame from SS to RIP
  14  *                      at the top of the kernel process stack.
  15  *
  16  * Some macro usage:
  17  * - ENTRY/END:         Define functions in the symbol table.
  18  * - TRACE_IRQ_*:       Trace hardirq state for lock debugging.
  19  * - idtentry:          Define exception entry points.
  20  */
  21 #include <linux/linkage.h>
  22 #include <asm/segment.h>
  23 #include <asm/cache.h>
  24 #include <asm/errno.h>
  25 #include "calling.h"
  26 #include <asm/asm-offsets.h>
  27 #include <asm/msr.h>
  28 #include <asm/unistd.h>
  29 #include <asm/thread_info.h>
  30 #include <asm/hw_irq.h>
  31 #include <asm/page_types.h>
  32 #include <asm/irqflags.h>
  33 #include <asm/paravirt.h>
  34 #include <asm/percpu.h>
  35 #include <asm/asm.h>
  36 #include <asm/smap.h>
  37 #include <asm/pgtable_types.h>
  38 #include <linux/err.h>
  39
  40 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  41 #include <linux/elf-em.h>
  42 #define AUDIT_ARCH_X86_64                       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  43 #define __AUDIT_ARCH_64BIT                      0x80000000
  44 #define __AUDIT_ARCH_LE                         0x40000000
  45
  46 .code64
  47 .section .entry.text, "ax"
  48
  49 #ifdef CONFIG_PARAVIRT
  50 ENTRY(native_usergs_sysret64)
  51         swapgs
  52         sysretq
  53 ENDPROC(native_usergs_sysret64)
  54 #endif /* CONFIG_PARAVIRT */
  55
  56 .macro TRACE_IRQS_IRETQ
  57 #ifdef CONFIG_TRACE_IRQFLAGS
  58         bt      $9, EFLAGS(%rsp)                /* interrupts off? */
  59         jnc     1f
  60         TRACE_IRQS_ON
  61 1:
  62 #endif
  63 .endm
  64
  65 /*
  66  * When dynamic function tracer is enabled it will add a breakpoint
  67  * to all locations that it is about to modify, sync CPUs, update
  68  * all the code, sync CPUs, then remove the breakpoints. In this time
  69  * if lockdep is enabled, it might jump back into the debug handler
  70  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
  71  *
  72  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
  73  * make sure the stack pointer does not get reset back to the top
  74  * of the debug stack, and instead just reuses the current stack.
  75  */
  76 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
  77
  78 .macro TRACE_IRQS_OFF_DEBUG
  79         call    debug_stack_set_zero
  80         TRACE_IRQS_OFF
  81         call    debug_stack_reset
  82 .endm
  83
  84 .macro TRACE_IRQS_ON_DEBUG
  85         call    debug_stack_set_zero
  86         TRACE_IRQS_ON
  87         call    debug_stack_reset
  88 .endm
  89
  90 .macro TRACE_IRQS_IRETQ_DEBUG
  91         bt      $9, EFLAGS(%rsp)                /* interrupts off? */
  92         jnc     1f
  93         TRACE_IRQS_ON_DEBUG
  94 1:
  95 .endm
  96
  97 #else
  98 # define TRACE_IRQS_OFF_DEBUG                   TRACE_IRQS_OFF
  99 # define TRACE_IRQS_ON_DEBUG                    TRACE_IRQS_ON
 100 # define TRACE_IRQS_IRETQ_DEBUG                 TRACE_IRQS_IRETQ
 101 #endif
 102
 103 /*
 104  * 64-bit SYSCALL instruction entry. Up to 6 arguments in registers.
 105  *
 106  * This is the only entry point used for 64-bit system calls.  The
 107  * hardware interface is reasonably well designed and the register to
 108  * argument mapping Linux uses fits well with the registers that are
 109  * available when SYSCALL is used.
 110  *
 111  * SYSCALL instructions can be found inlined in libc implementations as
 112  * well as some other programs and libraries.  There are also a handful
 113  * of SYSCALL instructions in the vDSO used, for example, as a
 114  * clock_gettimeofday fallback.
 115  *
 116  * 64-bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
 117  * then loads new ss, cs, and rip from previously programmed MSRs.
 118  * rflags gets masked by a value from another MSR (so CLD and CLAC
 119  * are not needed). SYSCALL does not save anything on the stack
 120  * and does not change rsp.
 121  *
 122  * Registers on entry:
 123  * rax  system call number
 124  * rcx  return address
 125  * r11  saved rflags (note: r11 is callee-clobbered register in C ABI)
 126  * rdi  arg0
 127  * rsi  arg1
 128  * rdx  arg2
 129  * r10  arg3 (needs to be moved to rcx to conform to C ABI)
 130  * r8   arg4
 131  * r9   arg5
 132  * (note: r12-r15, rbp, rbx are callee-preserved in C ABI)
 133  *
 134  * Only called from user space.
 135  *
 136  * When user can change pt_regs->foo always force IRET. That is because
 137  * it deals with uncanonical addresses better. SYSRET has trouble
 138  * with them due to bugs in both AMD and Intel CPUs.
 139  */
 140
 141 ENTRY(entry_SYSCALL_64)
 142         /*
 143          * Interrupts are off on entry.
 144          * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
 145          * it is too small to ever cause noticeable irq latency.
 146          */
 147         SWAPGS_UNSAFE_STACK
 148         /*
 149          * A hypervisor implementation might want to use a label
 150          * after the swapgs, so that it can do the swapgs
 151          * for the guest and jump here on syscall.
 152          */
 153 GLOBAL(entry_SYSCALL_64_after_swapgs)
 154
 155         movq    %rsp, PER_CPU_VAR(rsp_scratch)
 156         movq    PER_CPU_VAR(cpu_current_top_of_stack), %rsp
 157
 158         TRACE_IRQS_OFF
 159
 160         /* Construct struct pt_regs on stack */
 161         pushq   $__USER_DS                      /* pt_regs->ss */
 162         pushq   PER_CPU_VAR(rsp_scratch)        /* pt_regs->sp */
 163         pushq   %r11                            /* pt_regs->flags */
 164         pushq   $__USER_CS                      /* pt_regs->cs */
 165         pushq   %rcx                            /* pt_regs->ip */
 166         pushq   %rax                            /* pt_regs->orig_ax */
 167         pushq   %rdi                            /* pt_regs->di */
 168         pushq   %rsi                            /* pt_regs->si */
 169         pushq   %rdx                            /* pt_regs->dx */
 170         pushq   %rcx                            /* pt_regs->cx */
 171         pushq   $-ENOSYS                        /* pt_regs->ax */
 172         pushq   %r8                             /* pt_regs->r8 */
 173         pushq   %r9                             /* pt_regs->r9 */
 174         pushq   %r10                            /* pt_regs->r10 */
 175         pushq   %r11                            /* pt_regs->r11 */
 176         sub     $(6*8), %rsp                    /* pt_regs->bp, bx, r12-15 not saved */
 177
 178         /*
 179          * If we need to do entry work or if we guess we'll need to do
 180          * exit work, go straight to the slow path.
 181          */
 182         testl   $_TIF_WORK_SYSCALL_ENTRY|_TIF_ALLWORK_MASK, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
 183         jnz     entry_SYSCALL64_slow_path
 184
 185 entry_SYSCALL_64_fastpath:
 186         /*
 187          * Easy case: enable interrupts and issue the syscall.  If the syscall
 188          * needs pt_regs, we'll call a stub that disables interrupts again
 189          * and jumps to the slow path.
 190          */
 191         TRACE_IRQS_ON
 192         ENABLE_INTERRUPTS(CLBR_NONE)
 193 #if __SYSCALL_MASK == ~0
 194         cmpq    $__NR_syscall_max, %rax
 195 #else
 196         andl    $__SYSCALL_MASK, %eax
 197         cmpl    $__NR_syscall_max, %eax
 198 #endif
 199         ja      1f                              /* return -ENOSYS (already in pt_regs->ax) */
 200         movq    %r10, %rcx
 201
 202         /*
 203          * This call instruction is handled specially in stub_ptregs_64.
 204          * It might end up jumping to the slow path.  If it jumps, RAX
 205          * and all argument registers are clobbered.
 206          */
 207         call    *sys_call_table(, %rax, 8)
 208 .Lentry_SYSCALL_64_after_fastpath_call:
 209
 210         movq    %rax, RAX(%rsp)
 211 1:
 212
 213         /*
 214          * If we get here, then we know that pt_regs is clean for SYSRET64.
 215          * If we see that no exit work is required (which we are required
 216          * to check with IRQs off), then we can go straight to SYSRET64.
 217          */
 218         DISABLE_INTERRUPTS(CLBR_NONE)
 219         TRACE_IRQS_OFF
 220         testl   $_TIF_ALLWORK_MASK, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
 221         jnz     1f
 222
 223         LOCKDEP_SYS_EXIT
 224         TRACE_IRQS_ON           /* user mode is traced as IRQs on */
 225         movq    RIP(%rsp), %rcx
 226         movq    EFLAGS(%rsp), %r11
 227         RESTORE_C_REGS_EXCEPT_RCX_R11
 228         movq    RSP(%rsp), %rsp
 229         USERGS_SYSRET64
 230
 231 1:
 232         /*
 233          * The fast path looked good when we started, but something changed
 234          * along the way and we need to switch to the slow path.  Calling
 235          * raise(3) will trigger this, for example.  IRQs are off.
 236          */
 237         TRACE_IRQS_ON
 238         ENABLE_INTERRUPTS(CLBR_NONE)
 239         SAVE_EXTRA_REGS
 240         movq    %rsp, %rdi
 241         call    syscall_return_slowpath /* returns with IRQs disabled */
 242         jmp     return_from_SYSCALL_64
 243
 244 entry_SYSCALL64_slow_path:
 245         /* IRQs are off. */
 246         SAVE_EXTRA_REGS
 247         movq    %rsp, %rdi
 248         call    do_syscall_64           /* returns with IRQs disabled */
 249
 250 return_from_SYSCALL_64:
 251         RESTORE_EXTRA_REGS
 252         TRACE_IRQS_IRETQ                /* we're about to change IF */
 253
 254         /*
 255          * Try to use SYSRET instead of IRET if we're returning to
 256          * a completely clean 64-bit userspace context.
 257          */
 258         movq    RCX(%rsp), %rcx
 259         movq    RIP(%rsp), %r11
 260         cmpq    %rcx, %r11                      /* RCX == RIP */
 261         jne     opportunistic_sysret_failed
 262
 263         /*
 264          * On Intel CPUs, SYSRET with non-canonical RCX/RIP will #GP
 265          * in kernel space.  This essentially lets the user take over
 266          * the kernel, since userspace controls RSP.
 267          *
 268          * If width of "canonical tail" ever becomes variable, this will need
 269          * to be updated to remain correct on both old and new CPUs.
 270          */
 271         .ifne __VIRTUAL_MASK_SHIFT - 47
 272         .error "virtual address width changed -- SYSRET checks need update"
 273         .endif
 274
 275         /* Change top 16 bits to be the sign-extension of 47th bit */
 276         shl     $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
 277         sar     $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
 278
 279         /* If this changed %rcx, it was not canonical */
 280         cmpq    %rcx, %r11
 281         jne     opportunistic_sysret_failed
 282
 283         cmpq    $__USER_CS, CS(%rsp)            /* CS must match SYSRET */
 284         jne     opportunistic_sysret_failed
 285
 286         movq    R11(%rsp), %r11
 287         cmpq    %r11, EFLAGS(%rsp)              /* R11 == RFLAGS */
 288         jne     opportunistic_sysret_failed
 289
 290         /*
 291          * SYSRET can't restore RF.  SYSRET can restore TF, but unlike IRET,
 292          * restoring TF results in a trap from userspace immediately after
 293          * SYSRET.  This would cause an infinite loop whenever #DB happens
 294          * with register state that satisfies the opportunistic SYSRET
 295          * conditions.  For example, single-stepping this user code:
 296          *
 297          *           movq       $stuck_here, %rcx
 298          *           pushfq
 299          *           popq %r11
 300          *   stuck_here:
 301          *
 302          * would never get past 'stuck_here'.
 303          */
 304         testq   $(X86_EFLAGS_RF|X86_EFLAGS_TF), %r11
 305         jnz     opportunistic_sysret_failed
 306
 307         /* nothing to check for RSP */
 308
 309         cmpq    $__USER_DS, SS(%rsp)            /* SS must match SYSRET */
 310         jne     opportunistic_sysret_failed
 311
 312         /*
 313          * We win! This label is here just for ease of understanding
 314          * perf profiles. Nothing jumps here.
 315          */
 316 syscall_return_via_sysret:
 317         /* rcx and r11 are already restored (see code above) */
 318         RESTORE_C_REGS_EXCEPT_RCX_R11
 319         movq    RSP(%rsp), %rsp
 320         USERGS_SYSRET64
 321
 322 opportunistic_sysret_failed:
 323         SWAPGS
 324         jmp     restore_c_regs_and_iret
 325 END(entry_SYSCALL_64)
 326
 327 ENTRY(stub_ptregs_64)
 328         /*
 329          * Syscalls marked as needing ptregs land here.
 330          * If we are on the fast path, we need to save the extra regs,
 331          * which we achieve by trying again on the slow path.  If we are on
 332          * the slow path, the extra regs are already saved.
 333          *
 334          * RAX stores a pointer to the C function implementing the syscall.
 335          * IRQs are on.
 336          */
 337         cmpq    $.Lentry_SYSCALL_64_after_fastpath_call, (%rsp)
 338         jne     1f
 339
 340         /*
 341          * Called from fast path -- disable IRQs again, pop return address
 342          * and jump to slow path
 343          */
 344         DISABLE_INTERRUPTS(CLBR_NONE)
 345         TRACE_IRQS_OFF
 346         popq    %rax
 347         jmp     entry_SYSCALL64_slow_path
 348
 349 1:
 350         /* Called from C */
 351         jmp     *%rax                           /* called from C */
 352 END(stub_ptregs_64)
 353
 354 .macro ptregs_stub func
 355 ENTRY(ptregs_\func)
 356         leaq    \func(%rip), %rax
 357         jmp     stub_ptregs_64
 358 END(ptregs_\func)
 359 .endm
 360
 361 /* Instantiate ptregs_stub for each ptregs-using syscall */
 362 #define __SYSCALL_64_QUAL_(sym)
 363 #define __SYSCALL_64_QUAL_ptregs(sym) ptregs_stub sym
 364 #define __SYSCALL_64(nr, sym, qual) __SYSCALL_64_QUAL_##qual(sym)
 365 #include <asm/syscalls_64.h>
 366
 367 /*
 368  * A newly forked process directly context switches into this address.
 369  *
 370  * rdi: prev task we switched from
 371  */
 372 ENTRY(ret_from_fork)
 373         LOCK ; btr $TIF_FORK, TI_flags(%r8)
 374
 375         call    schedule_tail                   /* rdi: 'prev' task parameter */
 376
 377         testb   $3, CS(%rsp)                    /* from kernel_thread? */
 378         jnz     1f
 379
 380         /*
 381          * We came from kernel_thread.  This code path is quite twisted, and
 382          * someone should clean it up.
 383          *
 384          * copy_thread_tls stashes the function pointer in RBX and the
 385          * parameter to be passed in RBP.  The called function is permitted
 386          * to call do_execve and thereby jump to user mode.
 387          */
 388         movq    RBP(%rsp), %rdi
 389         call    *RBX(%rsp)
 390         movl    $0, RAX(%rsp)
 391
 392         /*
 393          * Fall through as though we're exiting a syscall.  This makes a
 394          * twisted sort of sense if we just called do_execve.
 395          */
 396
 397 1:
 398         movq    %rsp, %rdi
 399         call    syscall_return_slowpath /* returns with IRQs disabled */
 400         TRACE_IRQS_ON                   /* user mode is traced as IRQS on */
 401         SWAPGS
 402         jmp     restore_regs_and_iret
 403 END(ret_from_fork)
 404
 405 /*
 406  * Build the entry stubs with some assembler magic.
 407  * We pack 1 stub into every 8-byte block.
 408  */
 409         .align 8
 410 ENTRY(irq_entries_start)
 411     vector=FIRST_EXTERNAL_VECTOR
 412     .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
 413         pushq   $(~vector+0x80)                 /* Note: always in signed byte range */
 414     vector=vector+1
 415         jmp     common_interrupt
 416         .align  8
 417     .endr
 418 END(irq_entries_start)
 419
 420 /*
 421  * Interrupt entry/exit.
 422  *
 423  * Interrupt entry points save only callee clobbered registers in fast path.
 424  *
 425  * Entry runs with interrupts off.
 426  */
 427
 428 /* 0(%rsp): ~(interrupt number) */
 429         .macro interrupt func
 430         cld
 431         ALLOC_PT_GPREGS_ON_STACK
 432         SAVE_C_REGS
 433         SAVE_EXTRA_REGS
 434
 435         testb   $3, CS(%rsp)
 436         jz      1f
 437
 438         /*
 439          * IRQ from user mode.  Switch to kernel gsbase and inform context
 440          * tracking that we're in kernel mode.
 441          */
 442         SWAPGS
 443
 444         /*
 445          * We need to tell lockdep that IRQs are off.  We can't do this until
 446          * we fix gsbase, and we should do it before enter_from_user_mode
 447          * (which can take locks).  Since TRACE_IRQS_OFF idempotent,
 448          * the simplest way to handle it is to just call it twice if
 449          * we enter from user mode.  There's no reason to optimize this since
 450          * TRACE_IRQS_OFF is a no-op if lockdep is off.
 451          */
 452         TRACE_IRQS_OFF
 453
 454         CALL_enter_from_user_mode
 455
 456 1:
 457         /*
 458          * Save previous stack pointer, optionally switch to interrupt stack.
 459          * irq_count is used to check if a CPU is already on an interrupt stack
 460          * or not. While this is essentially redundant with preempt_count it is
 461          * a little cheaper to use a separate counter in the PDA (short of
 462          * moving irq_enter into assembly, which would be too much work)
 463          */
 464         movq    %rsp, %rdi
 465         incl    PER_CPU_VAR(irq_count)
 466         cmovzq  PER_CPU_VAR(irq_stack_ptr), %rsp
 467         pushq   %rdi
 468         /* We entered an interrupt context - irqs are off: */
 469         TRACE_IRQS_OFF
 470
 471         call    \func   /* rdi points to pt_regs */
 472         .endm
 473
 474         /*
 475          * The interrupt stubs push (~vector+0x80) onto the stack and
 476          * then jump to common_interrupt.
 477          */
 478         .p2align CONFIG_X86_L1_CACHE_SHIFT
 479 common_interrupt:
 480         ASM_CLAC
 481         addq    $-0x80, (%rsp)                  /* Adjust vector to [-256, -1] range */
 482         interrupt do_IRQ
 483         /* 0(%rsp): old RSP */
 484 ret_from_intr:
 485         DISABLE_INTERRUPTS(CLBR_NONE)
 486         TRACE_IRQS_OFF
 487         decl    PER_CPU_VAR(irq_count)
 488
 489         /* Restore saved previous stack */
 490         popq    %rsp
 491
 492         testb   $3, CS(%rsp)
 493         jz      retint_kernel
 494
 495         /* Interrupt came from user space */
 496 GLOBAL(retint_user)
 497         mov     %rsp,%rdi
 498         call    prepare_exit_to_usermode
 499         TRACE_IRQS_IRETQ
 500         SWAPGS
 501         jmp     restore_regs_and_iret
 502
 503 /* Returning to kernel space */
 504 retint_kernel:
 505 #ifdef CONFIG_PREEMPT
 506         /* Interrupts are off */
 507         /* Check if we need preemption */
 508         bt      $9, EFLAGS(%rsp)                /* were interrupts off? */
 509         jnc     1f
 510 0:      cmpl    $0, PER_CPU_VAR(__preempt_count)
 511         jnz     1f
 512         call    preempt_schedule_irq
 513         jmp     0b
 514 1:
 515 #endif
 516         /*
 517          * The iretq could re-enable interrupts:
 518          */
 519         TRACE_IRQS_IRETQ
 520
 521 /*
 522  * At this label, code paths which return to kernel and to user,
 523  * which come from interrupts/exception and from syscalls, merge.
 524  */
 525 GLOBAL(restore_regs_and_iret)
 526         RESTORE_EXTRA_REGS
 527 restore_c_regs_and_iret:
 528         RESTORE_C_REGS
 529         REMOVE_PT_GPREGS_FROM_STACK 8
 530         INTERRUPT_RETURN
 531
 532 ENTRY(native_iret)
 533         /*
 534          * Are we returning to a stack segment from the LDT?  Note: in
 535          * 64-bit mode SS:RSP on the exception stack is always valid.
 536          */
 537 #ifdef CONFIG_X86_ESPFIX64
 538         testb   $4, (SS-RIP)(%rsp)
 539         jnz     native_irq_return_ldt
 540 #endif
 541
 542 .global native_irq_return_iret
 543 native_irq_return_iret:
 544         /*
 545          * This may fault.  Non-paranoid faults on return to userspace are
 546          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 547          * Double-faults due to espfix64 are handled in do_double_fault.
 548          * Other faults here are fatal.
 549          */
 550         iretq
 551
 552 #ifdef CONFIG_X86_ESPFIX64
 553 native_irq_return_ldt:
 554         pushq   %rax
 555         pushq   %rdi
 556         SWAPGS
 557         movq    PER_CPU_VAR(espfix_waddr), %rdi
 558         movq    %rax, (0*8)(%rdi)               /* RAX */
 559         movq    (2*8)(%rsp), %rax               /* RIP */
 560         movq    %rax, (1*8)(%rdi)
 561         movq    (3*8)(%rsp), %rax               /* CS */
 562         movq    %rax, (2*8)(%rdi)
 563         movq    (4*8)(%rsp), %rax               /* RFLAGS */
 564         movq    %rax, (3*8)(%rdi)
 565         movq    (6*8)(%rsp), %rax               /* SS */
 566         movq    %rax, (5*8)(%rdi)
 567         movq    (5*8)(%rsp), %rax               /* RSP */
 568         movq    %rax, (4*8)(%rdi)
 569         andl    $0xffff0000, %eax
 570         popq    %rdi
 571         orq     PER_CPU_VAR(espfix_stack), %rax
 572         SWAPGS
 573         movq    %rax, %rsp
 574         popq    %rax
 575         jmp     native_irq_return_iret
 576 #endif
 577 END(common_interrupt)
 578
 579 /*
 580  * APIC interrupts.
 581  */
 582 .macro apicinterrupt3 num sym do_sym
 583 ENTRY(\sym)
 584         ASM_CLAC
 585         pushq   $~(\num)
 586 .Lcommon_\sym:
 587         interrupt \do_sym
 588         jmp     ret_from_intr
 589 END(\sym)
 590 .endm
 591
 592 #ifdef CONFIG_TRACING
 593 #define trace(sym) trace_##sym
 594 #define smp_trace(sym) smp_trace_##sym
 595
 596 .macro trace_apicinterrupt num sym
 597 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
 598 .endm
 599 #else
 600 .macro trace_apicinterrupt num sym do_sym
 601 .endm
 602 #endif
 603
 604 /* Make sure APIC interrupt handlers end up in the irqentry section: */
 605 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
 606 # define PUSH_SECTION_IRQENTRY  .pushsection .irqentry.text, "ax"
 607 # define POP_SECTION_IRQENTRY   .popsection
 608 #else
 609 # define PUSH_SECTION_IRQENTRY
 610 # define POP_SECTION_IRQENTRY
 611 #endif
 612
 613 .macro apicinterrupt num sym do_sym
 614 PUSH_SECTION_IRQENTRY
 615 apicinterrupt3 \num \sym \do_sym
 616 trace_apicinterrupt \num \sym
 617 POP_SECTION_IRQENTRY
 618 .endm
 619
 620 #ifdef CONFIG_SMP
 621 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR          irq_move_cleanup_interrupt      smp_irq_move_cleanup_interrupt
 622 apicinterrupt3 REBOOT_VECTOR                    reboot_interrupt                smp_reboot_interrupt
 623 #endif
 624
 625 #ifdef CONFIG_X86_UV
 626 apicinterrupt3 UV_BAU_MESSAGE                   uv_bau_message_intr1            uv_bau_message_interrupt
 627 #endif
 628
 629 apicinterrupt LOCAL_TIMER_VECTOR                apic_timer_interrupt            smp_apic_timer_interrupt
 630 apicinterrupt X86_PLATFORM_IPI_VECTOR           x86_platform_ipi                smp_x86_platform_ipi
 631
 632 #ifdef CONFIG_HAVE_KVM
 633 apicinterrupt3 POSTED_INTR_VECTOR               kvm_posted_intr_ipi             smp_kvm_posted_intr_ipi
 634 apicinterrupt3 POSTED_INTR_WAKEUP_VECTOR        kvm_posted_intr_wakeup_ipi      smp_kvm_posted_intr_wakeup_ipi
 635 #endif
 636
 637 #ifdef CONFIG_X86_MCE_THRESHOLD
 638 apicinterrupt THRESHOLD_APIC_VECTOR             threshold_interrupt             smp_threshold_interrupt
 639 #endif
 640
 641 #ifdef CONFIG_X86_MCE_AMD
 642 apicinterrupt DEFERRED_ERROR_VECTOR             deferred_error_interrupt        smp_deferred_error_interrupt
 643 #endif
 644
 645 #ifdef CONFIG_X86_THERMAL_VECTOR
 646 apicinterrupt THERMAL_APIC_VECTOR               thermal_interrupt               smp_thermal_interrupt
 647 #endif
 648
 649 #ifdef CONFIG_SMP
 650 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR       call_function_single_interrupt  smp_call_function_single_interrupt
 651 apicinterrupt CALL_FUNCTION_VECTOR              call_function_interrupt         smp_call_function_interrupt
 652 apicinterrupt RESCHEDULE_VECTOR                 reschedule_interrupt            smp_reschedule_interrupt
 653 #endif
 654
 655 apicinterrupt ERROR_APIC_VECTOR                 error_interrupt                 smp_error_interrupt
 656 apicinterrupt SPURIOUS_APIC_VECTOR              spurious_interrupt              smp_spurious_interrupt
 657
 658 #ifdef CONFIG_IRQ_WORK
 659 apicinterrupt IRQ_WORK_VECTOR                   irq_work_interrupt              smp_irq_work_interrupt
 660 #endif
 661
 662 /*
 663  * Exception entry points.
 664  */
 665 #define CPU_TSS_IST(x) PER_CPU_VAR(cpu_tss) + (TSS_ist + ((x) - 1) * 8)
 666
 667 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
 668 ENTRY(\sym)
 669         /* Sanity check */
 670         .if \shift_ist != -1 && \paranoid == 0
 671         .error "using shift_ist requires paranoid=1"
 672         .endif
 673
 674         ASM_CLAC
 675         PARAVIRT_ADJUST_EXCEPTION_FRAME
 676
 677         .ifeq \has_error_code
 678         pushq   $-1                             /* ORIG_RAX: no syscall to restart */
 679         .endif
 680
 681         ALLOC_PT_GPREGS_ON_STACK
 682
 683         .if \paranoid
 684         .if \paranoid == 1
 685         testb   $3, CS(%rsp)                    /* If coming from userspace, switch stacks */
 686         jnz     1f
 687         .endif
 688         call    paranoid_entry
 689         .else
 690         call    error_entry
 691         .endif
 692         /* returned flag: ebx=0: need swapgs on exit, ebx=1: don't need it */
 693
 694         .if \paranoid
 695         .if \shift_ist != -1
 696         TRACE_IRQS_OFF_DEBUG                    /* reload IDT in case of recursion */
 697         .else
 698         TRACE_IRQS_OFF
 699         .endif
 700         .endif
 701
 702         movq    %rsp, %rdi                      /* pt_regs pointer */
 703
 704         .if \has_error_code
 705         movq    ORIG_RAX(%rsp), %rsi            /* get error code */
 706         movq    $-1, ORIG_RAX(%rsp)             /* no syscall to restart */
 707         .else
 708         xorl    %esi, %esi                      /* no error code */
 709         .endif
 710
 711         .if \shift_ist != -1
 712         subq    $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
 713         .endif
 714
 715         call    \do_sym
 716
 717         .if \shift_ist != -1
 718         addq    $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
 719         .endif
 720
 721         /* these procedures expect "no swapgs" flag in ebx */
 722         .if \paranoid
 723         jmp     paranoid_exit
 724         .else
 725         jmp     error_exit
 726         .endif
 727
 728         .if \paranoid == 1
 729         /*
 730          * Paranoid entry from userspace.  Switch stacks and treat it
 731          * as a normal entry.  This means that paranoid handlers
 732          * run in real process context if user_mode(regs).
 733          */
 734 1:
 735         call    error_entry
 736
 737
 738         movq    %rsp, %rdi                      /* pt_regs pointer */
 739         call    sync_regs
 740         movq    %rax, %rsp                      /* switch stack */
 741
 742         movq    %rsp, %rdi                      /* pt_regs pointer */
 743
 744         .if \has_error_code
 745         movq    ORIG_RAX(%rsp), %rsi            /* get error code */
 746         movq    $-1, ORIG_RAX(%rsp)             /* no syscall to restart */
 747         .else
 748         xorl    %esi, %esi                      /* no error code */
 749         .endif
 750
 751         call    \do_sym
 752
 753         jmp     error_exit                      /* %ebx: no swapgs flag */
 754         .endif
 755 END(\sym)
 756 .endm
 757
 758 #ifdef CONFIG_TRACING
 759 .macro trace_idtentry sym do_sym has_error_code:req
 760 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
 761 idtentry \sym \do_sym has_error_code=\has_error_code
 762 .endm
 763 #else
 764 .macro trace_idtentry sym do_sym has_error_code:req
 765 idtentry \sym \do_sym has_error_code=\has_error_code
 766 .endm
 767 #endif
 768
 769 idtentry divide_error                   do_divide_error                 has_error_code=0
 770 idtentry overflow                       do_overflow                     has_error_code=0
 771 idtentry bounds                         do_bounds                       has_error_code=0
 772 idtentry invalid_op                     do_invalid_op                   has_error_code=0
 773 idtentry device_not_available           do_device_not_available         has_error_code=0
 774 idtentry double_fault                   do_double_fault                 has_error_code=1 paranoid=2
 775 idtentry coprocessor_segment_overrun    do_coprocessor_segment_overrun  has_error_code=0
 776 idtentry invalid_TSS                    do_invalid_TSS                  has_error_code=1
 777 idtentry segment_not_present            do_segment_not_present          has_error_code=1
 778 idtentry spurious_interrupt_bug         do_spurious_interrupt_bug       has_error_code=0
 779 idtentry coprocessor_error              do_coprocessor_error            has_error_code=0
 780 idtentry alignment_check                do_alignment_check              has_error_code=1
 781 idtentry simd_coprocessor_error         do_simd_coprocessor_error       has_error_code=0
 782
 783
 784         /*
 785          * Reload gs selector with exception handling
 786          * edi:  new selector
 787          */
 788 ENTRY(native_load_gs_index)
 789         pushfq
 790         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
 791         SWAPGS
 792 .Lgs_change:
 793         movl    %edi, %gs
 794 2:      ALTERNATIVE "", "mfence", X86_BUG_SWAPGS_FENCE
 795         SWAPGS
 796         popfq
 797         ret
 798 END(native_load_gs_index)
 799
 800         _ASM_EXTABLE(.Lgs_change, bad_gs)
 801         .section .fixup, "ax"
 802         /* running with kernelgs */
 803 bad_gs:
 804         SWAPGS                                  /* switch back to user gs */
 805 .macro ZAP_GS
 806         /* This can't be a string because the preprocessor needs to see it. */
 807         movl $__USER_DS, %eax
 808         movl %eax, %gs
 809 .endm
 810         ALTERNATIVE "", "ZAP_GS", X86_BUG_NULL_SEG
 811         xorl    %eax, %eax
 812         movl    %eax, %gs
 813         jmp     2b
 814         .previous
 815
 816 /* Call softirq on interrupt stack. Interrupts are off. */
 817 ENTRY(do_softirq_own_stack)
 818         pushq   %rbp
 819         mov     %rsp, %rbp
 820         incl    PER_CPU_VAR(irq_count)
 821         cmove   PER_CPU_VAR(irq_stack_ptr), %rsp
 822         push    %rbp                            /* frame pointer backlink */
 823         call    __do_softirq
 824         leaveq
 825         decl    PER_CPU_VAR(irq_count)
 826         ret
 827 END(do_softirq_own_stack)
 828
 829 #ifdef CONFIG_XEN
 830 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
 831
 832 /*
 833  * A note on the "critical region" in our callback handler.
 834  * We want to avoid stacking callback handlers due to events occurring
 835  * during handling of the last event. To do this, we keep events disabled
 836  * until we've done all processing. HOWEVER, we must enable events before
 837  * popping the stack frame (can't be done atomically) and so it would still
 838  * be possible to get enough handler activations to overflow the stack.
 839  * Although unlikely, bugs of that kind are hard to track down, so we'd
 840  * like to avoid the possibility.
 841  * So, on entry to the handler we detect whether we interrupted an
 842  * existing activation in its critical region -- if so, we pop the current
 843  * activation and restart the handler using the previous one.
 844  */
 845 ENTRY(xen_do_hypervisor_callback)               /* do_hypervisor_callback(struct *pt_regs) */
 846
 847 /*
 848  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
 849  * see the correct pointer to the pt_regs
 850  */
 851         movq    %rdi, %rsp                      /* we don't return, adjust the stack frame */
 852 11:     incl    PER_CPU_VAR(irq_count)
 853         movq    %rsp, %rbp
 854         cmovzq  PER_CPU_VAR(irq_stack_ptr), %rsp
 855         pushq   %rbp                            /* frame pointer backlink */
 856         call    xen_evtchn_do_upcall
 857         popq    %rsp
 858         decl    PER_CPU_VAR(irq_count)
 859 #ifndef CONFIG_PREEMPT
 860         call    xen_maybe_preempt_hcall
 861 #endif
 862         jmp     error_exit
 863 END(xen_do_hypervisor_callback)
 864
 865 /*
 866  * Hypervisor uses this for application faults while it executes.
 867  * We get here for two reasons:
 868  *  1. Fault while reloading DS, ES, FS or GS
 869  *  2. Fault while executing IRET
 870  * Category 1 we do not need to fix up as Xen has already reloaded all segment
 871  * registers that could be reloaded and zeroed the others.
 872  * Category 2 we fix up by killing the current process. We cannot use the
 873  * normal Linux return path in this case because if we use the IRET hypercall
 874  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 875  * We distinguish between categories by comparing each saved segment register
 876  * with its current contents: any discrepancy means we in category 1.
 877  */
 878 ENTRY(xen_failsafe_callback)
 879         movl    %ds, %ecx
 880         cmpw    %cx, 0x10(%rsp)
 881         jne     1f
 882         movl    %es, %ecx
 883         cmpw    %cx, 0x18(%rsp)
 884         jne     1f
 885         movl    %fs, %ecx
 886         cmpw    %cx, 0x20(%rsp)
 887         jne     1f
 888         movl    %gs, %ecx
 889         cmpw    %cx, 0x28(%rsp)
 890         jne     1f
 891         /* All segments match their saved values => Category 2 (Bad IRET). */
 892         movq    (%rsp), %rcx
 893         movq    8(%rsp), %r11
 894         addq    $0x30, %rsp
 895         pushq   $0                              /* RIP */
 896         pushq   %r11
 897         pushq   %rcx
 898         jmp     general_protection
 899 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
 900         movq    (%rsp), %rcx
 901         movq    8(%rsp), %r11
 902         addq    $0x30, %rsp
 903         pushq   $-1 /* orig_ax = -1 => not a system call */
 904         ALLOC_PT_GPREGS_ON_STACK
 905         SAVE_C_REGS
 906         SAVE_EXTRA_REGS
 907         jmp     error_exit
 908 END(xen_failsafe_callback)
 909
 910 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
 911         xen_hvm_callback_vector xen_evtchn_do_upcall
 912
 913 #endif /* CONFIG_XEN */
 914
 915 #if IS_ENABLED(CONFIG_HYPERV)
 916 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
 917         hyperv_callback_vector hyperv_vector_handler
 918 #endif /* CONFIG_HYPERV */
 919
 920 idtentry debug                  do_debug                has_error_code=0        paranoid=1 shift_ist=DEBUG_STACK
 921 idtentry int3                   do_int3                 has_error_code=0        paranoid=1 shift_ist=DEBUG_STACK
 922 idtentry stack_segment          do_stack_segment        has_error_code=1
 923
 924 #ifdef CONFIG_XEN
 925 idtentry xen_debug              do_debug                has_error_code=0
 926 idtentry xen_int3               do_int3                 has_error_code=0
 927 idtentry xen_stack_segment      do_stack_segment        has_error_code=1
 928 #endif
 929
 930 idtentry general_protection     do_general_protection   has_error_code=1
 931 trace_idtentry page_fault       do_page_fault           has_error_code=1
 932
 933 #ifdef CONFIG_KVM_GUEST
 934 idtentry async_page_fault       do_async_page_fault     has_error_code=1
 935 #endif
 936
 937 #ifdef CONFIG_X86_MCE
 938 idtentry machine_check                                  has_error_code=0        paranoid=1 do_sym=*machine_check_vector(%rip)
 939 #endif
 940
 941 /*
 942  * Save all registers in pt_regs, and switch gs if needed.
 943  * Use slow, but surefire "are we in kernel?" check.
 944  * Return: ebx=0: need swapgs on exit, ebx=1: otherwise
 945  */
 946 ENTRY(paranoid_entry)
 947         cld
 948         SAVE_C_REGS 8
 949         SAVE_EXTRA_REGS 8
 950         movl    $1, %ebx
 951         movl    $MSR_GS_BASE, %ecx
 952         rdmsr
 953         testl   %edx, %edx
 954         js      1f                              /* negative -> in kernel */
 955         SWAPGS
 956         xorl    %ebx, %ebx
 957 1:      ret
 958 END(paranoid_entry)
 959
 960 /*
 961  * "Paranoid" exit path from exception stack.  This is invoked
 962  * only on return from non-NMI IST interrupts that came
 963  * from kernel space.
 964  *
 965  * We may be returning to very strange contexts (e.g. very early
 966  * in syscall entry), so checking for preemption here would
 967  * be complicated.  Fortunately, we there's no good reason
 968  * to try to handle preemption here.
 969  *
 970  * On entry, ebx is "no swapgs" flag (1: don't need swapgs, 0: need it)
 971  */
 972 ENTRY(paranoid_exit)
 973         DISABLE_INTERRUPTS(CLBR_NONE)
 974         TRACE_IRQS_OFF_DEBUG
 975         testl   %ebx, %ebx                      /* swapgs needed? */
 976         jnz     paranoid_exit_no_swapgs
 977         TRACE_IRQS_IRETQ
 978         SWAPGS_UNSAFE_STACK
 979         jmp     paranoid_exit_restore
 980 paranoid_exit_no_swapgs:
 981         TRACE_IRQS_IRETQ_DEBUG
 982 paranoid_exit_restore:
 983         RESTORE_EXTRA_REGS
 984         RESTORE_C_REGS
 985         REMOVE_PT_GPREGS_FROM_STACK 8
 986         INTERRUPT_RETURN
 987 END(paranoid_exit)
 988
 989 /*
 990  * Save all registers in pt_regs, and switch gs if needed.
 991  * Return: EBX=0: came from user mode; EBX=1: otherwise
 992  */
 993 ENTRY(error_entry)
 994         cld
 995         SAVE_C_REGS 8
 996         SAVE_EXTRA_REGS 8
 997         xorl    %ebx, %ebx
 998         testb   $3, CS+8(%rsp)
 999         jz      .Lerror_kernelspace
1000
1001 .Lerror_entry_from_usermode_swapgs:
1002         /*
1003          * We entered from user mode or we're pretending to have entered
1004          * from user mode due to an IRET fault.
1005          */
1006         SWAPGS
1007
1008 .Lerror_entry_from_usermode_after_swapgs:
1009         /*
1010          * We need to tell lockdep that IRQs are off.  We can't do this until
1011          * we fix gsbase, and we should do it before enter_from_user_mode
1012          * (which can take locks).
1013          */
1014         TRACE_IRQS_OFF
1015         CALL_enter_from_user_mode
1016         ret
1017
1018 .Lerror_entry_done:
1019         TRACE_IRQS_OFF
1020         ret
1021
1022         /*
1023          * There are two places in the kernel that can potentially fault with
1024          * usergs. Handle them here.  B stepping K8s sometimes report a
1025          * truncated RIP for IRET exceptions returning to compat mode. Check
1026          * for these here too.
1027          */
1028 .Lerror_kernelspace:
1029         incl    %ebx
1030         leaq    native_irq_return_iret(%rip), %rcx
1031         cmpq    %rcx, RIP+8(%rsp)
1032         je      .Lerror_bad_iret
1033         movl    %ecx, %eax                      /* zero extend */
1034         cmpq    %rax, RIP+8(%rsp)
1035         je      .Lbstep_iret
1036         cmpq    $.Lgs_change, RIP+8(%rsp)
1037         jne     .Lerror_entry_done
1038
1039         /*
1040          * hack: .Lgs_change can fail with user gsbase.  If this happens, fix up
1041          * gsbase and proceed.  We'll fix up the exception and land in
1042          * .Lgs_change's error handler with kernel gsbase.
1043          */
1044         jmp     .Lerror_entry_from_usermode_swapgs
1045
1046 .Lbstep_iret:
1047         /* Fix truncated RIP */
1048         movq    %rcx, RIP+8(%rsp)
1049         /* fall through */
1050
1051 .Lerror_bad_iret:
1052         /*
1053          * We came from an IRET to user mode, so we have user gsbase.
1054          * Switch to kernel gsbase:
1055          */
1056         SWAPGS
1057
1058         /*
1059          * Pretend that the exception came from user mode: set up pt_regs
1060          * as if we faulted immediately after IRET and clear EBX so that
1061          * error_exit knows that we will be returning to user mode.
1062          */
1063         mov     %rsp, %rdi
1064         call    fixup_bad_iret
1065         mov     %rax, %rsp
1066         decl    %ebx
1067         jmp     .Lerror_entry_from_usermode_after_swapgs
1068 END(error_entry)
1069
1070
1071 /*
1072  * On entry, EBS is a "return to kernel mode" flag:
1073  *   1: already in kernel mode, don't need SWAPGS
1074  *   0: user gsbase is loaded, we need SWAPGS and standard preparation for return to usermode
1075  */
1076 ENTRY(error_exit)
1077         movl    %ebx, %eax
1078         DISABLE_INTERRUPTS(CLBR_NONE)
1079         TRACE_IRQS_OFF
1080         testl   %eax, %eax
1081         jnz     retint_kernel
1082         jmp     retint_user
1083 END(error_exit)
1084
1085 /* Runs on exception stack */
1086 ENTRY(nmi)
1087         /*
1088          * Fix up the exception frame if we're on Xen.
1089          * PARAVIRT_ADJUST_EXCEPTION_FRAME is guaranteed to push at most
1090          * one value to the stack on native, so it may clobber the rdx
1091          * scratch slot, but it won't clobber any of the important
1092          * slots past it.
1093          *
1094          * Xen is a different story, because the Xen frame itself overlaps
1095          * the "NMI executing" variable.
1096          */
1097         PARAVIRT_ADJUST_EXCEPTION_FRAME
1098
1099         /*
1100          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1101          * the iretq it performs will take us out of NMI context.
1102          * This means that we can have nested NMIs where the next
1103          * NMI is using the top of the stack of the previous NMI. We
1104          * can't let it execute because the nested NMI will corrupt the
1105          * stack of the previous NMI. NMI handlers are not re-entrant
1106          * anyway.
1107          *
1108          * To handle this case we do the following:
1109          *  Check the a special location on the stack that contains
1110          *  a variable that is set when NMIs are executing.
1111          *  The interrupted task's stack is also checked to see if it
1112          *  is an NMI stack.
1113          *  If the variable is not set and the stack is not the NMI
1114          *  stack then:
1115          *    o Set the special variable on the stack
1116          *    o Copy the interrupt frame into an "outermost" location on the
1117          *      stack
1118          *    o Copy the interrupt frame into an "iret" location on the stack
1119          *    o Continue processing the NMI
1120          *  If the variable is set or the previous stack is the NMI stack:
1121          *    o Modify the "iret" location to jump to the repeat_nmi
1122          *    o return back to the first NMI
1123          *
1124          * Now on exit of the first NMI, we first clear the stack variable
1125          * The NMI stack will tell any nested NMIs at that point that it is
1126          * nested. Then we pop the stack normally with iret, and if there was
1127          * a nested NMI that updated the copy interrupt stack frame, a
1128          * jump will be made to the repeat_nmi code that will handle the second
1129          * NMI.
1130          *
1131          * However, espfix prevents us from directly returning to userspace
1132          * with a single IRET instruction.  Similarly, IRET to user mode
1133          * can fault.  We therefore handle NMIs from user space like
1134          * other IST entries.
1135          */
1136
1137         /* Use %rdx as our temp variable throughout */
1138         pushq   %rdx
1139
1140         testb   $3, CS-RIP+8(%rsp)
1141         jz      .Lnmi_from_kernel
1142
1143         /*
1144          * NMI from user mode.  We need to run on the thread stack, but we
1145          * can't go through the normal entry paths: NMIs are masked, and
1146          * we don't want to enable interrupts, because then we'll end
1147          * up in an awkward situation in which IRQs are on but NMIs
1148          * are off.
1149          *
1150          * We also must not push anything to the stack before switching
1151          * stacks lest we corrupt the "NMI executing" variable.
1152          */
1153
1154         SWAPGS_UNSAFE_STACK
1155         cld
1156         movq    %rsp, %rdx
1157         movq    PER_CPU_VAR(cpu_current_top_of_stack), %rsp
1158         pushq   5*8(%rdx)       /* pt_regs->ss */
1159         pushq   4*8(%rdx)       /* pt_regs->rsp */
1160         pushq   3*8(%rdx)       /* pt_regs->flags */
1161         pushq   2*8(%rdx)       /* pt_regs->cs */
1162         pushq   1*8(%rdx)       /* pt_regs->rip */
1163         pushq   $-1             /* pt_regs->orig_ax */
1164         pushq   %rdi            /* pt_regs->di */
1165         pushq   %rsi            /* pt_regs->si */
1166         pushq   (%rdx)          /* pt_regs->dx */
1167         pushq   %rcx            /* pt_regs->cx */
1168         pushq   %rax            /* pt_regs->ax */
1169         pushq   %r8             /* pt_regs->r8 */
1170         pushq   %r9             /* pt_regs->r9 */
1171         pushq   %r10            /* pt_regs->r10 */
1172         pushq   %r11            /* pt_regs->r11 */
1173         pushq   %rbx            /* pt_regs->rbx */
1174         pushq   %rbp            /* pt_regs->rbp */
1175         pushq   %r12            /* pt_regs->r12 */
1176         pushq   %r13            /* pt_regs->r13 */
1177         pushq   %r14            /* pt_regs->r14 */
1178         pushq   %r15            /* pt_regs->r15 */
1179
1180         /*
1181          * At this point we no longer need to worry about stack damage
1182          * due to nesting -- we're on the normal thread stack and we're
1183          * done with the NMI stack.
1184          */
1185
1186         movq    %rsp, %rdi
1187         movq    $-1, %rsi
1188         call    do_nmi
1189
1190         /*
1191          * Return back to user mode.  We must *not* do the normal exit
1192          * work, because we don't want to enable interrupts.  Fortunately,
1193          * do_nmi doesn't modify pt_regs.
1194          */
1195         SWAPGS
1196         jmp     restore_c_regs_and_iret
1197
1198 .Lnmi_from_kernel:
1199         /*
1200          * Here's what our stack frame will look like:
1201          * +---------------------------------------------------------+
1202          * | original SS                                             |
1203          * | original Return RSP                                     |
1204          * | original RFLAGS                                         |
1205          * | original CS                                             |
1206          * | original RIP                                            |
1207          * +---------------------------------------------------------+
1208          * | temp storage for rdx                                    |
1209          * +---------------------------------------------------------+
1210          * | "NMI executing" variable                                |
1211          * +---------------------------------------------------------+
1212          * | iret SS          } Copied from "outermost" frame        |
1213          * | iret Return RSP  } on each loop iteration; overwritten  |
1214          * | iret RFLAGS      } by a nested NMI to force another     |
1215          * | iret CS          } iteration if needed.                 |
1216          * | iret RIP         }                                      |
1217          * +---------------------------------------------------------+
1218          * | outermost SS          } initialized in first_nmi;       |
1219          * | outermost Return RSP  } will not be changed before      |
1220          * | outermost RFLAGS      } NMI processing is done.         |
1221          * | outermost CS          } Copied to "iret" frame on each  |
1222          * | outermost RIP         } iteration.                      |
1223          * +---------------------------------------------------------+
1224          * | pt_regs                                                 |
1225          * +---------------------------------------------------------+
1226          *
1227          * The "original" frame is used by hardware.  Before re-enabling
1228          * NMIs, we need to be done with it, and we need to leave enough
1229          * space for the asm code here.
1230          *
1231          * We return by executing IRET while RSP points to the "iret" frame.
1232          * That will either return for real or it will loop back into NMI
1233          * processing.
1234          *
1235          * The "outermost" frame is copied to the "iret" frame on each
1236          * iteration of the loop, so each iteration starts with the "iret"
1237          * frame pointing to the final return target.
1238          */
1239
1240         /*
1241          * Determine whether we're a nested NMI.
1242          *
1243          * If we interrupted kernel code between repeat_nmi and
1244          * end_repeat_nmi, then we are a nested NMI.  We must not
1245          * modify the "iret" frame because it's being written by
1246          * the outer NMI.  That's okay; the outer NMI handler is
1247          * about to about to call do_nmi anyway, so we can just
1248          * resume the outer NMI.
1249          */
1250
1251         movq    $repeat_nmi, %rdx
1252         cmpq    8(%rsp), %rdx
1253         ja      1f
1254         movq    $end_repeat_nmi, %rdx
1255         cmpq    8(%rsp), %rdx
1256         ja      nested_nmi_out
1257 1:
1258
1259         /*
1260          * Now check "NMI executing".  If it's set, then we're nested.
1261          * This will not detect if we interrupted an outer NMI just
1262          * before IRET.
1263          */
1264         cmpl    $1, -8(%rsp)
1265         je      nested_nmi
1266
1267         /*
1268          * Now test if the previous stack was an NMI stack.  This covers
1269          * the case where we interrupt an outer NMI after it clears
1270          * "NMI executing" but before IRET.  We need to be careful, though:
1271          * there is one case in which RSP could point to the NMI stack
1272          * despite there being no NMI active: naughty userspace controls
1273          * RSP at the very beginning of the SYSCALL targets.  We can
1274          * pull a fast one on naughty userspace, though: we program
1275          * SYSCALL to mask DF, so userspace cannot cause DF to be set
1276          * if it controls the kernel's RSP.  We set DF before we clear
1277          * "NMI executing".
1278          */
1279         lea     6*8(%rsp), %rdx
1280         /* Compare the NMI stack (rdx) with the stack we came from (4*8(%rsp)) */
1281         cmpq    %rdx, 4*8(%rsp)
1282         /* If the stack pointer is above the NMI stack, this is a normal NMI */
1283         ja      first_nmi
1284
1285         subq    $EXCEPTION_STKSZ, %rdx
1286         cmpq    %rdx, 4*8(%rsp)
1287         /* If it is below the NMI stack, it is a normal NMI */
1288         jb      first_nmi
1289
1290         /* Ah, it is within the NMI stack. */
1291
1292         testb   $(X86_EFLAGS_DF >> 8), (3*8 + 1)(%rsp)
1293         jz      first_nmi       /* RSP was user controlled. */
1294
1295         /* This is a nested NMI. */
1296
1297 nested_nmi:
1298         /*
1299          * Modify the "iret" frame to point to repeat_nmi, forcing another
1300          * iteration of NMI handling.
1301          */
1302         subq    $8, %rsp
1303         leaq    -10*8(%rsp), %rdx
1304         pushq   $__KERNEL_DS
1305         pushq   %rdx
1306         pushfq
1307         pushq   $__KERNEL_CS
1308         pushq   $repeat_nmi
1309
1310         /* Put stack back */
1311         addq    $(6*8), %rsp
1312
1313 nested_nmi_out:
1314         popq    %rdx
1315
1316         /* We are returning to kernel mode, so this cannot result in a fault. */
1317         INTERRUPT_RETURN
1318
1319 first_nmi:
1320         /* Restore rdx. */
1321         movq    (%rsp), %rdx
1322
1323         /* Make room for "NMI executing". */
1324         pushq   $0
1325
1326         /* Leave room for the "iret" frame */
1327         subq    $(5*8), %rsp
1328
1329         /* Copy the "original" frame to the "outermost" frame */
1330         .rept 5
1331         pushq   11*8(%rsp)
1332         .endr
1333
1334         /* Everything up to here is safe from nested NMIs */
1335
1336 #ifdef CONFIG_DEBUG_ENTRY
1337         /*
1338          * For ease of testing, unmask NMIs right away.  Disabled by
1339          * default because IRET is very expensive.
1340          */
1341         pushq   $0              /* SS */
1342         pushq   %rsp            /* RSP (minus 8 because of the previous push) */
1343         addq    $8, (%rsp)      /* Fix up RSP */
1344         pushfq                  /* RFLAGS */
1345         pushq   $__KERNEL_CS    /* CS */
1346         pushq   $1f             /* RIP */
1347         INTERRUPT_RETURN        /* continues at repeat_nmi below */
1348 1:
1349 #endif
1350
1351 repeat_nmi:
1352         /*
1353          * If there was a nested NMI, the first NMI's iret will return
1354          * here. But NMIs are still enabled and we can take another
1355          * nested NMI. The nested NMI checks the interrupted RIP to see
1356          * if it is between repeat_nmi and end_repeat_nmi, and if so
1357          * it will just return, as we are about to repeat an NMI anyway.
1358          * This makes it safe to copy to the stack frame that a nested
1359          * NMI will update.
1360          *
1361          * RSP is pointing to "outermost RIP".  gsbase is unknown, but, if
1362          * we're repeating an NMI, gsbase has the same value that it had on
1363          * the first iteration.  paranoid_entry will load the kernel
1364          * gsbase if needed before we call do_nmi.  "NMI executing"
1365          * is zero.
1366          */
1367         movq    $1, 10*8(%rsp)          /* Set "NMI executing". */
1368
1369         /*
1370          * Copy the "outermost" frame to the "iret" frame.  NMIs that nest
1371          * here must not modify the "iret" frame while we're writing to
1372          * it or it will end up containing garbage.
1373          */
1374         addq    $(10*8), %rsp
1375         .rept 5
1376         pushq   -6*8(%rsp)
1377         .endr
1378         subq    $(5*8), %rsp
1379 end_repeat_nmi:
1380
1381         /*
1382          * Everything below this point can be preempted by a nested NMI.
1383          * If this happens, then the inner NMI will change the "iret"
1384          * frame to point back to repeat_nmi.
1385          */
1386         pushq   $-1                             /* ORIG_RAX: no syscall to restart */
1387         ALLOC_PT_GPREGS_ON_STACK
1388
1389         /*
1390          * Use paranoid_entry to handle SWAPGS, but no need to use paranoid_exit
1391          * as we should not be calling schedule in NMI context.
1392          * Even with normal interrupts enabled. An NMI should not be
1393          * setting NEED_RESCHED or anything that normal interrupts and
1394          * exceptions might do.
1395          */
1396         call    paranoid_entry
1397
1398         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1399         movq    %rsp, %rdi
1400         movq    $-1, %rsi
1401         call    do_nmi
1402
1403         testl   %ebx, %ebx                      /* swapgs needed? */
1404         jnz     nmi_restore
1405 nmi_swapgs:
1406         SWAPGS_UNSAFE_STACK
1407 nmi_restore:
1408         RESTORE_EXTRA_REGS
1409         RESTORE_C_REGS
1410
1411         /* Point RSP at the "iret" frame. */
1412         REMOVE_PT_GPREGS_FROM_STACK 6*8
1413
1414         /*
1415          * Clear "NMI executing".  Set DF first so that we can easily
1416          * distinguish the remaining code between here and IRET from
1417          * the SYSCALL entry and exit paths.  On a native kernel, we
1418          * could just inspect RIP, but, on paravirt kernels,
1419          * INTERRUPT_RETURN can translate into a jump into a
1420          * hypercall page.
1421          */
1422         std
1423         movq    $0, 5*8(%rsp)           /* clear "NMI executing" */
1424
1425         /*
1426          * INTERRUPT_RETURN reads the "iret" frame and exits the NMI
1427          * stack in a single instruction.  We are returning to kernel
1428          * mode, so this cannot result in a fault.
1429          */
1430         INTERRUPT_RETURN
1431 END(nmi)
1432
1433 ENTRY(ignore_sysret)
1434         mov     $-ENOSYS, %eax
1435         sysret
1436 END(ignore_sysret)
1437
1438 ENTRY(rewind_stack_do_exit)
1439         /* Prevent any naive code from trying to unwind to our caller. */
1440         xorl    %ebp, %ebp
1441
1442         movq    PER_CPU_VAR(cpu_current_top_of_stack), %rax
1443         leaq    -TOP_OF_KERNEL_STACK_PADDING-PTREGS_SIZE(%rax), %rsp
1444
1445         call    do_exit
1446 1:      jmp 1b
1447 END(rewind_stack_do_exit)