arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - idtentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/percpu.h>
  57 #include <asm/asm.h>
  58 #include <asm/context_tracking.h>
  59 #include <asm/smap.h>
  60 #include <asm/pgtable_types.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72
  73 #ifndef CONFIG_PREEMPT
  74 #define retint_kernel retint_restore_args
  75 #endif
  76
  77 #ifdef CONFIG_PARAVIRT
  78 ENTRY(native_usergs_sysret64)
  79         swapgs
  80         sysretq
  81 ENDPROC(native_usergs_sysret64)
  82 #endif /* CONFIG_PARAVIRT */
  83
  84
  85 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
  88         jnc  1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 /*
  95  * When dynamic function tracer is enabled it will add a breakpoint
  96  * to all locations that it is about to modify, sync CPUs, update
  97  * all the code, sync CPUs, then remove the breakpoints. In this time
  98  * if lockdep is enabled, it might jump back into the debug handler
  99  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 100  *
 101  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 102  * make sure the stack pointer does not get reset back to the top
 103  * of the debug stack, and instead just reuses the current stack.
 104  */
 105 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 106
 107 .macro TRACE_IRQS_OFF_DEBUG
 108         call debug_stack_set_zero
 109         TRACE_IRQS_OFF
 110         call debug_stack_reset
 111 .endm
 112
 113 .macro TRACE_IRQS_ON_DEBUG
 114         call debug_stack_set_zero
 115         TRACE_IRQS_ON
 116         call debug_stack_reset
 117 .endm
 118
 119 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 120         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 121         jnc  1f
 122         TRACE_IRQS_ON_DEBUG
 123 1:
 124 .endm
 125
 126 #else
 127 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 128 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 129 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 130 #endif
 131
 132 /*
 133  * C code is not supposed to know about undefined top of stack. Every time
 134  * a C function with an pt_regs argument is called from the SYSCALL based
 135  * fast path FIXUP_TOP_OF_STACK is needed.
 136  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 137  * manipulation.
 138  */
 139
 140         /* %rsp:at FRAMEEND */
 141         .macro FIXUP_TOP_OF_STACK tmp offset=0
 142         movq PER_CPU_VAR(old_rsp),\tmp
 143         movq \tmp,RSP+\offset(%rsp)
 144         movq $__USER_DS,SS+\offset(%rsp)
 145         movq $__USER_CS,CS+\offset(%rsp)
 146         movq $-1,RCX+\offset(%rsp)
 147         movq R11+\offset(%rsp),\tmp  /* get eflags */
 148         movq \tmp,EFLAGS+\offset(%rsp)
 149         .endm
 150
 151         .macro RESTORE_TOP_OF_STACK tmp offset=0
 152         movq RSP+\offset(%rsp),\tmp
 153         movq \tmp,PER_CPU_VAR(old_rsp)
 154         movq EFLAGS+\offset(%rsp),\tmp
 155         movq \tmp,R11+\offset(%rsp)
 156         .endm
 157
 158         .macro FAKE_STACK_FRAME child_rip
 159         /* push in order ss, rsp, eflags, cs, rip */
 160         xorl %eax, %eax
 161         pushq_cfi $__KERNEL_DS /* ss */
 162         /*CFI_REL_OFFSET        ss,0*/
 163         pushq_cfi %rax /* rsp */
 164         CFI_REL_OFFSET  rsp,0
 165         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 166         /*CFI_REL_OFFSET        rflags,0*/
 167         pushq_cfi $__KERNEL_CS /* cs */
 168         /*CFI_REL_OFFSET        cs,0*/
 169         pushq_cfi \child_rip /* rip */
 170         CFI_REL_OFFSET  rip,0
 171         pushq_cfi %rax /* orig rax */
 172         .endm
 173
 174         .macro UNFAKE_STACK_FRAME
 175         addq $8*6, %rsp
 176         CFI_ADJUST_CFA_OFFSET   -(6*8)
 177         .endm
 178
 179 /*
 180  * initial frame state for interrupts (and exceptions without error code)
 181  */
 182         .macro EMPTY_FRAME start=1 offset=0
 183         .if \start
 184         CFI_STARTPROC simple
 185         CFI_SIGNAL_FRAME
 186         CFI_DEF_CFA rsp,8+\offset
 187         .else
 188         CFI_DEF_CFA_OFFSET 8+\offset
 189         .endif
 190         .endm
 191
 192 /*
 193  * initial frame state for interrupts (and exceptions without error code)
 194  */
 195         .macro INTR_FRAME start=1 offset=0
 196         EMPTY_FRAME \start, SS+8+\offset-RIP
 197         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 198         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 199         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 200         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 201         CFI_REL_OFFSET rip, RIP+\offset-RIP
 202         .endm
 203
 204 /*
 205  * initial frame state for exceptions with error code (and interrupts
 206  * with vector already pushed)
 207  */
 208         .macro XCPT_FRAME start=1 offset=0
 209         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 210         .endm
 211
 212 /*
 213  * frame that enables calling into C.
 214  */
 215         .macro PARTIAL_FRAME start=1 offset=0
 216         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 217         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 218         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 219         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 220         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 221         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 222         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 223         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 224         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 225         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 226         .endm
 227
 228 /*
 229  * frame that enables passing a complete pt_regs to a C function.
 230  */
 231         .macro DEFAULT_FRAME start=1 offset=0
 232         PARTIAL_FRAME \start, R11+\offset-R15
 233         CFI_REL_OFFSET rbx, RBX+\offset
 234         CFI_REL_OFFSET rbp, RBP+\offset
 235         CFI_REL_OFFSET r12, R12+\offset
 236         CFI_REL_OFFSET r13, R13+\offset
 237         CFI_REL_OFFSET r14, R14+\offset
 238         CFI_REL_OFFSET r15, R15+\offset
 239         .endm
 240
 241 /* save partial stack frame */
 242         .macro SAVE_ARGS_IRQ
 243         cld
 244         /* start from rbp in pt_regs and jump over */
 245         movq_cfi rdi, (RDI-RBP)
 246         movq_cfi rsi, (RSI-RBP)
 247         movq_cfi rdx, (RDX-RBP)
 248         movq_cfi rcx, (RCX-RBP)
 249         movq_cfi rax, (RAX-RBP)
 250         movq_cfi  r8,  (R8-RBP)
 251         movq_cfi  r9,  (R9-RBP)
 252         movq_cfi r10, (R10-RBP)
 253         movq_cfi r11, (R11-RBP)
 254
 255         /* Save rbp so that we can unwind from get_irq_regs() */
 256         movq_cfi rbp, 0
 257
 258         /* Save previous stack value */
 259         movq %rsp, %rsi
 260
 261         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 262         testl $3, CS-RBP(%rsi)
 263         je 1f
 264         SWAPGS
 265         /*
 266          * irq_count is used to check if a CPU is already on an interrupt stack
 267          * or not. While this is essentially redundant with preempt_count it is
 268          * a little cheaper to use a separate counter in the PDA (short of
 269          * moving irq_enter into assembly, which would be too much work)
 270          */
 271 1:      incl PER_CPU_VAR(irq_count)
 272         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 273         CFI_DEF_CFA_REGISTER    rsi
 274
 275         /* Store previous stack value */
 276         pushq %rsi
 277         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 278                         0x77 /* DW_OP_breg7 */, 0, \
 279                         0x06 /* DW_OP_deref */, \
 280                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 281                         0x22 /* DW_OP_plus */
 282         /* We entered an interrupt context - irqs are off: */
 283         TRACE_IRQS_OFF
 284         .endm
 285
 286 ENTRY(save_paranoid)
 287         XCPT_FRAME 1 RDI+8
 288         cld
 289         movq %rdi, RDI+8(%rsp)
 290         movq %rsi, RSI+8(%rsp)
 291         movq_cfi rdx, RDX+8
 292         movq_cfi rcx, RCX+8
 293         movq_cfi rax, RAX+8
 294         movq %r8, R8+8(%rsp)
 295         movq %r9, R9+8(%rsp)
 296         movq %r10, R10+8(%rsp)
 297         movq %r11, R11+8(%rsp)
 298         movq_cfi rbx, RBX+8
 299         movq %rbp, RBP+8(%rsp)
 300         movq %r12, R12+8(%rsp)
 301         movq %r13, R13+8(%rsp)
 302         movq %r14, R14+8(%rsp)
 303         movq %r15, R15+8(%rsp)
 304         movl $1,%ebx
 305         movl $MSR_GS_BASE,%ecx
 306         rdmsr
 307         testl %edx,%edx
 308         js 1f   /* negative -> in kernel */
 309         SWAPGS
 310         xorl %ebx,%ebx
 311 1:      ret
 312         CFI_ENDPROC
 313 END(save_paranoid)
 314
 315 /*
 316  * A newly forked process directly context switches into this address.
 317  *
 318  * rdi: prev task we switched from
 319  */
 320 ENTRY(ret_from_fork)
 321         DEFAULT_FRAME
 322
 323         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 324
 325         pushq_cfi $0x0002
 326         popfq_cfi                               # reset kernel eflags
 327
 328         call schedule_tail                      # rdi: 'prev' task parameter
 329
 330         GET_THREAD_INFO(%rcx)
 331
 332         RESTORE_REST
 333
 334         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 335         jz   1f
 336
 337         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 338         jnz  int_ret_from_sys_call
 339
 340         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 341         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 342
 343 1:
 344         subq $REST_SKIP, %rsp   # leave space for volatiles
 345         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 346         movq %rbp, %rdi
 347         call *%rbx
 348         movl $0, RAX(%rsp)
 349         RESTORE_REST
 350         jmp int_ret_from_sys_call
 351         CFI_ENDPROC
 352 END(ret_from_fork)
 353
 354 /*
 355  * System call entry. Up to 6 arguments in registers are supported.
 356  *
 357  * SYSCALL does not save anything on the stack and does not change the
 358  * stack pointer.  However, it does mask the flags register for us, so
 359  * CLD and CLAC are not needed.
 360  */
 361
 362 /*
 363  * Register setup:
 364  * rax  system call number
 365  * rdi  arg0
 366  * rcx  return address for syscall/sysret, C arg3
 367  * rsi  arg1
 368  * rdx  arg2
 369  * r10  arg3    (--> moved to rcx for C)
 370  * r8   arg4
 371  * r9   arg5
 372  * r11  eflags for syscall/sysret, temporary for C
 373  * r12-r15,rbp,rbx saved by C code, not touched.
 374  *
 375  * Interrupts are off on entry.
 376  * Only called from user space.
 377  *
 378  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 379  *      and report it properly in ps. Unfortunately we haven't.
 380  *
 381  * When user can change the frames always force IRET. That is because
 382  * it deals with uncanonical addresses better. SYSRET has trouble
 383  * with them due to bugs in both AMD and Intel CPUs.
 384  */
 385
 386 ENTRY(system_call)
 387         CFI_STARTPROC   simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 390         CFI_REGISTER    rip,rcx
 391         /*CFI_REGISTER  rflags,r11*/
 392         SWAPGS_UNSAFE_STACK
 393         /*
 394          * A hypervisor implementation might want to use a label
 395          * after the swapgs, so that it can do the swapgs
 396          * for the guest and jump here on syscall.
 397          */
 398 GLOBAL(system_call_after_swapgs)
 399
 400         movq    %rsp,PER_CPU_VAR(old_rsp)
 401         movq    PER_CPU_VAR(kernel_stack),%rsp
 402         /*
 403          * No need to follow this irqs off/on section - it's straight
 404          * and short:
 405          */
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407         SAVE_ARGS 8,0
 408         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 409         movq  %rcx,RIP-ARGOFFSET(%rsp)
 410         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 411         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 412         jnz tracesys
 413 system_call_fastpath:
 414 #if __SYSCALL_MASK == ~0
 415         cmpq $__NR_syscall_max,%rax
 416 #else
 417         andl $__SYSCALL_MASK,%eax
 418         cmpl $__NR_syscall_max,%eax
 419 #endif
 420         ja badsys
 421         movq %r10,%rcx
 422         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 423         movq %rax,RAX-ARGOFFSET(%rsp)
 424 /*
 425  * Syscall return path ending with SYSRET (fast path)
 426  * Has incomplete stack frame and undefined top of stack.
 427  */
 428 ret_from_sys_call:
 429         movl $_TIF_ALLWORK_MASK,%edi
 430         /* edi: flagmask */
 431 sysret_check:
 432         LOCKDEP_SYS_EXIT
 433         DISABLE_INTERRUPTS(CLBR_NONE)
 434         TRACE_IRQS_OFF
 435         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 436         andl %edi,%edx
 437         jnz  sysret_careful
 438         CFI_REMEMBER_STATE
 439         /*
 440          * sysretq will re-enable interrupts:
 441          */
 442         TRACE_IRQS_ON
 443         movq RIP-ARGOFFSET(%rsp),%rcx
 444         CFI_REGISTER    rip,rcx
 445         RESTORE_ARGS 1,-ARG_SKIP,0
 446         /*CFI_REGISTER  rflags,r11*/
 447         movq    PER_CPU_VAR(old_rsp), %rsp
 448         USERGS_SYSRET64
 449
 450         CFI_RESTORE_STATE
 451         /* Handle reschedules */
 452         /* edx: work, edi: workmask */
 453 sysret_careful:
 454         bt $TIF_NEED_RESCHED,%edx
 455         jnc sysret_signal
 456         TRACE_IRQS_ON
 457         ENABLE_INTERRUPTS(CLBR_NONE)
 458         pushq_cfi %rdi
 459         SCHEDULE_USER
 460         popq_cfi %rdi
 461         jmp sysret_check
 462
 463         /* Handle a signal */
 464 sysret_signal:
 465         TRACE_IRQS_ON
 466         ENABLE_INTERRUPTS(CLBR_NONE)
 467 #ifdef CONFIG_AUDITSYSCALL
 468         bt $TIF_SYSCALL_AUDIT,%edx
 469         jc sysret_audit
 470 #endif
 471         /*
 472          * We have a signal, or exit tracing or single-step.
 473          * These all wind up with the iret return path anyway,
 474          * so just join that path right now.
 475          */
 476         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 477         jmp int_check_syscall_exit_work
 478
 479 badsys:
 480         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 481         jmp ret_from_sys_call
 482
 483 #ifdef CONFIG_AUDITSYSCALL
 484         /*
 485          * Fast path for syscall audit without full syscall trace.
 486          * We just call __audit_syscall_entry() directly, and then
 487          * jump back to the normal fast path.
 488          */
 489 auditsys:
 490         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 491         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 492         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 493         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 494         movq %rax,%rsi                  /* 2nd arg: syscall number */
 495         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 496         call __audit_syscall_entry
 497         LOAD_ARGS 0             /* reload call-clobbered registers */
 498         jmp system_call_fastpath
 499
 500         /*
 501          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 502          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 503          * masked off.
 504          */
 505 sysret_audit:
 506         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 507         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 508         setbe %al               /* 1 if so, 0 if not */
 509         movzbl %al,%edi         /* zero-extend that into %edi */
 510         call __audit_syscall_exit
 511         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 512         jmp sysret_check
 513 #endif  /* CONFIG_AUDITSYSCALL */
 514
 515         /* Do syscall tracing */
 516 tracesys:
 517 #ifdef CONFIG_AUDITSYSCALL
 518         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 519         jz auditsys
 520 #endif
 521         SAVE_REST
 522         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 523         FIXUP_TOP_OF_STACK %rdi
 524         movq %rsp,%rdi
 525         call syscall_trace_enter
 526         /*
 527          * Reload arg registers from stack in case ptrace changed them.
 528          * We don't reload %rax because syscall_trace_enter() returned
 529          * the value it wants us to use in the table lookup.
 530          */
 531         LOAD_ARGS ARGOFFSET, 1
 532         RESTORE_REST
 533 #if __SYSCALL_MASK == ~0
 534         cmpq $__NR_syscall_max,%rax
 535 #else
 536         andl $__SYSCALL_MASK,%eax
 537         cmpl $__NR_syscall_max,%eax
 538 #endif
 539         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 540         movq %r10,%rcx  /* fixup for C */
 541         call *sys_call_table(,%rax,8)
 542         movq %rax,RAX-ARGOFFSET(%rsp)
 543         /* Use IRET because user could have changed frame */
 544
 545 /*
 546  * Syscall return path ending with IRET.
 547  * Has correct top of stack, but partial stack frame.
 548  */
 549 GLOBAL(int_ret_from_sys_call)
 550         DISABLE_INTERRUPTS(CLBR_NONE)
 551         TRACE_IRQS_OFF
 552         movl $_TIF_ALLWORK_MASK,%edi
 553         /* edi: mask to check */
 554 GLOBAL(int_with_check)
 555         LOCKDEP_SYS_EXIT_IRQ
 556         GET_THREAD_INFO(%rcx)
 557         movl TI_flags(%rcx),%edx
 558         andl %edi,%edx
 559         jnz   int_careful
 560         andl    $~TS_COMPAT,TI_status(%rcx)
 561         jmp   retint_swapgs
 562
 563         /* Either reschedule or signal or syscall exit tracking needed. */
 564         /* First do a reschedule test. */
 565         /* edx: work, edi: workmask */
 566 int_careful:
 567         bt $TIF_NEED_RESCHED,%edx
 568         jnc  int_very_careful
 569         TRACE_IRQS_ON
 570         ENABLE_INTERRUPTS(CLBR_NONE)
 571         pushq_cfi %rdi
 572         SCHEDULE_USER
 573         popq_cfi %rdi
 574         DISABLE_INTERRUPTS(CLBR_NONE)
 575         TRACE_IRQS_OFF
 576         jmp int_with_check
 577
 578         /* handle signals and tracing -- both require a full stack frame */
 579 int_very_careful:
 580         TRACE_IRQS_ON
 581         ENABLE_INTERRUPTS(CLBR_NONE)
 582 int_check_syscall_exit_work:
 583         SAVE_REST
 584         /* Check for syscall exit trace */
 585         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 586         jz int_signal
 587         pushq_cfi %rdi
 588         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 589         call syscall_trace_leave
 590         popq_cfi %rdi
 591         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 592         jmp int_restore_rest
 593
 594 int_signal:
 595         testl $_TIF_DO_NOTIFY_MASK,%edx
 596         jz 1f
 597         movq %rsp,%rdi          # &ptregs -> arg1
 598         xorl %esi,%esi          # oldset -> arg2
 599         call do_notify_resume
 600 1:      movl $_TIF_WORK_MASK,%edi
 601 int_restore_rest:
 602         RESTORE_REST
 603         DISABLE_INTERRUPTS(CLBR_NONE)
 604         TRACE_IRQS_OFF
 605         jmp int_with_check
 606         CFI_ENDPROC
 607 END(system_call)
 608
 609         .macro FORK_LIKE func
 610 ENTRY(stub_\func)
 611         CFI_STARTPROC
 612         popq    %r11                    /* save return address */
 613         PARTIAL_FRAME 0
 614         SAVE_REST
 615         pushq   %r11                    /* put it back on stack */
 616         FIXUP_TOP_OF_STACK %r11, 8
 617         DEFAULT_FRAME 0 8               /* offset 8: return address */
 618         call sys_\func
 619         RESTORE_TOP_OF_STACK %r11, 8
 620         ret $REST_SKIP          /* pop extended registers */
 621         CFI_ENDPROC
 622 END(stub_\func)
 623         .endm
 624
 625         .macro FIXED_FRAME label,func
 626 ENTRY(\label)
 627         CFI_STARTPROC
 628         PARTIAL_FRAME 0 8               /* offset 8: return address */
 629         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 630         call \func
 631         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 632         ret
 633         CFI_ENDPROC
 634 END(\label)
 635         .endm
 636
 637         FORK_LIKE  clone
 638         FORK_LIKE  fork
 639         FORK_LIKE  vfork
 640         FIXED_FRAME stub_iopl, sys_iopl
 641
 642 ENTRY(ptregscall_common)
 643         DEFAULT_FRAME 1 8       /* offset 8: return address */
 644         RESTORE_TOP_OF_STACK %r11, 8
 645         movq_cfi_restore R15+8, r15
 646         movq_cfi_restore R14+8, r14
 647         movq_cfi_restore R13+8, r13
 648         movq_cfi_restore R12+8, r12
 649         movq_cfi_restore RBP+8, rbp
 650         movq_cfi_restore RBX+8, rbx
 651         ret $REST_SKIP          /* pop extended registers */
 652         CFI_ENDPROC
 653 END(ptregscall_common)
 654
 655 ENTRY(stub_execve)
 656         CFI_STARTPROC
 657         addq $8, %rsp
 658         PARTIAL_FRAME 0
 659         SAVE_REST
 660         FIXUP_TOP_OF_STACK %r11
 661         call sys_execve
 662         movq %rax,RAX(%rsp)
 663         RESTORE_REST
 664         jmp int_ret_from_sys_call
 665         CFI_ENDPROC
 666 END(stub_execve)
 667
 668 /*
 669  * sigreturn is special because it needs to restore all registers on return.
 670  * This cannot be done with SYSRET, so use the IRET return path instead.
 671  */
 672 ENTRY(stub_rt_sigreturn)
 673         CFI_STARTPROC
 674         addq $8, %rsp
 675         PARTIAL_FRAME 0
 676         SAVE_REST
 677         FIXUP_TOP_OF_STACK %r11
 678         call sys_rt_sigreturn
 679         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 680         RESTORE_REST
 681         jmp int_ret_from_sys_call
 682         CFI_ENDPROC
 683 END(stub_rt_sigreturn)
 684
 685 #ifdef CONFIG_X86_X32_ABI
 686 ENTRY(stub_x32_rt_sigreturn)
 687         CFI_STARTPROC
 688         addq $8, %rsp
 689         PARTIAL_FRAME 0
 690         SAVE_REST
 691         FIXUP_TOP_OF_STACK %r11
 692         call sys32_x32_rt_sigreturn
 693         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 694         RESTORE_REST
 695         jmp int_ret_from_sys_call
 696         CFI_ENDPROC
 697 END(stub_x32_rt_sigreturn)
 698
 699 ENTRY(stub_x32_execve)
 700         CFI_STARTPROC
 701         addq $8, %rsp
 702         PARTIAL_FRAME 0
 703         SAVE_REST
 704         FIXUP_TOP_OF_STACK %r11
 705         call compat_sys_execve
 706         RESTORE_TOP_OF_STACK %r11
 707         movq %rax,RAX(%rsp)
 708         RESTORE_REST
 709         jmp int_ret_from_sys_call
 710         CFI_ENDPROC
 711 END(stub_x32_execve)
 712
 713 #endif
 714
 715 /*
 716  * Build the entry stubs and pointer table with some assembler magic.
 717  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 718  * single cache line on all modern x86 implementations.
 719  */
 720         .section .init.rodata,"a"
 721 ENTRY(interrupt)
 722         .section .entry.text
 723         .p2align 5
 724         .p2align CONFIG_X86_L1_CACHE_SHIFT
 725 ENTRY(irq_entries_start)
 726         INTR_FRAME
 727 vector=FIRST_EXTERNAL_VECTOR
 728 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 729         .balign 32
 730   .rept 7
 731     .if vector < NR_VECTORS
 732       .if vector <> FIRST_EXTERNAL_VECTOR
 733         CFI_ADJUST_CFA_OFFSET -8
 734       .endif
 735 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 736       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 737         jmp 2f
 738       .endif
 739       .previous
 740         .quad 1b
 741       .section .entry.text
 742 vector=vector+1
 743     .endif
 744   .endr
 745 2:      jmp common_interrupt
 746 .endr
 747         CFI_ENDPROC
 748 END(irq_entries_start)
 749
 750 .previous
 751 END(interrupt)
 752 .previous
 753
 754 /*
 755  * Interrupt entry/exit.
 756  *
 757  * Interrupt entry points save only callee clobbered registers in fast path.
 758  *
 759  * Entry runs with interrupts off.
 760  */
 761
 762 /* 0(%rsp): ~(interrupt number) */
 763         .macro interrupt func
 764         /* reserve pt_regs for scratch regs and rbp */
 765         subq $ORIG_RAX-RBP, %rsp
 766         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 767         SAVE_ARGS_IRQ
 768         call \func
 769         .endm
 770
 771         /*
 772          * The interrupt stubs push (~vector+0x80) onto the stack and
 773          * then jump to common_interrupt.
 774          */
 775         .p2align CONFIG_X86_L1_CACHE_SHIFT
 776 common_interrupt:
 777         XCPT_FRAME
 778         ASM_CLAC
 779         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 780         interrupt do_IRQ
 781         /* 0(%rsp): old_rsp-ARGOFFSET */
 782 ret_from_intr:
 783         DISABLE_INTERRUPTS(CLBR_NONE)
 784         TRACE_IRQS_OFF
 785         decl PER_CPU_VAR(irq_count)
 786
 787         /* Restore saved previous stack */
 788         popq %rsi
 789         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 790         leaq ARGOFFSET-RBP(%rsi), %rsp
 791         CFI_DEF_CFA_REGISTER    rsp
 792         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 793
 794 exit_intr:
 795         GET_THREAD_INFO(%rcx)
 796         testl $3,CS-ARGOFFSET(%rsp)
 797         je retint_kernel
 798
 799         /* Interrupt came from user space */
 800         /*
 801          * Has a correct top of stack, but a partial stack frame
 802          * %rcx: thread info. Interrupts off.
 803          */
 804 retint_with_reschedule:
 805         movl $_TIF_WORK_MASK,%edi
 806 retint_check:
 807         LOCKDEP_SYS_EXIT_IRQ
 808         movl TI_flags(%rcx),%edx
 809         andl %edi,%edx
 810         CFI_REMEMBER_STATE
 811         jnz  retint_careful
 812
 813 retint_swapgs:          /* return to user-space */
 814         /*
 815          * The iretq could re-enable interrupts:
 816          */
 817         DISABLE_INTERRUPTS(CLBR_ANY)
 818         TRACE_IRQS_IRETQ
 819         SWAPGS
 820         jmp restore_args
 821
 822 retint_restore_args:    /* return to kernel space */
 823         DISABLE_INTERRUPTS(CLBR_ANY)
 824         /*
 825          * The iretq could re-enable interrupts:
 826          */
 827         TRACE_IRQS_IRETQ
 828 restore_args:
 829         RESTORE_ARGS 1,8,1
 830
 831 irq_return:
 832         INTERRUPT_RETURN
 833
 834 ENTRY(native_iret)
 835         /*
 836          * Are we returning to a stack segment from the LDT?  Note: in
 837          * 64-bit mode SS:RSP on the exception stack is always valid.
 838          */
 839 #ifdef CONFIG_X86_ESPFIX64
 840         testb $4,(SS-RIP)(%rsp)
 841         jnz native_irq_return_ldt
 842 #endif
 843
 844 native_irq_return_iret:
 845         iretq
 846         _ASM_EXTABLE(native_irq_return_iret, bad_iret)
 847
 848 #ifdef CONFIG_X86_ESPFIX64
 849 native_irq_return_ldt:
 850         pushq_cfi %rax
 851         pushq_cfi %rdi
 852         SWAPGS
 853         movq PER_CPU_VAR(espfix_waddr),%rdi
 854         movq %rax,(0*8)(%rdi)   /* RAX */
 855         movq (2*8)(%rsp),%rax   /* RIP */
 856         movq %rax,(1*8)(%rdi)
 857         movq (3*8)(%rsp),%rax   /* CS */
 858         movq %rax,(2*8)(%rdi)
 859         movq (4*8)(%rsp),%rax   /* RFLAGS */
 860         movq %rax,(3*8)(%rdi)
 861         movq (6*8)(%rsp),%rax   /* SS */
 862         movq %rax,(5*8)(%rdi)
 863         movq (5*8)(%rsp),%rax   /* RSP */
 864         movq %rax,(4*8)(%rdi)
 865         andl $0xffff0000,%eax
 866         popq_cfi %rdi
 867         orq PER_CPU_VAR(espfix_stack),%rax
 868         SWAPGS
 869         movq %rax,%rsp
 870         popq_cfi %rax
 871         jmp native_irq_return_iret
 872 #endif
 873
 874         .section .fixup,"ax"
 875 bad_iret:
 876         /*
 877          * The iret traps when the %cs or %ss being restored is bogus.
 878          * We've lost the original trap vector and error code.
 879          * #GPF is the most likely one to get for an invalid selector.
 880          * So pretend we completed the iret and took the #GPF in user mode.
 881          *
 882          * We are now running with the kernel GS after exception recovery.
 883          * But error_entry expects us to have user GS to match the user %cs,
 884          * so swap back.
 885          */
 886         pushq $0
 887
 888         SWAPGS
 889         jmp general_protection
 890
 891         .previous
 892
 893         /* edi: workmask, edx: work */
 894 retint_careful:
 895         CFI_RESTORE_STATE
 896         bt    $TIF_NEED_RESCHED,%edx
 897         jnc   retint_signal
 898         TRACE_IRQS_ON
 899         ENABLE_INTERRUPTS(CLBR_NONE)
 900         pushq_cfi %rdi
 901         SCHEDULE_USER
 902         popq_cfi %rdi
 903         GET_THREAD_INFO(%rcx)
 904         DISABLE_INTERRUPTS(CLBR_NONE)
 905         TRACE_IRQS_OFF
 906         jmp retint_check
 907
 908 retint_signal:
 909         testl $_TIF_DO_NOTIFY_MASK,%edx
 910         jz    retint_swapgs
 911         TRACE_IRQS_ON
 912         ENABLE_INTERRUPTS(CLBR_NONE)
 913         SAVE_REST
 914         movq $-1,ORIG_RAX(%rsp)
 915         xorl %esi,%esi          # oldset
 916         movq %rsp,%rdi          # &pt_regs
 917         call do_notify_resume
 918         RESTORE_REST
 919         DISABLE_INTERRUPTS(CLBR_NONE)
 920         TRACE_IRQS_OFF
 921         GET_THREAD_INFO(%rcx)
 922         jmp retint_with_reschedule
 923
 924 #ifdef CONFIG_PREEMPT
 925         /* Returning to kernel space. Check if we need preemption */
 926         /* rcx:  threadinfo. interrupts off. */
 927 ENTRY(retint_kernel)
 928         cmpl $0,PER_CPU_VAR(__preempt_count)
 929         jnz  retint_restore_args
 930         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 931         jnc  retint_restore_args
 932         call preempt_schedule_irq
 933         jmp exit_intr
 934 #endif
 935         CFI_ENDPROC
 936 END(common_interrupt)
 937
 938         /*
 939          * If IRET takes a fault on the espfix stack, then we
 940          * end up promoting it to a doublefault.  In that case,
 941          * modify the stack to make it look like we just entered
 942          * the #GP handler from user space, similar to bad_iret.
 943          */
 944 #ifdef CONFIG_X86_ESPFIX64
 945         ALIGN
 946 __do_double_fault:
 947         XCPT_FRAME 1 RDI+8
 948         movq RSP(%rdi),%rax             /* Trap on the espfix stack? */
 949         sarq $PGDIR_SHIFT,%rax
 950         cmpl $ESPFIX_PGD_ENTRY,%eax
 951         jne do_double_fault             /* No, just deliver the fault */
 952         cmpl $__KERNEL_CS,CS(%rdi)
 953         jne do_double_fault
 954         movq RIP(%rdi),%rax
 955         cmpq $native_irq_return_iret,%rax
 956         jne do_double_fault             /* This shouldn't happen... */
 957         movq PER_CPU_VAR(kernel_stack),%rax
 958         subq $(6*8-KERNEL_STACK_OFFSET),%rax    /* Reset to original stack */
 959         movq %rax,RSP(%rdi)
 960         movq $0,(%rax)                  /* Missing (lost) #GP error code */
 961         movq $general_protection,RIP(%rdi)
 962         retq
 963         CFI_ENDPROC
 964 END(__do_double_fault)
 965 #else
 966 # define __do_double_fault do_double_fault
 967 #endif
 968
 969 /*
 970  * APIC interrupts.
 971  */
 972 .macro apicinterrupt3 num sym do_sym
 973 ENTRY(\sym)
 974         INTR_FRAME
 975         ASM_CLAC
 976         pushq_cfi $~(\num)
 977 .Lcommon_\sym:
 978         interrupt \do_sym
 979         jmp ret_from_intr
 980         CFI_ENDPROC
 981 END(\sym)
 982 .endm
 983
 984 #ifdef CONFIG_TRACING
 985 #define trace(sym) trace_##sym
 986 #define smp_trace(sym) smp_trace_##sym
 987
 988 .macro trace_apicinterrupt num sym
 989 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
 990 .endm
 991 #else
 992 .macro trace_apicinterrupt num sym do_sym
 993 .endm
 994 #endif
 995
 996 .macro apicinterrupt num sym do_sym
 997 apicinterrupt3 \num \sym \do_sym
 998 trace_apicinterrupt \num \sym
 999 .endm
1000
1001 #ifdef CONFIG_SMP
1002 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1003         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1004 apicinterrupt3 REBOOT_VECTOR \
1005         reboot_interrupt smp_reboot_interrupt
1006 #endif
1007
1008 #ifdef CONFIG_X86_UV
1009 apicinterrupt3 UV_BAU_MESSAGE \
1010         uv_bau_message_intr1 uv_bau_message_interrupt
1011 #endif
1012 apicinterrupt LOCAL_TIMER_VECTOR \
1013         apic_timer_interrupt smp_apic_timer_interrupt
1014 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1015         x86_platform_ipi smp_x86_platform_ipi
1016
1017 #ifdef CONFIG_HAVE_KVM
1018 apicinterrupt3 POSTED_INTR_VECTOR \
1019         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1020 #endif
1021
1022 #ifdef CONFIG_X86_MCE_THRESHOLD
1023 apicinterrupt THRESHOLD_APIC_VECTOR \
1024         threshold_interrupt smp_threshold_interrupt
1025 #endif
1026
1027 #ifdef CONFIG_X86_THERMAL_VECTOR
1028 apicinterrupt THERMAL_APIC_VECTOR \
1029         thermal_interrupt smp_thermal_interrupt
1030 #endif
1031
1032 #ifdef CONFIG_SMP
1033 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1034         call_function_single_interrupt smp_call_function_single_interrupt
1035 apicinterrupt CALL_FUNCTION_VECTOR \
1036         call_function_interrupt smp_call_function_interrupt
1037 apicinterrupt RESCHEDULE_VECTOR \
1038         reschedule_interrupt smp_reschedule_interrupt
1039 #endif
1040
1041 apicinterrupt ERROR_APIC_VECTOR \
1042         error_interrupt smp_error_interrupt
1043 apicinterrupt SPURIOUS_APIC_VECTOR \
1044         spurious_interrupt smp_spurious_interrupt
1045
1046 #ifdef CONFIG_IRQ_WORK
1047 apicinterrupt IRQ_WORK_VECTOR \
1048         irq_work_interrupt smp_irq_work_interrupt
1049 #endif
1050
1051 /*
1052  * Exception entry points.
1053  */
1054 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1055
1056 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
1057 ENTRY(\sym)
1058         /* Sanity check */
1059         .if \shift_ist != -1 && \paranoid == 0
1060         .error "using shift_ist requires paranoid=1"
1061         .endif
1062
1063         .if \has_error_code
1064         XCPT_FRAME
1065         .else
1066         INTR_FRAME
1067         .endif
1068
1069         ASM_CLAC
1070         PARAVIRT_ADJUST_EXCEPTION_FRAME
1071
1072         .ifeq \has_error_code
1073         pushq_cfi $-1                   /* ORIG_RAX: no syscall to restart */
1074         .endif
1075
1076         subq $ORIG_RAX-R15, %rsp
1077         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1078
1079         .if \paranoid
1080         call save_paranoid
1081         .else
1082         call error_entry
1083         .endif
1084
1085         DEFAULT_FRAME 0
1086
1087         .if \paranoid
1088         .if \shift_ist != -1
1089         TRACE_IRQS_OFF_DEBUG            /* reload IDT in case of recursion */
1090         .else
1091         TRACE_IRQS_OFF
1092         .endif
1093         .endif
1094
1095         movq %rsp,%rdi                  /* pt_regs pointer */
1096
1097         .if \has_error_code
1098         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1099         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1100         .else
1101         xorl %esi,%esi                  /* no error code */
1102         .endif
1103
1104         .if \shift_ist != -1
1105         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1106         .endif
1107
1108         call \do_sym
1109
1110         .if \shift_ist != -1
1111         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1112         .endif
1113
1114         .if \paranoid
1115         jmp paranoid_exit               /* %ebx: no swapgs flag */
1116         .else
1117         jmp error_exit                  /* %ebx: no swapgs flag */
1118         .endif
1119
1120         CFI_ENDPROC
1121 END(\sym)
1122 .endm
1123
1124 #ifdef CONFIG_TRACING
1125 .macro trace_idtentry sym do_sym has_error_code:req
1126 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
1127 idtentry \sym \do_sym has_error_code=\has_error_code
1128 .endm
1129 #else
1130 .macro trace_idtentry sym do_sym has_error_code:req
1131 idtentry \sym \do_sym has_error_code=\has_error_code
1132 .endm
1133 #endif
1134
1135 idtentry divide_error do_divide_error has_error_code=0
1136 idtentry overflow do_overflow has_error_code=0
1137 idtentry bounds do_bounds has_error_code=0
1138 idtentry invalid_op do_invalid_op has_error_code=0
1139 idtentry device_not_available do_device_not_available has_error_code=0
1140 idtentry double_fault __do_double_fault has_error_code=1 paranoid=1
1141 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1142 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1143 idtentry segment_not_present do_segment_not_present has_error_code=1
1144 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1145 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1146 idtentry alignment_check do_alignment_check has_error_code=1
1147 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1148
1149
1150         /* Reload gs selector with exception handling */
1151         /* edi:  new selector */
1152 ENTRY(native_load_gs_index)
1153         CFI_STARTPROC
1154         pushfq_cfi
1155         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1156         SWAPGS
1157 gs_change:
1158         movl %edi,%gs
1159 2:      mfence          /* workaround */
1160         SWAPGS
1161         popfq_cfi
1162         ret
1163         CFI_ENDPROC
1164 END(native_load_gs_index)
1165
1166         _ASM_EXTABLE(gs_change,bad_gs)
1167         .section .fixup,"ax"
1168         /* running with kernelgs */
1169 bad_gs:
1170         SWAPGS                  /* switch back to user gs */
1171         xorl %eax,%eax
1172         movl %eax,%gs
1173         jmp  2b
1174         .previous
1175
1176 /* Call softirq on interrupt stack. Interrupts are off. */
1177 ENTRY(do_softirq_own_stack)
1178         CFI_STARTPROC
1179         pushq_cfi %rbp
1180         CFI_REL_OFFSET rbp,0
1181         mov  %rsp,%rbp
1182         CFI_DEF_CFA_REGISTER rbp
1183         incl PER_CPU_VAR(irq_count)
1184         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1185         push  %rbp                      # backlink for old unwinder
1186         call __do_softirq
1187         leaveq
1188         CFI_RESTORE             rbp
1189         CFI_DEF_CFA_REGISTER    rsp
1190         CFI_ADJUST_CFA_OFFSET   -8
1191         decl PER_CPU_VAR(irq_count)
1192         ret
1193         CFI_ENDPROC
1194 END(do_softirq_own_stack)
1195
1196 #ifdef CONFIG_XEN
1197 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1198
1199 /*
1200  * A note on the "critical region" in our callback handler.
1201  * We want to avoid stacking callback handlers due to events occurring
1202  * during handling of the last event. To do this, we keep events disabled
1203  * until we've done all processing. HOWEVER, we must enable events before
1204  * popping the stack frame (can't be done atomically) and so it would still
1205  * be possible to get enough handler activations to overflow the stack.
1206  * Although unlikely, bugs of that kind are hard to track down, so we'd
1207  * like to avoid the possibility.
1208  * So, on entry to the handler we detect whether we interrupted an
1209  * existing activation in its critical region -- if so, we pop the current
1210  * activation and restart the handler using the previous one.
1211  */
1212 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1213         CFI_STARTPROC
1214 /*
1215  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1216  * see the correct pointer to the pt_regs
1217  */
1218         movq %rdi, %rsp            # we don't return, adjust the stack frame
1219         CFI_ENDPROC
1220         DEFAULT_FRAME
1221 11:     incl PER_CPU_VAR(irq_count)
1222         movq %rsp,%rbp
1223         CFI_DEF_CFA_REGISTER rbp
1224         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1225         pushq %rbp                      # backlink for old unwinder
1226         call xen_evtchn_do_upcall
1227         popq %rsp
1228         CFI_DEF_CFA_REGISTER rsp
1229         decl PER_CPU_VAR(irq_count)
1230         jmp  error_exit
1231         CFI_ENDPROC
1232 END(xen_do_hypervisor_callback)
1233
1234 /*
1235  * Hypervisor uses this for application faults while it executes.
1236  * We get here for two reasons:
1237  *  1. Fault while reloading DS, ES, FS or GS
1238  *  2. Fault while executing IRET
1239  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1240  * registers that could be reloaded and zeroed the others.
1241  * Category 2 we fix up by killing the current process. We cannot use the
1242  * normal Linux return path in this case because if we use the IRET hypercall
1243  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1244  * We distinguish between categories by comparing each saved segment register
1245  * with its current contents: any discrepancy means we in category 1.
1246  */
1247 ENTRY(xen_failsafe_callback)
1248         INTR_FRAME 1 (6*8)
1249         /*CFI_REL_OFFSET gs,GS*/
1250         /*CFI_REL_OFFSET fs,FS*/
1251         /*CFI_REL_OFFSET es,ES*/
1252         /*CFI_REL_OFFSET ds,DS*/
1253         CFI_REL_OFFSET r11,8
1254         CFI_REL_OFFSET rcx,0
1255         movw %ds,%cx
1256         cmpw %cx,0x10(%rsp)
1257         CFI_REMEMBER_STATE
1258         jne 1f
1259         movw %es,%cx
1260         cmpw %cx,0x18(%rsp)
1261         jne 1f
1262         movw %fs,%cx
1263         cmpw %cx,0x20(%rsp)
1264         jne 1f
1265         movw %gs,%cx
1266         cmpw %cx,0x28(%rsp)
1267         jne 1f
1268         /* All segments match their saved values => Category 2 (Bad IRET). */
1269         movq (%rsp),%rcx
1270         CFI_RESTORE rcx
1271         movq 8(%rsp),%r11
1272         CFI_RESTORE r11
1273         addq $0x30,%rsp
1274         CFI_ADJUST_CFA_OFFSET -0x30
1275         pushq_cfi $0    /* RIP */
1276         pushq_cfi %r11
1277         pushq_cfi %rcx
1278         jmp general_protection
1279         CFI_RESTORE_STATE
1280 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1281         movq (%rsp),%rcx
1282         CFI_RESTORE rcx
1283         movq 8(%rsp),%r11
1284         CFI_RESTORE r11
1285         addq $0x30,%rsp
1286         CFI_ADJUST_CFA_OFFSET -0x30
1287         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1288         SAVE_ALL
1289         jmp error_exit
1290         CFI_ENDPROC
1291 END(xen_failsafe_callback)
1292
1293 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1294         xen_hvm_callback_vector xen_evtchn_do_upcall
1295
1296 #endif /* CONFIG_XEN */
1297
1298 #if IS_ENABLED(CONFIG_HYPERV)
1299 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1300         hyperv_callback_vector hyperv_vector_handler
1301 #endif /* CONFIG_HYPERV */
1302
1303 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1304 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1305 idtentry stack_segment do_stack_segment has_error_code=1 paranoid=1
1306 #ifdef CONFIG_XEN
1307 idtentry xen_debug do_debug has_error_code=0
1308 idtentry xen_int3 do_int3 has_error_code=0
1309 idtentry xen_stack_segment do_stack_segment has_error_code=1
1310 #endif
1311 idtentry general_protection do_general_protection has_error_code=1
1312 trace_idtentry page_fault do_page_fault has_error_code=1
1313 #ifdef CONFIG_KVM_GUEST
1314 idtentry async_page_fault do_async_page_fault has_error_code=1
1315 #endif
1316 #ifdef CONFIG_X86_MCE
1317 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1318 #endif
1319
1320         /*
1321          * "Paranoid" exit path from exception stack.
1322          * Paranoid because this is used by NMIs and cannot take
1323          * any kernel state for granted.
1324          * We don't do kernel preemption checks here, because only
1325          * NMI should be common and it does not enable IRQs and
1326          * cannot get reschedule ticks.
1327          *
1328          * "trace" is 0 for the NMI handler only, because irq-tracing
1329          * is fundamentally NMI-unsafe. (we cannot change the soft and
1330          * hard flags at once, atomically)
1331          */
1332
1333         /* ebx: no swapgs flag */
1334 ENTRY(paranoid_exit)
1335         DEFAULT_FRAME
1336         DISABLE_INTERRUPTS(CLBR_NONE)
1337         TRACE_IRQS_OFF_DEBUG
1338         testl %ebx,%ebx                         /* swapgs needed? */
1339         jnz paranoid_restore
1340         testl $3,CS(%rsp)
1341         jnz   paranoid_userspace
1342 paranoid_swapgs:
1343         TRACE_IRQS_IRETQ 0
1344         SWAPGS_UNSAFE_STACK
1345         RESTORE_ALL 8
1346         jmp irq_return
1347 paranoid_restore:
1348         TRACE_IRQS_IRETQ_DEBUG 0
1349         RESTORE_ALL 8
1350         jmp irq_return
1351 paranoid_userspace:
1352         GET_THREAD_INFO(%rcx)
1353         movl TI_flags(%rcx),%ebx
1354         andl $_TIF_WORK_MASK,%ebx
1355         jz paranoid_swapgs
1356         movq %rsp,%rdi                  /* &pt_regs */
1357         call sync_regs
1358         movq %rax,%rsp                  /* switch stack for scheduling */
1359         testl $_TIF_NEED_RESCHED,%ebx
1360         jnz paranoid_schedule
1361         movl %ebx,%edx                  /* arg3: thread flags */
1362         TRACE_IRQS_ON
1363         ENABLE_INTERRUPTS(CLBR_NONE)
1364         xorl %esi,%esi                  /* arg2: oldset */
1365         movq %rsp,%rdi                  /* arg1: &pt_regs */
1366         call do_notify_resume
1367         DISABLE_INTERRUPTS(CLBR_NONE)
1368         TRACE_IRQS_OFF
1369         jmp paranoid_userspace
1370 paranoid_schedule:
1371         TRACE_IRQS_ON
1372         ENABLE_INTERRUPTS(CLBR_ANY)
1373         SCHEDULE_USER
1374         DISABLE_INTERRUPTS(CLBR_ANY)
1375         TRACE_IRQS_OFF
1376         jmp paranoid_userspace
1377         CFI_ENDPROC
1378 END(paranoid_exit)
1379
1380 /*
1381  * Exception entry point. This expects an error code/orig_rax on the stack.
1382  * returns in "no swapgs flag" in %ebx.
1383  */
1384 ENTRY(error_entry)
1385         XCPT_FRAME
1386         CFI_ADJUST_CFA_OFFSET 15*8
1387         /* oldrax contains error code */
1388         cld
1389         movq %rdi, RDI+8(%rsp)
1390         movq %rsi, RSI+8(%rsp)
1391         movq %rdx, RDX+8(%rsp)
1392         movq %rcx, RCX+8(%rsp)
1393         movq %rax, RAX+8(%rsp)
1394         movq  %r8,  R8+8(%rsp)
1395         movq  %r9,  R9+8(%rsp)
1396         movq %r10, R10+8(%rsp)
1397         movq %r11, R11+8(%rsp)
1398         movq_cfi rbx, RBX+8
1399         movq %rbp, RBP+8(%rsp)
1400         movq %r12, R12+8(%rsp)
1401         movq %r13, R13+8(%rsp)
1402         movq %r14, R14+8(%rsp)
1403         movq %r15, R15+8(%rsp)
1404         xorl %ebx,%ebx
1405         testl $3,CS+8(%rsp)
1406         je error_kernelspace
1407 error_swapgs:
1408         SWAPGS
1409 error_sti:
1410         TRACE_IRQS_OFF
1411         ret
1412
1413 /*
1414  * There are two places in the kernel that can potentially fault with
1415  * usergs. Handle them here. The exception handlers after iret run with
1416  * kernel gs again, so don't set the user space flag. B stepping K8s
1417  * sometimes report an truncated RIP for IRET exceptions returning to
1418  * compat mode. Check for these here too.
1419  */
1420 error_kernelspace:
1421         CFI_REL_OFFSET rcx, RCX+8
1422         incl %ebx
1423         leaq native_irq_return_iret(%rip),%rcx
1424         cmpq %rcx,RIP+8(%rsp)
1425         je error_swapgs
1426         movl %ecx,%eax  /* zero extend */
1427         cmpq %rax,RIP+8(%rsp)
1428         je bstep_iret
1429         cmpq $gs_change,RIP+8(%rsp)
1430         je error_swapgs
1431         jmp error_sti
1432
1433 bstep_iret:
1434         /* Fix truncated RIP */
1435         movq %rcx,RIP+8(%rsp)
1436         jmp error_swapgs
1437         CFI_ENDPROC
1438 END(error_entry)
1439
1440
1441 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1442 ENTRY(error_exit)
1443         DEFAULT_FRAME
1444         movl %ebx,%eax
1445         RESTORE_REST
1446         DISABLE_INTERRUPTS(CLBR_NONE)
1447         TRACE_IRQS_OFF
1448         GET_THREAD_INFO(%rcx)
1449         testl %eax,%eax
1450         jne retint_kernel
1451         LOCKDEP_SYS_EXIT_IRQ
1452         movl TI_flags(%rcx),%edx
1453         movl $_TIF_WORK_MASK,%edi
1454         andl %edi,%edx
1455         jnz retint_careful
1456         jmp retint_swapgs
1457         CFI_ENDPROC
1458 END(error_exit)
1459
1460 /*
1461  * Test if a given stack is an NMI stack or not.
1462  */
1463         .macro test_in_nmi reg stack nmi_ret normal_ret
1464         cmpq %\reg, \stack
1465         ja \normal_ret
1466         subq $EXCEPTION_STKSZ, %\reg
1467         cmpq %\reg, \stack
1468         jb \normal_ret
1469         jmp \nmi_ret
1470         .endm
1471
1472         /* runs on exception stack */
1473 ENTRY(nmi)
1474         INTR_FRAME
1475         PARAVIRT_ADJUST_EXCEPTION_FRAME
1476         /*
1477          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1478          * the iretq it performs will take us out of NMI context.
1479          * This means that we can have nested NMIs where the next
1480          * NMI is using the top of the stack of the previous NMI. We
1481          * can't let it execute because the nested NMI will corrupt the
1482          * stack of the previous NMI. NMI handlers are not re-entrant
1483          * anyway.
1484          *
1485          * To handle this case we do the following:
1486          *  Check the a special location on the stack that contains
1487          *  a variable that is set when NMIs are executing.
1488          *  The interrupted task's stack is also checked to see if it
1489          *  is an NMI stack.
1490          *  If the variable is not set and the stack is not the NMI
1491          *  stack then:
1492          *    o Set the special variable on the stack
1493          *    o Copy the interrupt frame into a "saved" location on the stack
1494          *    o Copy the interrupt frame into a "copy" location on the stack
1495          *    o Continue processing the NMI
1496          *  If the variable is set or the previous stack is the NMI stack:
1497          *    o Modify the "copy" location to jump to the repeate_nmi
1498          *    o return back to the first NMI
1499          *
1500          * Now on exit of the first NMI, we first clear the stack variable
1501          * The NMI stack will tell any nested NMIs at that point that it is
1502          * nested. Then we pop the stack normally with iret, and if there was
1503          * a nested NMI that updated the copy interrupt stack frame, a
1504          * jump will be made to the repeat_nmi code that will handle the second
1505          * NMI.
1506          */
1507
1508         /* Use %rdx as out temp variable throughout */
1509         pushq_cfi %rdx
1510         CFI_REL_OFFSET rdx, 0
1511
1512         /*
1513          * If %cs was not the kernel segment, then the NMI triggered in user
1514          * space, which means it is definitely not nested.
1515          */
1516         cmpl $__KERNEL_CS, 16(%rsp)
1517         jne first_nmi
1518
1519         /*
1520          * Check the special variable on the stack to see if NMIs are
1521          * executing.
1522          */
1523         cmpl $1, -8(%rsp)
1524         je nested_nmi
1525
1526         /*
1527          * Now test if the previous stack was an NMI stack.
1528          * We need the double check. We check the NMI stack to satisfy the
1529          * race when the first NMI clears the variable before returning.
1530          * We check the variable because the first NMI could be in a
1531          * breakpoint routine using a breakpoint stack.
1532          */
1533         lea 6*8(%rsp), %rdx
1534         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1535         CFI_REMEMBER_STATE
1536
1537 nested_nmi:
1538         /*
1539          * Do nothing if we interrupted the fixup in repeat_nmi.
1540          * It's about to repeat the NMI handler, so we are fine
1541          * with ignoring this one.
1542          */
1543         movq $repeat_nmi, %rdx
1544         cmpq 8(%rsp), %rdx
1545         ja 1f
1546         movq $end_repeat_nmi, %rdx
1547         cmpq 8(%rsp), %rdx
1548         ja nested_nmi_out
1549
1550 1:
1551         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1552         leaq -1*8(%rsp), %rdx
1553         movq %rdx, %rsp
1554         CFI_ADJUST_CFA_OFFSET 1*8
1555         leaq -10*8(%rsp), %rdx
1556         pushq_cfi $__KERNEL_DS
1557         pushq_cfi %rdx
1558         pushfq_cfi
1559         pushq_cfi $__KERNEL_CS
1560         pushq_cfi $repeat_nmi
1561
1562         /* Put stack back */
1563         addq $(6*8), %rsp
1564         CFI_ADJUST_CFA_OFFSET -6*8
1565
1566 nested_nmi_out:
1567         popq_cfi %rdx
1568         CFI_RESTORE rdx
1569
1570         /* No need to check faults here */
1571         INTERRUPT_RETURN
1572
1573         CFI_RESTORE_STATE
1574 first_nmi:
1575         /*
1576          * Because nested NMIs will use the pushed location that we
1577          * stored in rdx, we must keep that space available.
1578          * Here's what our stack frame will look like:
1579          * +-------------------------+
1580          * | original SS             |
1581          * | original Return RSP     |
1582          * | original RFLAGS         |
1583          * | original CS             |
1584          * | original RIP            |
1585          * +-------------------------+
1586          * | temp storage for rdx    |
1587          * +-------------------------+
1588          * | NMI executing variable  |
1589          * +-------------------------+
1590          * | copied SS               |
1591          * | copied Return RSP       |
1592          * | copied RFLAGS           |
1593          * | copied CS               |
1594          * | copied RIP              |
1595          * +-------------------------+
1596          * | Saved SS                |
1597          * | Saved Return RSP        |
1598          * | Saved RFLAGS            |
1599          * | Saved CS                |
1600          * | Saved RIP               |
1601          * +-------------------------+
1602          * | pt_regs                 |
1603          * +-------------------------+
1604          *
1605          * The saved stack frame is used to fix up the copied stack frame
1606          * that a nested NMI may change to make the interrupted NMI iret jump
1607          * to the repeat_nmi. The original stack frame and the temp storage
1608          * is also used by nested NMIs and can not be trusted on exit.
1609          */
1610         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1611         movq (%rsp), %rdx
1612         CFI_RESTORE rdx
1613
1614         /* Set the NMI executing variable on the stack. */
1615         pushq_cfi $1
1616
1617         /*
1618          * Leave room for the "copied" frame
1619          */
1620         subq $(5*8), %rsp
1621         CFI_ADJUST_CFA_OFFSET 5*8
1622
1623         /* Copy the stack frame to the Saved frame */
1624         .rept 5
1625         pushq_cfi 11*8(%rsp)
1626         .endr
1627         CFI_DEF_CFA_OFFSET SS+8-RIP
1628
1629         /* Everything up to here is safe from nested NMIs */
1630
1631         /*
1632          * If there was a nested NMI, the first NMI's iret will return
1633          * here. But NMIs are still enabled and we can take another
1634          * nested NMI. The nested NMI checks the interrupted RIP to see
1635          * if it is between repeat_nmi and end_repeat_nmi, and if so
1636          * it will just return, as we are about to repeat an NMI anyway.
1637          * This makes it safe to copy to the stack frame that a nested
1638          * NMI will update.
1639          */
1640 repeat_nmi:
1641         /*
1642          * Update the stack variable to say we are still in NMI (the update
1643          * is benign for the non-repeat case, where 1 was pushed just above
1644          * to this very stack slot).
1645          */
1646         movq $1, 10*8(%rsp)
1647
1648         /* Make another copy, this one may be modified by nested NMIs */
1649         addq $(10*8), %rsp
1650         CFI_ADJUST_CFA_OFFSET -10*8
1651         .rept 5
1652         pushq_cfi -6*8(%rsp)
1653         .endr
1654         subq $(5*8), %rsp
1655         CFI_DEF_CFA_OFFSET SS+8-RIP
1656 end_repeat_nmi:
1657
1658         /*
1659          * Everything below this point can be preempted by a nested
1660          * NMI if the first NMI took an exception and reset our iret stack
1661          * so that we repeat another NMI.
1662          */
1663         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1664         subq $ORIG_RAX-R15, %rsp
1665         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1666         /*
1667          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1668          * as we should not be calling schedule in NMI context.
1669          * Even with normal interrupts enabled. An NMI should not be
1670          * setting NEED_RESCHED or anything that normal interrupts and
1671          * exceptions might do.
1672          */
1673         call save_paranoid
1674         DEFAULT_FRAME 0
1675
1676         /*
1677          * Save off the CR2 register. If we take a page fault in the NMI then
1678          * it could corrupt the CR2 value. If the NMI preempts a page fault
1679          * handler before it was able to read the CR2 register, and then the
1680          * NMI itself takes a page fault, the page fault that was preempted
1681          * will read the information from the NMI page fault and not the
1682          * origin fault. Save it off and restore it if it changes.
1683          * Use the r12 callee-saved register.
1684          */
1685         movq %cr2, %r12
1686
1687         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1688         movq %rsp,%rdi
1689         movq $-1,%rsi
1690         call do_nmi
1691
1692         /* Did the NMI take a page fault? Restore cr2 if it did */
1693         movq %cr2, %rcx
1694         cmpq %rcx, %r12
1695         je 1f
1696         movq %r12, %cr2
1697 1:
1698
1699         testl %ebx,%ebx                         /* swapgs needed? */
1700         jnz nmi_restore
1701 nmi_swapgs:
1702         SWAPGS_UNSAFE_STACK
1703 nmi_restore:
1704         /* Pop the extra iret frame at once */
1705         RESTORE_ALL 6*8
1706
1707         /* Clear the NMI executing stack variable */
1708         movq $0, 5*8(%rsp)
1709         jmp irq_return
1710         CFI_ENDPROC
1711 END(nmi)
1712
1713 ENTRY(ignore_sysret)
1714         CFI_STARTPROC
1715         mov $-ENOSYS,%eax
1716         sysret
1717         CFI_ENDPROC
1718 END(ignore_sysret)
1719