arch/powerpc/kernel/vmlinux.lds.S

   1 #ifdef CONFIG_PPC64
   2 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   3 #else
   4 #define PROVIDE32(x)    PROVIDE(x)
   5 #endif
   6 #include <asm/page.h>
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/thread_info.h>
  10
  11 ENTRY(_stext)
  12
  13 PHDRS {
  14         kernel PT_LOAD FLAGS(7); /* RWX */
  15         notes PT_NOTE FLAGS(0);
  16         dummy PT_NOTE FLAGS(0);
  17
  18         /* binutils < 2.18 has a bug that makes it misbehave when taking an
  19            ELF file with all segments at load address 0 as input.  This
  20            happens when running "strip" on vmlinux, because of the AT() magic
  21            in this linker script.  People using GCC >= 4.2 won't run into
  22            this problem, because the "build-id" support will put some data
  23            into the "notes" segment (at a non-zero load address).
  24
  25            To work around this, we force some data into both the "dummy"
  26            segment and the kernel segment, so the dummy segment will get a
  27            non-zero load address.  It's not enough to always create the
  28            "notes" segment, since if nothing gets assigned to it, its load
  29            address will be zero.  */
  30 }
  31
  32 #ifdef CONFIG_PPC64
  33 OUTPUT_ARCH(powerpc:common64)
  34 jiffies = jiffies_64;
  35 #else
  36 OUTPUT_ARCH(powerpc:common)
  37 jiffies = jiffies_64 + 4;
  38 #endif
  39 SECTIONS
  40 {
  41         . = KERNELBASE;
  42
  43 /*
  44  * Text, read only data and other permanent read-only sections
  45  */
  46
  47         _text = .;
  48         _stext = .;
  49
  50         /*
  51          * Head text.
  52          * This needs to be in its own output section to avoid ld placing
  53          * branch trampoline stubs randomly throughout the fixed sections,
  54          * which it will do (even if the branch comes from another section)
  55          * in order to optimize stub generation.
  56          */
  57         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  58 #ifdef CONFIG_PPC64
  59                 KEEP(*(.head.text.first_256B));
  60 #ifdef CONFIG_PPC_BOOK3E
  61 # define END_FIXED      0x100
  62 #else
  63                 KEEP(*(.head.text.real_vectors));
  64                 *(.head.text.real_trampolines);
  65                 KEEP(*(.head.text.virt_vectors));
  66                 *(.head.text.virt_trampolines);
  67 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  68                 KEEP(*(.head.data.fwnmi_page));
  69 #  define END_FIXED     0x8000
  70 # else
  71 #  define END_FIXED     0x7000
  72 # endif
  73 #endif
  74                 ASSERT((. == END_FIXED), "vmlinux.lds.S: fixed section overflow error");
  75 #else /* !CONFIG_PPC64 */
  76                 HEAD_TEXT
  77 #endif
  78         } :kernel
  79
  80         /*
  81          * If the build dies here, it's likely code in head_64.S is referencing
  82          * labels it can't reach, and the linker inserting stubs without the
  83          * assembler's knowledge. To debug, remove the above assert and
  84          * rebuild. Look for branch stubs in the fixed section region.
  85          *
  86          * Linker stub generation could be allowed in "trampoline"
  87          * sections if absolutely necessary, but this would require
  88          * some rework of the fixed sections. Before resorting to this,
  89          * consider references that have sufficient addressing range,
  90          * (e.g., hand coded trampolines) so the linker does not have
  91          * to add stubs.
  92          *
  93          * Linker stubs at the top of the main text section are currently not
  94          * detected, and will result in a crash at boot due to offsets being
  95          * wrong.
  96          */
  97         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  98                 ALIGN_FUNCTION();
  99                 /* careful! __ftr_alt_* sections need to be close to .text */
 100                 *(.text .fixup __ftr_alt_* .ref.text)
 101                 SCHED_TEXT
 102                 LOCK_TEXT
 103                 KPROBES_TEXT
 104                 IRQENTRY_TEXT
 105                 SOFTIRQENTRY_TEXT
 106                 MEM_KEEP(init.text)
 107                 MEM_KEEP(exit.text)
 108
 109 #ifdef CONFIG_PPC32
 110                 *(.got1)
 111                 __got2_start = .;
 112                 *(.got2)
 113                 __got2_end = .;
 114 #endif /* CONFIG_PPC32 */
 115
 116         } :kernel
 117
 118         . = ALIGN(PAGE_SIZE);
 119         _etext = .;
 120         PROVIDE32 (etext = .);
 121
 122         /* Read-only data */
 123         RODATA
 124
 125         EXCEPTION_TABLE(0)
 126
 127         NOTES :kernel :notes
 128
 129         /* The dummy segment contents for the bug workaround mentioned above
 130            near PHDRS.  */
 131         .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
 132                 LONG(0)
 133                 LONG(0)
 134                 LONG(0)
 135         } :kernel :dummy
 136
 137 /*
 138  * Init sections discarded at runtime
 139  */
 140         . = ALIGN(PAGE_SIZE);
 141         __init_begin = .;
 142         INIT_TEXT_SECTION(PAGE_SIZE) :kernel
 143
 144         /* .exit.text is discarded at runtime, not link time,
 145          * to deal with references from __bug_table
 146          */
 147         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 148                 EXIT_TEXT
 149         }
 150
 151         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 152                 INIT_DATA
 153                 __vtop_table_begin = .;
 154                 *(.vtop_fixup);
 155                 __vtop_table_end = .;
 156                 __ptov_table_begin = .;
 157                 *(.ptov_fixup);
 158                 __ptov_table_end = .;
 159         }
 160
 161         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 162                 INIT_SETUP(16)
 163         }
 164
 165         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 166                 INIT_CALLS
 167         }
 168
 169         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 170                 CON_INITCALL
 171         }
 172
 173         SECURITY_INIT
 174
 175         . = ALIGN(8);
 176         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 177                 __start___ftr_fixup = .;
 178                 *(__ftr_fixup)
 179                 __stop___ftr_fixup = .;
 180         }
 181         . = ALIGN(8);
 182         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 183                 __start___mmu_ftr_fixup = .;
 184                 *(__mmu_ftr_fixup)
 185                 __stop___mmu_ftr_fixup = .;
 186         }
 187         . = ALIGN(8);
 188         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 189                 __start___lwsync_fixup = .;
 190                 *(__lwsync_fixup)
 191                 __stop___lwsync_fixup = .;
 192         }
 193 #ifdef CONFIG_PPC64
 194         . = ALIGN(8);
 195         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 196                 __start___fw_ftr_fixup = .;
 197                 *(__fw_ftr_fixup)
 198                 __stop___fw_ftr_fixup = .;
 199         }
 200 #endif
 201         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 202                 INIT_RAM_FS
 203         }
 204
 205         PERCPU_SECTION(L1_CACHE_BYTES)
 206
 207         . = ALIGN(8);
 208         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 209                 __machine_desc_start = . ;
 210                 *(.machine.desc)
 211                 __machine_desc_end = . ;
 212         }
 213 #ifdef CONFIG_RELOCATABLE
 214         . = ALIGN(8);
 215         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 216         {
 217 #ifdef CONFIG_PPC32
 218                 __dynamic_symtab = .;
 219 #endif
 220                 *(.dynsym)
 221         }
 222         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 223         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 224         {
 225                 __dynamic_start = .;
 226                 *(.dynamic)
 227         }
 228         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 229         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 230         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 231         {
 232                 __rela_dyn_start = .;
 233                 *(.rela*)
 234         }
 235 #endif
 236         /* .exit.data is discarded at runtime, not link time,
 237          * to deal with references from .exit.text
 238          */
 239         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 240                 EXIT_DATA
 241         }
 242
 243         /* freed after init ends here */
 244         . = ALIGN(PAGE_SIZE);
 245         __init_end = .;
 246
 247 /*
 248  * And now the various read/write data
 249  */
 250
 251         . = ALIGN(PAGE_SIZE);
 252         _sdata = .;
 253
 254 #ifdef CONFIG_PPC32
 255         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 256                 DATA_DATA
 257                 *(.sdata)
 258                 *(.got.plt) *(.got)
 259         }
 260 #else
 261         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 262                 DATA_DATA
 263                 *(.data.rel*)
 264                 *(.toc1)
 265                 *(.branch_lt)
 266         }
 267
 268         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 269                 *(.opd)
 270         }
 271
 272         . = ALIGN(256);
 273         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 274                 __toc_start = .;
 275 #ifndef CONFIG_RELOCATABLE
 276                 __prom_init_toc_start = .;
 277                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 278                 __prom_init_toc_end = .;
 279 #endif
 280                 *(.got)
 281                 *(.toc)
 282         }
 283 #endif
 284
 285         /* The initial task and kernel stack */
 286         INIT_TASK_DATA_SECTION(THREAD_SIZE)
 287
 288         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 289                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 290         }
 291
 292         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 293                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 294         }
 295
 296         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 297                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 298         }
 299
 300         . = ALIGN(PAGE_SIZE);
 301         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 302                 NOSAVE_DATA
 303         }
 304
 305         . = ALIGN(PAGE_SIZE);
 306         _edata  =  .;
 307         PROVIDE32 (edata = .);
 308
 309 /*
 310  * And finally the bss
 311  */
 312
 313         BSS_SECTION(0, 0, 0)
 314
 315         . = ALIGN(PAGE_SIZE);
 316         _end = . ;
 317         PROVIDE32 (end = .);
 318
 319         /* Sections to be discarded. */
 320         DISCARDS
 321 }