tests/kmod-macros.at

   1 # OVS_KMOD_VSWITCHD_START([vsctl-args], [vsctl-output], [=override])
   2 #
   3 # Creates a database and starts ovsdb-server, starts ovs-vswitchd
   4 # connected to that database, calls ovs-vsctl to create a bridge named
   5 # br0 with predictable settings, passing 'vsctl-args' as additional
   6 # commands to ovs-vsctl.  If 'vsctl-args' causes ovs-vsctl to provide
   7 # output (e.g. because it includes "create" commands) then 'vsctl-output'
   8 # specifies the expected output after filtering through uuidfilt.pl.
   9 #
  10 m4_define([OVS_KMOD_VSWITCHD_START],
  11   [ AT_CHECK([modprobe openvswitch])
  12    _OVS_VSWITCHD_START([])
  13    dnl Add bridges, ports, etc.
  14    AT_CHECK([ovs-vsctl -- add-br br0 -- set bridge br0 protocols=[[OpenFlow10,OpenFlow11,OpenFlow12,OpenFlow13,OpenFlow14,OpenFlow15]] fail-mode=secure -- $1 m4_if([$2], [], [], [| ${PERL} $srcdir/uuidfilt.pl])], [0], [$2])
  15 ])
  16 #
  17 #
  18 # OVS_KMOD_VSWITCHD_STOP([WHITELIST], [extra_cmds])
  19 #
  20 # Gracefully stops ovs-vswitchd and ovsdb-server, checking their log files
  21 # for messages with severity WARN or higher and signaling an error if any
  22 # is present.  The optional WHITELIST may contain shell-quoted "sed"
  23 # commands to delete any warnings that are actually expected, e.g.:
  24 #
  25 #   OVS_KMOD_VSWITCHD_STOP(["/expected error/d"])
  26 #
  27 # 'extra_cmds' are shell commands to be executed afte OVS_VSWITCHD_STOP() is
  28 # invoked. They can be used to perform additional cleanups such as name space
  29 # removal.
  30 m4_define([OVS_KMOD_VSWITCHD_STOP],
  31   [AT_CHECK([ovs-vsctl del-br br0])
  32    OVS_VSWITCHD_STOP([$1])
  33    AT_CHECK([:; $2])
  34    AT_CHECK([modprobe -r openvswitch])
  35   ])
  36
  37 # DEL_NAMESPACES(ns [, ns ... ])
  38 #
  39 # Delete namespaces from the running OS
  40 m4_define([DEL_NAMESPACES],
  41    [m4_foreach([ns], [$@],
  42                [ip netns del ns
  43 ])
  44    ]
  45 )
  46 #
  47 # ADD_NAMESPACES(ns [, ns ... ])
  48 #
  49 # Add new namespaces, if ns exists, the old one
  50 # will be remove before new ones are installed.
  51 m4_define([ADD_NAMESPACES],
  52    [m4_foreach([ns], [$@],
  53                [DEL_NAMESPACES(ns)
  54                 AT_CHECK([ip netns add ns])
  55                ])
  56    ]
  57 )
  58
  59 # ADD_VETH([port], [namespace], [ovs-br], [ip_addr])
  60 #
  61 # Add a pair of veth ports. 'port' will be added to name space 'namespace',
  62 # and "ovs-'port'" will be added to ovs bridge 'ovs-br'.
  63 #
  64 # The 'port' in 'namespace' will be brought up with static IP address
  65 # with 'ip_addr' in CIDR notation.
  66 #
  67 # The existing 'port' or 'ovs-port' will be removed before new ones are added.
  68 #
  69 m4_define([ADD_VETH],
  70     [ AT_CHECK([ip link add $1 type veth peer name ovs-$1])
  71       AT_CHECK([ip link set $1 netns $2])
  72       AT_CHECK([ovs-vsctl add-port $3 ovs-$1])
  73       AT_CHECK([ip link set dev ovs-$1 up])
  74       AT_CHECK([ip netns exec $2 ip addr add $4 dev $1])
  75       AT_CHECK([ip netns exec $2 ip link set dev $1 up])
  76     ]
  77 )