arch/x86/realmode/rm/realmode.lds.S

   1 /*
   2  * realmode.lds.S
   3  *
   4  * Linker script for the real-mode code
   5  */
   6
   7 #include <asm/page_types.h>
   8
   9 #undef i386
  10
  11 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  12 OUTPUT_ARCH(i386)
  13
  14 SECTIONS
  15 {
  16         real_mode_seg = 0;
  17
  18         . = 0;
  19         .header : {
  20                 pa_real_mode_base = .;
  21                 *(.header)
  22         }
  23
  24         . = ALIGN(4);
  25         .rodata : {
  26                 *(.rodata)
  27                 *(.rodata.*)
  28         }
  29
  30         . = ALIGN(PAGE_SIZE);
  31         .text : {
  32                 pa_text_start = .;
  33                 *(.text)
  34                 *(.text.*)
  35         }
  36
  37         .text32 : {
  38                 *(.text32)
  39                 *(.text32.*)
  40                 pa_ro_end = .;
  41         }
  42
  43         . = ALIGN(PAGE_SIZE);
  44         .data : {
  45                 *(.data)
  46                 *(.data.*)
  47         }
  48
  49         . = ALIGN(128);
  50         .bss : {
  51                 *(.bss*)
  52         }
  53
  54         /* End signature for integrity checking */
  55         . = ALIGN(4);
  56         .signature : {
  57                 *(.signature)
  58                 pa_end = .;
  59         }
  60
  61         /DISCARD/ : {
  62                 *(.note*)
  63                 *(.debug*)
  64                 *(.eh_frame*)
  65         }
  66
  67 #include "pasyms.h"
  68 }