arch/arm64/kernel/hyp-stub.S

   1 /*
   2  * Hypervisor stub
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Author:      Marc Zyngier <marc.zyngier@arm.com>
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18  */
  19
  20 #include <linux/init.h>
  21 #include <linux/linkage.h>
  22 #include <linux/irqchip/arm-gic-v3.h>
  23
  24 #include <asm/assembler.h>
  25 #include <asm/kvm_arm.h>
  26 #include <asm/kvm_asm.h>
  27 #include <asm/ptrace.h>
  28 #include <asm/virt.h>
  29
  30         .text
  31         .align 11
  32
  33 ENTRY(__hyp_stub_vectors)
  34         ventry  el2_sync_invalid                // Synchronous EL2t
  35         ventry  el2_irq_invalid                 // IRQ EL2t
  36         ventry  el2_fiq_invalid                 // FIQ EL2t
  37         ventry  el2_error_invalid               // Error EL2t
  38
  39         ventry  el2_sync_invalid                // Synchronous EL2h
  40         ventry  el2_irq_invalid                 // IRQ EL2h
  41         ventry  el2_fiq_invalid                 // FIQ EL2h
  42         ventry  el2_error_invalid               // Error EL2h
  43
  44         ventry  el1_sync                        // Synchronous 64-bit EL1
  45         ventry  el1_irq_invalid                 // IRQ 64-bit EL1
  46         ventry  el1_fiq_invalid                 // FIQ 64-bit EL1
  47         ventry  el1_error_invalid               // Error 64-bit EL1
  48
  49         ventry  el1_sync_invalid                // Synchronous 32-bit EL1
  50         ventry  el1_irq_invalid                 // IRQ 32-bit EL1
  51         ventry  el1_fiq_invalid                 // FIQ 32-bit EL1
  52         ventry  el1_error_invalid               // Error 32-bit EL1
  53 ENDPROC(__hyp_stub_vectors)
  54
  55         .align 11
  56
  57 el1_sync:
  58         mrs     x30, esr_el2
  59         lsr     x30, x30, #ESR_ELx_EC_SHIFT
  60
  61         cmp     x30, #ESR_ELx_EC_HVC64
  62         b.ne    9f                              // Not an HVC trap
  63
  64         cmp     x0, #HVC_GET_VECTORS
  65         b.ne    1f
  66         mrs     x0, vbar_el2
  67         b       9f
  68
  69 1:      cmp     x0, #HVC_SET_VECTORS
  70         b.ne    2f
  71         msr     vbar_el2, x1
  72         b       9f
  73
  74         /* Someone called kvm_call_hyp() against the hyp-stub... */
  75 2:      mov     x0, #ARM_EXCEPTION_HYP_GONE
  76
  77 9:      eret
  78 ENDPROC(el1_sync)
  79
  80 .macro invalid_vector   label
  81 \label:
  82         b \label
  83 ENDPROC(\label)
  84 .endm
  85
  86         invalid_vector  el2_sync_invalid
  87         invalid_vector  el2_irq_invalid
  88         invalid_vector  el2_fiq_invalid
  89         invalid_vector  el2_error_invalid
  90         invalid_vector  el1_sync_invalid
  91         invalid_vector  el1_irq_invalid
  92         invalid_vector  el1_fiq_invalid
  93         invalid_vector  el1_error_invalid
  94
  95 /*
  96  * __hyp_set_vectors: Call this after boot to set the initial hypervisor
  97  * vectors as part of hypervisor installation.  On an SMP system, this should
  98  * be called on each CPU.
  99  *
 100  * x0 must be the physical address of the new vector table, and must be
 101  * 2KB aligned.
 102  *
 103  * Before calling this, you must check that the stub hypervisor is installed
 104  * everywhere, by waiting for any secondary CPUs to be brought up and then
 105  * checking that is_hyp_mode_available() is true.
 106  *
 107  * If not, there is a pre-existing hypervisor, some CPUs failed to boot, or
 108  * something else went wrong... in such cases, trying to install a new
 109  * hypervisor is unlikely to work as desired.
 110  *
 111  * When you call into your shiny new hypervisor, sp_el2 will contain junk,
 112  * so you will need to set that to something sensible at the new hypervisor's
 113  * initialisation entry point.
 114  */
 115
 116 ENTRY(__hyp_get_vectors)
 117         str     lr, [sp, #-16]!
 118         mov     x0, #HVC_GET_VECTORS
 119         hvc     #0
 120         ldr     lr, [sp], #16
 121         ret
 122 ENDPROC(__hyp_get_vectors)
 123
 124 ENTRY(__hyp_set_vectors)
 125         str     lr, [sp, #-16]!
 126         mov     x1, x0
 127         mov     x0, #HVC_SET_VECTORS
 128         hvc     #0
 129         ldr     lr, [sp], #16
 130         ret
 131 ENDPROC(__hyp_set_vectors)