arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - idtentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/percpu.h>
  57 #include <asm/asm.h>
  58 #include <asm/context_tracking.h>
  59 #include <asm/smap.h>
  60 #include <asm/pgtable_types.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72
  73 #ifndef CONFIG_PREEMPT
  74 #define retint_kernel retint_restore_args
  75 #endif
  76
  77 #ifdef CONFIG_PARAVIRT
  78 ENTRY(native_usergs_sysret64)
  79         swapgs
  80         sysretq
  81 ENDPROC(native_usergs_sysret64)
  82 #endif /* CONFIG_PARAVIRT */
  83
  84
  85 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
  88         jnc  1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 /*
  95  * When dynamic function tracer is enabled it will add a breakpoint
  96  * to all locations that it is about to modify, sync CPUs, update
  97  * all the code, sync CPUs, then remove the breakpoints. In this time
  98  * if lockdep is enabled, it might jump back into the debug handler
  99  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 100  *
 101  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 102  * make sure the stack pointer does not get reset back to the top
 103  * of the debug stack, and instead just reuses the current stack.
 104  */
 105 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 106
 107 .macro TRACE_IRQS_OFF_DEBUG
 108         call debug_stack_set_zero
 109         TRACE_IRQS_OFF
 110         call debug_stack_reset
 111 .endm
 112
 113 .macro TRACE_IRQS_ON_DEBUG
 114         call debug_stack_set_zero
 115         TRACE_IRQS_ON
 116         call debug_stack_reset
 117 .endm
 118
 119 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 120         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 121         jnc  1f
 122         TRACE_IRQS_ON_DEBUG
 123 1:
 124 .endm
 125
 126 #else
 127 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 128 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 129 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 130 #endif
 131
 132 /*
 133  * C code is not supposed to know about undefined top of stack. Every time
 134  * a C function with an pt_regs argument is called from the SYSCALL based
 135  * fast path FIXUP_TOP_OF_STACK is needed.
 136  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 137  * manipulation.
 138  */
 139
 140         /* %rsp:at FRAMEEND */
 141         .macro FIXUP_TOP_OF_STACK tmp offset=0
 142         movq PER_CPU_VAR(old_rsp),\tmp
 143         movq \tmp,RSP+\offset(%rsp)
 144         movq $__USER_DS,SS+\offset(%rsp)
 145         movq $__USER_CS,CS+\offset(%rsp)
 146         movq $-1,RCX+\offset(%rsp)
 147         movq R11+\offset(%rsp),\tmp  /* get eflags */
 148         movq \tmp,EFLAGS+\offset(%rsp)
 149         .endm
 150
 151         .macro RESTORE_TOP_OF_STACK tmp offset=0
 152         movq RSP+\offset(%rsp),\tmp
 153         movq \tmp,PER_CPU_VAR(old_rsp)
 154         movq EFLAGS+\offset(%rsp),\tmp
 155         movq \tmp,R11+\offset(%rsp)
 156         .endm
 157
 158         .macro FAKE_STACK_FRAME child_rip
 159         /* push in order ss, rsp, eflags, cs, rip */
 160         xorl %eax, %eax
 161         pushq_cfi $__KERNEL_DS /* ss */
 162         /*CFI_REL_OFFSET        ss,0*/
 163         pushq_cfi %rax /* rsp */
 164         CFI_REL_OFFSET  rsp,0
 165         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 166         /*CFI_REL_OFFSET        rflags,0*/
 167         pushq_cfi $__KERNEL_CS /* cs */
 168         /*CFI_REL_OFFSET        cs,0*/
 169         pushq_cfi \child_rip /* rip */
 170         CFI_REL_OFFSET  rip,0
 171         pushq_cfi %rax /* orig rax */
 172         .endm
 173
 174         .macro UNFAKE_STACK_FRAME
 175         addq $8*6, %rsp
 176         CFI_ADJUST_CFA_OFFSET   -(6*8)
 177         .endm
 178
 179 /*
 180  * initial frame state for interrupts (and exceptions without error code)
 181  */
 182         .macro EMPTY_FRAME start=1 offset=0
 183         .if \start
 184         CFI_STARTPROC simple
 185         CFI_SIGNAL_FRAME
 186         CFI_DEF_CFA rsp,8+\offset
 187         .else
 188         CFI_DEF_CFA_OFFSET 8+\offset
 189         .endif
 190         .endm
 191
 192 /*
 193  * initial frame state for interrupts (and exceptions without error code)
 194  */
 195         .macro INTR_FRAME start=1 offset=0
 196         EMPTY_FRAME \start, SS+8+\offset-RIP
 197         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 198         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 199         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 200         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 201         CFI_REL_OFFSET rip, RIP+\offset-RIP
 202         .endm
 203
 204 /*
 205  * initial frame state for exceptions with error code (and interrupts
 206  * with vector already pushed)
 207  */
 208         .macro XCPT_FRAME start=1 offset=0
 209         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 210         .endm
 211
 212 /*
 213  * frame that enables calling into C.
 214  */
 215         .macro PARTIAL_FRAME start=1 offset=0
 216         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 217         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 218         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 219         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 220         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 221         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 222         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 223         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 224         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 225         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 226         .endm
 227
 228 /*
 229  * frame that enables passing a complete pt_regs to a C function.
 230  */
 231         .macro DEFAULT_FRAME start=1 offset=0
 232         PARTIAL_FRAME \start, R11+\offset-R15
 233         CFI_REL_OFFSET rbx, RBX+\offset
 234         CFI_REL_OFFSET rbp, RBP+\offset
 235         CFI_REL_OFFSET r12, R12+\offset
 236         CFI_REL_OFFSET r13, R13+\offset
 237         CFI_REL_OFFSET r14, R14+\offset
 238         CFI_REL_OFFSET r15, R15+\offset
 239         .endm
 240
 241 /* save partial stack frame */
 242         .macro SAVE_ARGS_IRQ
 243         cld
 244         /* start from rbp in pt_regs and jump over */
 245         movq_cfi rdi, (RDI-RBP)
 246         movq_cfi rsi, (RSI-RBP)
 247         movq_cfi rdx, (RDX-RBP)
 248         movq_cfi rcx, (RCX-RBP)
 249         movq_cfi rax, (RAX-RBP)
 250         movq_cfi  r8,  (R8-RBP)
 251         movq_cfi  r9,  (R9-RBP)
 252         movq_cfi r10, (R10-RBP)
 253         movq_cfi r11, (R11-RBP)
 254
 255         /* Save rbp so that we can unwind from get_irq_regs() */
 256         movq_cfi rbp, 0
 257
 258         /* Save previous stack value */
 259         movq %rsp, %rsi
 260
 261         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 262         testl $3, CS-RBP(%rsi)
 263         je 1f
 264         SWAPGS
 265         /*
 266          * irq_count is used to check if a CPU is already on an interrupt stack
 267          * or not. While this is essentially redundant with preempt_count it is
 268          * a little cheaper to use a separate counter in the PDA (short of
 269          * moving irq_enter into assembly, which would be too much work)
 270          */
 271 1:      incl PER_CPU_VAR(irq_count)
 272         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 273         CFI_DEF_CFA_REGISTER    rsi
 274
 275         /* Store previous stack value */
 276         pushq %rsi
 277         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 278                         0x77 /* DW_OP_breg7 */, 0, \
 279                         0x06 /* DW_OP_deref */, \
 280                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 281                         0x22 /* DW_OP_plus */
 282         /* We entered an interrupt context - irqs are off: */
 283         TRACE_IRQS_OFF
 284         .endm
 285
 286 ENTRY(save_paranoid)
 287         XCPT_FRAME 1 RDI+8
 288         cld
 289         movq %rdi, RDI+8(%rsp)
 290         movq %rsi, RSI+8(%rsp)
 291         movq_cfi rdx, RDX+8
 292         movq_cfi rcx, RCX+8
 293         movq_cfi rax, RAX+8
 294         movq %r8, R8+8(%rsp)
 295         movq %r9, R9+8(%rsp)
 296         movq %r10, R10+8(%rsp)
 297         movq %r11, R11+8(%rsp)
 298         movq_cfi rbx, RBX+8
 299         movq %rbp, RBP+8(%rsp)
 300         movq %r12, R12+8(%rsp)
 301         movq %r13, R13+8(%rsp)
 302         movq %r14, R14+8(%rsp)
 303         movq %r15, R15+8(%rsp)
 304         movl $1,%ebx
 305         movl $MSR_GS_BASE,%ecx
 306         rdmsr
 307         testl %edx,%edx
 308         js 1f   /* negative -> in kernel */
 309         SWAPGS
 310         xorl %ebx,%ebx
 311 1:      ret
 312         CFI_ENDPROC
 313 END(save_paranoid)
 314
 315 /*
 316  * A newly forked process directly context switches into this address.
 317  *
 318  * rdi: prev task we switched from
 319  */
 320 ENTRY(ret_from_fork)
 321         DEFAULT_FRAME
 322
 323         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 324
 325         pushq_cfi $0x0002
 326         popfq_cfi                               # reset kernel eflags
 327
 328         call schedule_tail                      # rdi: 'prev' task parameter
 329
 330         GET_THREAD_INFO(%rcx)
 331
 332         RESTORE_REST
 333
 334         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 335         jz   1f
 336
 337         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 338         jnz  int_ret_from_sys_call
 339
 340         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 341         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 342
 343 1:
 344         subq $REST_SKIP, %rsp   # leave space for volatiles
 345         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 346         movq %rbp, %rdi
 347         call *%rbx
 348         movl $0, RAX(%rsp)
 349         RESTORE_REST
 350         jmp int_ret_from_sys_call
 351         CFI_ENDPROC
 352 END(ret_from_fork)
 353
 354 /*
 355  * System call entry. Up to 6 arguments in registers are supported.
 356  *
 357  * SYSCALL does not save anything on the stack and does not change the
 358  * stack pointer.  However, it does mask the flags register for us, so
 359  * CLD and CLAC are not needed.
 360  */
 361
 362 /*
 363  * Register setup:
 364  * rax  system call number
 365  * rdi  arg0
 366  * rcx  return address for syscall/sysret, C arg3
 367  * rsi  arg1
 368  * rdx  arg2
 369  * r10  arg3    (--> moved to rcx for C)
 370  * r8   arg4
 371  * r9   arg5
 372  * r11  eflags for syscall/sysret, temporary for C
 373  * r12-r15,rbp,rbx saved by C code, not touched.
 374  *
 375  * Interrupts are off on entry.
 376  * Only called from user space.
 377  *
 378  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 379  *      and report it properly in ps. Unfortunately we haven't.
 380  *
 381  * When user can change the frames always force IRET. That is because
 382  * it deals with uncanonical addresses better. SYSRET has trouble
 383  * with them due to bugs in both AMD and Intel CPUs.
 384  */
 385
 386 ENTRY(system_call)
 387         CFI_STARTPROC   simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 390         CFI_REGISTER    rip,rcx
 391         /*CFI_REGISTER  rflags,r11*/
 392         SWAPGS_UNSAFE_STACK
 393         /*
 394          * A hypervisor implementation might want to use a label
 395          * after the swapgs, so that it can do the swapgs
 396          * for the guest and jump here on syscall.
 397          */
 398 GLOBAL(system_call_after_swapgs)
 399
 400         movq    %rsp,PER_CPU_VAR(old_rsp)
 401         movq    PER_CPU_VAR(kernel_stack),%rsp
 402         /*
 403          * No need to follow this irqs off/on section - it's straight
 404          * and short:
 405          */
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407         SAVE_ARGS 8, 0, rax_enosys=1
 408         movq_cfi rax,(ORIG_RAX-ARGOFFSET)
 409         movq  %rcx,RIP-ARGOFFSET(%rsp)
 410         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 411         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 412         jnz tracesys
 413 system_call_fastpath:
 414 #if __SYSCALL_MASK == ~0
 415         cmpq $__NR_syscall_max,%rax
 416 #else
 417         andl $__SYSCALL_MASK,%eax
 418         cmpl $__NR_syscall_max,%eax
 419 #endif
 420         ja ret_from_sys_call  /* and return regs->ax */
 421         movq %r10,%rcx
 422         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 423         movq %rax,RAX-ARGOFFSET(%rsp)
 424 /*
 425  * Syscall return path ending with SYSRET (fast path)
 426  * Has incomplete stack frame and undefined top of stack.
 427  */
 428 ret_from_sys_call:
 429         movl $_TIF_ALLWORK_MASK,%edi
 430         /* edi: flagmask */
 431 sysret_check:
 432         LOCKDEP_SYS_EXIT
 433         DISABLE_INTERRUPTS(CLBR_NONE)
 434         TRACE_IRQS_OFF
 435         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 436         andl %edi,%edx
 437         jnz  sysret_careful
 438         CFI_REMEMBER_STATE
 439         /*
 440          * sysretq will re-enable interrupts:
 441          */
 442         TRACE_IRQS_ON
 443         movq RIP-ARGOFFSET(%rsp),%rcx
 444         CFI_REGISTER    rip,rcx
 445         RESTORE_ARGS 1,-ARG_SKIP,0
 446         /*CFI_REGISTER  rflags,r11*/
 447         movq    PER_CPU_VAR(old_rsp), %rsp
 448         USERGS_SYSRET64
 449
 450         CFI_RESTORE_STATE
 451         /* Handle reschedules */
 452         /* edx: work, edi: workmask */
 453 sysret_careful:
 454         bt $TIF_NEED_RESCHED,%edx
 455         jnc sysret_signal
 456         TRACE_IRQS_ON
 457         ENABLE_INTERRUPTS(CLBR_NONE)
 458         pushq_cfi %rdi
 459         SCHEDULE_USER
 460         popq_cfi %rdi
 461         jmp sysret_check
 462
 463         /* Handle a signal */
 464 sysret_signal:
 465         TRACE_IRQS_ON
 466         ENABLE_INTERRUPTS(CLBR_NONE)
 467 #ifdef CONFIG_AUDITSYSCALL
 468         bt $TIF_SYSCALL_AUDIT,%edx
 469         jc sysret_audit
 470 #endif
 471         /*
 472          * We have a signal, or exit tracing or single-step.
 473          * These all wind up with the iret return path anyway,
 474          * so just join that path right now.
 475          */
 476         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 477         jmp int_check_syscall_exit_work
 478
 479 #ifdef CONFIG_AUDITSYSCALL
 480         /*
 481          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 482          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 483          * masked off.
 484          */
 485 sysret_audit:
 486         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 487         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 488         setbe %al               /* 1 if so, 0 if not */
 489         movzbl %al,%edi         /* zero-extend that into %edi */
 490         call __audit_syscall_exit
 491         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 492         jmp sysret_check
 493 #endif  /* CONFIG_AUDITSYSCALL */
 494
 495         /* Do syscall tracing */
 496 tracesys:
 497         leaq -REST_SKIP(%rsp), %rdi
 498         movq $AUDIT_ARCH_X86_64, %rsi
 499         call syscall_trace_enter_phase1
 500         test %rax, %rax
 501         jnz tracesys_phase2             /* if needed, run the slow path */
 502         LOAD_ARGS 0                     /* else restore clobbered regs */
 503         jmp system_call_fastpath        /*      and return to the fast path */
 504
 505 tracesys_phase2:
 506         SAVE_REST
 507         FIXUP_TOP_OF_STACK %rdi
 508         movq %rsp, %rdi
 509         movq $AUDIT_ARCH_X86_64, %rsi
 510         movq %rax,%rdx
 511         call syscall_trace_enter_phase2
 512
 513         /*
 514          * Reload arg registers from stack in case ptrace changed them.
 515          * We don't reload %rax because syscall_trace_entry_phase2() returned
 516          * the value it wants us to use in the table lookup.
 517          */
 518         LOAD_ARGS ARGOFFSET, 1
 519         RESTORE_REST
 520 #if __SYSCALL_MASK == ~0
 521         cmpq $__NR_syscall_max,%rax
 522 #else
 523         andl $__SYSCALL_MASK,%eax
 524         cmpl $__NR_syscall_max,%eax
 525 #endif
 526         ja   int_ret_from_sys_call      /* RAX(%rsp) is already set */
 527         movq %r10,%rcx  /* fixup for C */
 528         call *sys_call_table(,%rax,8)
 529         movq %rax,RAX-ARGOFFSET(%rsp)
 530         /* Use IRET because user could have changed frame */
 531
 532 /*
 533  * Syscall return path ending with IRET.
 534  * Has correct top of stack, but partial stack frame.
 535  */
 536 GLOBAL(int_ret_from_sys_call)
 537         DISABLE_INTERRUPTS(CLBR_NONE)
 538         TRACE_IRQS_OFF
 539         movl $_TIF_ALLWORK_MASK,%edi
 540         /* edi: mask to check */
 541 GLOBAL(int_with_check)
 542         LOCKDEP_SYS_EXIT_IRQ
 543         GET_THREAD_INFO(%rcx)
 544         movl TI_flags(%rcx),%edx
 545         andl %edi,%edx
 546         jnz   int_careful
 547         andl    $~TS_COMPAT,TI_status(%rcx)
 548         jmp   retint_swapgs
 549
 550         /* Either reschedule or signal or syscall exit tracking needed. */
 551         /* First do a reschedule test. */
 552         /* edx: work, edi: workmask */
 553 int_careful:
 554         bt $TIF_NEED_RESCHED,%edx
 555         jnc  int_very_careful
 556         TRACE_IRQS_ON
 557         ENABLE_INTERRUPTS(CLBR_NONE)
 558         pushq_cfi %rdi
 559         SCHEDULE_USER
 560         popq_cfi %rdi
 561         DISABLE_INTERRUPTS(CLBR_NONE)
 562         TRACE_IRQS_OFF
 563         jmp int_with_check
 564
 565         /* handle signals and tracing -- both require a full stack frame */
 566 int_very_careful:
 567         TRACE_IRQS_ON
 568         ENABLE_INTERRUPTS(CLBR_NONE)
 569 int_check_syscall_exit_work:
 570         SAVE_REST
 571         /* Check for syscall exit trace */
 572         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 573         jz int_signal
 574         pushq_cfi %rdi
 575         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 576         call syscall_trace_leave
 577         popq_cfi %rdi
 578         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 579         jmp int_restore_rest
 580
 581 int_signal:
 582         testl $_TIF_DO_NOTIFY_MASK,%edx
 583         jz 1f
 584         movq %rsp,%rdi          # &ptregs -> arg1
 585         xorl %esi,%esi          # oldset -> arg2
 586         call do_notify_resume
 587 1:      movl $_TIF_WORK_MASK,%edi
 588 int_restore_rest:
 589         RESTORE_REST
 590         DISABLE_INTERRUPTS(CLBR_NONE)
 591         TRACE_IRQS_OFF
 592         jmp int_with_check
 593         CFI_ENDPROC
 594 END(system_call)
 595
 596         .macro FORK_LIKE func
 597 ENTRY(stub_\func)
 598         CFI_STARTPROC
 599         popq    %r11                    /* save return address */
 600         PARTIAL_FRAME 0
 601         SAVE_REST
 602         pushq   %r11                    /* put it back on stack */
 603         FIXUP_TOP_OF_STACK %r11, 8
 604         DEFAULT_FRAME 0 8               /* offset 8: return address */
 605         call sys_\func
 606         RESTORE_TOP_OF_STACK %r11, 8
 607         ret $REST_SKIP          /* pop extended registers */
 608         CFI_ENDPROC
 609 END(stub_\func)
 610         .endm
 611
 612         .macro FIXED_FRAME label,func
 613 ENTRY(\label)
 614         CFI_STARTPROC
 615         PARTIAL_FRAME 0 8               /* offset 8: return address */
 616         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 617         call \func
 618         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 619         ret
 620         CFI_ENDPROC
 621 END(\label)
 622         .endm
 623
 624         FORK_LIKE  clone
 625         FORK_LIKE  fork
 626         FORK_LIKE  vfork
 627         FIXED_FRAME stub_iopl, sys_iopl
 628
 629 ENTRY(ptregscall_common)
 630         DEFAULT_FRAME 1 8       /* offset 8: return address */
 631         RESTORE_TOP_OF_STACK %r11, 8
 632         movq_cfi_restore R15+8, r15
 633         movq_cfi_restore R14+8, r14
 634         movq_cfi_restore R13+8, r13
 635         movq_cfi_restore R12+8, r12
 636         movq_cfi_restore RBP+8, rbp
 637         movq_cfi_restore RBX+8, rbx
 638         ret $REST_SKIP          /* pop extended registers */
 639         CFI_ENDPROC
 640 END(ptregscall_common)
 641
 642 ENTRY(stub_execve)
 643         CFI_STARTPROC
 644         addq $8, %rsp
 645         PARTIAL_FRAME 0
 646         SAVE_REST
 647         FIXUP_TOP_OF_STACK %r11
 648         call sys_execve
 649         movq %rax,RAX(%rsp)
 650         RESTORE_REST
 651         jmp int_ret_from_sys_call
 652         CFI_ENDPROC
 653 END(stub_execve)
 654
 655 ENTRY(stub_execveat)
 656         CFI_STARTPROC
 657         addq $8, %rsp
 658         PARTIAL_FRAME 0
 659         SAVE_REST
 660         FIXUP_TOP_OF_STACK %r11
 661         call sys_execveat
 662         RESTORE_TOP_OF_STACK %r11
 663         movq %rax,RAX(%rsp)
 664         RESTORE_REST
 665         jmp int_ret_from_sys_call
 666         CFI_ENDPROC
 667 END(stub_execveat)
 668
 669 /*
 670  * sigreturn is special because it needs to restore all registers on return.
 671  * This cannot be done with SYSRET, so use the IRET return path instead.
 672  */
 673 ENTRY(stub_rt_sigreturn)
 674         CFI_STARTPROC
 675         addq $8, %rsp
 676         PARTIAL_FRAME 0
 677         SAVE_REST
 678         FIXUP_TOP_OF_STACK %r11
 679         call sys_rt_sigreturn
 680         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 681         RESTORE_REST
 682         jmp int_ret_from_sys_call
 683         CFI_ENDPROC
 684 END(stub_rt_sigreturn)
 685
 686 #ifdef CONFIG_X86_X32_ABI
 687 ENTRY(stub_x32_rt_sigreturn)
 688         CFI_STARTPROC
 689         addq $8, %rsp
 690         PARTIAL_FRAME 0
 691         SAVE_REST
 692         FIXUP_TOP_OF_STACK %r11
 693         call sys32_x32_rt_sigreturn
 694         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 695         RESTORE_REST
 696         jmp int_ret_from_sys_call
 697         CFI_ENDPROC
 698 END(stub_x32_rt_sigreturn)
 699
 700 ENTRY(stub_x32_execve)
 701         CFI_STARTPROC
 702         addq $8, %rsp
 703         PARTIAL_FRAME 0
 704         SAVE_REST
 705         FIXUP_TOP_OF_STACK %r11
 706         call compat_sys_execve
 707         RESTORE_TOP_OF_STACK %r11
 708         movq %rax,RAX(%rsp)
 709         RESTORE_REST
 710         jmp int_ret_from_sys_call
 711         CFI_ENDPROC
 712 END(stub_x32_execve)
 713
 714 ENTRY(stub_x32_execveat)
 715         CFI_STARTPROC
 716         addq $8, %rsp
 717         PARTIAL_FRAME 0
 718         SAVE_REST
 719         FIXUP_TOP_OF_STACK %r11
 720         call compat_sys_execveat
 721         RESTORE_TOP_OF_STACK %r11
 722         movq %rax,RAX(%rsp)
 723         RESTORE_REST
 724         jmp int_ret_from_sys_call
 725         CFI_ENDPROC
 726 END(stub_x32_execveat)
 727
 728 #endif
 729
 730 /*
 731  * Build the entry stubs and pointer table with some assembler magic.
 732  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 733  * single cache line on all modern x86 implementations.
 734  */
 735         .section .init.rodata,"a"
 736 ENTRY(interrupt)
 737         .section .entry.text
 738         .p2align 5
 739         .p2align CONFIG_X86_L1_CACHE_SHIFT
 740 ENTRY(irq_entries_start)
 741         INTR_FRAME
 742 vector=FIRST_EXTERNAL_VECTOR
 743 .rept (FIRST_SYSTEM_VECTOR-FIRST_EXTERNAL_VECTOR+6)/7
 744         .balign 32
 745   .rept 7
 746     .if vector < FIRST_SYSTEM_VECTOR
 747       .if vector <> FIRST_EXTERNAL_VECTOR
 748         CFI_ADJUST_CFA_OFFSET -8
 749       .endif
 750 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 751       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 752         jmp 2f
 753       .endif
 754       .previous
 755         .quad 1b
 756       .section .entry.text
 757 vector=vector+1
 758     .endif
 759   .endr
 760 2:      jmp common_interrupt
 761 .endr
 762         CFI_ENDPROC
 763 END(irq_entries_start)
 764
 765 .previous
 766 END(interrupt)
 767 .previous
 768
 769 /*
 770  * Interrupt entry/exit.
 771  *
 772  * Interrupt entry points save only callee clobbered registers in fast path.
 773  *
 774  * Entry runs with interrupts off.
 775  */
 776
 777 /* 0(%rsp): ~(interrupt number) */
 778         .macro interrupt func
 779         /* reserve pt_regs for scratch regs and rbp */
 780         subq $ORIG_RAX-RBP, %rsp
 781         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 782         SAVE_ARGS_IRQ
 783         call \func
 784         .endm
 785
 786         /*
 787          * The interrupt stubs push (~vector+0x80) onto the stack and
 788          * then jump to common_interrupt.
 789          */
 790         .p2align CONFIG_X86_L1_CACHE_SHIFT
 791 common_interrupt:
 792         XCPT_FRAME
 793         ASM_CLAC
 794         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 795         interrupt do_IRQ
 796         /* 0(%rsp): old_rsp-ARGOFFSET */
 797 ret_from_intr:
 798         DISABLE_INTERRUPTS(CLBR_NONE)
 799         TRACE_IRQS_OFF
 800         decl PER_CPU_VAR(irq_count)
 801
 802         /* Restore saved previous stack */
 803         popq %rsi
 804         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 805         leaq ARGOFFSET-RBP(%rsi), %rsp
 806         CFI_DEF_CFA_REGISTER    rsp
 807         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 808
 809 exit_intr:
 810         GET_THREAD_INFO(%rcx)
 811         testl $3,CS-ARGOFFSET(%rsp)
 812         je retint_kernel
 813
 814         /* Interrupt came from user space */
 815         /*
 816          * Has a correct top of stack, but a partial stack frame
 817          * %rcx: thread info. Interrupts off.
 818          */
 819 retint_with_reschedule:
 820         movl $_TIF_WORK_MASK,%edi
 821 retint_check:
 822         LOCKDEP_SYS_EXIT_IRQ
 823         movl TI_flags(%rcx),%edx
 824         andl %edi,%edx
 825         CFI_REMEMBER_STATE
 826         jnz  retint_careful
 827
 828 retint_swapgs:          /* return to user-space */
 829         /*
 830          * The iretq could re-enable interrupts:
 831          */
 832         DISABLE_INTERRUPTS(CLBR_ANY)
 833         TRACE_IRQS_IRETQ
 834         SWAPGS
 835         jmp restore_args
 836
 837 retint_restore_args:    /* return to kernel space */
 838         DISABLE_INTERRUPTS(CLBR_ANY)
 839         /*
 840          * The iretq could re-enable interrupts:
 841          */
 842         TRACE_IRQS_IRETQ
 843 restore_args:
 844         RESTORE_ARGS 1,8,1
 845
 846 irq_return:
 847         INTERRUPT_RETURN
 848
 849 ENTRY(native_iret)
 850         /*
 851          * Are we returning to a stack segment from the LDT?  Note: in
 852          * 64-bit mode SS:RSP on the exception stack is always valid.
 853          */
 854 #ifdef CONFIG_X86_ESPFIX64
 855         testb $4,(SS-RIP)(%rsp)
 856         jnz native_irq_return_ldt
 857 #endif
 858
 859 .global native_irq_return_iret
 860 native_irq_return_iret:
 861         /*
 862          * This may fault.  Non-paranoid faults on return to userspace are
 863          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 864          * Double-faults due to espfix64 are handled in do_double_fault.
 865          * Other faults here are fatal.
 866          */
 867         iretq
 868
 869 #ifdef CONFIG_X86_ESPFIX64
 870 native_irq_return_ldt:
 871         pushq_cfi %rax
 872         pushq_cfi %rdi
 873         SWAPGS
 874         movq PER_CPU_VAR(espfix_waddr),%rdi
 875         movq %rax,(0*8)(%rdi)   /* RAX */
 876         movq (2*8)(%rsp),%rax   /* RIP */
 877         movq %rax,(1*8)(%rdi)
 878         movq (3*8)(%rsp),%rax   /* CS */
 879         movq %rax,(2*8)(%rdi)
 880         movq (4*8)(%rsp),%rax   /* RFLAGS */
 881         movq %rax,(3*8)(%rdi)
 882         movq (6*8)(%rsp),%rax   /* SS */
 883         movq %rax,(5*8)(%rdi)
 884         movq (5*8)(%rsp),%rax   /* RSP */
 885         movq %rax,(4*8)(%rdi)
 886         andl $0xffff0000,%eax
 887         popq_cfi %rdi
 888         orq PER_CPU_VAR(espfix_stack),%rax
 889         SWAPGS
 890         movq %rax,%rsp
 891         popq_cfi %rax
 892         jmp native_irq_return_iret
 893 #endif
 894
 895         /* edi: workmask, edx: work */
 896 retint_careful:
 897         CFI_RESTORE_STATE
 898         bt    $TIF_NEED_RESCHED,%edx
 899         jnc   retint_signal
 900         TRACE_IRQS_ON
 901         ENABLE_INTERRUPTS(CLBR_NONE)
 902         pushq_cfi %rdi
 903         SCHEDULE_USER
 904         popq_cfi %rdi
 905         GET_THREAD_INFO(%rcx)
 906         DISABLE_INTERRUPTS(CLBR_NONE)
 907         TRACE_IRQS_OFF
 908         jmp retint_check
 909
 910 retint_signal:
 911         testl $_TIF_DO_NOTIFY_MASK,%edx
 912         jz    retint_swapgs
 913         TRACE_IRQS_ON
 914         ENABLE_INTERRUPTS(CLBR_NONE)
 915         SAVE_REST
 916         movq $-1,ORIG_RAX(%rsp)
 917         xorl %esi,%esi          # oldset
 918         movq %rsp,%rdi          # &pt_regs
 919         call do_notify_resume
 920         RESTORE_REST
 921         DISABLE_INTERRUPTS(CLBR_NONE)
 922         TRACE_IRQS_OFF
 923         GET_THREAD_INFO(%rcx)
 924         jmp retint_with_reschedule
 925
 926 #ifdef CONFIG_PREEMPT
 927         /* Returning to kernel space. Check if we need preemption */
 928         /* rcx:  threadinfo. interrupts off. */
 929 ENTRY(retint_kernel)
 930         cmpl $0,PER_CPU_VAR(__preempt_count)
 931         jnz  retint_restore_args
 932         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 933         jnc  retint_restore_args
 934         call preempt_schedule_irq
 935         jmp exit_intr
 936 #endif
 937         CFI_ENDPROC
 938 END(common_interrupt)
 939
 940 /*
 941  * APIC interrupts.
 942  */
 943 .macro apicinterrupt3 num sym do_sym
 944 ENTRY(\sym)
 945         INTR_FRAME
 946         ASM_CLAC
 947         pushq_cfi $~(\num)
 948 .Lcommon_\sym:
 949         interrupt \do_sym
 950         jmp ret_from_intr
 951         CFI_ENDPROC
 952 END(\sym)
 953 .endm
 954
 955 #ifdef CONFIG_TRACING
 956 #define trace(sym) trace_##sym
 957 #define smp_trace(sym) smp_trace_##sym
 958
 959 .macro trace_apicinterrupt num sym
 960 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
 961 .endm
 962 #else
 963 .macro trace_apicinterrupt num sym do_sym
 964 .endm
 965 #endif
 966
 967 .macro apicinterrupt num sym do_sym
 968 apicinterrupt3 \num \sym \do_sym
 969 trace_apicinterrupt \num \sym
 970 .endm
 971
 972 #ifdef CONFIG_SMP
 973 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
 974         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 975 apicinterrupt3 REBOOT_VECTOR \
 976         reboot_interrupt smp_reboot_interrupt
 977 #endif
 978
 979 #ifdef CONFIG_X86_UV
 980 apicinterrupt3 UV_BAU_MESSAGE \
 981         uv_bau_message_intr1 uv_bau_message_interrupt
 982 #endif
 983 apicinterrupt LOCAL_TIMER_VECTOR \
 984         apic_timer_interrupt smp_apic_timer_interrupt
 985 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 986         x86_platform_ipi smp_x86_platform_ipi
 987
 988 #ifdef CONFIG_HAVE_KVM
 989 apicinterrupt3 POSTED_INTR_VECTOR \
 990         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
 991 #endif
 992
 993 #ifdef CONFIG_X86_MCE_THRESHOLD
 994 apicinterrupt THRESHOLD_APIC_VECTOR \
 995         threshold_interrupt smp_threshold_interrupt
 996 #endif
 997
 998 #ifdef CONFIG_X86_THERMAL_VECTOR
 999 apicinterrupt THERMAL_APIC_VECTOR \
1000         thermal_interrupt smp_thermal_interrupt
1001 #endif
1002
1003 #ifdef CONFIG_SMP
1004 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1005         call_function_single_interrupt smp_call_function_single_interrupt
1006 apicinterrupt CALL_FUNCTION_VECTOR \
1007         call_function_interrupt smp_call_function_interrupt
1008 apicinterrupt RESCHEDULE_VECTOR \
1009         reschedule_interrupt smp_reschedule_interrupt
1010 #endif
1011
1012 apicinterrupt ERROR_APIC_VECTOR \
1013         error_interrupt smp_error_interrupt
1014 apicinterrupt SPURIOUS_APIC_VECTOR \
1015         spurious_interrupt smp_spurious_interrupt
1016
1017 #ifdef CONFIG_IRQ_WORK
1018 apicinterrupt IRQ_WORK_VECTOR \
1019         irq_work_interrupt smp_irq_work_interrupt
1020 #endif
1021
1022 /*
1023  * Exception entry points.
1024  */
1025 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1026
1027 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
1028 ENTRY(\sym)
1029         /* Sanity check */
1030         .if \shift_ist != -1 && \paranoid == 0
1031         .error "using shift_ist requires paranoid=1"
1032         .endif
1033
1034         .if \has_error_code
1035         XCPT_FRAME
1036         .else
1037         INTR_FRAME
1038         .endif
1039
1040         ASM_CLAC
1041         PARAVIRT_ADJUST_EXCEPTION_FRAME
1042
1043         .ifeq \has_error_code
1044         pushq_cfi $-1                   /* ORIG_RAX: no syscall to restart */
1045         .endif
1046
1047         subq $ORIG_RAX-R15, %rsp
1048         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1049
1050         .if \paranoid
1051         .if \paranoid == 1
1052         CFI_REMEMBER_STATE
1053         testl $3, CS(%rsp)              /* If coming from userspace, switch */
1054         jnz 1f                          /* stacks. */
1055         .endif
1056         call save_paranoid
1057         .else
1058         call error_entry
1059         .endif
1060
1061         DEFAULT_FRAME 0
1062
1063         .if \paranoid
1064         .if \shift_ist != -1
1065         TRACE_IRQS_OFF_DEBUG            /* reload IDT in case of recursion */
1066         .else
1067         TRACE_IRQS_OFF
1068         .endif
1069         .endif
1070
1071         movq %rsp,%rdi                  /* pt_regs pointer */
1072
1073         .if \has_error_code
1074         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1075         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1076         .else
1077         xorl %esi,%esi                  /* no error code */
1078         .endif
1079
1080         .if \shift_ist != -1
1081         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1082         .endif
1083
1084         call \do_sym
1085
1086         .if \shift_ist != -1
1087         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1088         .endif
1089
1090         .if \paranoid
1091         jmp paranoid_exit               /* %ebx: no swapgs flag */
1092         .else
1093         jmp error_exit                  /* %ebx: no swapgs flag */
1094         .endif
1095
1096         .if \paranoid == 1
1097         CFI_RESTORE_STATE
1098         /*
1099          * Paranoid entry from userspace.  Switch stacks and treat it
1100          * as a normal entry.  This means that paranoid handlers
1101          * run in real process context if user_mode(regs).
1102          */
1103 1:
1104         call error_entry
1105
1106         DEFAULT_FRAME 0
1107
1108         movq %rsp,%rdi                  /* pt_regs pointer */
1109         call sync_regs
1110         movq %rax,%rsp                  /* switch stack */
1111
1112         movq %rsp,%rdi                  /* pt_regs pointer */
1113
1114         .if \has_error_code
1115         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1116         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1117         .else
1118         xorl %esi,%esi                  /* no error code */
1119         .endif
1120
1121         call \do_sym
1122
1123         jmp error_exit                  /* %ebx: no swapgs flag */
1124         .endif
1125
1126         CFI_ENDPROC
1127 END(\sym)
1128 .endm
1129
1130 #ifdef CONFIG_TRACING
1131 .macro trace_idtentry sym do_sym has_error_code:req
1132 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
1133 idtentry \sym \do_sym has_error_code=\has_error_code
1134 .endm
1135 #else
1136 .macro trace_idtentry sym do_sym has_error_code:req
1137 idtentry \sym \do_sym has_error_code=\has_error_code
1138 .endm
1139 #endif
1140
1141 idtentry divide_error do_divide_error has_error_code=0
1142 idtentry overflow do_overflow has_error_code=0
1143 idtentry bounds do_bounds has_error_code=0
1144 idtentry invalid_op do_invalid_op has_error_code=0
1145 idtentry device_not_available do_device_not_available has_error_code=0
1146 idtentry double_fault do_double_fault has_error_code=1 paranoid=2
1147 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1148 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1149 idtentry segment_not_present do_segment_not_present has_error_code=1
1150 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1151 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1152 idtentry alignment_check do_alignment_check has_error_code=1
1153 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1154
1155
1156         /* Reload gs selector with exception handling */
1157         /* edi:  new selector */
1158 ENTRY(native_load_gs_index)
1159         CFI_STARTPROC
1160         pushfq_cfi
1161         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1162         SWAPGS
1163 gs_change:
1164         movl %edi,%gs
1165 2:      mfence          /* workaround */
1166         SWAPGS
1167         popfq_cfi
1168         ret
1169         CFI_ENDPROC
1170 END(native_load_gs_index)
1171
1172         _ASM_EXTABLE(gs_change,bad_gs)
1173         .section .fixup,"ax"
1174         /* running with kernelgs */
1175 bad_gs:
1176         SWAPGS                  /* switch back to user gs */
1177         xorl %eax,%eax
1178         movl %eax,%gs
1179         jmp  2b
1180         .previous
1181
1182 /* Call softirq on interrupt stack. Interrupts are off. */
1183 ENTRY(do_softirq_own_stack)
1184         CFI_STARTPROC
1185         pushq_cfi %rbp
1186         CFI_REL_OFFSET rbp,0
1187         mov  %rsp,%rbp
1188         CFI_DEF_CFA_REGISTER rbp
1189         incl PER_CPU_VAR(irq_count)
1190         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1191         push  %rbp                      # backlink for old unwinder
1192         call __do_softirq
1193         leaveq
1194         CFI_RESTORE             rbp
1195         CFI_DEF_CFA_REGISTER    rsp
1196         CFI_ADJUST_CFA_OFFSET   -8
1197         decl PER_CPU_VAR(irq_count)
1198         ret
1199         CFI_ENDPROC
1200 END(do_softirq_own_stack)
1201
1202 #ifdef CONFIG_XEN
1203 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1204
1205 /*
1206  * A note on the "critical region" in our callback handler.
1207  * We want to avoid stacking callback handlers due to events occurring
1208  * during handling of the last event. To do this, we keep events disabled
1209  * until we've done all processing. HOWEVER, we must enable events before
1210  * popping the stack frame (can't be done atomically) and so it would still
1211  * be possible to get enough handler activations to overflow the stack.
1212  * Although unlikely, bugs of that kind are hard to track down, so we'd
1213  * like to avoid the possibility.
1214  * So, on entry to the handler we detect whether we interrupted an
1215  * existing activation in its critical region -- if so, we pop the current
1216  * activation and restart the handler using the previous one.
1217  */
1218 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1219         CFI_STARTPROC
1220 /*
1221  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1222  * see the correct pointer to the pt_regs
1223  */
1224         movq %rdi, %rsp            # we don't return, adjust the stack frame
1225         CFI_ENDPROC
1226         DEFAULT_FRAME
1227 11:     incl PER_CPU_VAR(irq_count)
1228         movq %rsp,%rbp
1229         CFI_DEF_CFA_REGISTER rbp
1230         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1231         pushq %rbp                      # backlink for old unwinder
1232         call xen_evtchn_do_upcall
1233         popq %rsp
1234         CFI_DEF_CFA_REGISTER rsp
1235         decl PER_CPU_VAR(irq_count)
1236         jmp  error_exit
1237         CFI_ENDPROC
1238 END(xen_do_hypervisor_callback)
1239
1240 /*
1241  * Hypervisor uses this for application faults while it executes.
1242  * We get here for two reasons:
1243  *  1. Fault while reloading DS, ES, FS or GS
1244  *  2. Fault while executing IRET
1245  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1246  * registers that could be reloaded and zeroed the others.
1247  * Category 2 we fix up by killing the current process. We cannot use the
1248  * normal Linux return path in this case because if we use the IRET hypercall
1249  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1250  * We distinguish between categories by comparing each saved segment register
1251  * with its current contents: any discrepancy means we in category 1.
1252  */
1253 ENTRY(xen_failsafe_callback)
1254         INTR_FRAME 1 (6*8)
1255         /*CFI_REL_OFFSET gs,GS*/
1256         /*CFI_REL_OFFSET fs,FS*/
1257         /*CFI_REL_OFFSET es,ES*/
1258         /*CFI_REL_OFFSET ds,DS*/
1259         CFI_REL_OFFSET r11,8
1260         CFI_REL_OFFSET rcx,0
1261         movw %ds,%cx
1262         cmpw %cx,0x10(%rsp)
1263         CFI_REMEMBER_STATE
1264         jne 1f
1265         movw %es,%cx
1266         cmpw %cx,0x18(%rsp)
1267         jne 1f
1268         movw %fs,%cx
1269         cmpw %cx,0x20(%rsp)
1270         jne 1f
1271         movw %gs,%cx
1272         cmpw %cx,0x28(%rsp)
1273         jne 1f
1274         /* All segments match their saved values => Category 2 (Bad IRET). */
1275         movq (%rsp),%rcx
1276         CFI_RESTORE rcx
1277         movq 8(%rsp),%r11
1278         CFI_RESTORE r11
1279         addq $0x30,%rsp
1280         CFI_ADJUST_CFA_OFFSET -0x30
1281         pushq_cfi $0    /* RIP */
1282         pushq_cfi %r11
1283         pushq_cfi %rcx
1284         jmp general_protection
1285         CFI_RESTORE_STATE
1286 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1287         movq (%rsp),%rcx
1288         CFI_RESTORE rcx
1289         movq 8(%rsp),%r11
1290         CFI_RESTORE r11
1291         addq $0x30,%rsp
1292         CFI_ADJUST_CFA_OFFSET -0x30
1293         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1294         SAVE_ALL
1295         jmp error_exit
1296         CFI_ENDPROC
1297 END(xen_failsafe_callback)
1298
1299 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1300         xen_hvm_callback_vector xen_evtchn_do_upcall
1301
1302 #endif /* CONFIG_XEN */
1303
1304 #if IS_ENABLED(CONFIG_HYPERV)
1305 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1306         hyperv_callback_vector hyperv_vector_handler
1307 #endif /* CONFIG_HYPERV */
1308
1309 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1310 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1311 idtentry stack_segment do_stack_segment has_error_code=1
1312 #ifdef CONFIG_XEN
1313 idtentry xen_debug do_debug has_error_code=0
1314 idtentry xen_int3 do_int3 has_error_code=0
1315 idtentry xen_stack_segment do_stack_segment has_error_code=1
1316 #endif
1317 idtentry general_protection do_general_protection has_error_code=1
1318 trace_idtentry page_fault do_page_fault has_error_code=1
1319 #ifdef CONFIG_KVM_GUEST
1320 idtentry async_page_fault do_async_page_fault has_error_code=1
1321 #endif
1322 #ifdef CONFIG_X86_MCE
1323 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1324 #endif
1325
1326         /*
1327          * "Paranoid" exit path from exception stack.  This is invoked
1328          * only on return from non-NMI IST interrupts that came
1329          * from kernel space.
1330          *
1331          * We may be returning to very strange contexts (e.g. very early
1332          * in syscall entry), so checking for preemption here would
1333          * be complicated.  Fortunately, we there's no good reason
1334          * to try to handle preemption here.
1335          */
1336
1337         /* ebx: no swapgs flag */
1338 ENTRY(paranoid_exit)
1339         DEFAULT_FRAME
1340         DISABLE_INTERRUPTS(CLBR_NONE)
1341         TRACE_IRQS_OFF_DEBUG
1342         testl %ebx,%ebx                         /* swapgs needed? */
1343         jnz paranoid_restore
1344         TRACE_IRQS_IRETQ 0
1345         SWAPGS_UNSAFE_STACK
1346         RESTORE_ALL 8
1347         INTERRUPT_RETURN
1348 paranoid_restore:
1349         TRACE_IRQS_IRETQ_DEBUG 0
1350         RESTORE_ALL 8
1351         INTERRUPT_RETURN
1352         CFI_ENDPROC
1353 END(paranoid_exit)
1354
1355 /*
1356  * Exception entry point. This expects an error code/orig_rax on the stack.
1357  * returns in "no swapgs flag" in %ebx.
1358  */
1359 ENTRY(error_entry)
1360         XCPT_FRAME
1361         CFI_ADJUST_CFA_OFFSET 15*8
1362         /* oldrax contains error code */
1363         cld
1364         movq %rdi, RDI+8(%rsp)
1365         movq %rsi, RSI+8(%rsp)
1366         movq %rdx, RDX+8(%rsp)
1367         movq %rcx, RCX+8(%rsp)
1368         movq %rax, RAX+8(%rsp)
1369         movq  %r8,  R8+8(%rsp)
1370         movq  %r9,  R9+8(%rsp)
1371         movq %r10, R10+8(%rsp)
1372         movq %r11, R11+8(%rsp)
1373         movq_cfi rbx, RBX+8
1374         movq %rbp, RBP+8(%rsp)
1375         movq %r12, R12+8(%rsp)
1376         movq %r13, R13+8(%rsp)
1377         movq %r14, R14+8(%rsp)
1378         movq %r15, R15+8(%rsp)
1379         xorl %ebx,%ebx
1380         testl $3,CS+8(%rsp)
1381         je error_kernelspace
1382 error_swapgs:
1383         SWAPGS
1384 error_sti:
1385         TRACE_IRQS_OFF
1386         ret
1387
1388 /*
1389  * There are two places in the kernel that can potentially fault with
1390  * usergs. Handle them here.  B stepping K8s sometimes report a
1391  * truncated RIP for IRET exceptions returning to compat mode. Check
1392  * for these here too.
1393  */
1394 error_kernelspace:
1395         CFI_REL_OFFSET rcx, RCX+8
1396         incl %ebx
1397         leaq native_irq_return_iret(%rip),%rcx
1398         cmpq %rcx,RIP+8(%rsp)
1399         je error_bad_iret
1400         movl %ecx,%eax  /* zero extend */
1401         cmpq %rax,RIP+8(%rsp)
1402         je bstep_iret
1403         cmpq $gs_change,RIP+8(%rsp)
1404         je error_swapgs
1405         jmp error_sti
1406
1407 bstep_iret:
1408         /* Fix truncated RIP */
1409         movq %rcx,RIP+8(%rsp)
1410         /* fall through */
1411
1412 error_bad_iret:
1413         SWAPGS
1414         mov %rsp,%rdi
1415         call fixup_bad_iret
1416         mov %rax,%rsp
1417         decl %ebx       /* Return to usergs */
1418         jmp error_sti
1419         CFI_ENDPROC
1420 END(error_entry)
1421
1422
1423 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1424 ENTRY(error_exit)
1425         DEFAULT_FRAME
1426         movl %ebx,%eax
1427         RESTORE_REST
1428         DISABLE_INTERRUPTS(CLBR_NONE)
1429         TRACE_IRQS_OFF
1430         GET_THREAD_INFO(%rcx)
1431         testl %eax,%eax
1432         jne retint_kernel
1433         LOCKDEP_SYS_EXIT_IRQ
1434         movl TI_flags(%rcx),%edx
1435         movl $_TIF_WORK_MASK,%edi
1436         andl %edi,%edx
1437         jnz retint_careful
1438         jmp retint_swapgs
1439         CFI_ENDPROC
1440 END(error_exit)
1441
1442 /*
1443  * Test if a given stack is an NMI stack or not.
1444  */
1445         .macro test_in_nmi reg stack nmi_ret normal_ret
1446         cmpq %\reg, \stack
1447         ja \normal_ret
1448         subq $EXCEPTION_STKSZ, %\reg
1449         cmpq %\reg, \stack
1450         jb \normal_ret
1451         jmp \nmi_ret
1452         .endm
1453
1454         /* runs on exception stack */
1455 ENTRY(nmi)
1456         INTR_FRAME
1457         PARAVIRT_ADJUST_EXCEPTION_FRAME
1458         /*
1459          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1460          * the iretq it performs will take us out of NMI context.
1461          * This means that we can have nested NMIs where the next
1462          * NMI is using the top of the stack of the previous NMI. We
1463          * can't let it execute because the nested NMI will corrupt the
1464          * stack of the previous NMI. NMI handlers are not re-entrant
1465          * anyway.
1466          *
1467          * To handle this case we do the following:
1468          *  Check the a special location on the stack that contains
1469          *  a variable that is set when NMIs are executing.
1470          *  The interrupted task's stack is also checked to see if it
1471          *  is an NMI stack.
1472          *  If the variable is not set and the stack is not the NMI
1473          *  stack then:
1474          *    o Set the special variable on the stack
1475          *    o Copy the interrupt frame into a "saved" location on the stack
1476          *    o Copy the interrupt frame into a "copy" location on the stack
1477          *    o Continue processing the NMI
1478          *  If the variable is set or the previous stack is the NMI stack:
1479          *    o Modify the "copy" location to jump to the repeate_nmi
1480          *    o return back to the first NMI
1481          *
1482          * Now on exit of the first NMI, we first clear the stack variable
1483          * The NMI stack will tell any nested NMIs at that point that it is
1484          * nested. Then we pop the stack normally with iret, and if there was
1485          * a nested NMI that updated the copy interrupt stack frame, a
1486          * jump will be made to the repeat_nmi code that will handle the second
1487          * NMI.
1488          */
1489
1490         /* Use %rdx as out temp variable throughout */
1491         pushq_cfi %rdx
1492         CFI_REL_OFFSET rdx, 0
1493
1494         /*
1495          * If %cs was not the kernel segment, then the NMI triggered in user
1496          * space, which means it is definitely not nested.
1497          */
1498         cmpl $__KERNEL_CS, 16(%rsp)
1499         jne first_nmi
1500
1501         /*
1502          * Check the special variable on the stack to see if NMIs are
1503          * executing.
1504          */
1505         cmpl $1, -8(%rsp)
1506         je nested_nmi
1507
1508         /*
1509          * Now test if the previous stack was an NMI stack.
1510          * We need the double check. We check the NMI stack to satisfy the
1511          * race when the first NMI clears the variable before returning.
1512          * We check the variable because the first NMI could be in a
1513          * breakpoint routine using a breakpoint stack.
1514          */
1515         lea 6*8(%rsp), %rdx
1516         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1517         CFI_REMEMBER_STATE
1518
1519 nested_nmi:
1520         /*
1521          * Do nothing if we interrupted the fixup in repeat_nmi.
1522          * It's about to repeat the NMI handler, so we are fine
1523          * with ignoring this one.
1524          */
1525         movq $repeat_nmi, %rdx
1526         cmpq 8(%rsp), %rdx
1527         ja 1f
1528         movq $end_repeat_nmi, %rdx
1529         cmpq 8(%rsp), %rdx
1530         ja nested_nmi_out
1531
1532 1:
1533         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1534         leaq -1*8(%rsp), %rdx
1535         movq %rdx, %rsp
1536         CFI_ADJUST_CFA_OFFSET 1*8
1537         leaq -10*8(%rsp), %rdx
1538         pushq_cfi $__KERNEL_DS
1539         pushq_cfi %rdx
1540         pushfq_cfi
1541         pushq_cfi $__KERNEL_CS
1542         pushq_cfi $repeat_nmi
1543
1544         /* Put stack back */
1545         addq $(6*8), %rsp
1546         CFI_ADJUST_CFA_OFFSET -6*8
1547
1548 nested_nmi_out:
1549         popq_cfi %rdx
1550         CFI_RESTORE rdx
1551
1552         /* No need to check faults here */
1553         INTERRUPT_RETURN
1554
1555         CFI_RESTORE_STATE
1556 first_nmi:
1557         /*
1558          * Because nested NMIs will use the pushed location that we
1559          * stored in rdx, we must keep that space available.
1560          * Here's what our stack frame will look like:
1561          * +-------------------------+
1562          * | original SS             |
1563          * | original Return RSP     |
1564          * | original RFLAGS         |
1565          * | original CS             |
1566          * | original RIP            |
1567          * +-------------------------+
1568          * | temp storage for rdx    |
1569          * +-------------------------+
1570          * | NMI executing variable  |
1571          * +-------------------------+
1572          * | copied SS               |
1573          * | copied Return RSP       |
1574          * | copied RFLAGS           |
1575          * | copied CS               |
1576          * | copied RIP              |
1577          * +-------------------------+
1578          * | Saved SS                |
1579          * | Saved Return RSP        |
1580          * | Saved RFLAGS            |
1581          * | Saved CS                |
1582          * | Saved RIP               |
1583          * +-------------------------+
1584          * | pt_regs                 |
1585          * +-------------------------+
1586          *
1587          * The saved stack frame is used to fix up the copied stack frame
1588          * that a nested NMI may change to make the interrupted NMI iret jump
1589          * to the repeat_nmi. The original stack frame and the temp storage
1590          * is also used by nested NMIs and can not be trusted on exit.
1591          */
1592         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1593         movq (%rsp), %rdx
1594         CFI_RESTORE rdx
1595
1596         /* Set the NMI executing variable on the stack. */
1597         pushq_cfi $1
1598
1599         /*
1600          * Leave room for the "copied" frame
1601          */
1602         subq $(5*8), %rsp
1603         CFI_ADJUST_CFA_OFFSET 5*8
1604
1605         /* Copy the stack frame to the Saved frame */
1606         .rept 5
1607         pushq_cfi 11*8(%rsp)
1608         .endr
1609         CFI_DEF_CFA_OFFSET SS+8-RIP
1610
1611         /* Everything up to here is safe from nested NMIs */
1612
1613         /*
1614          * If there was a nested NMI, the first NMI's iret will return
1615          * here. But NMIs are still enabled and we can take another
1616          * nested NMI. The nested NMI checks the interrupted RIP to see
1617          * if it is between repeat_nmi and end_repeat_nmi, and if so
1618          * it will just return, as we are about to repeat an NMI anyway.
1619          * This makes it safe to copy to the stack frame that a nested
1620          * NMI will update.
1621          */
1622 repeat_nmi:
1623         /*
1624          * Update the stack variable to say we are still in NMI (the update
1625          * is benign for the non-repeat case, where 1 was pushed just above
1626          * to this very stack slot).
1627          */
1628         movq $1, 10*8(%rsp)
1629
1630         /* Make another copy, this one may be modified by nested NMIs */
1631         addq $(10*8), %rsp
1632         CFI_ADJUST_CFA_OFFSET -10*8
1633         .rept 5
1634         pushq_cfi -6*8(%rsp)
1635         .endr
1636         subq $(5*8), %rsp
1637         CFI_DEF_CFA_OFFSET SS+8-RIP
1638 end_repeat_nmi:
1639
1640         /*
1641          * Everything below this point can be preempted by a nested
1642          * NMI if the first NMI took an exception and reset our iret stack
1643          * so that we repeat another NMI.
1644          */
1645         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1646         subq $ORIG_RAX-R15, %rsp
1647         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1648         /*
1649          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1650          * as we should not be calling schedule in NMI context.
1651          * Even with normal interrupts enabled. An NMI should not be
1652          * setting NEED_RESCHED or anything that normal interrupts and
1653          * exceptions might do.
1654          */
1655         call save_paranoid
1656         DEFAULT_FRAME 0
1657
1658         /*
1659          * Save off the CR2 register. If we take a page fault in the NMI then
1660          * it could corrupt the CR2 value. If the NMI preempts a page fault
1661          * handler before it was able to read the CR2 register, and then the
1662          * NMI itself takes a page fault, the page fault that was preempted
1663          * will read the information from the NMI page fault and not the
1664          * origin fault. Save it off and restore it if it changes.
1665          * Use the r12 callee-saved register.
1666          */
1667         movq %cr2, %r12
1668
1669         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1670         movq %rsp,%rdi
1671         movq $-1,%rsi
1672         call do_nmi
1673
1674         /* Did the NMI take a page fault? Restore cr2 if it did */
1675         movq %cr2, %rcx
1676         cmpq %rcx, %r12
1677         je 1f
1678         movq %r12, %cr2
1679 1:
1680
1681         testl %ebx,%ebx                         /* swapgs needed? */
1682         jnz nmi_restore
1683 nmi_swapgs:
1684         SWAPGS_UNSAFE_STACK
1685 nmi_restore:
1686         /* Pop the extra iret frame at once */
1687         RESTORE_ALL 6*8
1688
1689         /* Clear the NMI executing stack variable */
1690         movq $0, 5*8(%rsp)
1691         jmp irq_return
1692         CFI_ENDPROC
1693 END(nmi)
1694
1695 ENTRY(ignore_sysret)
1696         CFI_STARTPROC
1697         mov $-ENOSYS,%eax
1698         sysret
1699         CFI_ENDPROC
1700 END(ignore_sysret)
1701