arch/arm/mach-shmobile/headsmp.S

   1 /*
   2  * SMP support for R-Mobile / SH-Mobile
   3  *
   4  * Copyright (C) 2010  Magnus Damm
   5  * Copyright (C) 2010  Takashi Yoshii
   6  *
   7  * Based on vexpress, Copyright (c) 2003 ARM Limited, All Rights Reserved
   8  *
   9  * This program is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License version 2 as
  11  * published by the Free Software Foundation.
  12  */
  13 #include <linux/init.h>
  14 #include <linux/linkage.h>
  15 #include <linux/threads.h>
  16 #include <asm/assembler.h>
  17 #include <asm/memory.h>
  18
  19 #ifdef CONFIG_SMP
  20 ENTRY(shmobile_invalidate_start)
  21         bl      v7_invalidate_l1
  22         b       secondary_startup
  23 ENDPROC(shmobile_invalidate_start)
  24 #endif
  25
  26 /*
  27  * Reset vector for secondary CPUs.
  28  * This will be mapped at address 0 by SBAR register.
  29  * We need _long_ jump to the physical address.
  30  */
  31         .arm
  32         .align  12
  33 ENTRY(shmobile_boot_vector)
  34         ldr     r0, 2f
  35         ldr     r1, 1f
  36         bx      r1
  37
  38 ENDPROC(shmobile_boot_vector)
  39
  40         .align  2
  41         .globl  shmobile_boot_fn
  42 shmobile_boot_fn:
  43 1:      .space  4
  44         .globl  shmobile_boot_arg
  45 shmobile_boot_arg:
  46 2:      .space  4
  47         .globl  shmobile_boot_size
  48 shmobile_boot_size:
  49         .long   . - shmobile_boot_vector
  50
  51 /*
  52  * Per-CPU SMP boot function/argument selection code based on MPIDR
  53  */
  54
  55 ENTRY(shmobile_smp_boot)
  56                                                 @ r0 = MPIDR_HWID_BITMASK
  57         mrc     p15, 0, r1, c0, c0, 5           @ r1 = MPIDR
  58         and     r0, r1, r0                      @ r0 = cpu_logical_map() value
  59         mov     r1, #0                          @ r1 = CPU index
  60         adr     r5, 1f                          @ array of per-cpu mpidr values
  61         adr     r6, 2f                          @ array of per-cpu functions
  62         adr     r7, 3f                          @ array of per-cpu arguments
  63
  64 shmobile_smp_boot_find_mpidr:
  65         ldr     r8, [r5, r1, lsl #2]
  66         cmp     r8, r0
  67         bne     shmobile_smp_boot_next
  68
  69         ldr     r9, [r6, r1, lsl #2]
  70         cmp     r9, #0
  71         bne     shmobile_smp_boot_found
  72
  73 shmobile_smp_boot_next:
  74         add     r1, r1, #1
  75         cmp     r1, #NR_CPUS
  76         blo     shmobile_smp_boot_find_mpidr
  77
  78         b       shmobile_smp_sleep
  79
  80 shmobile_smp_boot_found:
  81         ldr     r0, [r7, r1, lsl #2]
  82         ret     r9
  83 ENDPROC(shmobile_smp_boot)
  84
  85 ENTRY(shmobile_smp_sleep)
  86         wfi
  87         b       shmobile_smp_boot
  88 ENDPROC(shmobile_smp_sleep)
  89
  90         .globl  shmobile_smp_mpidr
  91 shmobile_smp_mpidr:
  92 1:      .space  NR_CPUS * 4
  93         .globl  shmobile_smp_fn
  94 shmobile_smp_fn:
  95 2:      .space  NR_CPUS * 4
  96         .globl  shmobile_smp_arg
  97 shmobile_smp_arg:
  98 3:      .space  NR_CPUS * 4