arch/s390/kernel/entry64.S

   1 /*
   2  *    S390 low-level entry points.
   3  *
   4  *    Copyright IBM Corp. 1999, 2012
   5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   6  *               Hartmut Penner (hp@de.ibm.com),
   7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
   9  */
  10
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/processor.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21 #include <asm/sigp.h>
  22 #include <asm/irq.h>
  23
  24 __PT_R0      =  __PT_GPRS
  25 __PT_R1      =  __PT_GPRS + 8
  26 __PT_R2      =  __PT_GPRS + 16
  27 __PT_R3      =  __PT_GPRS + 24
  28 __PT_R4      =  __PT_GPRS + 32
  29 __PT_R5      =  __PT_GPRS + 40
  30 __PT_R6      =  __PT_GPRS + 48
  31 __PT_R7      =  __PT_GPRS + 56
  32 __PT_R8      =  __PT_GPRS + 64
  33 __PT_R9      =  __PT_GPRS + 72
  34 __PT_R10     =  __PT_GPRS + 80
  35 __PT_R11     =  __PT_GPRS + 88
  36 __PT_R12     =  __PT_GPRS + 96
  37 __PT_R13     =  __PT_GPRS + 104
  38 __PT_R14     =  __PT_GPRS + 112
  39 __PT_R15     =  __PT_GPRS + 120
  40
  41 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  42 STACK_SIZE  = 1 << STACK_SHIFT
  43 STACK_INIT = STACK_SIZE - STACK_FRAME_OVERHEAD - __PT_SIZE
  44
  45 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  46                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
  47 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  48                  _TIF_MCCK_PENDING)
  49 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  50                  _TIF_SYSCALL_TRACEPOINT)
  51
  52 #define BASED(name) name-system_call(%r13)
  53
  54         .macro  TRACE_IRQS_ON
  55 #ifdef CONFIG_TRACE_IRQFLAGS
  56         basr    %r2,%r0
  57         brasl   %r14,trace_hardirqs_on_caller
  58 #endif
  59         .endm
  60
  61         .macro  TRACE_IRQS_OFF
  62 #ifdef CONFIG_TRACE_IRQFLAGS
  63         basr    %r2,%r0
  64         brasl   %r14,trace_hardirqs_off_caller
  65 #endif
  66         .endm
  67
  68         .macro  LOCKDEP_SYS_EXIT
  69 #ifdef CONFIG_LOCKDEP
  70         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  71         jz      .+10
  72         brasl   %r14,lockdep_sys_exit
  73 #endif
  74         .endm
  75
  76         .macro LPP newpp
  77 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  78         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_LPP
  79         jz      .+8
  80         .insn   s,0xb2800000,\newpp
  81 #endif
  82         .endm
  83
  84         .macro  HANDLE_SIE_INTERCEPT scratch,reason
  85 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  86         tmhh    %r8,0x0001              # interrupting from user ?
  87         jnz     .+62
  88         lgr     \scratch,%r9
  89         slg     \scratch,BASED(.Lsie_critical)
  90         clg     \scratch,BASED(.Lsie_critical_length)
  91         .if     \reason==1
  92         # Some program interrupts are suppressing (e.g. protection).
  93         # We must also check the instruction after SIE in that case.
  94         # do_protection_exception will rewind to rewind_pad
  95         jh      .+42
  96         .else
  97         jhe     .+42
  98         .endif
  99         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
 100         LPP     __SF_EMPTY+16(%r15)             # set host id
 101         ni      __SIE_PROG0C+3(%r14),0xfe       # no longer in SIE
 102         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 103         larl    %r9,sie_exit                    # skip forward to sie_exit
 104         mvi     __SF_EMPTY+31(%r15),\reason     # set exit reason
 105 #endif
 106         .endm
 107
 108         .macro  CHECK_STACK stacksize,savearea
 109 #ifdef CONFIG_CHECK_STACK
 110         tml     %r15,\stacksize - CONFIG_STACK_GUARD
 111         lghi    %r14,\savearea
 112         jz      stack_overflow
 113 #endif
 114         .endm
 115
 116         .macro  SWITCH_ASYNC savearea,stack,shift
 117         tmhh    %r8,0x0001              # interrupting from user ?
 118         jnz     1f
 119         lgr     %r14,%r9
 120         slg     %r14,BASED(.Lcritical_start)
 121         clg     %r14,BASED(.Lcritical_length)
 122         jhe     0f
 123         lghi    %r11,\savearea          # inside critical section, do cleanup
 124         brasl   %r14,cleanup_critical
 125         tmhh    %r8,0x0001              # retest problem state after cleanup
 126         jnz     1f
 127 0:      lg      %r14,\stack             # are we already on the target stack?
 128         slgr    %r14,%r15
 129         srag    %r14,%r14,\shift
 130         jnz     1f
 131         CHECK_STACK 1<<\shift,\savearea
 132         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 133         j       2f
 134 1:      lg      %r15,\stack             # load target stack
 135 2:      la      %r11,STACK_FRAME_OVERHEAD(%r15)
 136         .endm
 137
 138         .macro UPDATE_VTIME scratch,enter_timer
 139         lg      \scratch,__LC_EXIT_TIMER
 140         slg     \scratch,\enter_timer
 141         alg     \scratch,__LC_USER_TIMER
 142         stg     \scratch,__LC_USER_TIMER
 143         lg      \scratch,__LC_LAST_UPDATE_TIMER
 144         slg     \scratch,__LC_EXIT_TIMER
 145         alg     \scratch,__LC_SYSTEM_TIMER
 146         stg     \scratch,__LC_SYSTEM_TIMER
 147         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 148         .endm
 149
 150         .macro  LAST_BREAK scratch
 151         srag    \scratch,%r10,23
 152         jz      .+10
 153         stg     %r10,__TI_last_break(%r12)
 154         .endm
 155
 156         .macro REENABLE_IRQS
 157         stg     %r8,__LC_RETURN_PSW
 158         ni      __LC_RETURN_PSW,0xbf
 159         ssm     __LC_RETURN_PSW
 160         .endm
 161
 162         .macro STCK savearea
 163 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
 164         .insn   s,0xb27c0000,\savearea          # store clock fast
 165 #else
 166         .insn   s,0xb2050000,\savearea          # store clock
 167 #endif
 168         .endm
 169
 170         .section .kprobes.text, "ax"
 171
 172 /*
 173  * Scheduler resume function, called by switch_to
 174  *  gpr2 = (task_struct *) prev
 175  *  gpr3 = (task_struct *) next
 176  * Returns:
 177  *  gpr2 = prev
 178  */
 179 ENTRY(__switch_to)
 180         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 181         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 182         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
 183         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
 184         lgr     %r15,%r5
 185         aghi    %r15,STACK_INIT                 # end of kernel stack of next
 186         stg     %r3,__LC_CURRENT                # store task struct of next
 187         stg     %r5,__LC_THREAD_INFO            # store thread info of next
 188         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
 189         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 190         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
 191         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 192         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 193         jz      0f
 194         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 195         oi      __TI_flags+7(%r5),_TIF_MCCK_PENDING     # set it in next
 196 0:      lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 197         br      %r14
 198
 199 __critical_start:
 200 /*
 201  * SVC interrupt handler routine. System calls are synchronous events and
 202  * are executed with interrupts enabled.
 203  */
 204
 205 ENTRY(system_call)
 206         stpt    __LC_SYNC_ENTER_TIMER
 207 sysc_stmg:
 208         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 209         lg      %r10,__LC_LAST_BREAK
 210         lg      %r12,__LC_THREAD_INFO
 211 sysc_per:
 212         lg      %r15,__LC_KERNEL_STACK
 213         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 214 sysc_vtime:
 215         UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
 216         LAST_BREAK %r13
 217         stmg    %r0,%r7,__PT_R0(%r11)
 218         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 219         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
 220         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 221 sysc_do_svc:
 222         oi      __TI_flags+7(%r12),_TIF_SYSCALL
 223         lg      %r10,__TI_sysc_table(%r12)      # address of system call table
 224         llgh    %r8,__PT_INT_CODE+2(%r11)
 225         slag    %r8,%r8,2                       # shift and test for svc 0
 226         jnz     sysc_nr_ok
 227         # svc 0: system call number in %r1
 228         llgfr   %r1,%r1                         # clear high word in r1
 229         cghi    %r1,NR_syscalls
 230         jnl     sysc_nr_ok
 231         sth     %r1,__PT_INT_CODE+2(%r11)
 232         slag    %r8,%r1,2
 233 sysc_nr_ok:
 234         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 235         stg     %r2,__PT_ORIG_GPR2(%r11)
 236         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 237         lgf     %r9,0(%r8,%r10)                 # get system call add.
 238         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 239         jnz     sysc_tracesys
 240         basr    %r14,%r9                        # call sys_xxxx
 241         stg     %r2,__PT_R2(%r11)               # store return value
 242
 243 sysc_return:
 244         LOCKDEP_SYS_EXIT
 245 sysc_tif:
 246         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
 247         jno     sysc_restore
 248         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
 249         jnz     sysc_work                       # check for work
 250         ni      __TI_flags+7(%r12),255-_TIF_SYSCALL
 251 sysc_restore:
 252         lg      %r14,__LC_VDSO_PER_CPU
 253         lmg     %r0,%r10,__PT_R0(%r11)
 254         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 255         stpt    __LC_EXIT_TIMER
 256         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 257         lmg     %r11,%r15,__PT_R11(%r11)
 258         lpswe   __LC_RETURN_PSW
 259 sysc_done:
 260
 261 #
 262 # One of the work bits is on. Find out which one.
 263 #
 264 sysc_work:
 265         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 266         jo      sysc_mcck_pending
 267         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 268         jo      sysc_reschedule
 269         tm      __TI_flags+7(%r12),_TIF_PER_TRAP
 270         jo      sysc_singlestep
 271         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 272         jo      sysc_sigpending
 273         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 274         jo      sysc_notify_resume
 275         j       sysc_return             # beware of critical section cleanup
 276
 277 #
 278 # _TIF_NEED_RESCHED is set, call schedule
 279 #
 280 sysc_reschedule:
 281         larl    %r14,sysc_return
 282         jg      schedule
 283
 284 #
 285 # _TIF_MCCK_PENDING is set, call handler
 286 #
 287 sysc_mcck_pending:
 288         larl    %r14,sysc_return
 289         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 290
 291 #
 292 # _TIF_SIGPENDING is set, call do_signal
 293 #
 294 sysc_sigpending:
 295         lgr     %r2,%r11                # pass pointer to pt_regs
 296         brasl   %r14,do_signal
 297         tm      __TI_flags+7(%r12),_TIF_SYSCALL
 298         jno     sysc_return
 299         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
 300         lghi    %r8,0                   # svc 0 returns -ENOSYS
 301         llgh    %r1,__PT_INT_CODE+2(%r11)       # load new svc number
 302         cghi    %r1,NR_syscalls
 303         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 304         slag    %r8,%r1,2
 305         j       sysc_nr_ok              # restart svc
 306
 307 #
 308 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 309 #
 310 sysc_notify_resume:
 311         lgr     %r2,%r11                # pass pointer to pt_regs
 312         larl    %r14,sysc_return
 313         jg      do_notify_resume
 314
 315 #
 316 # _TIF_PER_TRAP is set, call do_per_trap
 317 #
 318 sysc_singlestep:
 319         ni      __TI_flags+7(%r12),255-_TIF_PER_TRAP
 320         lgr     %r2,%r11                # pass pointer to pt_regs
 321         larl    %r14,sysc_return
 322         jg      do_per_trap
 323
 324 #
 325 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 326 # and after the system call
 327 #
 328 sysc_tracesys:
 329         lgr     %r2,%r11                # pass pointer to pt_regs
 330         la      %r3,0
 331         llgh    %r0,__PT_INT_CODE+2(%r11)
 332         stg     %r0,__PT_R2(%r11)
 333         brasl   %r14,do_syscall_trace_enter
 334         lghi    %r0,NR_syscalls
 335         clgr    %r0,%r2
 336         jnh     sysc_tracenogo
 337         sllg    %r8,%r2,2
 338         lgf     %r9,0(%r8,%r10)
 339 sysc_tracego:
 340         lmg     %r3,%r7,__PT_R3(%r11)
 341         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 342         lg      %r2,__PT_ORIG_GPR2(%r11)
 343         basr    %r14,%r9                # call sys_xxx
 344         stg     %r2,__PT_R2(%r11)       # store return value
 345 sysc_tracenogo:
 346         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 347         jz      sysc_return
 348         lgr     %r2,%r11                # pass pointer to pt_regs
 349         larl    %r14,sysc_return
 350         jg      do_syscall_trace_exit
 351
 352 #
 353 # a new process exits the kernel with ret_from_fork
 354 #
 355 ENTRY(ret_from_fork)
 356         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 357         lg      %r12,__LC_THREAD_INFO
 358         brasl   %r14,schedule_tail
 359         TRACE_IRQS_ON
 360         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 361         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 362         jne     sysc_tracenogo
 363         # it's a kernel thread
 364         lmg     %r9,%r10,__PT_R9(%r11)  # load gprs
 365 ENTRY(kernel_thread_starter)
 366         la      %r2,0(%r10)
 367         basr    %r14,%r9
 368         j       sysc_tracenogo
 369
 370 /*
 371  * Program check handler routine
 372  */
 373
 374 ENTRY(pgm_check_handler)
 375         stpt    __LC_SYNC_ENTER_TIMER
 376         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 377         lg      %r10,__LC_LAST_BREAK
 378         lg      %r12,__LC_THREAD_INFO
 379         larl    %r13,system_call
 380         lmg     %r8,%r9,__LC_PGM_OLD_PSW
 381         HANDLE_SIE_INTERCEPT %r14,1
 382         tmhh    %r8,0x0001              # test problem state bit
 383         jnz     1f                      # -> fault in user space
 384         tmhh    %r8,0x4000              # PER bit set in old PSW ?
 385         jnz     0f                      # -> enabled, can't be a double fault
 386         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 387         jnz     pgm_svcper              # -> single stepped svc
 388 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 389         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 390         j       2f
 391 1:      UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
 392         LAST_BREAK %r14
 393         lg      %r15,__LC_KERNEL_STACK
 394         lg      %r14,__TI_task(%r12)
 395         lghi    %r13,__LC_PGM_TDB
 396         tm      __LC_PGM_ILC+2,0x02     # check for transaction abort
 397         jz      2f
 398         mvc     __THREAD_trap_tdb(256,%r14),0(%r13)
 399 2:      la      %r11,STACK_FRAME_OVERHEAD(%r15)
 400         stmg    %r0,%r7,__PT_R0(%r11)
 401         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 402         stmg    %r8,%r9,__PT_PSW(%r11)
 403         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 404         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
 405         stg     %r10,__PT_ARGS(%r11)
 406         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 407         jz      0f
 408         tmhh    %r8,0x0001              # kernel per event ?
 409         jz      pgm_kprobe
 410         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
 411         mvc     __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
 412         mvc     __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
 413         mvc     __THREAD_per_paid(1,%r14),__LC_PER_PAID
 414 0:      REENABLE_IRQS
 415         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 416         larl    %r1,pgm_check_table
 417         llgh    %r10,__PT_INT_CODE+2(%r11)
 418         nill    %r10,0x007f
 419         sll     %r10,2
 420         je      sysc_return
 421         lgf     %r1,0(%r10,%r1)         # load address of handler routine
 422         lgr     %r2,%r11                # pass pointer to pt_regs
 423         basr    %r14,%r1                # branch to interrupt-handler
 424         j       sysc_return
 425
 426 #
 427 # PER event in supervisor state, must be kprobes
 428 #
 429 pgm_kprobe:
 430         REENABLE_IRQS
 431         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 432         lgr     %r2,%r11                # pass pointer to pt_regs
 433         brasl   %r14,do_per_trap
 434         j       sysc_return
 435
 436 #
 437 # single stepped system call
 438 #
 439 pgm_svcper:
 440         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
 441         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
 442         larl    %r14,sysc_per
 443         stg     %r14,__LC_RETURN_PSW+8
 444         lpswe   __LC_RETURN_PSW         # branch to sysc_per and enable irqs
 445
 446 /*
 447  * IO interrupt handler routine
 448  */
 449 ENTRY(io_int_handler)
 450         STCK    __LC_INT_CLOCK
 451         stpt    __LC_ASYNC_ENTER_TIMER
 452         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 453         lg      %r10,__LC_LAST_BREAK
 454         lg      %r12,__LC_THREAD_INFO
 455         larl    %r13,system_call
 456         lmg     %r8,%r9,__LC_IO_OLD_PSW
 457         HANDLE_SIE_INTERCEPT %r14,2
 458         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 459         tmhh    %r8,0x0001              # interrupting from user?
 460         jz      io_skip
 461         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 462         LAST_BREAK %r14
 463 io_skip:
 464         stmg    %r0,%r7,__PT_R0(%r11)
 465         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 466         stmg    %r8,%r9,__PT_PSW(%r11)
 467         mvc     __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
 468         TRACE_IRQS_OFF
 469         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 470 io_loop:
 471         lgr     %r2,%r11                # pass pointer to pt_regs
 472         lghi    %r3,IO_INTERRUPT
 473         tm      __PT_INT_CODE+8(%r11),0x80      # adapter interrupt ?
 474         jz      io_call
 475         lghi    %r3,THIN_INTERRUPT
 476 io_call:
 477         brasl   %r14,do_IRQ
 478         tm      __LC_MACHINE_FLAGS+6,0x10       # MACHINE_FLAG_LPAR
 479         jz      io_return
 480         tpi     0
 481         jz      io_return
 482         mvc     __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
 483         j       io_loop
 484 io_return:
 485         LOCKDEP_SYS_EXIT
 486         TRACE_IRQS_ON
 487 io_tif:
 488         tm      __TI_flags+7(%r12),_TIF_WORK_INT
 489         jnz     io_work                 # there is work to do (signals etc.)
 490 io_restore:
 491         lg      %r14,__LC_VDSO_PER_CPU
 492         lmg     %r0,%r10,__PT_R0(%r11)
 493         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 494         stpt    __LC_EXIT_TIMER
 495         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 496         lmg     %r11,%r15,__PT_R11(%r11)
 497         lpswe   __LC_RETURN_PSW
 498 io_done:
 499
 500 #
 501 # There is work todo, find out in which context we have been interrupted:
 502 # 1) if we return to user space we can do all _TIF_WORK_INT work
 503 # 2) if we return to kernel code and kvm is enabled check if we need to
 504 #    modify the psw to leave SIE
 505 # 3) if we return to kernel code and preemptive scheduling is enabled check
 506 #    the preemption counter and if it is zero call preempt_schedule_irq
 507 # Before any work can be done, a switch to the kernel stack is required.
 508 #
 509 io_work:
 510         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 511         jo      io_work_user            # yes -> do resched & signal
 512 #ifdef CONFIG_PREEMPT
 513         # check for preemptive scheduling
 514         icm     %r0,15,__TI_precount(%r12)
 515         jnz     io_restore              # preemption is disabled
 516         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 517         jno     io_restore
 518         # switch to kernel stack
 519         lg      %r1,__PT_R15(%r11)
 520         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 521         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 522         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 523         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 524         lgr     %r15,%r1
 525         # TRACE_IRQS_ON already done at io_return, call
 526         # TRACE_IRQS_OFF to keep things symmetrical
 527         TRACE_IRQS_OFF
 528         brasl   %r14,preempt_schedule_irq
 529         j       io_return
 530 #else
 531         j       io_restore
 532 #endif
 533
 534 #
 535 # Need to do work before returning to userspace, switch to kernel stack
 536 #
 537 io_work_user:
 538         lg      %r1,__LC_KERNEL_STACK
 539         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 540         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 541         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 542         lgr     %r15,%r1
 543
 544 #
 545 # One of the work bits is on. Find out which one.
 546 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 547 #              and _TIF_MCCK_PENDING
 548 #
 549 io_work_tif:
 550         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 551         jo      io_mcck_pending
 552         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 553         jo      io_reschedule
 554         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 555         jo      io_sigpending
 556         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 557         jo      io_notify_resume
 558         j       io_return               # beware of critical section cleanup
 559
 560 #
 561 # _TIF_MCCK_PENDING is set, call handler
 562 #
 563 io_mcck_pending:
 564         # TRACE_IRQS_ON already done at io_return
 565         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 566         TRACE_IRQS_OFF
 567         j       io_return
 568
 569 #
 570 # _TIF_NEED_RESCHED is set, call schedule
 571 #
 572 io_reschedule:
 573         # TRACE_IRQS_ON already done at io_return
 574         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 575         brasl   %r14,schedule           # call scheduler
 576         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 577         TRACE_IRQS_OFF
 578         j       io_return
 579
 580 #
 581 # _TIF_SIGPENDING or is set, call do_signal
 582 #
 583 io_sigpending:
 584         # TRACE_IRQS_ON already done at io_return
 585         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 586         lgr     %r2,%r11                # pass pointer to pt_regs
 587         brasl   %r14,do_signal
 588         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 589         TRACE_IRQS_OFF
 590         j       io_return
 591
 592 #
 593 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 594 #
 595 io_notify_resume:
 596         # TRACE_IRQS_ON already done at io_return
 597         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 598         lgr     %r2,%r11                # pass pointer to pt_regs
 599         brasl   %r14,do_notify_resume
 600         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 601         TRACE_IRQS_OFF
 602         j       io_return
 603
 604 /*
 605  * External interrupt handler routine
 606  */
 607 ENTRY(ext_int_handler)
 608         STCK    __LC_INT_CLOCK
 609         stpt    __LC_ASYNC_ENTER_TIMER
 610         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 611         lg      %r10,__LC_LAST_BREAK
 612         lg      %r12,__LC_THREAD_INFO
 613         larl    %r13,system_call
 614         lmg     %r8,%r9,__LC_EXT_OLD_PSW
 615         HANDLE_SIE_INTERCEPT %r14,3
 616         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 617         tmhh    %r8,0x0001              # interrupting from user ?
 618         jz      ext_skip
 619         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 620         LAST_BREAK %r14
 621 ext_skip:
 622         stmg    %r0,%r7,__PT_R0(%r11)
 623         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 624         stmg    %r8,%r9,__PT_PSW(%r11)
 625         lghi    %r1,__LC_EXT_PARAMS2
 626         mvc     __PT_INT_CODE(4,%r11),__LC_EXT_CPU_ADDR
 627         mvc     __PT_INT_PARM(4,%r11),__LC_EXT_PARAMS
 628         mvc     __PT_INT_PARM_LONG(8,%r11),0(%r1)
 629         TRACE_IRQS_OFF
 630         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 631         lgr     %r2,%r11                # pass pointer to pt_regs
 632         lghi    %r3,EXT_INTERRUPT
 633         brasl   %r14,do_IRQ
 634         j       io_return
 635
 636 /*
 637  * Load idle PSW. The second "half" of this function is in cleanup_idle.
 638  */
 639 ENTRY(psw_idle)
 640         stg     %r3,__SF_EMPTY(%r15)
 641         larl    %r1,psw_idle_lpsw+4
 642         stg     %r1,__SF_EMPTY+8(%r15)
 643         STCK    __CLOCK_IDLE_ENTER(%r2)
 644         stpt    __TIMER_IDLE_ENTER(%r2)
 645 psw_idle_lpsw:
 646         lpswe   __SF_EMPTY(%r15)
 647         br      %r14
 648 psw_idle_end:
 649
 650 __critical_end:
 651
 652 /*
 653  * Machine check handler routines
 654  */
 655 ENTRY(mcck_int_handler)
 656         STCK    __LC_MCCK_CLOCK
 657         la      %r1,4095                # revalidate r1
 658         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 659         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 660         lg      %r10,__LC_LAST_BREAK
 661         lg      %r12,__LC_THREAD_INFO
 662         larl    %r13,system_call
 663         lmg     %r8,%r9,__LC_MCK_OLD_PSW
 664         HANDLE_SIE_INTERCEPT %r14,4
 665         tm      __LC_MCCK_CODE,0x80     # system damage?
 666         jo      mcck_panic              # yes -> rest of mcck code invalid
 667         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
 668         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 669         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 670         jo      3f
 671         la      %r14,__LC_SYNC_ENTER_TIMER
 672         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 673         jl      0f
 674         la      %r14,__LC_ASYNC_ENTER_TIMER
 675 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 676         jl      1f
 677         la      %r14,__LC_EXIT_TIMER
 678 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 679         jl      2f
 680         la      %r14,__LC_LAST_UPDATE_TIMER
 681 2:      spt     0(%r14)
 682         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 683 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 684         jno     mcck_panic              # no -> skip cleanup critical
 685         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
 686         tm      %r8,0x0001              # interrupting from user ?
 687         jz      mcck_skip
 688         UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
 689         LAST_BREAK %r14
 690 mcck_skip:
 691         lghi    %r14,__LC_GPREGS_SAVE_AREA+64
 692         stmg    %r0,%r7,__PT_R0(%r11)
 693         mvc     __PT_R8(64,%r11),0(%r14)
 694         stmg    %r8,%r9,__PT_PSW(%r11)
 695         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 696         lgr     %r2,%r11                # pass pointer to pt_regs
 697         brasl   %r14,s390_do_machine_check
 698         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 699         jno     mcck_return
 700         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 701         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 702         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 703         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 704         lgr     %r15,%r1
 705         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
 706         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 707         jno     mcck_return
 708         TRACE_IRQS_OFF
 709         brasl   %r14,s390_handle_mcck
 710         TRACE_IRQS_ON
 711 mcck_return:
 712         lg      %r14,__LC_VDSO_PER_CPU
 713         lmg     %r0,%r10,__PT_R0(%r11)
 714         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
 715         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 716         jno     0f
 717         stpt    __LC_EXIT_TIMER
 718         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 719 0:      lmg     %r11,%r15,__PT_R11(%r11)
 720         lpswe   __LC_RETURN_MCCK_PSW
 721
 722 mcck_panic:
 723         lg      %r14,__LC_PANIC_STACK
 724         slgr    %r14,%r15
 725         srag    %r14,%r14,PAGE_SHIFT
 726         jz      0f
 727         lg      %r15,__LC_PANIC_STACK
 728 0:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 729         j       mcck_skip
 730
 731 #
 732 # PSW restart interrupt handler
 733 #
 734 ENTRY(restart_int_handler)
 735         stg     %r15,__LC_SAVE_AREA_RESTART
 736         lg      %r15,__LC_RESTART_STACK
 737         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
 738         xc      0(__PT_SIZE,%r15),0(%r15)
 739         stmg    %r0,%r14,__PT_R0(%r15)
 740         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
 741         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
 742         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
 743         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
 744         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
 745         lg      %r2,__LC_RESTART_DATA
 746         lg      %r3,__LC_RESTART_SOURCE
 747         ltgr    %r3,%r3                         # test source cpu address
 748         jm      1f                              # negative -> skip source stop
 749 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
 750         brc     10,0b                           # wait for status stored
 751 1:      basr    %r14,%r1                        # call function
 752         stap    __SF_EMPTY(%r15)                # store cpu address
 753         llgh    %r3,__SF_EMPTY(%r15)
 754 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
 755         brc     2,2b
 756 3:      j       3b
 757
 758         .section .kprobes.text, "ax"
 759
 760 #ifdef CONFIG_CHECK_STACK
 761 /*
 762  * The synchronous or the asynchronous stack overflowed. We are dead.
 763  * No need to properly save the registers, we are going to panic anyway.
 764  * Setup a pt_regs so that show_trace can provide a good call trace.
 765  */
 766 stack_overflow:
 767         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 768         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 769         stmg    %r0,%r7,__PT_R0(%r11)
 770         stmg    %r8,%r9,__PT_PSW(%r11)
 771         mvc     __PT_R8(64,%r11),0(%r14)
 772         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
 773         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 774         lgr     %r2,%r11                # pass pointer to pt_regs
 775         jg      kernel_stack_overflow
 776 #endif
 777
 778         .align  8
 779 cleanup_table:
 780         .quad   system_call
 781         .quad   sysc_do_svc
 782         .quad   sysc_tif
 783         .quad   sysc_restore
 784         .quad   sysc_done
 785         .quad   io_tif
 786         .quad   io_restore
 787         .quad   io_done
 788         .quad   psw_idle
 789         .quad   psw_idle_end
 790
 791 cleanup_critical:
 792         clg     %r9,BASED(cleanup_table)        # system_call
 793         jl      0f
 794         clg     %r9,BASED(cleanup_table+8)      # sysc_do_svc
 795         jl      cleanup_system_call
 796         clg     %r9,BASED(cleanup_table+16)     # sysc_tif
 797         jl      0f
 798         clg     %r9,BASED(cleanup_table+24)     # sysc_restore
 799         jl      cleanup_sysc_tif
 800         clg     %r9,BASED(cleanup_table+32)     # sysc_done
 801         jl      cleanup_sysc_restore
 802         clg     %r9,BASED(cleanup_table+40)     # io_tif
 803         jl      0f
 804         clg     %r9,BASED(cleanup_table+48)     # io_restore
 805         jl      cleanup_io_tif
 806         clg     %r9,BASED(cleanup_table+56)     # io_done
 807         jl      cleanup_io_restore
 808         clg     %r9,BASED(cleanup_table+64)     # psw_idle
 809         jl      0f
 810         clg     %r9,BASED(cleanup_table+72)     # psw_idle_end
 811         jl      cleanup_idle
 812 0:      br      %r14
 813
 814
 815 cleanup_system_call:
 816         # check if stpt has been executed
 817         clg     %r9,BASED(cleanup_system_call_insn)
 818         jh      0f
 819         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 820         cghi    %r11,__LC_SAVE_AREA_ASYNC
 821         je      0f
 822         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 823 0:      # check if stmg has been executed
 824         clg     %r9,BASED(cleanup_system_call_insn+8)
 825         jh      0f
 826         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
 827 0:      # check if base register setup + TIF bit load has been done
 828         clg     %r9,BASED(cleanup_system_call_insn+16)
 829         jhe     0f
 830         # set up saved registers r10 and r12
 831         stg     %r10,16(%r11)           # r10 last break
 832         stg     %r12,32(%r11)           # r12 thread-info pointer
 833 0:      # check if the user time update has been done
 834         clg     %r9,BASED(cleanup_system_call_insn+24)
 835         jh      0f
 836         lg      %r15,__LC_EXIT_TIMER
 837         slg     %r15,__LC_SYNC_ENTER_TIMER
 838         alg     %r15,__LC_USER_TIMER
 839         stg     %r15,__LC_USER_TIMER
 840 0:      # check if the system time update has been done
 841         clg     %r9,BASED(cleanup_system_call_insn+32)
 842         jh      0f
 843         lg      %r15,__LC_LAST_UPDATE_TIMER
 844         slg     %r15,__LC_EXIT_TIMER
 845         alg     %r15,__LC_SYSTEM_TIMER
 846         stg     %r15,__LC_SYSTEM_TIMER
 847 0:      # update accounting time stamp
 848         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 849         # do LAST_BREAK
 850         lg      %r9,16(%r11)
 851         srag    %r9,%r9,23
 852         jz      0f
 853         mvc     __TI_last_break(8,%r12),16(%r11)
 854 0:      # set up saved register r11
 855         lg      %r15,__LC_KERNEL_STACK
 856         la      %r9,STACK_FRAME_OVERHEAD(%r15)
 857         stg     %r9,24(%r11)            # r11 pt_regs pointer
 858         # fill pt_regs
 859         mvc     __PT_R8(64,%r9),__LC_SAVE_AREA_SYNC
 860         stmg    %r0,%r7,__PT_R0(%r9)
 861         mvc     __PT_PSW(16,%r9),__LC_SVC_OLD_PSW
 862         mvc     __PT_INT_CODE(4,%r9),__LC_SVC_ILC
 863         # setup saved register r15
 864         stg     %r15,56(%r11)           # r15 stack pointer
 865         # set new psw address and exit
 866         larl    %r9,sysc_do_svc
 867         br      %r14
 868 cleanup_system_call_insn:
 869         .quad   system_call
 870         .quad   sysc_stmg
 871         .quad   sysc_per
 872         .quad   sysc_vtime+18
 873         .quad   sysc_vtime+42
 874
 875 cleanup_sysc_tif:
 876         larl    %r9,sysc_tif
 877         br      %r14
 878
 879 cleanup_sysc_restore:
 880         clg     %r9,BASED(cleanup_sysc_restore_insn)
 881         je      0f
 882         lg      %r9,24(%r11)            # get saved pointer to pt_regs
 883         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 884         mvc     0(64,%r11),__PT_R8(%r9)
 885         lmg     %r0,%r7,__PT_R0(%r9)
 886 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 887         br      %r14
 888 cleanup_sysc_restore_insn:
 889         .quad   sysc_done - 4
 890
 891 cleanup_io_tif:
 892         larl    %r9,io_tif
 893         br      %r14
 894
 895 cleanup_io_restore:
 896         clg     %r9,BASED(cleanup_io_restore_insn)
 897         je      0f
 898         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
 899         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 900         mvc     0(64,%r11),__PT_R8(%r9)
 901         lmg     %r0,%r7,__PT_R0(%r9)
 902 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 903         br      %r14
 904 cleanup_io_restore_insn:
 905         .quad   io_done - 4
 906
 907 cleanup_idle:
 908         # copy interrupt clock & cpu timer
 909         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
 910         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
 911         cghi    %r11,__LC_SAVE_AREA_ASYNC
 912         je      0f
 913         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
 914         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
 915 0:      # check if stck & stpt have been executed
 916         clg     %r9,BASED(cleanup_idle_insn)
 917         jhe     1f
 918         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
 919         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
 920 1:      # account system time going idle
 921         lg      %r9,__LC_STEAL_TIMER
 922         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
 923         slg     %r9,__LC_LAST_UPDATE_CLOCK
 924         stg     %r9,__LC_STEAL_TIMER
 925         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
 926         lg      %r9,__LC_SYSTEM_TIMER
 927         alg     %r9,__LC_LAST_UPDATE_TIMER
 928         slg     %r9,__TIMER_IDLE_ENTER(%r2)
 929         stg     %r9,__LC_SYSTEM_TIMER
 930         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
 931         # prepare return psw
 932         nihh    %r8,0xfcfd              # clear irq & wait state bits
 933         lg      %r9,48(%r11)            # return from psw_idle
 934         br      %r14
 935 cleanup_idle_insn:
 936         .quad   psw_idle_lpsw
 937
 938 /*
 939  * Integer constants
 940  */
 941         .align  8
 942 .Lcritical_start:
 943         .quad   __critical_start
 944 .Lcritical_length:
 945         .quad   __critical_end - __critical_start
 946
 947
 948 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 949 /*
 950  * sie64a calling convention:
 951  * %r2 pointer to sie control block
 952  * %r3 guest register save area
 953  */
 954 ENTRY(sie64a)
 955         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
 956         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
 957         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
 958         xc      __SF_EMPTY+16(16,%r15),__SF_EMPTY+16(%r15) # host id & reason
 959         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
 960         lg      %r14,__LC_GMAP                  # get gmap pointer
 961         ltgr    %r14,%r14
 962         jz      sie_gmap
 963         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
 964 sie_gmap:
 965         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
 966         oi      __SIE_PROG0C+3(%r14),1          # we are going into SIE now
 967         tm      __SIE_PROG20+3(%r14),1          # last exit...
 968         jnz     sie_done
 969         LPP     __SF_EMPTY(%r15)                # set guest id
 970         sie     0(%r14)
 971 sie_done:
 972         LPP     __SF_EMPTY+16(%r15)             # set host id
 973         ni      __SIE_PROG0C+3(%r14),0xfe       # no longer in SIE
 974         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 975 # some program checks are suppressing. C code (e.g. do_protection_exception)
 976 # will rewind the PSW by the ILC, which is 4 bytes in case of SIE. Other
 977 # instructions beween sie64a and sie_done should not cause program
 978 # interrupts. So lets use a nop (47 00 00 00) as a landing pad.
 979 # See also HANDLE_SIE_INTERCEPT
 980 rewind_pad:
 981         nop     0
 982         .globl sie_exit
 983 sie_exit:
 984         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
 985         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
 986         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
 987         lg      %r2,__SF_EMPTY+24(%r15)         # return exit reason code
 988         br      %r14
 989 sie_fault:
 990         lghi    %r14,-EFAULT
 991         stg     %r14,__SF_EMPTY+24(%r15)        # set exit reason code
 992         j       sie_exit
 993
 994         .align  8
 995 .Lsie_critical:
 996         .quad   sie_gmap
 997 .Lsie_critical_length:
 998         .quad   sie_done - sie_gmap
 999
1000         EX_TABLE(rewind_pad,sie_fault)
1001         EX_TABLE(sie_exit,sie_fault)
1002 #endif
1003
1004                 .section .rodata, "a"
1005 #define SYSCALL(esa,esame,emu)  .long esame
1006         .globl  sys_call_table
1007 sys_call_table:
1008 #include "syscalls.S"
1009 #undef SYSCALL
1010
1011 #ifdef CONFIG_COMPAT
1012
1013 #define SYSCALL(esa,esame,emu)  .long emu
1014         .globl  sys_call_table_emu
1015 sys_call_table_emu:
1016 #include "syscalls.S"
1017 #undef SYSCALL
1018 #endif