arch/arm/lib/getuser.S

   1 /*
   2  *  linux/arch/arm/lib/getuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make them more
  13  * efficient, especially as they return an error value in addition to
  14  * the "real" return value.
  15  *
  16  * __get_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r1 contains the address limit, which must be preserved
  20  * Outputs:     r0 is the error code
  21  *              r2, r3 contains the zero-extended value
  22  *              lr corrupted
  23  *
  24  * No other registers must be altered.  (see <asm/uaccess.h>
  25  * for specific ASM register usage).
  26  *
  27  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  28  * Note also that it is intended that __get_user_bad is not global.
  29  */
  30 #include <linux/linkage.h>
  31 #include <asm/assembler.h>
  32 #include <asm/errno.h>
  33 #include <asm/domain.h>
  34 #include <asm/export.h>
  35
  36 ENTRY(__get_user_1)
  37         check_uaccess r0, 1, r1, r2, __get_user_bad
  38 1: TUSER(ldrb)  r2, [r0]
  39         mov     r0, #0
  40         ret     lr
  41 ENDPROC(__get_user_1)
  42 EXPORT_SYMBOL(__get_user_1)
  43
  44 ENTRY(__get_user_2)
  45         check_uaccess r0, 2, r1, r2, __get_user_bad
  46 #ifdef CONFIG_CPU_USE_DOMAINS
  47 rb      .req    ip
  48 2:      ldrbt   r2, [r0], #1
  49 3:      ldrbt   rb, [r0], #0
  50 #else
  51 rb      .req    r0
  52 2:      ldrb    r2, [r0]
  53 3:      ldrb    rb, [r0, #1]
  54 #endif
  55 #ifndef __ARMEB__
  56         orr     r2, r2, rb, lsl #8
  57 #else
  58         orr     r2, rb, r2, lsl #8
  59 #endif
  60         mov     r0, #0
  61         ret     lr
  62 ENDPROC(__get_user_2)
  63 EXPORT_SYMBOL(__get_user_2)
  64
  65 ENTRY(__get_user_4)
  66         check_uaccess r0, 4, r1, r2, __get_user_bad
  67 4: TUSER(ldr)   r2, [r0]
  68         mov     r0, #0
  69         ret     lr
  70 ENDPROC(__get_user_4)
  71 EXPORT_SYMBOL(__get_user_4)
  72
  73 ENTRY(__get_user_8)
  74         check_uaccess r0, 8, r1, r2, __get_user_bad
  75 #ifdef CONFIG_THUMB2_KERNEL
  76 5: TUSER(ldr)   r2, [r0]
  77 6: TUSER(ldr)   r3, [r0, #4]
  78 #else
  79 5: TUSER(ldr)   r2, [r0], #4
  80 6: TUSER(ldr)   r3, [r0]
  81 #endif
  82         mov     r0, #0
  83         ret     lr
  84 ENDPROC(__get_user_8)
  85 EXPORT_SYMBOL(__get_user_8)
  86
  87 #ifdef __ARMEB__
  88 ENTRY(__get_user_32t_8)
  89         check_uaccess r0, 8, r1, r2, __get_user_bad
  90 #ifdef CONFIG_CPU_USE_DOMAINS
  91         add     r0, r0, #4
  92 7:      ldrt    r2, [r0]
  93 #else
  94 7:      ldr     r2, [r0, #4]
  95 #endif
  96         mov     r0, #0
  97         ret     lr
  98 ENDPROC(__get_user_32t_8)
  99 EXPORT_SYMBOL(__get_user_32t_8)
 100
 101 ENTRY(__get_user_64t_1)
 102         check_uaccess r0, 1, r1, r2, __get_user_bad8
 103 8: TUSER(ldrb)  r3, [r0]
 104         mov     r0, #0
 105         ret     lr
 106 ENDPROC(__get_user_64t_1)
 107 EXPORT_SYMBOL(__get_user_64t_1)
 108
 109 ENTRY(__get_user_64t_2)
 110         check_uaccess r0, 2, r1, r2, __get_user_bad8
 111 #ifdef CONFIG_CPU_USE_DOMAINS
 112 rb      .req    ip
 113 9:      ldrbt   r3, [r0], #1
 114 10:     ldrbt   rb, [r0], #0
 115 #else
 116 rb      .req    r0
 117 9:      ldrb    r3, [r0]
 118 10:     ldrb    rb, [r0, #1]
 119 #endif
 120         orr     r3, rb, r3, lsl #8
 121         mov     r0, #0
 122         ret     lr
 123 ENDPROC(__get_user_64t_2)
 124 EXPORT_SYMBOL(__get_user_64t_2)
 125
 126 ENTRY(__get_user_64t_4)
 127         check_uaccess r0, 4, r1, r2, __get_user_bad8
 128 11: TUSER(ldr)  r3, [r0]
 129         mov     r0, #0
 130         ret     lr
 131 ENDPROC(__get_user_64t_4)
 132 EXPORT_SYMBOL(__get_user_64t_4)
 133 #endif
 134
 135 __get_user_bad8:
 136         mov     r3, #0
 137 __get_user_bad:
 138         mov     r2, #0
 139         mov     r0, #-EFAULT
 140         ret     lr
 141 ENDPROC(__get_user_bad)
 142 ENDPROC(__get_user_bad8)
 143
 144 .pushsection __ex_table, "a"
 145         .long   1b, __get_user_bad
 146         .long   2b, __get_user_bad
 147         .long   3b, __get_user_bad
 148         .long   4b, __get_user_bad
 149         .long   5b, __get_user_bad8
 150         .long   6b, __get_user_bad8
 151 #ifdef __ARMEB__
 152         .long   7b, __get_user_bad
 153         .long   8b, __get_user_bad8
 154         .long   9b, __get_user_bad8
 155         .long   10b, __get_user_bad8
 156         .long   11b, __get_user_bad8
 157 #endif
 158 .popsection