arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #ifdef CONFIG_XIP_KERNEL
   7 #include "vmlinux-xip.lds.S"
   8 #else
   9
  10 #include <asm-generic/vmlinux.lds.h>
  11 #include <asm/cache.h>
  12 #include <asm/thread_info.h>
  13 #include <asm/memory.h>
  14 #include <asm/page.h>
  15 #include <asm/pgtable.h>
  16
  17 #define PROC_INFO                                                       \
  18         . = ALIGN(4);                                                   \
  19         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  20         *(.proc.info.init)                                              \
  21         VMLINUX_SYMBOL(__proc_info_end) = .;
  22
  23 #define HYPERVISOR_TEXT                                                 \
  24         VMLINUX_SYMBOL(__hyp_text_start) = .;                           \
  25         *(.hyp.text)                                                    \
  26         VMLINUX_SYMBOL(__hyp_text_end) = .;
  27
  28 #define IDMAP_TEXT                                                      \
  29         ALIGN_FUNCTION();                                               \
  30         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  31         *(.idmap.text)                                                  \
  32         VMLINUX_SYMBOL(__idmap_text_end) = .;                           \
  33         . = ALIGN(PAGE_SIZE);                                           \
  34         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;                     \
  35         *(.hyp.idmap.text)                                              \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;
  37
  38 #ifdef CONFIG_HOTPLUG_CPU
  39 #define ARM_CPU_DISCARD(x)
  40 #define ARM_CPU_KEEP(x)         x
  41 #else
  42 #define ARM_CPU_DISCARD(x)      x
  43 #define ARM_CPU_KEEP(x)
  44 #endif
  45
  46 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  47         defined(CONFIG_GENERIC_BUG)
  48 #define ARM_EXIT_KEEP(x)        x
  49 #define ARM_EXIT_DISCARD(x)
  50 #else
  51 #define ARM_EXIT_KEEP(x)
  52 #define ARM_EXIT_DISCARD(x)     x
  53 #endif
  54
  55 OUTPUT_ARCH(arm)
  56 ENTRY(stext)
  57
  58 #ifndef __ARMEB__
  59 jiffies = jiffies_64;
  60 #else
  61 jiffies = jiffies_64 + 4;
  62 #endif
  63
  64 SECTIONS
  65 {
  66         /*
  67          * XXX: The linker does not define how output sections are
  68          * assigned to input sections when there are multiple statements
  69          * matching the same input section name.  There is no documented
  70          * order of matching.
  71          *
  72          * unwind exit sections must be discarded before the rest of the
  73          * unwind sections get included.
  74          */
  75         /DISCARD/ : {
  76                 *(.ARM.exidx.exit.text)
  77                 *(.ARM.extab.exit.text)
  78                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  79                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  80                 ARM_EXIT_DISCARD(EXIT_TEXT)
  81                 ARM_EXIT_DISCARD(EXIT_DATA)
  82                 EXIT_CALL
  83 #ifndef CONFIG_MMU
  84                 *(.text.fixup)
  85                 *(__ex_table)
  86 #endif
  87 #ifndef CONFIG_SMP_ON_UP
  88                 *(.alt.smp.init)
  89 #endif
  90                 *(.discard)
  91                 *(.discard.*)
  92         }
  93
  94         . = PAGE_OFFSET + TEXT_OFFSET;
  95         .head.text : {
  96                 _text = .;
  97                 HEAD_TEXT
  98         }
  99
 100 #ifdef CONFIG_DEBUG_RODATA
 101         . = ALIGN(1<<SECTION_SHIFT);
 102 #endif
 103
 104         .text : {                       /* Real text segment            */
 105                 _stext = .;             /* Text and read-only data      */
 106                         IDMAP_TEXT
 107                         __exception_text_start = .;
 108                         *(.exception.text)
 109                         __exception_text_end = .;
 110                         IRQENTRY_TEXT
 111                         TEXT_TEXT
 112                         SCHED_TEXT
 113                         LOCK_TEXT
 114                         HYPERVISOR_TEXT
 115                         KPROBES_TEXT
 116                         *(.gnu.warning)
 117                         *(.glue_7)
 118                         *(.glue_7t)
 119                 . = ALIGN(4);
 120                 *(.got)                 /* Global offset table          */
 121                         ARM_CPU_KEEP(PROC_INFO)
 122         }
 123
 124 #ifdef CONFIG_DEBUG_ALIGN_RODATA
 125         . = ALIGN(1<<SECTION_SHIFT);
 126 #endif
 127         RO_DATA(PAGE_SIZE)
 128
 129         . = ALIGN(4);
 130         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
 131                 __start___ex_table = .;
 132 #ifdef CONFIG_MMU
 133                 *(__ex_table)
 134 #endif
 135                 __stop___ex_table = .;
 136         }
 137
 138 #ifdef CONFIG_ARM_UNWIND
 139         /*
 140          * Stack unwinding tables
 141          */
 142         . = ALIGN(8);
 143         .ARM.unwind_idx : {
 144                 __start_unwind_idx = .;
 145                 *(.ARM.exidx*)
 146                 __stop_unwind_idx = .;
 147         }
 148         .ARM.unwind_tab : {
 149                 __start_unwind_tab = .;
 150                 *(.ARM.extab*)
 151                 __stop_unwind_tab = .;
 152         }
 153 #endif
 154
 155         NOTES
 156
 157         _etext = .;                     /* End of text and rodata section */
 158
 159 #ifdef CONFIG_DEBUG_RODATA
 160         . = ALIGN(1<<SECTION_SHIFT);
 161 #else
 162         . = ALIGN(PAGE_SIZE);
 163 #endif
 164         __init_begin = .;
 165
 166         /*
 167          * The vectors and stubs are relocatable code, and the
 168          * only thing that matters is their relative offsets
 169          */
 170         __vectors_start = .;
 171         .vectors 0xffff0000 : AT(__vectors_start) {
 172                 *(.vectors)
 173         }
 174         . = __vectors_start + SIZEOF(.vectors);
 175         __vectors_end = .;
 176
 177         __stubs_start = .;
 178         .stubs ADDR(.vectors) + 0x1000 : AT(__stubs_start) {
 179                 *(.stubs)
 180         }
 181         . = __stubs_start + SIZEOF(.stubs);
 182         __stubs_end = .;
 183
 184         PROVIDE(vector_fiq_offset = vector_fiq - ADDR(.vectors));
 185
 186         INIT_TEXT_SECTION(8)
 187         .exit.text : {
 188                 ARM_EXIT_KEEP(EXIT_TEXT)
 189         }
 190         .init.proc.info : {
 191                 ARM_CPU_DISCARD(PROC_INFO)
 192         }
 193         .init.arch.info : {
 194                 __arch_info_begin = .;
 195                 *(.arch.info.init)
 196                 __arch_info_end = .;
 197         }
 198         .init.tagtable : {
 199                 __tagtable_begin = .;
 200                 *(.taglist.init)
 201                 __tagtable_end = .;
 202         }
 203 #ifdef CONFIG_SMP_ON_UP
 204         .init.smpalt : {
 205                 __smpalt_begin = .;
 206                 *(.alt.smp.init)
 207                 __smpalt_end = .;
 208         }
 209 #endif
 210         .init.pv_table : {
 211                 __pv_table_begin = .;
 212                 *(.pv_table)
 213                 __pv_table_end = .;
 214         }
 215         .init.data : {
 216                 INIT_DATA
 217                 INIT_SETUP(16)
 218                 INIT_CALLS
 219                 CON_INITCALL
 220                 SECURITY_INITCALL
 221                 INIT_RAM_FS
 222         }
 223         .exit.data : {
 224                 ARM_EXIT_KEEP(EXIT_DATA)
 225         }
 226
 227 #ifdef CONFIG_SMP
 228         PERCPU_SECTION(L1_CACHE_BYTES)
 229 #endif
 230
 231 #ifdef CONFIG_DEBUG_RODATA
 232         . = ALIGN(1<<SECTION_SHIFT);
 233 #else
 234         . = ALIGN(THREAD_SIZE);
 235 #endif
 236         __init_end = .;
 237         __data_loc = .;
 238
 239         .data : AT(__data_loc) {
 240                 _data = .;              /* address in memory */
 241                 _sdata = .;
 242
 243                 /*
 244                  * first, the init task union, aligned
 245                  * to an 8192 byte boundary.
 246                  */
 247                 INIT_TASK_DATA(THREAD_SIZE)
 248
 249                 NOSAVE_DATA
 250                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 251                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 252
 253                 /*
 254                  * and the usual data section
 255                  */
 256                 DATA_DATA
 257                 CONSTRUCTORS
 258
 259                 _edata = .;
 260         }
 261         _edata_loc = __data_loc + SIZEOF(.data);
 262
 263 #ifdef CONFIG_HAVE_TCM
 264         /*
 265          * We align everything to a page boundary so we can
 266          * free it after init has commenced and TCM contents have
 267          * been copied to its destination.
 268          */
 269         .tcm_start : {
 270                 . = ALIGN(PAGE_SIZE);
 271                 __tcm_start = .;
 272                 __itcm_start = .;
 273         }
 274
 275         /*
 276          * Link these to the ITCM RAM
 277          * Put VMA to the TCM address and LMA to the common RAM
 278          * and we'll upload the contents from RAM to TCM and free
 279          * the used RAM after that.
 280          */
 281         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 282         {
 283                 __sitcm_text = .;
 284                 *(.tcm.text)
 285                 *(.tcm.rodata)
 286                 . = ALIGN(4);
 287                 __eitcm_text = .;
 288         }
 289
 290         /*
 291          * Reset the dot pointer, this is needed to create the
 292          * relative __dtcm_start below (to be used as extern in code).
 293          */
 294         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 295
 296         .dtcm_start : {
 297                 __dtcm_start = .;
 298         }
 299
 300         /* TODO: add remainder of ITCM as well, that can be used for data! */
 301         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 302         {
 303                 . = ALIGN(4);
 304                 __sdtcm_data = .;
 305                 *(.tcm.data)
 306                 . = ALIGN(4);
 307                 __edtcm_data = .;
 308         }
 309
 310         /* Reset the dot pointer or the linker gets confused */
 311         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 312
 313         /* End marker for freeing TCM copy in linked object */
 314         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 315                 . = ALIGN(PAGE_SIZE);
 316                 __tcm_end = .;
 317         }
 318 #endif
 319
 320         BSS_SECTION(0, 0, 0)
 321         _end = .;
 322
 323         STABS_DEBUG
 324 }
 325
 326 #ifdef CONFIG_DEBUG_RODATA
 327 /*
 328  * Without CONFIG_DEBUG_ALIGN_RODATA, __start_rodata_section_aligned will
 329  * be the first section-aligned location after __start_rodata. Otherwise,
 330  * it will be equal to __start_rodata.
 331  */
 332 __start_rodata_section_aligned = ALIGN(__start_rodata, 1 << SECTION_SHIFT);
 333 #endif
 334
 335 /*
 336  * These must never be empty
 337  * If you have to comment these two assert statements out, your
 338  * binutils is too old (for other reasons as well)
 339  */
 340 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 341 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
 342
 343 /*
 344  * The HYP init code can't be more than a page long,
 345  * and should not cross a page boundary.
 346  * The above comment applies as well.
 347  */
 348 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & PAGE_MASK) <= PAGE_SIZE,
 349         "HYP init code too big or misaligned")
 350
 351 #endif /* CONFIG_XIP_KERNEL */