arch/powerpc/kernel/vmlinux.lds.S

   1 #ifdef CONFIG_PPC64
   2 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   3 #else
   4 #define PROVIDE32(x)    PROVIDE(x)
   5 #endif
   6 #include <asm/page.h>
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/thread_info.h>
  10
  11 ENTRY(_stext)
  12
  13 PHDRS {
  14         kernel PT_LOAD FLAGS(7); /* RWX */
  15         notes PT_NOTE FLAGS(0);
  16         dummy PT_NOTE FLAGS(0);
  17
  18         /* binutils < 2.18 has a bug that makes it misbehave when taking an
  19            ELF file with all segments at load address 0 as input.  This
  20            happens when running "strip" on vmlinux, because of the AT() magic
  21            in this linker script.  People using GCC >= 4.2 won't run into
  22            this problem, because the "build-id" support will put some data
  23            into the "notes" segment (at a non-zero load address).
  24
  25            To work around this, we force some data into both the "dummy"
  26            segment and the kernel segment, so the dummy segment will get a
  27            non-zero load address.  It's not enough to always create the
  28            "notes" segment, since if nothing gets assigned to it, its load
  29            address will be zero.  */
  30 }
  31
  32 #ifdef CONFIG_PPC64
  33 OUTPUT_ARCH(powerpc:common64)
  34 jiffies = jiffies_64;
  35 #else
  36 OUTPUT_ARCH(powerpc:common)
  37 jiffies = jiffies_64 + 4;
  38 #endif
  39 SECTIONS
  40 {
  41         . = KERNELBASE;
  42
  43 /*
  44  * Text, read only data and other permanent read-only sections
  45  */
  46
  47         /* Text and gots */
  48         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  49                 ALIGN_FUNCTION();
  50                 HEAD_TEXT
  51                 _text = .;
  52                 /* careful! __ftr_alt_* sections need to be close to .text */
  53                 *(.text .fixup __ftr_alt_* .ref.text)
  54                 SCHED_TEXT
  55                 CPUIDLE_TEXT
  56                 LOCK_TEXT
  57                 KPROBES_TEXT
  58                 IRQENTRY_TEXT
  59                 SOFTIRQENTRY_TEXT
  60
  61 #ifdef CONFIG_PPC32
  62                 *(.got1)
  63                 __got2_start = .;
  64                 *(.got2)
  65                 __got2_end = .;
  66 #endif /* CONFIG_PPC32 */
  67
  68         } :kernel
  69
  70         . = ALIGN(PAGE_SIZE);
  71         _etext = .;
  72         PROVIDE32 (etext = .);
  73
  74         /* Read-only data */
  75         RODATA
  76
  77         EXCEPTION_TABLE(0)
  78
  79         NOTES :kernel :notes
  80
  81         /* The dummy segment contents for the bug workaround mentioned above
  82            near PHDRS.  */
  83         .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
  84                 LONG(0)
  85                 LONG(0)
  86                 LONG(0)
  87         } :kernel :dummy
  88
  89 /*
  90  * Init sections discarded at runtime
  91  */
  92         . = ALIGN(PAGE_SIZE);
  93         __init_begin = .;
  94         INIT_TEXT_SECTION(PAGE_SIZE) :kernel
  95
  96         /* .exit.text is discarded at runtime, not link time,
  97          * to deal with references from __bug_table
  98          */
  99         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 100                 EXIT_TEXT
 101         }
 102
 103         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 104                 INIT_DATA
 105                 __vtop_table_begin = .;
 106                 *(.vtop_fixup);
 107                 __vtop_table_end = .;
 108                 __ptov_table_begin = .;
 109                 *(.ptov_fixup);
 110                 __ptov_table_end = .;
 111         }
 112
 113         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 114                 INIT_SETUP(16)
 115         }
 116
 117         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 118                 INIT_CALLS
 119         }
 120
 121         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 122                 CON_INITCALL
 123         }
 124
 125         SECURITY_INIT
 126
 127         . = ALIGN(8);
 128         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 129                 __start___ftr_fixup = .;
 130                 *(__ftr_fixup)
 131                 __stop___ftr_fixup = .;
 132         }
 133         . = ALIGN(8);
 134         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 135                 __start___mmu_ftr_fixup = .;
 136                 *(__mmu_ftr_fixup)
 137                 __stop___mmu_ftr_fixup = .;
 138         }
 139         . = ALIGN(8);
 140         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 141                 __start___lwsync_fixup = .;
 142                 *(__lwsync_fixup)
 143                 __stop___lwsync_fixup = .;
 144         }
 145 #ifdef CONFIG_PPC64
 146         . = ALIGN(8);
 147         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 148                 __start___fw_ftr_fixup = .;
 149                 *(__fw_ftr_fixup)
 150                 __stop___fw_ftr_fixup = .;
 151         }
 152 #endif
 153         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 154                 INIT_RAM_FS
 155         }
 156
 157         PERCPU_SECTION(L1_CACHE_BYTES)
 158
 159         . = ALIGN(8);
 160         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 161                 __machine_desc_start = . ;
 162                 *(.machine.desc)
 163                 __machine_desc_end = . ;
 164         }
 165 #ifdef CONFIG_RELOCATABLE
 166         . = ALIGN(8);
 167         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 168         {
 169 #ifdef CONFIG_PPC32
 170                 __dynamic_symtab = .;
 171 #endif
 172                 *(.dynsym)
 173         }
 174         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 175         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 176         {
 177                 __dynamic_start = .;
 178                 *(.dynamic)
 179         }
 180         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 181         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 182         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 183         {
 184                 __rela_dyn_start = .;
 185                 *(.rela*)
 186         }
 187 #endif
 188         /* .exit.data is discarded at runtime, not link time,
 189          * to deal with references from .exit.text
 190          */
 191         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 192                 EXIT_DATA
 193         }
 194
 195         /* freed after init ends here */
 196         . = ALIGN(PAGE_SIZE);
 197         __init_end = .;
 198
 199 /*
 200  * And now the various read/write data
 201  */
 202
 203         . = ALIGN(PAGE_SIZE);
 204         _sdata = .;
 205
 206 #ifdef CONFIG_PPC32
 207         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 208                 DATA_DATA
 209                 *(.sdata)
 210                 *(.got.plt) *(.got)
 211         }
 212 #else
 213         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 214                 DATA_DATA
 215                 *(.data.rel*)
 216                 *(.toc1)
 217                 *(.branch_lt)
 218         }
 219
 220         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 221                 *(.opd)
 222         }
 223
 224         . = ALIGN(256);
 225         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 226                 __toc_start = .;
 227 #ifndef CONFIG_RELOCATABLE
 228                 __prom_init_toc_start = .;
 229                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 230                 __prom_init_toc_end = .;
 231 #endif
 232                 *(.got)
 233                 *(.toc)
 234         }
 235 #endif
 236
 237         /* The initial task and kernel stack */
 238         INIT_TASK_DATA_SECTION(THREAD_SIZE)
 239
 240         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 241                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 242         }
 243
 244         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 245                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 246         }
 247
 248         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 249                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 250         }
 251
 252         . = ALIGN(PAGE_SIZE);
 253         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 254                 NOSAVE_DATA
 255         }
 256
 257         . = ALIGN(PAGE_SIZE);
 258         _edata  =  .;
 259         PROVIDE32 (edata = .);
 260
 261 /*
 262  * And finally the bss
 263  */
 264
 265         BSS_SECTION(0, 0, 0)
 266
 267         . = ALIGN(PAGE_SIZE);
 268         _end = . ;
 269         PROVIDE32 (end = .);
 270
 271         /* Sections to be discarded. */
 272         DISCARDS
 273 }