arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Interrupt exit functions should be protected against kprobes
 319  */
 320         .pushsection .kprobes.text, "ax"
 321 /*
 322  * Return to user mode is not as complex as all this looks,
 323  * but we want the default path for a system call return to
 324  * go as quickly as possible which is why some of this is
 325  * less clear than it otherwise should be.
 326  */
 327
 328         # userspace resumption stub bypassing syscall exit tracing
 329         ALIGN
 330         RING0_PTREGS_FRAME
 331 ret_from_exception:
 332         preempt_stop(CLBR_ANY)
 333 ret_from_intr:
 334         GET_THREAD_INFO(%ebp)
 335 #ifdef CONFIG_VM86
 336         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 337         movb PT_CS(%esp), %al
 338         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 339 #else
 340         /*
 341          * We can be coming here from child spawned by kernel_thread().
 342          */
 343         movl PT_CS(%esp), %eax
 344         andl $SEGMENT_RPL_MASK, %eax
 345 #endif
 346         cmpl $USER_RPL, %eax
 347         jb resume_kernel                # not returning to v8086 or userspace
 348
 349 ENTRY(resume_userspace)
 350         LOCKDEP_SYS_EXIT
 351         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 352                                         # setting need_resched or sigpending
 353                                         # between sampling and the iret
 354         TRACE_IRQS_OFF
 355         movl TI_flags(%ebp), %ecx
 356         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 357                                         # int/exception return?
 358         jne work_pending
 359         jmp restore_all
 360 END(ret_from_exception)
 361
 362 #ifdef CONFIG_PREEMPT
 363 ENTRY(resume_kernel)
 364         DISABLE_INTERRUPTS(CLBR_ANY)
 365         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 366         jnz restore_all
 367 need_resched:
 368         movl TI_flags(%ebp), %ecx       # need_resched set ?
 369         testb $_TIF_NEED_RESCHED, %cl
 370         jz restore_all
 371         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 372         jz restore_all
 373         call preempt_schedule_irq
 374         jmp need_resched
 375 END(resume_kernel)
 376 #endif
 377         CFI_ENDPROC
 378 /*
 379  * End of kprobes section
 380  */
 381         .popsection
 382
 383 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 384    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 385
 386         # sysenter call handler stub
 387 ENTRY(ia32_sysenter_target)
 388         CFI_STARTPROC simple
 389         CFI_SIGNAL_FRAME
 390         CFI_DEF_CFA esp, 0
 391         CFI_REGISTER esp, ebp
 392         movl TSS_sysenter_sp0(%esp),%esp
 393 sysenter_past_esp:
 394         /*
 395          * Interrupts are disabled here, but we can't trace it until
 396          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 397          * we immediately enable interrupts at that point anyway.
 398          */
 399         pushl_cfi $__USER_DS
 400         /*CFI_REL_OFFSET ss, 0*/
 401         pushl_cfi %ebp
 402         CFI_REL_OFFSET esp, 0
 403         pushfl_cfi
 404         orl $X86_EFLAGS_IF, (%esp)
 405         pushl_cfi $__USER_CS
 406         /*CFI_REL_OFFSET cs, 0*/
 407         /*
 408          * Push current_thread_info()->sysenter_return to the stack.
 409          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 410          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 411          */
 412         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 413         CFI_REL_OFFSET eip, 0
 414
 415         pushl_cfi %eax
 416         SAVE_ALL
 417         ENABLE_INTERRUPTS(CLBR_NONE)
 418
 419 /*
 420  * Load the potential sixth argument from user stack.
 421  * Careful about security.
 422  */
 423         cmpl $__PAGE_OFFSET-3,%ebp
 424         jae syscall_fault
 425         ASM_STAC
 426 1:      movl (%ebp),%ebp
 427         ASM_CLAC
 428         movl %ebp,PT_EBP(%esp)
 429         _ASM_EXTABLE(1b,syscall_fault)
 430
 431         GET_THREAD_INFO(%ebp)
 432
 433         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 434         jnz sysenter_audit
 435 sysenter_do_call:
 436         cmpl $(NR_syscalls), %eax
 437         jae syscall_badsys
 438         call *sys_call_table(,%eax,4)
 439         movl %eax,PT_EAX(%esp)
 440         LOCKDEP_SYS_EXIT
 441         DISABLE_INTERRUPTS(CLBR_ANY)
 442         TRACE_IRQS_OFF
 443         movl TI_flags(%ebp), %ecx
 444         testl $_TIF_ALLWORK_MASK, %ecx
 445         jne sysexit_audit
 446 sysenter_exit:
 447 /* if something modifies registers it must also disable sysexit */
 448         movl PT_EIP(%esp), %edx
 449         movl PT_OLDESP(%esp), %ecx
 450         xorl %ebp,%ebp
 451         TRACE_IRQS_ON
 452 1:      mov  PT_FS(%esp), %fs
 453         PTGS_TO_GS
 454         ENABLE_INTERRUPTS_SYSEXIT
 455
 456 #ifdef CONFIG_AUDITSYSCALL
 457 sysenter_audit:
 458         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 459         jnz syscall_trace_entry
 460         addl $4,%esp
 461         CFI_ADJUST_CFA_OFFSET -4
 462         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 463         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 464         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 465         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 466         movl %eax,%edx                  /* 2nd arg: syscall number */
 467         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 468         call __audit_syscall_entry
 469         pushl_cfi %ebx
 470         movl PT_EAX(%esp),%eax          /* reload syscall number */
 471         jmp sysenter_do_call
 472
 473 sysexit_audit:
 474         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 475         jne syscall_exit_work
 476         TRACE_IRQS_ON
 477         ENABLE_INTERRUPTS(CLBR_ANY)
 478         movl %eax,%edx          /* second arg, syscall return value */
 479         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 480         setbe %al               /* 1 if so, 0 if not */
 481         movzbl %al,%eax         /* zero-extend that */
 482         call __audit_syscall_exit
 483         DISABLE_INTERRUPTS(CLBR_ANY)
 484         TRACE_IRQS_OFF
 485         movl TI_flags(%ebp), %ecx
 486         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 487         jne syscall_exit_work
 488         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 489         jmp sysenter_exit
 490 #endif
 491
 492         CFI_ENDPROC
 493 .pushsection .fixup,"ax"
 494 2:      movl $0,PT_FS(%esp)
 495         jmp 1b
 496 .popsection
 497         _ASM_EXTABLE(1b,2b)
 498         PTGS_TO_GS_EX
 499 ENDPROC(ia32_sysenter_target)
 500
 501 /*
 502  * syscall stub including irq exit should be protected against kprobes
 503  */
 504         .pushsection .kprobes.text, "ax"
 505         # system call handler stub
 506 ENTRY(system_call)
 507         RING0_INT_FRAME                 # can't unwind into user space anyway
 508         ASM_CLAC
 509         pushl_cfi %eax                  # save orig_eax
 510         SAVE_ALL
 511         GET_THREAD_INFO(%ebp)
 512                                         # system call tracing in operation / emulation
 513         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 514         jnz syscall_trace_entry
 515         cmpl $(NR_syscalls), %eax
 516         jae syscall_badsys
 517 syscall_call:
 518         call *sys_call_table(,%eax,4)
 519         movl %eax,PT_EAX(%esp)          # store the return value
 520 syscall_exit:
 521         LOCKDEP_SYS_EXIT
 522         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 523                                         # setting need_resched or sigpending
 524                                         # between sampling and the iret
 525         TRACE_IRQS_OFF
 526         movl TI_flags(%ebp), %ecx
 527         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 528         jne syscall_exit_work
 529
 530 restore_all:
 531         TRACE_IRQS_IRET
 532 restore_all_notrace:
 533         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 534         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 535         # are returning to the kernel.
 536         # See comments in process.c:copy_thread() for details.
 537         movb PT_OLDSS(%esp), %ah
 538         movb PT_CS(%esp), %al
 539         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 540         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 541         CFI_REMEMBER_STATE
 542         je ldt_ss                       # returning to user-space with LDT SS
 543 restore_nocheck:
 544         RESTORE_REGS 4                  # skip orig_eax/error_code
 545 irq_return:
 546         INTERRUPT_RETURN
 547 .section .fixup,"ax"
 548 ENTRY(iret_exc)
 549         pushl $0                        # no error code
 550         pushl $do_iret_error
 551         jmp error_code
 552 .previous
 553         _ASM_EXTABLE(irq_return,iret_exc)
 554
 555         CFI_RESTORE_STATE
 556 ldt_ss:
 557         larl PT_OLDSS(%esp), %eax
 558         jnz restore_nocheck
 559         testl $0x00400000, %eax         # returning to 32bit stack?
 560         jnz restore_nocheck             # allright, normal return
 561
 562 #ifdef CONFIG_PARAVIRT
 563         /*
 564          * The kernel can't run on a non-flat stack if paravirt mode
 565          * is active.  Rather than try to fixup the high bits of
 566          * ESP, bypass this code entirely.  This may break DOSemu
 567          * and/or Wine support in a paravirt VM, although the option
 568          * is still available to implement the setting of the high
 569          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 570          */
 571         cmpl $0, pv_info+PARAVIRT_enabled
 572         jne restore_nocheck
 573 #endif
 574
 575 /*
 576  * Setup and switch to ESPFIX stack
 577  *
 578  * We're returning to userspace with a 16 bit stack. The CPU will not
 579  * restore the high word of ESP for us on executing iret... This is an
 580  * "official" bug of all the x86-compatible CPUs, which we can work
 581  * around to make dosemu and wine happy. We do this by preloading the
 582  * high word of ESP with the high word of the userspace ESP while
 583  * compensating for the offset by changing to the ESPFIX segment with
 584  * a base address that matches for the difference.
 585  */
 586 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 587         mov %esp, %edx                  /* load kernel esp */
 588         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 589         mov %dx, %ax                    /* eax: new kernel esp */
 590         sub %eax, %edx                  /* offset (low word is 0) */
 591         shr $16, %edx
 592         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 593         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 594         pushl_cfi $__ESPFIX_SS
 595         pushl_cfi %eax                  /* new kernel esp */
 596         /* Disable interrupts, but do not irqtrace this section: we
 597          * will soon execute iret and the tracer was already set to
 598          * the irqstate after the iret */
 599         DISABLE_INTERRUPTS(CLBR_EAX)
 600         lss (%esp), %esp                /* switch to espfix segment */
 601         CFI_ADJUST_CFA_OFFSET -8
 602         jmp restore_nocheck
 603         CFI_ENDPROC
 604 ENDPROC(system_call)
 605
 606         # perform work that needs to be done immediately before resumption
 607         ALIGN
 608         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 609 work_pending:
 610         testb $_TIF_NEED_RESCHED, %cl
 611         jz work_notifysig
 612 work_resched:
 613         call schedule
 614         LOCKDEP_SYS_EXIT
 615         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 616                                         # setting need_resched or sigpending
 617                                         # between sampling and the iret
 618         TRACE_IRQS_OFF
 619         movl TI_flags(%ebp), %ecx
 620         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 621                                         # than syscall tracing?
 622         jz restore_all
 623         testb $_TIF_NEED_RESCHED, %cl
 624         jnz work_resched
 625
 626 work_notifysig:                         # deal with pending signals and
 627                                         # notify-resume requests
 628 #ifdef CONFIG_VM86
 629         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 630         movl %esp, %eax
 631         jne work_notifysig_v86          # returning to kernel-space or
 632                                         # vm86-space
 633 1:
 634 #else
 635         movl %esp, %eax
 636 #endif
 637         TRACE_IRQS_ON
 638         ENABLE_INTERRUPTS(CLBR_NONE)
 639         movb PT_CS(%esp), %bl
 640         andb $SEGMENT_RPL_MASK, %bl
 641         cmpb $USER_RPL, %bl
 642         jb resume_kernel
 643         xorl %edx, %edx
 644         call do_notify_resume
 645         jmp resume_userspace
 646
 647 #ifdef CONFIG_VM86
 648         ALIGN
 649 work_notifysig_v86:
 650         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 651         call save_v86_state             # %eax contains pt_regs pointer
 652         popl_cfi %ecx
 653         movl %eax, %esp
 654         jmp 1b
 655 #endif
 656 END(work_pending)
 657
 658         # perform syscall exit tracing
 659         ALIGN
 660 syscall_trace_entry:
 661         movl $-ENOSYS,PT_EAX(%esp)
 662         movl %esp, %eax
 663         call syscall_trace_enter
 664         /* What it returned is what we'll actually use.  */
 665         cmpl $(NR_syscalls), %eax
 666         jnae syscall_call
 667         jmp syscall_exit
 668 END(syscall_trace_entry)
 669
 670         # perform syscall exit tracing
 671         ALIGN
 672 syscall_exit_work:
 673         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 674         jz work_pending
 675         TRACE_IRQS_ON
 676         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 677                                         # schedule() instead
 678         movl %esp, %eax
 679         call syscall_trace_leave
 680         jmp resume_userspace
 681 END(syscall_exit_work)
 682         CFI_ENDPROC
 683
 684         RING0_INT_FRAME                 # can't unwind into user space anyway
 685 syscall_fault:
 686         ASM_CLAC
 687         GET_THREAD_INFO(%ebp)
 688         movl $-EFAULT,PT_EAX(%esp)
 689         jmp resume_userspace
 690 END(syscall_fault)
 691
 692 syscall_badsys:
 693         movl $-ENOSYS,PT_EAX(%esp)
 694         jmp resume_userspace
 695 END(syscall_badsys)
 696         CFI_ENDPROC
 697 /*
 698  * End of kprobes section
 699  */
 700         .popsection
 701
 702 .macro FIXUP_ESPFIX_STACK
 703 /*
 704  * Switch back for ESPFIX stack to the normal zerobased stack
 705  *
 706  * We can't call C functions using the ESPFIX stack. This code reads
 707  * the high word of the segment base from the GDT and swiches to the
 708  * normal stack and adjusts ESP with the matching offset.
 709  */
 710         /* fixup the stack */
 711         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 712         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 713         shl $16, %eax
 714         addl %esp, %eax                 /* the adjusted stack pointer */
 715         pushl_cfi $__KERNEL_DS
 716         pushl_cfi %eax
 717         lss (%esp), %esp                /* switch to the normal stack segment */
 718         CFI_ADJUST_CFA_OFFSET -8
 719 .endm
 720 .macro UNWIND_ESPFIX_STACK
 721         movl %ss, %eax
 722         /* see if on espfix stack */
 723         cmpw $__ESPFIX_SS, %ax
 724         jne 27f
 725         movl $__KERNEL_DS, %eax
 726         movl %eax, %ds
 727         movl %eax, %es
 728         /* switch to normal stack */
 729         FIXUP_ESPFIX_STACK
 730 27:
 731 .endm
 732
 733 /*
 734  * Build the entry stubs and pointer table with some assembler magic.
 735  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 736  * single cache line on all modern x86 implementations.
 737  */
 738 .section .init.rodata,"a"
 739 ENTRY(interrupt)
 740 .section .entry.text, "ax"
 741         .p2align 5
 742         .p2align CONFIG_X86_L1_CACHE_SHIFT
 743 ENTRY(irq_entries_start)
 744         RING0_INT_FRAME
 745 vector=FIRST_EXTERNAL_VECTOR
 746 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 747         .balign 32
 748   .rept 7
 749     .if vector < NR_VECTORS
 750       .if vector <> FIRST_EXTERNAL_VECTOR
 751         CFI_ADJUST_CFA_OFFSET -4
 752       .endif
 753 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 754       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 755         jmp 2f
 756       .endif
 757       .previous
 758         .long 1b
 759       .section .entry.text, "ax"
 760 vector=vector+1
 761     .endif
 762   .endr
 763 2:      jmp common_interrupt
 764 .endr
 765 END(irq_entries_start)
 766
 767 .previous
 768 END(interrupt)
 769 .previous
 770
 771 /*
 772  * the CPU automatically disables interrupts when executing an IRQ vector,
 773  * so IRQ-flags tracing has to follow that:
 774  */
 775         .p2align CONFIG_X86_L1_CACHE_SHIFT
 776 common_interrupt:
 777         ASM_CLAC
 778         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 779         SAVE_ALL
 780         TRACE_IRQS_OFF
 781         movl %esp,%eax
 782         call do_IRQ
 783         jmp ret_from_intr
 784 ENDPROC(common_interrupt)
 785         CFI_ENDPROC
 786
 787 /*
 788  *  Irq entries should be protected against kprobes
 789  */
 790         .pushsection .kprobes.text, "ax"
 791 #define BUILD_INTERRUPT3(name, nr, fn)  \
 792 ENTRY(name)                             \
 793         RING0_INT_FRAME;                \
 794         ASM_CLAC;                       \
 795         pushl_cfi $~(nr);               \
 796         SAVE_ALL;                       \
 797         TRACE_IRQS_OFF                  \
 798         movl %esp,%eax;                 \
 799         call fn;                        \
 800         jmp ret_from_intr;              \
 801         CFI_ENDPROC;                    \
 802 ENDPROC(name)
 803
 804
 805 #ifdef CONFIG_TRACING
 806 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 807         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 808 #else
 809 #define TRACE_BUILD_INTERRUPT(name, nr)
 810 #endif
 811
 812 #define BUILD_INTERRUPT(name, nr) \
 813         BUILD_INTERRUPT3(name, nr, smp_##name); \
 814         TRACE_BUILD_INTERRUPT(name, nr)
 815
 816 /* The include is where all of the SMP etc. interrupts come from */
 817 #include <asm/entry_arch.h>
 818
 819 ENTRY(coprocessor_error)
 820         RING0_INT_FRAME
 821         ASM_CLAC
 822         pushl_cfi $0
 823         pushl_cfi $do_coprocessor_error
 824         jmp error_code
 825         CFI_ENDPROC
 826 END(coprocessor_error)
 827
 828 ENTRY(simd_coprocessor_error)
 829         RING0_INT_FRAME
 830         ASM_CLAC
 831         pushl_cfi $0
 832 #ifdef CONFIG_X86_INVD_BUG
 833         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 834 661:    pushl_cfi $do_general_protection
 835 662:
 836 .section .altinstructions,"a"
 837         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 838 .previous
 839 .section .altinstr_replacement,"ax"
 840 663:    pushl $do_simd_coprocessor_error
 841 664:
 842 .previous
 843 #else
 844         pushl_cfi $do_simd_coprocessor_error
 845 #endif
 846         jmp error_code
 847         CFI_ENDPROC
 848 END(simd_coprocessor_error)
 849
 850 ENTRY(device_not_available)
 851         RING0_INT_FRAME
 852         ASM_CLAC
 853         pushl_cfi $-1                   # mark this as an int
 854         pushl_cfi $do_device_not_available
 855         jmp error_code
 856         CFI_ENDPROC
 857 END(device_not_available)
 858
 859 #ifdef CONFIG_PARAVIRT
 860 ENTRY(native_iret)
 861         iret
 862         _ASM_EXTABLE(native_iret, iret_exc)
 863 END(native_iret)
 864
 865 ENTRY(native_irq_enable_sysexit)
 866         sti
 867         sysexit
 868 END(native_irq_enable_sysexit)
 869 #endif
 870
 871 ENTRY(overflow)
 872         RING0_INT_FRAME
 873         ASM_CLAC
 874         pushl_cfi $0
 875         pushl_cfi $do_overflow
 876         jmp error_code
 877         CFI_ENDPROC
 878 END(overflow)
 879
 880 ENTRY(bounds)
 881         RING0_INT_FRAME
 882         ASM_CLAC
 883         pushl_cfi $0
 884         pushl_cfi $do_bounds
 885         jmp error_code
 886         CFI_ENDPROC
 887 END(bounds)
 888
 889 ENTRY(invalid_op)
 890         RING0_INT_FRAME
 891         ASM_CLAC
 892         pushl_cfi $0
 893         pushl_cfi $do_invalid_op
 894         jmp error_code
 895         CFI_ENDPROC
 896 END(invalid_op)
 897
 898 ENTRY(coprocessor_segment_overrun)
 899         RING0_INT_FRAME
 900         ASM_CLAC
 901         pushl_cfi $0
 902         pushl_cfi $do_coprocessor_segment_overrun
 903         jmp error_code
 904         CFI_ENDPROC
 905 END(coprocessor_segment_overrun)
 906
 907 ENTRY(invalid_TSS)
 908         RING0_EC_FRAME
 909         ASM_CLAC
 910         pushl_cfi $do_invalid_TSS
 911         jmp error_code
 912         CFI_ENDPROC
 913 END(invalid_TSS)
 914
 915 ENTRY(segment_not_present)
 916         RING0_EC_FRAME
 917         ASM_CLAC
 918         pushl_cfi $do_segment_not_present
 919         jmp error_code
 920         CFI_ENDPROC
 921 END(segment_not_present)
 922
 923 ENTRY(stack_segment)
 924         RING0_EC_FRAME
 925         ASM_CLAC
 926         pushl_cfi $do_stack_segment
 927         jmp error_code
 928         CFI_ENDPROC
 929 END(stack_segment)
 930
 931 ENTRY(alignment_check)
 932         RING0_EC_FRAME
 933         ASM_CLAC
 934         pushl_cfi $do_alignment_check
 935         jmp error_code
 936         CFI_ENDPROC
 937 END(alignment_check)
 938
 939 ENTRY(divide_error)
 940         RING0_INT_FRAME
 941         ASM_CLAC
 942         pushl_cfi $0                    # no error code
 943         pushl_cfi $do_divide_error
 944         jmp error_code
 945         CFI_ENDPROC
 946 END(divide_error)
 947
 948 #ifdef CONFIG_X86_MCE
 949 ENTRY(machine_check)
 950         RING0_INT_FRAME
 951         ASM_CLAC
 952         pushl_cfi $0
 953         pushl_cfi machine_check_vector
 954         jmp error_code
 955         CFI_ENDPROC
 956 END(machine_check)
 957 #endif
 958
 959 ENTRY(spurious_interrupt_bug)
 960         RING0_INT_FRAME
 961         ASM_CLAC
 962         pushl_cfi $0
 963         pushl_cfi $do_spurious_interrupt_bug
 964         jmp error_code
 965         CFI_ENDPROC
 966 END(spurious_interrupt_bug)
 967 /*
 968  * End of kprobes section
 969  */
 970         .popsection
 971
 972 #ifdef CONFIG_XEN
 973 /* Xen doesn't set %esp to be precisely what the normal sysenter
 974    entrypoint expects, so fix it up before using the normal path. */
 975 ENTRY(xen_sysenter_target)
 976         RING0_INT_FRAME
 977         addl $5*4, %esp         /* remove xen-provided frame */
 978         CFI_ADJUST_CFA_OFFSET -5*4
 979         jmp sysenter_past_esp
 980         CFI_ENDPROC
 981
 982 ENTRY(xen_hypervisor_callback)
 983         CFI_STARTPROC
 984         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 985         SAVE_ALL
 986         TRACE_IRQS_OFF
 987
 988         /* Check to see if we got the event in the critical
 989            region in xen_iret_direct, after we've reenabled
 990            events and checked for pending events.  This simulates
 991            iret instruction's behaviour where it delivers a
 992            pending interrupt when enabling interrupts. */
 993         movl PT_EIP(%esp),%eax
 994         cmpl $xen_iret_start_crit,%eax
 995         jb   1f
 996         cmpl $xen_iret_end_crit,%eax
 997         jae  1f
 998
 999         jmp  xen_iret_crit_fixup
1000
1001 ENTRY(xen_do_upcall)
1002 1:      mov %esp, %eax
1003         call xen_evtchn_do_upcall
1004         jmp  ret_from_intr
1005         CFI_ENDPROC
1006 ENDPROC(xen_hypervisor_callback)
1007
1008 # Hypervisor uses this for application faults while it executes.
1009 # We get here for two reasons:
1010 #  1. Fault while reloading DS, ES, FS or GS
1011 #  2. Fault while executing IRET
1012 # Category 1 we fix up by reattempting the load, and zeroing the segment
1013 # register if the load fails.
1014 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1015 # normal Linux return path in this case because if we use the IRET hypercall
1016 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1017 # We distinguish between categories by maintaining a status value in EAX.
1018 ENTRY(xen_failsafe_callback)
1019         CFI_STARTPROC
1020         pushl_cfi %eax
1021         movl $1,%eax
1022 1:      mov 4(%esp),%ds
1023 2:      mov 8(%esp),%es
1024 3:      mov 12(%esp),%fs
1025 4:      mov 16(%esp),%gs
1026         /* EAX == 0 => Category 1 (Bad segment)
1027            EAX != 0 => Category 2 (Bad IRET) */
1028         testl %eax,%eax
1029         popl_cfi %eax
1030         lea 16(%esp),%esp
1031         CFI_ADJUST_CFA_OFFSET -16
1032         jz 5f
1033         jmp iret_exc
1034 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1035         SAVE_ALL
1036         jmp ret_from_exception
1037         CFI_ENDPROC
1038
1039 .section .fixup,"ax"
1040 6:      xorl %eax,%eax
1041         movl %eax,4(%esp)
1042         jmp 1b
1043 7:      xorl %eax,%eax
1044         movl %eax,8(%esp)
1045         jmp 2b
1046 8:      xorl %eax,%eax
1047         movl %eax,12(%esp)
1048         jmp 3b
1049 9:      xorl %eax,%eax
1050         movl %eax,16(%esp)
1051         jmp 4b
1052 .previous
1053         _ASM_EXTABLE(1b,6b)
1054         _ASM_EXTABLE(2b,7b)
1055         _ASM_EXTABLE(3b,8b)
1056         _ASM_EXTABLE(4b,9b)
1057 ENDPROC(xen_failsafe_callback)
1058
1059 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1060                 xen_evtchn_do_upcall)
1061
1062 #endif  /* CONFIG_XEN */
1063
1064 #if IS_ENABLED(CONFIG_HYPERV)
1065
1066 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1067         hyperv_vector_handler)
1068
1069 #endif /* CONFIG_HYPERV */
1070
1071 #ifdef CONFIG_FUNCTION_TRACER
1072 #ifdef CONFIG_DYNAMIC_FTRACE
1073
1074 ENTRY(mcount)
1075         ret
1076 END(mcount)
1077
1078 ENTRY(ftrace_caller)
1079         cmpl $0, function_trace_stop
1080         jne  ftrace_stub
1081
1082         pushl %eax
1083         pushl %ecx
1084         pushl %edx
1085         pushl $0        /* Pass NULL as regs pointer */
1086         movl 4*4(%esp), %eax
1087         movl 0x4(%ebp), %edx
1088         leal function_trace_op, %ecx
1089         subl $MCOUNT_INSN_SIZE, %eax
1090
1091 .globl ftrace_call
1092 ftrace_call:
1093         call ftrace_stub
1094
1095         addl $4,%esp    /* skip NULL pointer */
1096         popl %edx
1097         popl %ecx
1098         popl %eax
1099 ftrace_ret:
1100 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1101 .globl ftrace_graph_call
1102 ftrace_graph_call:
1103         jmp ftrace_stub
1104 #endif
1105
1106 .globl ftrace_stub
1107 ftrace_stub:
1108         ret
1109 END(ftrace_caller)
1110
1111 ENTRY(ftrace_regs_caller)
1112         pushf   /* push flags before compare (in cs location) */
1113         cmpl $0, function_trace_stop
1114         jne ftrace_restore_flags
1115
1116         /*
1117          * i386 does not save SS and ESP when coming from kernel.
1118          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1119          * Unfortunately, that means eflags must be at the same location
1120          * as the current return ip is. We move the return ip into the
1121          * ip location, and move flags into the return ip location.
1122          */
1123         pushl 4(%esp)   /* save return ip into ip slot */
1124
1125         pushl $0        /* Load 0 into orig_ax */
1126         pushl %gs
1127         pushl %fs
1128         pushl %es
1129         pushl %ds
1130         pushl %eax
1131         pushl %ebp
1132         pushl %edi
1133         pushl %esi
1134         pushl %edx
1135         pushl %ecx
1136         pushl %ebx
1137
1138         movl 13*4(%esp), %eax   /* Get the saved flags */
1139         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1140                                 /* clobbering return ip */
1141         movl $__KERNEL_CS,13*4(%esp)
1142
1143         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1144         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1145         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1146         leal function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1147         pushl %esp              /* Save pt_regs as 4th parameter */
1148
1149 GLOBAL(ftrace_regs_call)
1150         call ftrace_stub
1151
1152         addl $4, %esp           /* Skip pt_regs */
1153         movl 14*4(%esp), %eax   /* Move flags back into cs */
1154         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1155         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1156         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1157
1158         popl %ebx
1159         popl %ecx
1160         popl %edx
1161         popl %esi
1162         popl %edi
1163         popl %ebp
1164         popl %eax
1165         popl %ds
1166         popl %es
1167         popl %fs
1168         popl %gs
1169         addl $8, %esp           /* Skip orig_ax and ip */
1170         popf                    /* Pop flags at end (no addl to corrupt flags) */
1171         jmp ftrace_ret
1172
1173 ftrace_restore_flags:
1174         popf
1175         jmp  ftrace_stub
1176 #else /* ! CONFIG_DYNAMIC_FTRACE */
1177
1178 ENTRY(mcount)
1179         cmpl $__PAGE_OFFSET, %esp
1180         jb ftrace_stub          /* Paging not enabled yet? */
1181
1182         cmpl $0, function_trace_stop
1183         jne  ftrace_stub
1184
1185         cmpl $ftrace_stub, ftrace_trace_function
1186         jnz trace
1187 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1188         cmpl $ftrace_stub, ftrace_graph_return
1189         jnz ftrace_graph_caller
1190
1191         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1192         jnz ftrace_graph_caller
1193 #endif
1194 .globl ftrace_stub
1195 ftrace_stub:
1196         ret
1197
1198         /* taken from glibc */
1199 trace:
1200         pushl %eax
1201         pushl %ecx
1202         pushl %edx
1203         movl 0xc(%esp), %eax
1204         movl 0x4(%ebp), %edx
1205         subl $MCOUNT_INSN_SIZE, %eax
1206
1207         call *ftrace_trace_function
1208
1209         popl %edx
1210         popl %ecx
1211         popl %eax
1212         jmp ftrace_stub
1213 END(mcount)
1214 #endif /* CONFIG_DYNAMIC_FTRACE */
1215 #endif /* CONFIG_FUNCTION_TRACER */
1216
1217 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1218 ENTRY(ftrace_graph_caller)
1219         pushl %eax
1220         pushl %ecx
1221         pushl %edx
1222         movl 0xc(%esp), %edx
1223         lea 0x4(%ebp), %eax
1224         movl (%ebp), %ecx
1225         subl $MCOUNT_INSN_SIZE, %edx
1226         call prepare_ftrace_return
1227         popl %edx
1228         popl %ecx
1229         popl %eax
1230         ret
1231 END(ftrace_graph_caller)
1232
1233 .globl return_to_handler
1234 return_to_handler:
1235         pushl %eax
1236         pushl %edx
1237         movl %ebp, %eax
1238         call ftrace_return_to_handler
1239         movl %eax, %ecx
1240         popl %edx
1241         popl %eax
1242         jmp *%ecx
1243 #endif
1244
1245 /*
1246  * Some functions should be protected against kprobes
1247  */
1248         .pushsection .kprobes.text, "ax"
1249
1250 ENTRY(page_fault)
1251         RING0_EC_FRAME
1252         ASM_CLAC
1253         pushl_cfi $do_page_fault
1254         ALIGN
1255 error_code:
1256         /* the function address is in %gs's slot on the stack */
1257         pushl_cfi %fs
1258         /*CFI_REL_OFFSET fs, 0*/
1259         pushl_cfi %es
1260         /*CFI_REL_OFFSET es, 0*/
1261         pushl_cfi %ds
1262         /*CFI_REL_OFFSET ds, 0*/
1263         pushl_cfi %eax
1264         CFI_REL_OFFSET eax, 0
1265         pushl_cfi %ebp
1266         CFI_REL_OFFSET ebp, 0
1267         pushl_cfi %edi
1268         CFI_REL_OFFSET edi, 0
1269         pushl_cfi %esi
1270         CFI_REL_OFFSET esi, 0
1271         pushl_cfi %edx
1272         CFI_REL_OFFSET edx, 0
1273         pushl_cfi %ecx
1274         CFI_REL_OFFSET ecx, 0
1275         pushl_cfi %ebx
1276         CFI_REL_OFFSET ebx, 0
1277         cld
1278         movl $(__KERNEL_PERCPU), %ecx
1279         movl %ecx, %fs
1280         UNWIND_ESPFIX_STACK
1281         GS_TO_REG %ecx
1282         movl PT_GS(%esp), %edi          # get the function address
1283         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1284         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1285         REG_TO_PTGS %ecx
1286         SET_KERNEL_GS %ecx
1287         movl $(__USER_DS), %ecx
1288         movl %ecx, %ds
1289         movl %ecx, %es
1290         TRACE_IRQS_OFF
1291         movl %esp,%eax                  # pt_regs pointer
1292         call *%edi
1293         jmp ret_from_exception
1294         CFI_ENDPROC
1295 END(page_fault)
1296
1297 /*
1298  * Debug traps and NMI can happen at the one SYSENTER instruction
1299  * that sets up the real kernel stack. Check here, since we can't
1300  * allow the wrong stack to be used.
1301  *
1302  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1303  * already pushed 3 words if it hits on the sysenter instruction:
1304  * eflags, cs and eip.
1305  *
1306  * We just load the right stack, and push the three (known) values
1307  * by hand onto the new stack - while updating the return eip past
1308  * the instruction that would have done it for sysenter.
1309  */
1310 .macro FIX_STACK offset ok label
1311         cmpw $__KERNEL_CS, 4(%esp)
1312         jne \ok
1313 \label:
1314         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1315         CFI_DEF_CFA esp, 0
1316         CFI_UNDEFINED eip
1317         pushfl_cfi
1318         pushl_cfi $__KERNEL_CS
1319         pushl_cfi $sysenter_past_esp
1320         CFI_REL_OFFSET eip, 0
1321 .endm
1322
1323 ENTRY(debug)
1324         RING0_INT_FRAME
1325         ASM_CLAC
1326         cmpl $ia32_sysenter_target,(%esp)
1327         jne debug_stack_correct
1328         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1329 debug_stack_correct:
1330         pushl_cfi $-1                   # mark this as an int
1331         SAVE_ALL
1332         TRACE_IRQS_OFF
1333         xorl %edx,%edx                  # error code 0
1334         movl %esp,%eax                  # pt_regs pointer
1335         call do_debug
1336         jmp ret_from_exception
1337         CFI_ENDPROC
1338 END(debug)
1339
1340 /*
1341  * NMI is doubly nasty. It can happen _while_ we're handling
1342  * a debug fault, and the debug fault hasn't yet been able to
1343  * clear up the stack. So we first check whether we got  an
1344  * NMI on the sysenter entry path, but after that we need to
1345  * check whether we got an NMI on the debug path where the debug
1346  * fault happened on the sysenter path.
1347  */
1348 ENTRY(nmi)
1349         RING0_INT_FRAME
1350         ASM_CLAC
1351         pushl_cfi %eax
1352         movl %ss, %eax
1353         cmpw $__ESPFIX_SS, %ax
1354         popl_cfi %eax
1355         je nmi_espfix_stack
1356         cmpl $ia32_sysenter_target,(%esp)
1357         je nmi_stack_fixup
1358         pushl_cfi %eax
1359         movl %esp,%eax
1360         /* Do not access memory above the end of our stack page,
1361          * it might not exist.
1362          */
1363         andl $(THREAD_SIZE-1),%eax
1364         cmpl $(THREAD_SIZE-20),%eax
1365         popl_cfi %eax
1366         jae nmi_stack_correct
1367         cmpl $ia32_sysenter_target,12(%esp)
1368         je nmi_debug_stack_check
1369 nmi_stack_correct:
1370         /* We have a RING0_INT_FRAME here */
1371         pushl_cfi %eax
1372         SAVE_ALL
1373         xorl %edx,%edx          # zero error code
1374         movl %esp,%eax          # pt_regs pointer
1375         call do_nmi
1376         jmp restore_all_notrace
1377         CFI_ENDPROC
1378
1379 nmi_stack_fixup:
1380         RING0_INT_FRAME
1381         FIX_STACK 12, nmi_stack_correct, 1
1382         jmp nmi_stack_correct
1383
1384 nmi_debug_stack_check:
1385         /* We have a RING0_INT_FRAME here */
1386         cmpw $__KERNEL_CS,16(%esp)
1387         jne nmi_stack_correct
1388         cmpl $debug,(%esp)
1389         jb nmi_stack_correct
1390         cmpl $debug_esp_fix_insn,(%esp)
1391         ja nmi_stack_correct
1392         FIX_STACK 24, nmi_stack_correct, 1
1393         jmp nmi_stack_correct
1394
1395 nmi_espfix_stack:
1396         /* We have a RING0_INT_FRAME here.
1397          *
1398          * create the pointer to lss back
1399          */
1400         pushl_cfi %ss
1401         pushl_cfi %esp
1402         addl $4, (%esp)
1403         /* copy the iret frame of 12 bytes */
1404         .rept 3
1405         pushl_cfi 16(%esp)
1406         .endr
1407         pushl_cfi %eax
1408         SAVE_ALL
1409         FIXUP_ESPFIX_STACK              # %eax == %esp
1410         xorl %edx,%edx                  # zero error code
1411         call do_nmi
1412         RESTORE_REGS
1413         lss 12+4(%esp), %esp            # back to espfix stack
1414         CFI_ADJUST_CFA_OFFSET -24
1415         jmp irq_return
1416         CFI_ENDPROC
1417 END(nmi)
1418
1419 ENTRY(int3)
1420         RING0_INT_FRAME
1421         ASM_CLAC
1422         pushl_cfi $-1                   # mark this as an int
1423         SAVE_ALL
1424         TRACE_IRQS_OFF
1425         xorl %edx,%edx          # zero error code
1426         movl %esp,%eax          # pt_regs pointer
1427         call do_int3
1428         jmp ret_from_exception
1429         CFI_ENDPROC
1430 END(int3)
1431
1432 ENTRY(general_protection)
1433         RING0_EC_FRAME
1434         pushl_cfi $do_general_protection
1435         jmp error_code
1436         CFI_ENDPROC
1437 END(general_protection)
1438
1439 #ifdef CONFIG_KVM_GUEST
1440 ENTRY(async_page_fault)
1441         RING0_EC_FRAME
1442         ASM_CLAC
1443         pushl_cfi $do_async_page_fault
1444         jmp error_code
1445         CFI_ENDPROC
1446 END(async_page_fault)
1447 #endif
1448
1449 /*
1450  * End of kprobes section
1451  */
1452         .popsection