arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Return to user mode is not as complex as all this looks,
 319  * but we want the default path for a system call return to
 320  * go as quickly as possible which is why some of this is
 321  * less clear than it otherwise should be.
 322  */
 323
 324         # userspace resumption stub bypassing syscall exit tracing
 325         ALIGN
 326         RING0_PTREGS_FRAME
 327 ret_from_exception:
 328         preempt_stop(CLBR_ANY)
 329 ret_from_intr:
 330         GET_THREAD_INFO(%ebp)
 331 #ifdef CONFIG_VM86
 332         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 333         movb PT_CS(%esp), %al
 334         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 335 #else
 336         /*
 337          * We can be coming here from child spawned by kernel_thread().
 338          */
 339         movl PT_CS(%esp), %eax
 340         andl $SEGMENT_RPL_MASK, %eax
 341 #endif
 342         cmpl $USER_RPL, %eax
 343         jb resume_kernel                # not returning to v8086 or userspace
 344
 345 ENTRY(resume_userspace)
 346         LOCKDEP_SYS_EXIT
 347         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 348                                         # setting need_resched or sigpending
 349                                         # between sampling and the iret
 350         TRACE_IRQS_OFF
 351         movl TI_flags(%ebp), %ecx
 352         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 353                                         # int/exception return?
 354         jne work_pending
 355         jmp restore_all
 356 END(ret_from_exception)
 357
 358 #ifdef CONFIG_PREEMPT
 359 ENTRY(resume_kernel)
 360         DISABLE_INTERRUPTS(CLBR_ANY)
 361 need_resched:
 362         cmpl $0,PER_CPU_VAR(__preempt_count)
 363         jnz restore_all
 364         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 365         jz restore_all
 366         call preempt_schedule_irq
 367         jmp need_resched
 368 END(resume_kernel)
 369 #endif
 370         CFI_ENDPROC
 371
 372 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 373    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 374
 375         # sysenter call handler stub
 376 ENTRY(ia32_sysenter_target)
 377         CFI_STARTPROC simple
 378         CFI_SIGNAL_FRAME
 379         CFI_DEF_CFA esp, 0
 380         CFI_REGISTER esp, ebp
 381         movl TSS_sysenter_sp0(%esp),%esp
 382 sysenter_past_esp:
 383         /*
 384          * Interrupts are disabled here, but we can't trace it until
 385          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 386          * we immediately enable interrupts at that point anyway.
 387          */
 388         pushl_cfi $__USER_DS
 389         /*CFI_REL_OFFSET ss, 0*/
 390         pushl_cfi %ebp
 391         CFI_REL_OFFSET esp, 0
 392         pushfl_cfi
 393         orl $X86_EFLAGS_IF, (%esp)
 394         pushl_cfi $__USER_CS
 395         /*CFI_REL_OFFSET cs, 0*/
 396         /*
 397          * Push current_thread_info()->sysenter_return to the stack.
 398          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 399          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 400          */
 401         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 402         CFI_REL_OFFSET eip, 0
 403
 404         pushl_cfi %eax
 405         SAVE_ALL
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407
 408 /*
 409  * Load the potential sixth argument from user stack.
 410  * Careful about security.
 411  */
 412         cmpl $__PAGE_OFFSET-3,%ebp
 413         jae syscall_fault
 414         ASM_STAC
 415 1:      movl (%ebp),%ebp
 416         ASM_CLAC
 417         movl %ebp,PT_EBP(%esp)
 418         _ASM_EXTABLE(1b,syscall_fault)
 419
 420         GET_THREAD_INFO(%ebp)
 421
 422         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 423         jnz sysenter_audit
 424 sysenter_do_call:
 425         cmpl $(NR_syscalls), %eax
 426         jae sysenter_badsys
 427         call *sys_call_table(,%eax,4)
 428 sysenter_after_call:
 429         movl %eax,PT_EAX(%esp)
 430         LOCKDEP_SYS_EXIT
 431         DISABLE_INTERRUPTS(CLBR_ANY)
 432         TRACE_IRQS_OFF
 433         movl TI_flags(%ebp), %ecx
 434         testl $_TIF_ALLWORK_MASK, %ecx
 435         jne sysexit_audit
 436 sysenter_exit:
 437 /* if something modifies registers it must also disable sysexit */
 438         movl PT_EIP(%esp), %edx
 439         movl PT_OLDESP(%esp), %ecx
 440         xorl %ebp,%ebp
 441         TRACE_IRQS_ON
 442 1:      mov  PT_FS(%esp), %fs
 443         PTGS_TO_GS
 444         ENABLE_INTERRUPTS_SYSEXIT
 445
 446 #ifdef CONFIG_AUDITSYSCALL
 447 sysenter_audit:
 448         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 449         jnz syscall_trace_entry
 450         addl $4,%esp
 451         CFI_ADJUST_CFA_OFFSET -4
 452         movl %esi,4(%esp)               /* 5th arg: 4th syscall arg */
 453         movl %edx,(%esp)                /* 4th arg: 3rd syscall arg */
 454         /* %ecx already in %ecx            3rd arg: 2nd syscall arg */
 455         movl %ebx,%edx                  /* 2nd arg: 1st syscall arg */
 456         /* %eax already in %eax            1st arg: syscall number */
 457         call __audit_syscall_entry
 458         pushl_cfi %ebx
 459         movl PT_EAX(%esp),%eax          /* reload syscall number */
 460         jmp sysenter_do_call
 461
 462 sysexit_audit:
 463         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 464         jne syscall_exit_work
 465         TRACE_IRQS_ON
 466         ENABLE_INTERRUPTS(CLBR_ANY)
 467         movl %eax,%edx          /* second arg, syscall return value */
 468         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 469         setbe %al               /* 1 if so, 0 if not */
 470         movzbl %al,%eax         /* zero-extend that */
 471         call __audit_syscall_exit
 472         DISABLE_INTERRUPTS(CLBR_ANY)
 473         TRACE_IRQS_OFF
 474         movl TI_flags(%ebp), %ecx
 475         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 476         jne syscall_exit_work
 477         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 478         jmp sysenter_exit
 479 #endif
 480
 481         CFI_ENDPROC
 482 .pushsection .fixup,"ax"
 483 2:      movl $0,PT_FS(%esp)
 484         jmp 1b
 485 .popsection
 486         _ASM_EXTABLE(1b,2b)
 487         PTGS_TO_GS_EX
 488 ENDPROC(ia32_sysenter_target)
 489
 490         # system call handler stub
 491 ENTRY(system_call)
 492         RING0_INT_FRAME                 # can't unwind into user space anyway
 493         ASM_CLAC
 494         pushl_cfi %eax                  # save orig_eax
 495         SAVE_ALL
 496         GET_THREAD_INFO(%ebp)
 497                                         # system call tracing in operation / emulation
 498         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 499         jnz syscall_trace_entry
 500         cmpl $(NR_syscalls), %eax
 501         jae syscall_badsys
 502 syscall_call:
 503         call *sys_call_table(,%eax,4)
 504 syscall_after_call:
 505         movl %eax,PT_EAX(%esp)          # store the return value
 506 syscall_exit:
 507         LOCKDEP_SYS_EXIT
 508         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 509                                         # setting need_resched or sigpending
 510                                         # between sampling and the iret
 511         TRACE_IRQS_OFF
 512         movl TI_flags(%ebp), %ecx
 513         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 514         jne syscall_exit_work
 515
 516 restore_all:
 517         TRACE_IRQS_IRET
 518 restore_all_notrace:
 519 #ifdef CONFIG_X86_ESPFIX32
 520         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 521         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 522         # are returning to the kernel.
 523         # See comments in process.c:copy_thread() for details.
 524         movb PT_OLDSS(%esp), %ah
 525         movb PT_CS(%esp), %al
 526         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 527         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 528         CFI_REMEMBER_STATE
 529         je ldt_ss                       # returning to user-space with LDT SS
 530 #endif
 531 restore_nocheck:
 532         RESTORE_REGS 4                  # skip orig_eax/error_code
 533 irq_return:
 534         INTERRUPT_RETURN
 535 .section .fixup,"ax"
 536 ENTRY(iret_exc)
 537         pushl $0                        # no error code
 538         pushl $do_iret_error
 539         jmp error_code
 540 .previous
 541         _ASM_EXTABLE(irq_return,iret_exc)
 542
 543 #ifdef CONFIG_X86_ESPFIX32
 544         CFI_RESTORE_STATE
 545 ldt_ss:
 546 #ifdef CONFIG_PARAVIRT
 547         /*
 548          * The kernel can't run on a non-flat stack if paravirt mode
 549          * is active.  Rather than try to fixup the high bits of
 550          * ESP, bypass this code entirely.  This may break DOSemu
 551          * and/or Wine support in a paravirt VM, although the option
 552          * is still available to implement the setting of the high
 553          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 554          */
 555         cmpl $0, pv_info+PARAVIRT_enabled
 556         jne restore_nocheck
 557 #endif
 558
 559 /*
 560  * Setup and switch to ESPFIX stack
 561  *
 562  * We're returning to userspace with a 16 bit stack. The CPU will not
 563  * restore the high word of ESP for us on executing iret... This is an
 564  * "official" bug of all the x86-compatible CPUs, which we can work
 565  * around to make dosemu and wine happy. We do this by preloading the
 566  * high word of ESP with the high word of the userspace ESP while
 567  * compensating for the offset by changing to the ESPFIX segment with
 568  * a base address that matches for the difference.
 569  */
 570 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 571         mov %esp, %edx                  /* load kernel esp */
 572         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 573         mov %dx, %ax                    /* eax: new kernel esp */
 574         sub %eax, %edx                  /* offset (low word is 0) */
 575         shr $16, %edx
 576         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 577         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 578         pushl_cfi $__ESPFIX_SS
 579         pushl_cfi %eax                  /* new kernel esp */
 580         /* Disable interrupts, but do not irqtrace this section: we
 581          * will soon execute iret and the tracer was already set to
 582          * the irqstate after the iret */
 583         DISABLE_INTERRUPTS(CLBR_EAX)
 584         lss (%esp), %esp                /* switch to espfix segment */
 585         CFI_ADJUST_CFA_OFFSET -8
 586         jmp restore_nocheck
 587 #endif
 588         CFI_ENDPROC
 589 ENDPROC(system_call)
 590
 591         # perform work that needs to be done immediately before resumption
 592         ALIGN
 593         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 594 work_pending:
 595         testb $_TIF_NEED_RESCHED, %cl
 596         jz work_notifysig
 597 work_resched:
 598         call schedule
 599         LOCKDEP_SYS_EXIT
 600         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 601                                         # setting need_resched or sigpending
 602                                         # between sampling and the iret
 603         TRACE_IRQS_OFF
 604         movl TI_flags(%ebp), %ecx
 605         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 606                                         # than syscall tracing?
 607         jz restore_all
 608         testb $_TIF_NEED_RESCHED, %cl
 609         jnz work_resched
 610
 611 work_notifysig:                         # deal with pending signals and
 612                                         # notify-resume requests
 613 #ifdef CONFIG_VM86
 614         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 615         movl %esp, %eax
 616         jne work_notifysig_v86          # returning to kernel-space or
 617                                         # vm86-space
 618 1:
 619 #else
 620         movl %esp, %eax
 621 #endif
 622         TRACE_IRQS_ON
 623         ENABLE_INTERRUPTS(CLBR_NONE)
 624         movb PT_CS(%esp), %bl
 625         andb $SEGMENT_RPL_MASK, %bl
 626         cmpb $USER_RPL, %bl
 627         jb resume_kernel
 628         xorl %edx, %edx
 629         call do_notify_resume
 630         jmp resume_userspace
 631
 632 #ifdef CONFIG_VM86
 633         ALIGN
 634 work_notifysig_v86:
 635         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 636         call save_v86_state             # %eax contains pt_regs pointer
 637         popl_cfi %ecx
 638         movl %eax, %esp
 639         jmp 1b
 640 #endif
 641 END(work_pending)
 642
 643         # perform syscall exit tracing
 644         ALIGN
 645 syscall_trace_entry:
 646         movl $-ENOSYS,PT_EAX(%esp)
 647         movl %esp, %eax
 648         call syscall_trace_enter
 649         /* What it returned is what we'll actually use.  */
 650         cmpl $(NR_syscalls), %eax
 651         jnae syscall_call
 652         jmp syscall_exit
 653 END(syscall_trace_entry)
 654
 655         # perform syscall exit tracing
 656         ALIGN
 657 syscall_exit_work:
 658         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 659         jz work_pending
 660         TRACE_IRQS_ON
 661         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 662                                         # schedule() instead
 663         movl %esp, %eax
 664         call syscall_trace_leave
 665         jmp resume_userspace
 666 END(syscall_exit_work)
 667         CFI_ENDPROC
 668
 669         RING0_INT_FRAME                 # can't unwind into user space anyway
 670 syscall_fault:
 671         ASM_CLAC
 672         GET_THREAD_INFO(%ebp)
 673         movl $-EFAULT,PT_EAX(%esp)
 674         jmp resume_userspace
 675 END(syscall_fault)
 676
 677 syscall_badsys:
 678         movl $-ENOSYS,%eax
 679         jmp syscall_after_call
 680 END(syscall_badsys)
 681
 682 sysenter_badsys:
 683         movl $-ENOSYS,%eax
 684         jmp sysenter_after_call
 685 END(sysenter_badsys)
 686         CFI_ENDPROC
 687
 688 .macro FIXUP_ESPFIX_STACK
 689 /*
 690  * Switch back for ESPFIX stack to the normal zerobased stack
 691  *
 692  * We can't call C functions using the ESPFIX stack. This code reads
 693  * the high word of the segment base from the GDT and swiches to the
 694  * normal stack and adjusts ESP with the matching offset.
 695  */
 696 #ifdef CONFIG_X86_ESPFIX32
 697         /* fixup the stack */
 698         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 699         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 700         shl $16, %eax
 701         addl %esp, %eax                 /* the adjusted stack pointer */
 702         pushl_cfi $__KERNEL_DS
 703         pushl_cfi %eax
 704         lss (%esp), %esp                /* switch to the normal stack segment */
 705         CFI_ADJUST_CFA_OFFSET -8
 706 #endif
 707 .endm
 708 .macro UNWIND_ESPFIX_STACK
 709 #ifdef CONFIG_X86_ESPFIX32
 710         movl %ss, %eax
 711         /* see if on espfix stack */
 712         cmpw $__ESPFIX_SS, %ax
 713         jne 27f
 714         movl $__KERNEL_DS, %eax
 715         movl %eax, %ds
 716         movl %eax, %es
 717         /* switch to normal stack */
 718         FIXUP_ESPFIX_STACK
 719 27:
 720 #endif
 721 .endm
 722
 723 /*
 724  * Build the entry stubs and pointer table with some assembler magic.
 725  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 726  * single cache line on all modern x86 implementations.
 727  */
 728 .section .init.rodata,"a"
 729 ENTRY(interrupt)
 730 .section .entry.text, "ax"
 731         .p2align 5
 732         .p2align CONFIG_X86_L1_CACHE_SHIFT
 733 ENTRY(irq_entries_start)
 734         RING0_INT_FRAME
 735 vector=FIRST_EXTERNAL_VECTOR
 736 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 737         .balign 32
 738   .rept 7
 739     .if vector < NR_VECTORS
 740       .if vector <> FIRST_EXTERNAL_VECTOR
 741         CFI_ADJUST_CFA_OFFSET -4
 742       .endif
 743 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 744       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 745         jmp 2f
 746       .endif
 747       .previous
 748         .long 1b
 749       .section .entry.text, "ax"
 750 vector=vector+1
 751     .endif
 752   .endr
 753 2:      jmp common_interrupt
 754 .endr
 755 END(irq_entries_start)
 756
 757 .previous
 758 END(interrupt)
 759 .previous
 760
 761 /*
 762  * the CPU automatically disables interrupts when executing an IRQ vector,
 763  * so IRQ-flags tracing has to follow that:
 764  */
 765         .p2align CONFIG_X86_L1_CACHE_SHIFT
 766 common_interrupt:
 767         ASM_CLAC
 768         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 769         SAVE_ALL
 770         TRACE_IRQS_OFF
 771         movl %esp,%eax
 772         call do_IRQ
 773         jmp ret_from_intr
 774 ENDPROC(common_interrupt)
 775         CFI_ENDPROC
 776
 777 #define BUILD_INTERRUPT3(name, nr, fn)  \
 778 ENTRY(name)                             \
 779         RING0_INT_FRAME;                \
 780         ASM_CLAC;                       \
 781         pushl_cfi $~(nr);               \
 782         SAVE_ALL;                       \
 783         TRACE_IRQS_OFF                  \
 784         movl %esp,%eax;                 \
 785         call fn;                        \
 786         jmp ret_from_intr;              \
 787         CFI_ENDPROC;                    \
 788 ENDPROC(name)
 789
 790
 791 #ifdef CONFIG_TRACING
 792 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 793         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 794 #else
 795 #define TRACE_BUILD_INTERRUPT(name, nr)
 796 #endif
 797
 798 #define BUILD_INTERRUPT(name, nr) \
 799         BUILD_INTERRUPT3(name, nr, smp_##name); \
 800         TRACE_BUILD_INTERRUPT(name, nr)
 801
 802 /* The include is where all of the SMP etc. interrupts come from */
 803 #include <asm/entry_arch.h>
 804
 805 ENTRY(coprocessor_error)
 806         RING0_INT_FRAME
 807         ASM_CLAC
 808         pushl_cfi $0
 809         pushl_cfi $do_coprocessor_error
 810         jmp error_code
 811         CFI_ENDPROC
 812 END(coprocessor_error)
 813
 814 ENTRY(simd_coprocessor_error)
 815         RING0_INT_FRAME
 816         ASM_CLAC
 817         pushl_cfi $0
 818 #ifdef CONFIG_X86_INVD_BUG
 819         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 820 661:    pushl_cfi $do_general_protection
 821 662:
 822 .section .altinstructions,"a"
 823         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 824 .previous
 825 .section .altinstr_replacement,"ax"
 826 663:    pushl $do_simd_coprocessor_error
 827 664:
 828 .previous
 829 #else
 830         pushl_cfi $do_simd_coprocessor_error
 831 #endif
 832         jmp error_code
 833         CFI_ENDPROC
 834 END(simd_coprocessor_error)
 835
 836 ENTRY(device_not_available)
 837         RING0_INT_FRAME
 838         ASM_CLAC
 839         pushl_cfi $-1                   # mark this as an int
 840         pushl_cfi $do_device_not_available
 841         jmp error_code
 842         CFI_ENDPROC
 843 END(device_not_available)
 844
 845 #ifdef CONFIG_PARAVIRT
 846 ENTRY(native_iret)
 847         iret
 848         _ASM_EXTABLE(native_iret, iret_exc)
 849 END(native_iret)
 850
 851 ENTRY(native_irq_enable_sysexit)
 852         sti
 853         sysexit
 854 END(native_irq_enable_sysexit)
 855 #endif
 856
 857 ENTRY(overflow)
 858         RING0_INT_FRAME
 859         ASM_CLAC
 860         pushl_cfi $0
 861         pushl_cfi $do_overflow
 862         jmp error_code
 863         CFI_ENDPROC
 864 END(overflow)
 865
 866 ENTRY(bounds)
 867         RING0_INT_FRAME
 868         ASM_CLAC
 869         pushl_cfi $0
 870         pushl_cfi $do_bounds
 871         jmp error_code
 872         CFI_ENDPROC
 873 END(bounds)
 874
 875 ENTRY(invalid_op)
 876         RING0_INT_FRAME
 877         ASM_CLAC
 878         pushl_cfi $0
 879         pushl_cfi $do_invalid_op
 880         jmp error_code
 881         CFI_ENDPROC
 882 END(invalid_op)
 883
 884 ENTRY(coprocessor_segment_overrun)
 885         RING0_INT_FRAME
 886         ASM_CLAC
 887         pushl_cfi $0
 888         pushl_cfi $do_coprocessor_segment_overrun
 889         jmp error_code
 890         CFI_ENDPROC
 891 END(coprocessor_segment_overrun)
 892
 893 ENTRY(invalid_TSS)
 894         RING0_EC_FRAME
 895         ASM_CLAC
 896         pushl_cfi $do_invalid_TSS
 897         jmp error_code
 898         CFI_ENDPROC
 899 END(invalid_TSS)
 900
 901 ENTRY(segment_not_present)
 902         RING0_EC_FRAME
 903         ASM_CLAC
 904         pushl_cfi $do_segment_not_present
 905         jmp error_code
 906         CFI_ENDPROC
 907 END(segment_not_present)
 908
 909 ENTRY(stack_segment)
 910         RING0_EC_FRAME
 911         ASM_CLAC
 912         pushl_cfi $do_stack_segment
 913         jmp error_code
 914         CFI_ENDPROC
 915 END(stack_segment)
 916
 917 ENTRY(alignment_check)
 918         RING0_EC_FRAME
 919         ASM_CLAC
 920         pushl_cfi $do_alignment_check
 921         jmp error_code
 922         CFI_ENDPROC
 923 END(alignment_check)
 924
 925 ENTRY(divide_error)
 926         RING0_INT_FRAME
 927         ASM_CLAC
 928         pushl_cfi $0                    # no error code
 929         pushl_cfi $do_divide_error
 930         jmp error_code
 931         CFI_ENDPROC
 932 END(divide_error)
 933
 934 #ifdef CONFIG_X86_MCE
 935 ENTRY(machine_check)
 936         RING0_INT_FRAME
 937         ASM_CLAC
 938         pushl_cfi $0
 939         pushl_cfi machine_check_vector
 940         jmp error_code
 941         CFI_ENDPROC
 942 END(machine_check)
 943 #endif
 944
 945 ENTRY(spurious_interrupt_bug)
 946         RING0_INT_FRAME
 947         ASM_CLAC
 948         pushl_cfi $0
 949         pushl_cfi $do_spurious_interrupt_bug
 950         jmp error_code
 951         CFI_ENDPROC
 952 END(spurious_interrupt_bug)
 953
 954 #ifdef CONFIG_XEN
 955 /* Xen doesn't set %esp to be precisely what the normal sysenter
 956    entrypoint expects, so fix it up before using the normal path. */
 957 ENTRY(xen_sysenter_target)
 958         RING0_INT_FRAME
 959         addl $5*4, %esp         /* remove xen-provided frame */
 960         CFI_ADJUST_CFA_OFFSET -5*4
 961         jmp sysenter_past_esp
 962         CFI_ENDPROC
 963
 964 ENTRY(xen_hypervisor_callback)
 965         CFI_STARTPROC
 966         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 967         SAVE_ALL
 968         TRACE_IRQS_OFF
 969
 970         /* Check to see if we got the event in the critical
 971            region in xen_iret_direct, after we've reenabled
 972            events and checked for pending events.  This simulates
 973            iret instruction's behaviour where it delivers a
 974            pending interrupt when enabling interrupts. */
 975         movl PT_EIP(%esp),%eax
 976         cmpl $xen_iret_start_crit,%eax
 977         jb   1f
 978         cmpl $xen_iret_end_crit,%eax
 979         jae  1f
 980
 981         jmp  xen_iret_crit_fixup
 982
 983 ENTRY(xen_do_upcall)
 984 1:      mov %esp, %eax
 985         call xen_evtchn_do_upcall
 986         jmp  ret_from_intr
 987         CFI_ENDPROC
 988 ENDPROC(xen_hypervisor_callback)
 989
 990 # Hypervisor uses this for application faults while it executes.
 991 # We get here for two reasons:
 992 #  1. Fault while reloading DS, ES, FS or GS
 993 #  2. Fault while executing IRET
 994 # Category 1 we fix up by reattempting the load, and zeroing the segment
 995 # register if the load fails.
 996 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
 997 # normal Linux return path in this case because if we use the IRET hypercall
 998 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 999 # We distinguish between categories by maintaining a status value in EAX.
1000 ENTRY(xen_failsafe_callback)
1001         CFI_STARTPROC
1002         pushl_cfi %eax
1003         movl $1,%eax
1004 1:      mov 4(%esp),%ds
1005 2:      mov 8(%esp),%es
1006 3:      mov 12(%esp),%fs
1007 4:      mov 16(%esp),%gs
1008         /* EAX == 0 => Category 1 (Bad segment)
1009            EAX != 0 => Category 2 (Bad IRET) */
1010         testl %eax,%eax
1011         popl_cfi %eax
1012         lea 16(%esp),%esp
1013         CFI_ADJUST_CFA_OFFSET -16
1014         jz 5f
1015         jmp iret_exc
1016 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1017         SAVE_ALL
1018         jmp ret_from_exception
1019         CFI_ENDPROC
1020
1021 .section .fixup,"ax"
1022 6:      xorl %eax,%eax
1023         movl %eax,4(%esp)
1024         jmp 1b
1025 7:      xorl %eax,%eax
1026         movl %eax,8(%esp)
1027         jmp 2b
1028 8:      xorl %eax,%eax
1029         movl %eax,12(%esp)
1030         jmp 3b
1031 9:      xorl %eax,%eax
1032         movl %eax,16(%esp)
1033         jmp 4b
1034 .previous
1035         _ASM_EXTABLE(1b,6b)
1036         _ASM_EXTABLE(2b,7b)
1037         _ASM_EXTABLE(3b,8b)
1038         _ASM_EXTABLE(4b,9b)
1039 ENDPROC(xen_failsafe_callback)
1040
1041 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1042                 xen_evtchn_do_upcall)
1043
1044 #endif  /* CONFIG_XEN */
1045
1046 #if IS_ENABLED(CONFIG_HYPERV)
1047
1048 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1049         hyperv_vector_handler)
1050
1051 #endif /* CONFIG_HYPERV */
1052
1053 #ifdef CONFIG_FUNCTION_TRACER
1054 #ifdef CONFIG_DYNAMIC_FTRACE
1055
1056 ENTRY(mcount)
1057         ret
1058 END(mcount)
1059
1060 ENTRY(ftrace_caller)
1061         pushl %eax
1062         pushl %ecx
1063         pushl %edx
1064         pushl $0        /* Pass NULL as regs pointer */
1065         movl 4*4(%esp), %eax
1066         movl 0x4(%ebp), %edx
1067         movl function_trace_op, %ecx
1068         subl $MCOUNT_INSN_SIZE, %eax
1069
1070 .globl ftrace_call
1071 ftrace_call:
1072         call ftrace_stub
1073
1074         addl $4,%esp    /* skip NULL pointer */
1075         popl %edx
1076         popl %ecx
1077         popl %eax
1078 ftrace_ret:
1079 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1080 .globl ftrace_graph_call
1081 ftrace_graph_call:
1082         jmp ftrace_stub
1083 #endif
1084
1085 .globl ftrace_stub
1086 ftrace_stub:
1087         ret
1088 END(ftrace_caller)
1089
1090 ENTRY(ftrace_regs_caller)
1091         pushf   /* push flags before compare (in cs location) */
1092
1093         /*
1094          * i386 does not save SS and ESP when coming from kernel.
1095          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1096          * Unfortunately, that means eflags must be at the same location
1097          * as the current return ip is. We move the return ip into the
1098          * ip location, and move flags into the return ip location.
1099          */
1100         pushl 4(%esp)   /* save return ip into ip slot */
1101
1102         pushl $0        /* Load 0 into orig_ax */
1103         pushl %gs
1104         pushl %fs
1105         pushl %es
1106         pushl %ds
1107         pushl %eax
1108         pushl %ebp
1109         pushl %edi
1110         pushl %esi
1111         pushl %edx
1112         pushl %ecx
1113         pushl %ebx
1114
1115         movl 13*4(%esp), %eax   /* Get the saved flags */
1116         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1117                                 /* clobbering return ip */
1118         movl $__KERNEL_CS,13*4(%esp)
1119
1120         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1121         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1122         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1123         movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1124         pushl %esp              /* Save pt_regs as 4th parameter */
1125
1126 GLOBAL(ftrace_regs_call)
1127         call ftrace_stub
1128
1129         addl $4, %esp           /* Skip pt_regs */
1130         movl 14*4(%esp), %eax   /* Move flags back into cs */
1131         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1132         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1133         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1134
1135         popl %ebx
1136         popl %ecx
1137         popl %edx
1138         popl %esi
1139         popl %edi
1140         popl %ebp
1141         popl %eax
1142         popl %ds
1143         popl %es
1144         popl %fs
1145         popl %gs
1146         addl $8, %esp           /* Skip orig_ax and ip */
1147         popf                    /* Pop flags at end (no addl to corrupt flags) */
1148         jmp ftrace_ret
1149
1150         popf
1151         jmp  ftrace_stub
1152 #else /* ! CONFIG_DYNAMIC_FTRACE */
1153
1154 ENTRY(mcount)
1155         cmpl $__PAGE_OFFSET, %esp
1156         jb ftrace_stub          /* Paging not enabled yet? */
1157
1158         cmpl $ftrace_stub, ftrace_trace_function
1159         jnz trace
1160 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1161         cmpl $ftrace_stub, ftrace_graph_return
1162         jnz ftrace_graph_caller
1163
1164         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1165         jnz ftrace_graph_caller
1166 #endif
1167 .globl ftrace_stub
1168 ftrace_stub:
1169         ret
1170
1171         /* taken from glibc */
1172 trace:
1173         pushl %eax
1174         pushl %ecx
1175         pushl %edx
1176         movl 0xc(%esp), %eax
1177         movl 0x4(%ebp), %edx
1178         subl $MCOUNT_INSN_SIZE, %eax
1179
1180         call *ftrace_trace_function
1181
1182         popl %edx
1183         popl %ecx
1184         popl %eax
1185         jmp ftrace_stub
1186 END(mcount)
1187 #endif /* CONFIG_DYNAMIC_FTRACE */
1188 #endif /* CONFIG_FUNCTION_TRACER */
1189
1190 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1191 ENTRY(ftrace_graph_caller)
1192         pushl %eax
1193         pushl %ecx
1194         pushl %edx
1195         movl 0xc(%esp), %edx
1196         lea 0x4(%ebp), %eax
1197         movl (%ebp), %ecx
1198         subl $MCOUNT_INSN_SIZE, %edx
1199         call prepare_ftrace_return
1200         popl %edx
1201         popl %ecx
1202         popl %eax
1203         ret
1204 END(ftrace_graph_caller)
1205
1206 .globl return_to_handler
1207 return_to_handler:
1208         pushl %eax
1209         pushl %edx
1210         movl %ebp, %eax
1211         call ftrace_return_to_handler
1212         movl %eax, %ecx
1213         popl %edx
1214         popl %eax
1215         jmp *%ecx
1216 #endif
1217
1218 #ifdef CONFIG_TRACING
1219 ENTRY(trace_page_fault)
1220         RING0_EC_FRAME
1221         ASM_CLAC
1222         pushl_cfi $trace_do_page_fault
1223         jmp error_code
1224         CFI_ENDPROC
1225 END(trace_page_fault)
1226 #endif
1227
1228 ENTRY(page_fault)
1229         RING0_EC_FRAME
1230         ASM_CLAC
1231         pushl_cfi $do_page_fault
1232         ALIGN
1233 error_code:
1234         /* the function address is in %gs's slot on the stack */
1235         pushl_cfi %fs
1236         /*CFI_REL_OFFSET fs, 0*/
1237         pushl_cfi %es
1238         /*CFI_REL_OFFSET es, 0*/
1239         pushl_cfi %ds
1240         /*CFI_REL_OFFSET ds, 0*/
1241         pushl_cfi %eax
1242         CFI_REL_OFFSET eax, 0
1243         pushl_cfi %ebp
1244         CFI_REL_OFFSET ebp, 0
1245         pushl_cfi %edi
1246         CFI_REL_OFFSET edi, 0
1247         pushl_cfi %esi
1248         CFI_REL_OFFSET esi, 0
1249         pushl_cfi %edx
1250         CFI_REL_OFFSET edx, 0
1251         pushl_cfi %ecx
1252         CFI_REL_OFFSET ecx, 0
1253         pushl_cfi %ebx
1254         CFI_REL_OFFSET ebx, 0
1255         cld
1256         movl $(__KERNEL_PERCPU), %ecx
1257         movl %ecx, %fs
1258         UNWIND_ESPFIX_STACK
1259         GS_TO_REG %ecx
1260         movl PT_GS(%esp), %edi          # get the function address
1261         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1262         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1263         REG_TO_PTGS %ecx
1264         SET_KERNEL_GS %ecx
1265         movl $(__USER_DS), %ecx
1266         movl %ecx, %ds
1267         movl %ecx, %es
1268         TRACE_IRQS_OFF
1269         movl %esp,%eax                  # pt_regs pointer
1270         call *%edi
1271         jmp ret_from_exception
1272         CFI_ENDPROC
1273 END(page_fault)
1274
1275 /*
1276  * Debug traps and NMI can happen at the one SYSENTER instruction
1277  * that sets up the real kernel stack. Check here, since we can't
1278  * allow the wrong stack to be used.
1279  *
1280  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1281  * already pushed 3 words if it hits on the sysenter instruction:
1282  * eflags, cs and eip.
1283  *
1284  * We just load the right stack, and push the three (known) values
1285  * by hand onto the new stack - while updating the return eip past
1286  * the instruction that would have done it for sysenter.
1287  */
1288 .macro FIX_STACK offset ok label
1289         cmpw $__KERNEL_CS, 4(%esp)
1290         jne \ok
1291 \label:
1292         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1293         CFI_DEF_CFA esp, 0
1294         CFI_UNDEFINED eip
1295         pushfl_cfi
1296         pushl_cfi $__KERNEL_CS
1297         pushl_cfi $sysenter_past_esp
1298         CFI_REL_OFFSET eip, 0
1299 .endm
1300
1301 ENTRY(debug)
1302         RING0_INT_FRAME
1303         ASM_CLAC
1304         cmpl $ia32_sysenter_target,(%esp)
1305         jne debug_stack_correct
1306         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1307 debug_stack_correct:
1308         pushl_cfi $-1                   # mark this as an int
1309         SAVE_ALL
1310         TRACE_IRQS_OFF
1311         xorl %edx,%edx                  # error code 0
1312         movl %esp,%eax                  # pt_regs pointer
1313         call do_debug
1314         jmp ret_from_exception
1315         CFI_ENDPROC
1316 END(debug)
1317
1318 /*
1319  * NMI is doubly nasty. It can happen _while_ we're handling
1320  * a debug fault, and the debug fault hasn't yet been able to
1321  * clear up the stack. So we first check whether we got  an
1322  * NMI on the sysenter entry path, but after that we need to
1323  * check whether we got an NMI on the debug path where the debug
1324  * fault happened on the sysenter path.
1325  */
1326 ENTRY(nmi)
1327         RING0_INT_FRAME
1328         ASM_CLAC
1329 #ifdef CONFIG_X86_ESPFIX32
1330         pushl_cfi %eax
1331         movl %ss, %eax
1332         cmpw $__ESPFIX_SS, %ax
1333         popl_cfi %eax
1334         je nmi_espfix_stack
1335 #endif
1336         cmpl $ia32_sysenter_target,(%esp)
1337         je nmi_stack_fixup
1338         pushl_cfi %eax
1339         movl %esp,%eax
1340         /* Do not access memory above the end of our stack page,
1341          * it might not exist.
1342          */
1343         andl $(THREAD_SIZE-1),%eax
1344         cmpl $(THREAD_SIZE-20),%eax
1345         popl_cfi %eax
1346         jae nmi_stack_correct
1347         cmpl $ia32_sysenter_target,12(%esp)
1348         je nmi_debug_stack_check
1349 nmi_stack_correct:
1350         /* We have a RING0_INT_FRAME here */
1351         pushl_cfi %eax
1352         SAVE_ALL
1353         xorl %edx,%edx          # zero error code
1354         movl %esp,%eax          # pt_regs pointer
1355         call do_nmi
1356         jmp restore_all_notrace
1357         CFI_ENDPROC
1358
1359 nmi_stack_fixup:
1360         RING0_INT_FRAME
1361         FIX_STACK 12, nmi_stack_correct, 1
1362         jmp nmi_stack_correct
1363
1364 nmi_debug_stack_check:
1365         /* We have a RING0_INT_FRAME here */
1366         cmpw $__KERNEL_CS,16(%esp)
1367         jne nmi_stack_correct
1368         cmpl $debug,(%esp)
1369         jb nmi_stack_correct
1370         cmpl $debug_esp_fix_insn,(%esp)
1371         ja nmi_stack_correct
1372         FIX_STACK 24, nmi_stack_correct, 1
1373         jmp nmi_stack_correct
1374
1375 #ifdef CONFIG_X86_ESPFIX32
1376 nmi_espfix_stack:
1377         /* We have a RING0_INT_FRAME here.
1378          *
1379          * create the pointer to lss back
1380          */
1381         pushl_cfi %ss
1382         pushl_cfi %esp
1383         addl $4, (%esp)
1384         /* copy the iret frame of 12 bytes */
1385         .rept 3
1386         pushl_cfi 16(%esp)
1387         .endr
1388         pushl_cfi %eax
1389         SAVE_ALL
1390         FIXUP_ESPFIX_STACK              # %eax == %esp
1391         xorl %edx,%edx                  # zero error code
1392         call do_nmi
1393         RESTORE_REGS
1394         lss 12+4(%esp), %esp            # back to espfix stack
1395         CFI_ADJUST_CFA_OFFSET -24
1396         jmp irq_return
1397 #endif
1398         CFI_ENDPROC
1399 END(nmi)
1400
1401 ENTRY(int3)
1402         RING0_INT_FRAME
1403         ASM_CLAC
1404         pushl_cfi $-1                   # mark this as an int
1405         SAVE_ALL
1406         TRACE_IRQS_OFF
1407         xorl %edx,%edx          # zero error code
1408         movl %esp,%eax          # pt_regs pointer
1409         call do_int3
1410         jmp ret_from_exception
1411         CFI_ENDPROC
1412 END(int3)
1413
1414 ENTRY(general_protection)
1415         RING0_EC_FRAME
1416         pushl_cfi $do_general_protection
1417         jmp error_code
1418         CFI_ENDPROC
1419 END(general_protection)
1420
1421 #ifdef CONFIG_KVM_GUEST
1422 ENTRY(async_page_fault)
1423         RING0_EC_FRAME
1424         ASM_CLAC
1425         pushl_cfi $do_async_page_fault
1426         jmp error_code
1427         CFI_ENDPROC
1428 END(async_page_fault)
1429 #endif
1430