arch/openrisc/kernel/vmlinux.lds.S

   1 /*
   2  * OpenRISC vmlinux.lds.S
   3  *
   4  * Linux architectural port borrowing liberally from similar works of
   5  * others.  All original copyrights apply as per the original source
   6  * declaration.
   7  *
   8  * Modifications for the OpenRISC architecture:
   9  * Copyright (C) 2003 Matjaz Breskvar <phoenix@bsemi.com>
  10  * Copyright (C) 2010-2011 Jonas Bonn <jonas@southpole.se>
  11  *
  12  *      This program is free software; you can redistribute it and/or
  13  *      modify it under the terms of the GNU General Public License
  14  *      as published by the Free Software Foundation; either version
  15  *      2 of the License, or (at your option) any later version.
  16  *
  17  * ld script for OpenRISC architecture
  18  */
  19
  20 /* TODO
  21  *              - clean up __offset & stuff
  22  *              - change all 8192 aligment to PAGE !!!
  23  *              - recheck if all aligments are really needed
  24  */
  25
  26 #  define LOAD_OFFSET  PAGE_OFFSET
  27 #  define LOAD_BASE    PAGE_OFFSET
  28
  29 #include <asm/page.h>
  30 #include <asm/cache.h>
  31 #include <asm-generic/vmlinux.lds.h>
  32
  33 OUTPUT_FORMAT("elf32-or32", "elf32-or32", "elf32-or32")
  34 jiffies = jiffies_64 + 4;
  35
  36 SECTIONS
  37 {
  38         /* Read-only sections, merged into text segment: */
  39         . = LOAD_BASE ;
  40
  41         /* _s_kernel_ro must be page aligned */
  42         . = ALIGN(PAGE_SIZE);
  43         _s_kernel_ro = .;
  44
  45         .text                   : AT(ADDR(.text) - LOAD_OFFSET)
  46         {
  47           _stext = .;
  48           TEXT_TEXT
  49           SCHED_TEXT
  50           CPUIDLE_TEXT
  51           LOCK_TEXT
  52           KPROBES_TEXT
  53           IRQENTRY_TEXT
  54           SOFTIRQENTRY_TEXT
  55           *(.fixup)
  56           *(.text.__*)
  57           _etext = .;
  58         }
  59         /* TODO: Check if fixup and text.__* are really necessary
  60          * fixup is definitely necessary
  61          */
  62
  63         _sdata = .;
  64
  65         /* Page alignment required for RO_DATA_SECTION */
  66         RO_DATA_SECTION(PAGE_SIZE)
  67         _e_kernel_ro = .;
  68
  69         /* Whatever comes after _e_kernel_ro had better be page-aligend, too */
  70
  71         /* 32 here is cacheline size... recheck this */
  72         RW_DATA_SECTION(32, PAGE_SIZE, PAGE_SIZE)
  73
  74         _edata  =  .;
  75
  76         EXCEPTION_TABLE(4)
  77         NOTES
  78
  79         /* Init code and data */
  80         . = ALIGN(PAGE_SIZE);
  81         __init_begin = .;
  82
  83         HEAD_TEXT_SECTION
  84
  85         /* Page aligned */
  86         INIT_TEXT_SECTION(PAGE_SIZE)
  87
  88         /* Align __setup_start on 16 byte boundary */
  89         INIT_DATA_SECTION(16)
  90
  91         PERCPU_SECTION(L1_CACHE_BYTES)
  92
  93         __init_end = .;
  94
  95         . = ALIGN(PAGE_SIZE);
  96         .initrd                 : AT(ADDR(.initrd) - LOAD_OFFSET)
  97         {
  98                 __initrd_start = .;
  99                 *(.initrd)
 100                 __initrd_end = .;
 101                 FILL (0);
 102                 . = ALIGN (PAGE_SIZE);
 103         }
 104
 105         __vmlinux_end = .;            /* last address of the physical file */
 106
 107         BSS_SECTION(0, 0, 0x20)
 108
 109         _end = .;
 110
 111         /* Throw in the debugging sections */
 112         STABS_DEBUG
 113         DWARF_DEBUG
 114
 115         /* Sections to be discarded -- must be last */
 116         DISCARDS
 117 }