arch/mips/kernel/mcount.S

   1 /*
   2  * MIPS specific _mcount support
   3  *
   4  * This file is subject to the terms and conditions of the GNU General Public
   5  * License.  See the file "COPYING" in the main directory of this archive for
   6  * more details.
   7  *
   8  * Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
   9  * Copyright (C) 2010 DSLab, Lanzhou University, China
  10  * Author: Wu Zhangjin <wuzhangjin@gmail.com>
  11  */
  12
  13 #include <asm/regdef.h>
  14 #include <asm/stackframe.h>
  15 #include <asm/ftrace.h>
  16
  17         .text
  18         .set noreorder
  19         .set noat
  20
  21         .macro MCOUNT_SAVE_REGS
  22         PTR_SUBU        sp, PT_SIZE
  23         PTR_S   ra, PT_R31(sp)
  24         PTR_S   AT, PT_R1(sp)
  25         PTR_S   a0, PT_R4(sp)
  26         PTR_S   a1, PT_R5(sp)
  27         PTR_S   a2, PT_R6(sp)
  28         PTR_S   a3, PT_R7(sp)
  29 #ifdef CONFIG_64BIT
  30         PTR_S   a4, PT_R8(sp)
  31         PTR_S   a5, PT_R9(sp)
  32         PTR_S   a6, PT_R10(sp)
  33         PTR_S   a7, PT_R11(sp)
  34 #endif
  35         .endm
  36
  37         .macro MCOUNT_RESTORE_REGS
  38         PTR_L   ra, PT_R31(sp)
  39         PTR_L   AT, PT_R1(sp)
  40         PTR_L   a0, PT_R4(sp)
  41         PTR_L   a1, PT_R5(sp)
  42         PTR_L   a2, PT_R6(sp)
  43         PTR_L   a3, PT_R7(sp)
  44 #ifdef CONFIG_64BIT
  45         PTR_L   a4, PT_R8(sp)
  46         PTR_L   a5, PT_R9(sp)
  47         PTR_L   a6, PT_R10(sp)
  48         PTR_L   a7, PT_R11(sp)
  49 #endif
  50         PTR_ADDIU       sp, PT_SIZE
  51         .endm
  52
  53         .macro RETURN_BACK
  54         jr ra
  55          move ra, AT
  56         .endm
  57
  58 /*
  59  * The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
  60  * the location of the parent's return address.
  61  */
  62 #define MCOUNT_RA_ADDRESS_REG   $12
  63
  64 #ifdef CONFIG_DYNAMIC_FTRACE
  65
  66 NESTED(ftrace_caller, PT_SIZE, ra)
  67         .globl _mcount
  68 _mcount:
  69         b       ftrace_stub
  70 #ifdef CONFIG_32BIT
  71          addiu sp,sp,8
  72 #else
  73          nop
  74 #endif
  75
  76         /* When tracing is activated, it calls ftrace_caller+8 (aka here) */
  77         MCOUNT_SAVE_REGS
  78 #ifdef KBUILD_MCOUNT_RA_ADDRESS
  79         PTR_S   MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
  80 #endif
  81
  82         PTR_SUBU a0, ra, 8      /* arg1: self address */
  83         .globl ftrace_call
  84 ftrace_call:
  85         nop     /* a placeholder for the call to a real tracing function */
  86          move   a1, AT          /* arg2: parent's return address */
  87
  88 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  89         .globl ftrace_graph_call
  90 ftrace_graph_call:
  91         nop
  92          nop
  93 #endif
  94
  95         MCOUNT_RESTORE_REGS
  96         .globl ftrace_stub
  97 ftrace_stub:
  98         RETURN_BACK
  99         END(ftrace_caller)
 100
 101 #else   /* ! CONFIG_DYNAMIC_FTRACE */
 102
 103 NESTED(_mcount, PT_SIZE, ra)
 104         PTR_LA  t1, ftrace_stub
 105         PTR_L   t2, ftrace_trace_function /* Prepare t2 for (1) */
 106         bne     t1, t2, static_trace
 107          nop
 108
 109 #ifdef  CONFIG_FUNCTION_GRAPH_TRACER
 110         PTR_L   t3, ftrace_graph_return
 111         bne     t1, t3, ftrace_graph_caller
 112          nop
 113         PTR_LA  t1, ftrace_graph_entry_stub
 114         PTR_L   t3, ftrace_graph_entry
 115         bne     t1, t3, ftrace_graph_caller
 116          nop
 117 #endif
 118         b       ftrace_stub
 119          nop
 120
 121 static_trace:
 122         MCOUNT_SAVE_REGS
 123
 124         move    a0, ra          /* arg1: self return address */
 125         jalr    t2              /* (1) call *ftrace_trace_function */
 126          move   a1, AT          /* arg2: parent's return address */
 127
 128         MCOUNT_RESTORE_REGS
 129         .globl ftrace_stub
 130 ftrace_stub:
 131         RETURN_BACK
 132         END(_mcount)
 133
 134 #endif  /* ! CONFIG_DYNAMIC_FTRACE */
 135
 136 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 137
 138 NESTED(ftrace_graph_caller, PT_SIZE, ra)
 139 #ifndef CONFIG_DYNAMIC_FTRACE
 140         MCOUNT_SAVE_REGS
 141 #endif
 142
 143         /* arg1: Get the location of the parent's return address */
 144 #ifdef KBUILD_MCOUNT_RA_ADDRESS
 145 #ifdef CONFIG_DYNAMIC_FTRACE
 146         PTR_L   a0, PT_R12(sp)
 147 #else
 148         move    a0, MCOUNT_RA_ADDRESS_REG
 149 #endif
 150         bnez    a0, 1f  /* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
 151          nop
 152 #endif
 153         PTR_LA  a0, PT_R1(sp)   /* leaf func: the location in current stack */
 154 1:
 155
 156         /* arg2: Get self return address */
 157 #ifdef CONFIG_DYNAMIC_FTRACE
 158         PTR_L   a1, PT_R31(sp)
 159 #else
 160         move    a1, ra
 161 #endif
 162
 163         /* arg3: Get frame pointer of current stack */
 164 #ifdef CONFIG_64BIT
 165         PTR_LA  a2, PT_SIZE(sp)
 166 #else
 167         PTR_LA  a2, (PT_SIZE+8)(sp)
 168 #endif
 169
 170         jal     prepare_ftrace_return
 171          nop
 172         MCOUNT_RESTORE_REGS
 173         RETURN_BACK
 174         END(ftrace_graph_caller)
 175
 176         .align  2
 177         .globl  return_to_handler
 178 return_to_handler:
 179         PTR_SUBU        sp, PT_SIZE
 180         PTR_S   v0, PT_R2(sp)
 181
 182         jal     ftrace_return_to_handler
 183          PTR_S  v1, PT_R3(sp)
 184
 185         /* restore the real parent address: v0 -> ra */
 186         move    ra, v0
 187
 188         PTR_L   v0, PT_R2(sp)
 189         PTR_L   v1, PT_R3(sp)
 190         jr      ra
 191          PTR_ADDIU      sp, PT_SIZE
 192 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
 193
 194         .set at
 195         .set reorder