arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <asm/context_tracking.h>
  60 #include <asm/smap.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72 #ifdef CONFIG_FUNCTION_TRACER
  73
  74 #ifdef CC_USING_FENTRY
  75 # define function_hook  __fentry__
  76 #else
  77 # define function_hook  mcount
  78 #endif
  79
  80 #ifdef CONFIG_DYNAMIC_FTRACE
  81
  82 ENTRY(function_hook)
  83         retq
  84 END(function_hook)
  85
  86 /* skip is set if stack has been adjusted */
  87 .macro ftrace_caller_setup skip=0
  88         MCOUNT_SAVE_FRAME \skip
  89
  90         /* Load the ftrace_ops into the 3rd parameter */
  91         leaq function_trace_op, %rdx
  92
  93         /* Load ip into the first parameter */
  94         movq RIP(%rsp), %rdi
  95         subq $MCOUNT_INSN_SIZE, %rdi
  96         /* Load the parent_ip into the second parameter */
  97 #ifdef CC_USING_FENTRY
  98         movq SS+16(%rsp), %rsi
  99 #else
 100         movq 8(%rbp), %rsi
 101 #endif
 102 .endm
 103
 104 ENTRY(ftrace_caller)
 105         /* Check if tracing was disabled (quick check) */
 106         cmpl $0, function_trace_stop
 107         jne  ftrace_stub
 108
 109         ftrace_caller_setup
 110         /* regs go into 4th parameter (but make it NULL) */
 111         movq $0, %rcx
 112
 113 GLOBAL(ftrace_call)
 114         call ftrace_stub
 115
 116         MCOUNT_RESTORE_FRAME
 117 ftrace_return:
 118
 119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 120 GLOBAL(ftrace_graph_call)
 121         jmp ftrace_stub
 122 #endif
 123
 124 GLOBAL(ftrace_stub)
 125         retq
 126 END(ftrace_caller)
 127
 128 ENTRY(ftrace_regs_caller)
 129         /* Save the current flags before compare (in SS location)*/
 130         pushfq
 131
 132         /* Check if tracing was disabled (quick check) */
 133         cmpl $0, function_trace_stop
 134         jne  ftrace_restore_flags
 135
 136         /* skip=8 to skip flags saved in SS */
 137         ftrace_caller_setup 8
 138
 139         /* Save the rest of pt_regs */
 140         movq %r15, R15(%rsp)
 141         movq %r14, R14(%rsp)
 142         movq %r13, R13(%rsp)
 143         movq %r12, R12(%rsp)
 144         movq %r11, R11(%rsp)
 145         movq %r10, R10(%rsp)
 146         movq %rbp, RBP(%rsp)
 147         movq %rbx, RBX(%rsp)
 148         /* Copy saved flags */
 149         movq SS(%rsp), %rcx
 150         movq %rcx, EFLAGS(%rsp)
 151         /* Kernel segments */
 152         movq $__KERNEL_DS, %rcx
 153         movq %rcx, SS(%rsp)
 154         movq $__KERNEL_CS, %rcx
 155         movq %rcx, CS(%rsp)
 156         /* Stack - skipping return address */
 157         leaq SS+16(%rsp), %rcx
 158         movq %rcx, RSP(%rsp)
 159
 160         /* regs go into 4th parameter */
 161         leaq (%rsp), %rcx
 162
 163 GLOBAL(ftrace_regs_call)
 164         call ftrace_stub
 165
 166         /* Copy flags back to SS, to restore them */
 167         movq EFLAGS(%rsp), %rax
 168         movq %rax, SS(%rsp)
 169
 170         /* Handlers can change the RIP */
 171         movq RIP(%rsp), %rax
 172         movq %rax, SS+8(%rsp)
 173
 174         /* restore the rest of pt_regs */
 175         movq R15(%rsp), %r15
 176         movq R14(%rsp), %r14
 177         movq R13(%rsp), %r13
 178         movq R12(%rsp), %r12
 179         movq R10(%rsp), %r10
 180         movq RBP(%rsp), %rbp
 181         movq RBX(%rsp), %rbx
 182
 183         /* skip=8 to skip flags saved in SS */
 184         MCOUNT_RESTORE_FRAME 8
 185
 186         /* Restore flags */
 187         popfq
 188
 189         jmp ftrace_return
 190 ftrace_restore_flags:
 191         popfq
 192         jmp  ftrace_stub
 193
 194 END(ftrace_regs_caller)
 195
 196
 197 #else /* ! CONFIG_DYNAMIC_FTRACE */
 198
 199 ENTRY(function_hook)
 200         cmpl $0, function_trace_stop
 201         jne  ftrace_stub
 202
 203         cmpq $ftrace_stub, ftrace_trace_function
 204         jnz trace
 205
 206 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 207         cmpq $ftrace_stub, ftrace_graph_return
 208         jnz ftrace_graph_caller
 209
 210         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 211         jnz ftrace_graph_caller
 212 #endif
 213
 214 GLOBAL(ftrace_stub)
 215         retq
 216
 217 trace:
 218         MCOUNT_SAVE_FRAME
 219
 220         movq RIP(%rsp), %rdi
 221 #ifdef CC_USING_FENTRY
 222         movq SS+16(%rsp), %rsi
 223 #else
 224         movq 8(%rbp), %rsi
 225 #endif
 226         subq $MCOUNT_INSN_SIZE, %rdi
 227
 228         call   *ftrace_trace_function
 229
 230         MCOUNT_RESTORE_FRAME
 231
 232         jmp ftrace_stub
 233 END(function_hook)
 234 #endif /* CONFIG_DYNAMIC_FTRACE */
 235 #endif /* CONFIG_FUNCTION_TRACER */
 236
 237 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 238 ENTRY(ftrace_graph_caller)
 239         MCOUNT_SAVE_FRAME
 240
 241 #ifdef CC_USING_FENTRY
 242         leaq SS+16(%rsp), %rdi
 243         movq $0, %rdx   /* No framepointers needed */
 244 #else
 245         leaq 8(%rbp), %rdi
 246         movq (%rbp), %rdx
 247 #endif
 248         movq RIP(%rsp), %rsi
 249         subq $MCOUNT_INSN_SIZE, %rsi
 250
 251         call    prepare_ftrace_return
 252
 253         MCOUNT_RESTORE_FRAME
 254
 255         retq
 256 END(ftrace_graph_caller)
 257
 258 GLOBAL(return_to_handler)
 259         subq  $24, %rsp
 260
 261         /* Save the return values */
 262         movq %rax, (%rsp)
 263         movq %rdx, 8(%rsp)
 264         movq %rbp, %rdi
 265
 266         call ftrace_return_to_handler
 267
 268         movq %rax, %rdi
 269         movq 8(%rsp), %rdx
 270         movq (%rsp), %rax
 271         addq $24, %rsp
 272         jmp *%rdi
 273 #endif
 274
 275
 276 #ifndef CONFIG_PREEMPT
 277 #define retint_kernel retint_restore_args
 278 #endif
 279
 280 #ifdef CONFIG_PARAVIRT
 281 ENTRY(native_usergs_sysret64)
 282         swapgs
 283         sysretq
 284 ENDPROC(native_usergs_sysret64)
 285 #endif /* CONFIG_PARAVIRT */
 286
 287
 288 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 289 #ifdef CONFIG_TRACE_IRQFLAGS
 290         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 291         jnc  1f
 292         TRACE_IRQS_ON
 293 1:
 294 #endif
 295 .endm
 296
 297 /*
 298  * When dynamic function tracer is enabled it will add a breakpoint
 299  * to all locations that it is about to modify, sync CPUs, update
 300  * all the code, sync CPUs, then remove the breakpoints. In this time
 301  * if lockdep is enabled, it might jump back into the debug handler
 302  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 303  *
 304  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 305  * make sure the stack pointer does not get reset back to the top
 306  * of the debug stack, and instead just reuses the current stack.
 307  */
 308 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 309
 310 .macro TRACE_IRQS_OFF_DEBUG
 311         call debug_stack_set_zero
 312         TRACE_IRQS_OFF
 313         call debug_stack_reset
 314 .endm
 315
 316 .macro TRACE_IRQS_ON_DEBUG
 317         call debug_stack_set_zero
 318         TRACE_IRQS_ON
 319         call debug_stack_reset
 320 .endm
 321
 322 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 323         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 324         jnc  1f
 325         TRACE_IRQS_ON_DEBUG
 326 1:
 327 .endm
 328
 329 #else
 330 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 331 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 332 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 333 #endif
 334
 335 /*
 336  * C code is not supposed to know about undefined top of stack. Every time
 337  * a C function with an pt_regs argument is called from the SYSCALL based
 338  * fast path FIXUP_TOP_OF_STACK is needed.
 339  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 340  * manipulation.
 341  */
 342
 343         /* %rsp:at FRAMEEND */
 344         .macro FIXUP_TOP_OF_STACK tmp offset=0
 345         movq PER_CPU_VAR(old_rsp),\tmp
 346         movq \tmp,RSP+\offset(%rsp)
 347         movq $__USER_DS,SS+\offset(%rsp)
 348         movq $__USER_CS,CS+\offset(%rsp)
 349         movq $-1,RCX+\offset(%rsp)
 350         movq R11+\offset(%rsp),\tmp  /* get eflags */
 351         movq \tmp,EFLAGS+\offset(%rsp)
 352         .endm
 353
 354         .macro RESTORE_TOP_OF_STACK tmp offset=0
 355         movq RSP+\offset(%rsp),\tmp
 356         movq \tmp,PER_CPU_VAR(old_rsp)
 357         movq EFLAGS+\offset(%rsp),\tmp
 358         movq \tmp,R11+\offset(%rsp)
 359         .endm
 360
 361         .macro FAKE_STACK_FRAME child_rip
 362         /* push in order ss, rsp, eflags, cs, rip */
 363         xorl %eax, %eax
 364         pushq_cfi $__KERNEL_DS /* ss */
 365         /*CFI_REL_OFFSET        ss,0*/
 366         pushq_cfi %rax /* rsp */
 367         CFI_REL_OFFSET  rsp,0
 368         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 369         /*CFI_REL_OFFSET        rflags,0*/
 370         pushq_cfi $__KERNEL_CS /* cs */
 371         /*CFI_REL_OFFSET        cs,0*/
 372         pushq_cfi \child_rip /* rip */
 373         CFI_REL_OFFSET  rip,0
 374         pushq_cfi %rax /* orig rax */
 375         .endm
 376
 377         .macro UNFAKE_STACK_FRAME
 378         addq $8*6, %rsp
 379         CFI_ADJUST_CFA_OFFSET   -(6*8)
 380         .endm
 381
 382 /*
 383  * initial frame state for interrupts (and exceptions without error code)
 384  */
 385         .macro EMPTY_FRAME start=1 offset=0
 386         .if \start
 387         CFI_STARTPROC simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA rsp,8+\offset
 390         .else
 391         CFI_DEF_CFA_OFFSET 8+\offset
 392         .endif
 393         .endm
 394
 395 /*
 396  * initial frame state for interrupts (and exceptions without error code)
 397  */
 398         .macro INTR_FRAME start=1 offset=0
 399         EMPTY_FRAME \start, SS+8+\offset-RIP
 400         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 401         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 402         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 403         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 404         CFI_REL_OFFSET rip, RIP+\offset-RIP
 405         .endm
 406
 407 /*
 408  * initial frame state for exceptions with error code (and interrupts
 409  * with vector already pushed)
 410  */
 411         .macro XCPT_FRAME start=1 offset=0
 412         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 413         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 414         .endm
 415
 416 /*
 417  * frame that enables calling into C.
 418  */
 419         .macro PARTIAL_FRAME start=1 offset=0
 420         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 421         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 422         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 423         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 424         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 425         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 426         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 427         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 428         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 429         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 430         .endm
 431
 432 /*
 433  * frame that enables passing a complete pt_regs to a C function.
 434  */
 435         .macro DEFAULT_FRAME start=1 offset=0
 436         PARTIAL_FRAME \start, R11+\offset-R15
 437         CFI_REL_OFFSET rbx, RBX+\offset
 438         CFI_REL_OFFSET rbp, RBP+\offset
 439         CFI_REL_OFFSET r12, R12+\offset
 440         CFI_REL_OFFSET r13, R13+\offset
 441         CFI_REL_OFFSET r14, R14+\offset
 442         CFI_REL_OFFSET r15, R15+\offset
 443         .endm
 444
 445 /* save partial stack frame */
 446         .macro SAVE_ARGS_IRQ
 447         cld
 448         /* start from rbp in pt_regs and jump over */
 449         movq_cfi rdi, (RDI-RBP)
 450         movq_cfi rsi, (RSI-RBP)
 451         movq_cfi rdx, (RDX-RBP)
 452         movq_cfi rcx, (RCX-RBP)
 453         movq_cfi rax, (RAX-RBP)
 454         movq_cfi  r8,  (R8-RBP)
 455         movq_cfi  r9,  (R9-RBP)
 456         movq_cfi r10, (R10-RBP)
 457         movq_cfi r11, (R11-RBP)
 458
 459         /* Save rbp so that we can unwind from get_irq_regs() */
 460         movq_cfi rbp, 0
 461
 462         /* Save previous stack value */
 463         movq %rsp, %rsi
 464
 465         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 466         testl $3, CS-RBP(%rsi)
 467         je 1f
 468         SWAPGS
 469         /*
 470          * irq_count is used to check if a CPU is already on an interrupt stack
 471          * or not. While this is essentially redundant with preempt_count it is
 472          * a little cheaper to use a separate counter in the PDA (short of
 473          * moving irq_enter into assembly, which would be too much work)
 474          */
 475 1:      incl PER_CPU_VAR(irq_count)
 476         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 477         CFI_DEF_CFA_REGISTER    rsi
 478
 479         /* Store previous stack value */
 480         pushq %rsi
 481         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 482                         0x77 /* DW_OP_breg7 */, 0, \
 483                         0x06 /* DW_OP_deref */, \
 484                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 485                         0x22 /* DW_OP_plus */
 486         /* We entered an interrupt context - irqs are off: */
 487         TRACE_IRQS_OFF
 488         .endm
 489
 490 /* save complete stack frame */
 491         .pushsection .kprobes.text, "ax"
 492 ENTRY(save_paranoid)
 493         XCPT_FRAME 1 RDI+8
 494         cld
 495         movq_cfi rdi, RDI+8
 496         movq_cfi rsi, RSI+8
 497         movq_cfi rdx, RDX+8
 498         movq_cfi rcx, RCX+8
 499         movq_cfi rax, RAX+8
 500         movq_cfi r8, R8+8
 501         movq_cfi r9, R9+8
 502         movq_cfi r10, R10+8
 503         movq_cfi r11, R11+8
 504         movq_cfi rbx, RBX+8
 505         movq_cfi rbp, RBP+8
 506         movq_cfi r12, R12+8
 507         movq_cfi r13, R13+8
 508         movq_cfi r14, R14+8
 509         movq_cfi r15, R15+8
 510         movl $1,%ebx
 511         movl $MSR_GS_BASE,%ecx
 512         rdmsr
 513         testl %edx,%edx
 514         js 1f   /* negative -> in kernel */
 515         SWAPGS
 516         xorl %ebx,%ebx
 517 1:      ret
 518         CFI_ENDPROC
 519 END(save_paranoid)
 520         .popsection
 521
 522 /*
 523  * A newly forked process directly context switches into this address.
 524  *
 525  * rdi: prev task we switched from
 526  */
 527 ENTRY(ret_from_fork)
 528         DEFAULT_FRAME
 529
 530         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 531
 532         pushq_cfi $0x0002
 533         popfq_cfi                               # reset kernel eflags
 534
 535         call schedule_tail                      # rdi: 'prev' task parameter
 536
 537         GET_THREAD_INFO(%rcx)
 538
 539         RESTORE_REST
 540
 541         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 542         jz   1f
 543
 544         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 545         jnz  int_ret_from_sys_call
 546
 547         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 548         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 549
 550 1:
 551         subq $REST_SKIP, %rsp   # leave space for volatiles
 552         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 553         movq %rbp, %rdi
 554         call *%rbx
 555         movl $0, RAX(%rsp)
 556         RESTORE_REST
 557         jmp int_ret_from_sys_call
 558         CFI_ENDPROC
 559 END(ret_from_fork)
 560
 561 /*
 562  * System call entry. Up to 6 arguments in registers are supported.
 563  *
 564  * SYSCALL does not save anything on the stack and does not change the
 565  * stack pointer.  However, it does mask the flags register for us, so
 566  * CLD and CLAC are not needed.
 567  */
 568
 569 /*
 570  * Register setup:
 571  * rax  system call number
 572  * rdi  arg0
 573  * rcx  return address for syscall/sysret, C arg3
 574  * rsi  arg1
 575  * rdx  arg2
 576  * r10  arg3    (--> moved to rcx for C)
 577  * r8   arg4
 578  * r9   arg5
 579  * r11  eflags for syscall/sysret, temporary for C
 580  * r12-r15,rbp,rbx saved by C code, not touched.
 581  *
 582  * Interrupts are off on entry.
 583  * Only called from user space.
 584  *
 585  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 586  *      and report it properly in ps. Unfortunately we haven't.
 587  *
 588  * When user can change the frames always force IRET. That is because
 589  * it deals with uncanonical addresses better. SYSRET has trouble
 590  * with them due to bugs in both AMD and Intel CPUs.
 591  */
 592
 593 ENTRY(system_call)
 594         CFI_STARTPROC   simple
 595         CFI_SIGNAL_FRAME
 596         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 597         CFI_REGISTER    rip,rcx
 598         /*CFI_REGISTER  rflags,r11*/
 599         SWAPGS_UNSAFE_STACK
 600         /*
 601          * A hypervisor implementation might want to use a label
 602          * after the swapgs, so that it can do the swapgs
 603          * for the guest and jump here on syscall.
 604          */
 605 GLOBAL(system_call_after_swapgs)
 606
 607         movq    %rsp,PER_CPU_VAR(old_rsp)
 608         movq    PER_CPU_VAR(kernel_stack),%rsp
 609         /*
 610          * No need to follow this irqs off/on section - it's straight
 611          * and short:
 612          */
 613         ENABLE_INTERRUPTS(CLBR_NONE)
 614         SAVE_ARGS 8,0
 615         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 616         movq  %rcx,RIP-ARGOFFSET(%rsp)
 617         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 618         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 619         jnz tracesys
 620 system_call_fastpath:
 621 #if __SYSCALL_MASK == ~0
 622         cmpq $__NR_syscall_max,%rax
 623 #else
 624         andl $__SYSCALL_MASK,%eax
 625         cmpl $__NR_syscall_max,%eax
 626 #endif
 627         ja badsys
 628         movq %r10,%rcx
 629         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 630         movq %rax,RAX-ARGOFFSET(%rsp)
 631 /*
 632  * Syscall return path ending with SYSRET (fast path)
 633  * Has incomplete stack frame and undefined top of stack.
 634  */
 635 ret_from_sys_call:
 636         movl $_TIF_ALLWORK_MASK,%edi
 637         /* edi: flagmask */
 638 sysret_check:
 639         LOCKDEP_SYS_EXIT
 640         DISABLE_INTERRUPTS(CLBR_NONE)
 641         TRACE_IRQS_OFF
 642         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 643         andl %edi,%edx
 644         jnz  sysret_careful
 645         CFI_REMEMBER_STATE
 646         /*
 647          * sysretq will re-enable interrupts:
 648          */
 649         TRACE_IRQS_ON
 650         movq RIP-ARGOFFSET(%rsp),%rcx
 651         CFI_REGISTER    rip,rcx
 652         RESTORE_ARGS 1,-ARG_SKIP,0
 653         /*CFI_REGISTER  rflags,r11*/
 654         movq    PER_CPU_VAR(old_rsp), %rsp
 655         USERGS_SYSRET64
 656
 657         CFI_RESTORE_STATE
 658         /* Handle reschedules */
 659         /* edx: work, edi: workmask */
 660 sysret_careful:
 661         bt $TIF_NEED_RESCHED,%edx
 662         jnc sysret_signal
 663         TRACE_IRQS_ON
 664         ENABLE_INTERRUPTS(CLBR_NONE)
 665         pushq_cfi %rdi
 666         SCHEDULE_USER
 667         popq_cfi %rdi
 668         jmp sysret_check
 669
 670         /* Handle a signal */
 671 sysret_signal:
 672         TRACE_IRQS_ON
 673         ENABLE_INTERRUPTS(CLBR_NONE)
 674 #ifdef CONFIG_AUDITSYSCALL
 675         bt $TIF_SYSCALL_AUDIT,%edx
 676         jc sysret_audit
 677 #endif
 678         /*
 679          * We have a signal, or exit tracing or single-step.
 680          * These all wind up with the iret return path anyway,
 681          * so just join that path right now.
 682          */
 683         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 684         jmp int_check_syscall_exit_work
 685
 686 badsys:
 687         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 688         jmp ret_from_sys_call
 689
 690 #ifdef CONFIG_AUDITSYSCALL
 691         /*
 692          * Fast path for syscall audit without full syscall trace.
 693          * We just call __audit_syscall_entry() directly, and then
 694          * jump back to the normal fast path.
 695          */
 696 auditsys:
 697         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 698         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 699         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 700         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 701         movq %rax,%rsi                  /* 2nd arg: syscall number */
 702         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 703         call __audit_syscall_entry
 704         LOAD_ARGS 0             /* reload call-clobbered registers */
 705         jmp system_call_fastpath
 706
 707         /*
 708          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 709          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 710          * masked off.
 711          */
 712 sysret_audit:
 713         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 714         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 715         setbe %al               /* 1 if so, 0 if not */
 716         movzbl %al,%edi         /* zero-extend that into %edi */
 717         call __audit_syscall_exit
 718         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 719         jmp sysret_check
 720 #endif  /* CONFIG_AUDITSYSCALL */
 721
 722         /* Do syscall tracing */
 723 tracesys:
 724 #ifdef CONFIG_AUDITSYSCALL
 725         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 726         jz auditsys
 727 #endif
 728         SAVE_REST
 729         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 730         FIXUP_TOP_OF_STACK %rdi
 731         movq %rsp,%rdi
 732         call syscall_trace_enter
 733         /*
 734          * Reload arg registers from stack in case ptrace changed them.
 735          * We don't reload %rax because syscall_trace_enter() returned
 736          * the value it wants us to use in the table lookup.
 737          */
 738         LOAD_ARGS ARGOFFSET, 1
 739         RESTORE_REST
 740 #if __SYSCALL_MASK == ~0
 741         cmpq $__NR_syscall_max,%rax
 742 #else
 743         andl $__SYSCALL_MASK,%eax
 744         cmpl $__NR_syscall_max,%eax
 745 #endif
 746         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 747         movq %r10,%rcx  /* fixup for C */
 748         call *sys_call_table(,%rax,8)
 749         movq %rax,RAX-ARGOFFSET(%rsp)
 750         /* Use IRET because user could have changed frame */
 751
 752 /*
 753  * Syscall return path ending with IRET.
 754  * Has correct top of stack, but partial stack frame.
 755  */
 756 GLOBAL(int_ret_from_sys_call)
 757         DISABLE_INTERRUPTS(CLBR_NONE)
 758         TRACE_IRQS_OFF
 759         movl $_TIF_ALLWORK_MASK,%edi
 760         /* edi: mask to check */
 761 GLOBAL(int_with_check)
 762         LOCKDEP_SYS_EXIT_IRQ
 763         GET_THREAD_INFO(%rcx)
 764         movl TI_flags(%rcx),%edx
 765         andl %edi,%edx
 766         jnz   int_careful
 767         andl    $~TS_COMPAT,TI_status(%rcx)
 768         jmp   retint_swapgs
 769
 770         /* Either reschedule or signal or syscall exit tracking needed. */
 771         /* First do a reschedule test. */
 772         /* edx: work, edi: workmask */
 773 int_careful:
 774         bt $TIF_NEED_RESCHED,%edx
 775         jnc  int_very_careful
 776         TRACE_IRQS_ON
 777         ENABLE_INTERRUPTS(CLBR_NONE)
 778         pushq_cfi %rdi
 779         SCHEDULE_USER
 780         popq_cfi %rdi
 781         DISABLE_INTERRUPTS(CLBR_NONE)
 782         TRACE_IRQS_OFF
 783         jmp int_with_check
 784
 785         /* handle signals and tracing -- both require a full stack frame */
 786 int_very_careful:
 787         TRACE_IRQS_ON
 788         ENABLE_INTERRUPTS(CLBR_NONE)
 789 int_check_syscall_exit_work:
 790         SAVE_REST
 791         /* Check for syscall exit trace */
 792         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 793         jz int_signal
 794         pushq_cfi %rdi
 795         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 796         call syscall_trace_leave
 797         popq_cfi %rdi
 798         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 799         jmp int_restore_rest
 800
 801 int_signal:
 802         testl $_TIF_DO_NOTIFY_MASK,%edx
 803         jz 1f
 804         movq %rsp,%rdi          # &ptregs -> arg1
 805         xorl %esi,%esi          # oldset -> arg2
 806         call do_notify_resume
 807 1:      movl $_TIF_WORK_MASK,%edi
 808 int_restore_rest:
 809         RESTORE_REST
 810         DISABLE_INTERRUPTS(CLBR_NONE)
 811         TRACE_IRQS_OFF
 812         jmp int_with_check
 813         CFI_ENDPROC
 814 END(system_call)
 815
 816         .macro FORK_LIKE func
 817 ENTRY(stub_\func)
 818         CFI_STARTPROC
 819         popq    %r11                    /* save return address */
 820         PARTIAL_FRAME 0
 821         SAVE_REST
 822         pushq   %r11                    /* put it back on stack */
 823         FIXUP_TOP_OF_STACK %r11, 8
 824         DEFAULT_FRAME 0 8               /* offset 8: return address */
 825         call sys_\func
 826         RESTORE_TOP_OF_STACK %r11, 8
 827         ret $REST_SKIP          /* pop extended registers */
 828         CFI_ENDPROC
 829 END(stub_\func)
 830         .endm
 831
 832         .macro FIXED_FRAME label,func
 833 ENTRY(\label)
 834         CFI_STARTPROC
 835         PARTIAL_FRAME 0 8               /* offset 8: return address */
 836         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 837         call \func
 838         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 839         ret
 840         CFI_ENDPROC
 841 END(\label)
 842         .endm
 843
 844         FORK_LIKE  clone
 845         FORK_LIKE  fork
 846         FORK_LIKE  vfork
 847         FIXED_FRAME stub_iopl, sys_iopl
 848
 849 ENTRY(ptregscall_common)
 850         DEFAULT_FRAME 1 8       /* offset 8: return address */
 851         RESTORE_TOP_OF_STACK %r11, 8
 852         movq_cfi_restore R15+8, r15
 853         movq_cfi_restore R14+8, r14
 854         movq_cfi_restore R13+8, r13
 855         movq_cfi_restore R12+8, r12
 856         movq_cfi_restore RBP+8, rbp
 857         movq_cfi_restore RBX+8, rbx
 858         ret $REST_SKIP          /* pop extended registers */
 859         CFI_ENDPROC
 860 END(ptregscall_common)
 861
 862 ENTRY(stub_execve)
 863         CFI_STARTPROC
 864         addq $8, %rsp
 865         PARTIAL_FRAME 0
 866         SAVE_REST
 867         FIXUP_TOP_OF_STACK %r11
 868         call sys_execve
 869         movq %rax,RAX(%rsp)
 870         RESTORE_REST
 871         jmp int_ret_from_sys_call
 872         CFI_ENDPROC
 873 END(stub_execve)
 874
 875 /*
 876  * sigreturn is special because it needs to restore all registers on return.
 877  * This cannot be done with SYSRET, so use the IRET return path instead.
 878  */
 879 ENTRY(stub_rt_sigreturn)
 880         CFI_STARTPROC
 881         addq $8, %rsp
 882         PARTIAL_FRAME 0
 883         SAVE_REST
 884         FIXUP_TOP_OF_STACK %r11
 885         call sys_rt_sigreturn
 886         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 887         RESTORE_REST
 888         jmp int_ret_from_sys_call
 889         CFI_ENDPROC
 890 END(stub_rt_sigreturn)
 891
 892 #ifdef CONFIG_X86_X32_ABI
 893 ENTRY(stub_x32_rt_sigreturn)
 894         CFI_STARTPROC
 895         addq $8, %rsp
 896         PARTIAL_FRAME 0
 897         SAVE_REST
 898         FIXUP_TOP_OF_STACK %r11
 899         call sys32_x32_rt_sigreturn
 900         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 901         RESTORE_REST
 902         jmp int_ret_from_sys_call
 903         CFI_ENDPROC
 904 END(stub_x32_rt_sigreturn)
 905
 906 ENTRY(stub_x32_execve)
 907         CFI_STARTPROC
 908         addq $8, %rsp
 909         PARTIAL_FRAME 0
 910         SAVE_REST
 911         FIXUP_TOP_OF_STACK %r11
 912         call compat_sys_execve
 913         RESTORE_TOP_OF_STACK %r11
 914         movq %rax,RAX(%rsp)
 915         RESTORE_REST
 916         jmp int_ret_from_sys_call
 917         CFI_ENDPROC
 918 END(stub_x32_execve)
 919
 920 #endif
 921
 922 /*
 923  * Build the entry stubs and pointer table with some assembler magic.
 924  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 925  * single cache line on all modern x86 implementations.
 926  */
 927         .section .init.rodata,"a"
 928 ENTRY(interrupt)
 929         .section .entry.text
 930         .p2align 5
 931         .p2align CONFIG_X86_L1_CACHE_SHIFT
 932 ENTRY(irq_entries_start)
 933         INTR_FRAME
 934 vector=FIRST_EXTERNAL_VECTOR
 935 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 936         .balign 32
 937   .rept 7
 938     .if vector < NR_VECTORS
 939       .if vector <> FIRST_EXTERNAL_VECTOR
 940         CFI_ADJUST_CFA_OFFSET -8
 941       .endif
 942 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 943       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 944         jmp 2f
 945       .endif
 946       .previous
 947         .quad 1b
 948       .section .entry.text
 949 vector=vector+1
 950     .endif
 951   .endr
 952 2:      jmp common_interrupt
 953 .endr
 954         CFI_ENDPROC
 955 END(irq_entries_start)
 956
 957 .previous
 958 END(interrupt)
 959 .previous
 960
 961 /*
 962  * Interrupt entry/exit.
 963  *
 964  * Interrupt entry points save only callee clobbered registers in fast path.
 965  *
 966  * Entry runs with interrupts off.
 967  */
 968
 969 /* 0(%rsp): ~(interrupt number) */
 970         .macro interrupt func
 971         /* reserve pt_regs for scratch regs and rbp */
 972         subq $ORIG_RAX-RBP, %rsp
 973         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 974         SAVE_ARGS_IRQ
 975         call \func
 976         .endm
 977
 978 /*
 979  * Interrupt entry/exit should be protected against kprobes
 980  */
 981         .pushsection .kprobes.text, "ax"
 982         /*
 983          * The interrupt stubs push (~vector+0x80) onto the stack and
 984          * then jump to common_interrupt.
 985          */
 986         .p2align CONFIG_X86_L1_CACHE_SHIFT
 987 common_interrupt:
 988         XCPT_FRAME
 989         ASM_CLAC
 990         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 991         interrupt do_IRQ
 992         /* 0(%rsp): old_rsp-ARGOFFSET */
 993 ret_from_intr:
 994         DISABLE_INTERRUPTS(CLBR_NONE)
 995         TRACE_IRQS_OFF
 996         decl PER_CPU_VAR(irq_count)
 997
 998         /* Restore saved previous stack */
 999         popq %rsi
1000         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1001         leaq ARGOFFSET-RBP(%rsi), %rsp
1002         CFI_DEF_CFA_REGISTER    rsp
1003         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1004
1005 exit_intr:
1006         GET_THREAD_INFO(%rcx)
1007         testl $3,CS-ARGOFFSET(%rsp)
1008         je retint_kernel
1009
1010         /* Interrupt came from user space */
1011         /*
1012          * Has a correct top of stack, but a partial stack frame
1013          * %rcx: thread info. Interrupts off.
1014          */
1015 retint_with_reschedule:
1016         movl $_TIF_WORK_MASK,%edi
1017 retint_check:
1018         LOCKDEP_SYS_EXIT_IRQ
1019         movl TI_flags(%rcx),%edx
1020         andl %edi,%edx
1021         CFI_REMEMBER_STATE
1022         jnz  retint_careful
1023
1024 retint_swapgs:          /* return to user-space */
1025         /*
1026          * The iretq could re-enable interrupts:
1027          */
1028         DISABLE_INTERRUPTS(CLBR_ANY)
1029         TRACE_IRQS_IRETQ
1030         SWAPGS
1031         jmp restore_args
1032
1033 retint_restore_args:    /* return to kernel space */
1034         DISABLE_INTERRUPTS(CLBR_ANY)
1035         /*
1036          * The iretq could re-enable interrupts:
1037          */
1038         TRACE_IRQS_IRETQ
1039 restore_args:
1040         RESTORE_ARGS 1,8,1
1041
1042 irq_return:
1043         INTERRUPT_RETURN
1044         _ASM_EXTABLE(irq_return, bad_iret)
1045
1046 #ifdef CONFIG_PARAVIRT
1047 ENTRY(native_iret)
1048         iretq
1049         _ASM_EXTABLE(native_iret, bad_iret)
1050 #endif
1051
1052         .section .fixup,"ax"
1053 bad_iret:
1054         /*
1055          * The iret traps when the %cs or %ss being restored is bogus.
1056          * We've lost the original trap vector and error code.
1057          * #GPF is the most likely one to get for an invalid selector.
1058          * So pretend we completed the iret and took the #GPF in user mode.
1059          *
1060          * We are now running with the kernel GS after exception recovery.
1061          * But error_entry expects us to have user GS to match the user %cs,
1062          * so swap back.
1063          */
1064         pushq $0
1065
1066         SWAPGS
1067         jmp general_protection
1068
1069         .previous
1070
1071         /* edi: workmask, edx: work */
1072 retint_careful:
1073         CFI_RESTORE_STATE
1074         bt    $TIF_NEED_RESCHED,%edx
1075         jnc   retint_signal
1076         TRACE_IRQS_ON
1077         ENABLE_INTERRUPTS(CLBR_NONE)
1078         pushq_cfi %rdi
1079         SCHEDULE_USER
1080         popq_cfi %rdi
1081         GET_THREAD_INFO(%rcx)
1082         DISABLE_INTERRUPTS(CLBR_NONE)
1083         TRACE_IRQS_OFF
1084         jmp retint_check
1085
1086 retint_signal:
1087         testl $_TIF_DO_NOTIFY_MASK,%edx
1088         jz    retint_swapgs
1089         TRACE_IRQS_ON
1090         ENABLE_INTERRUPTS(CLBR_NONE)
1091         SAVE_REST
1092         movq $-1,ORIG_RAX(%rsp)
1093         xorl %esi,%esi          # oldset
1094         movq %rsp,%rdi          # &pt_regs
1095         call do_notify_resume
1096         RESTORE_REST
1097         DISABLE_INTERRUPTS(CLBR_NONE)
1098         TRACE_IRQS_OFF
1099         GET_THREAD_INFO(%rcx)
1100         jmp retint_with_reschedule
1101
1102 #ifdef CONFIG_PREEMPT
1103         /* Returning to kernel space. Check if we need preemption */
1104         /* rcx:  threadinfo. interrupts off. */
1105 ENTRY(retint_kernel)
1106         cmpl $0,TI_preempt_count(%rcx)
1107         jnz  retint_restore_args
1108         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1109         jnc  retint_restore_args
1110         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1111         jnc  retint_restore_args
1112         call preempt_schedule_irq
1113         jmp exit_intr
1114 #endif
1115
1116         CFI_ENDPROC
1117 END(common_interrupt)
1118 /*
1119  * End of kprobes section
1120  */
1121        .popsection
1122
1123 /*
1124  * APIC interrupts.
1125  */
1126 .macro apicinterrupt3 num sym do_sym
1127 ENTRY(\sym)
1128         INTR_FRAME
1129         ASM_CLAC
1130         pushq_cfi $~(\num)
1131 .Lcommon_\sym:
1132         interrupt \do_sym
1133         jmp ret_from_intr
1134         CFI_ENDPROC
1135 END(\sym)
1136 .endm
1137
1138 #ifdef CONFIG_TRACING
1139 #define trace(sym) trace_##sym
1140 #define smp_trace(sym) smp_trace_##sym
1141
1142 .macro trace_apicinterrupt num sym
1143 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
1144 .endm
1145 #else
1146 .macro trace_apicinterrupt num sym do_sym
1147 .endm
1148 #endif
1149
1150 .macro apicinterrupt num sym do_sym
1151 apicinterrupt3 \num \sym \do_sym
1152 trace_apicinterrupt \num \sym
1153 .endm
1154
1155 #ifdef CONFIG_SMP
1156 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1157         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1158 apicinterrupt3 REBOOT_VECTOR \
1159         reboot_interrupt smp_reboot_interrupt
1160 #endif
1161
1162 #ifdef CONFIG_X86_UV
1163 apicinterrupt3 UV_BAU_MESSAGE \
1164         uv_bau_message_intr1 uv_bau_message_interrupt
1165 #endif
1166 apicinterrupt LOCAL_TIMER_VECTOR \
1167         apic_timer_interrupt smp_apic_timer_interrupt
1168 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1169         x86_platform_ipi smp_x86_platform_ipi
1170
1171 #ifdef CONFIG_HAVE_KVM
1172 apicinterrupt3 POSTED_INTR_VECTOR \
1173         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1174 #endif
1175
1176 #ifdef CONFIG_X86_MCE_THRESHOLD
1177 apicinterrupt THRESHOLD_APIC_VECTOR \
1178         threshold_interrupt smp_threshold_interrupt
1179 #endif
1180
1181 #ifdef CONFIG_X86_THERMAL_VECTOR
1182 apicinterrupt THERMAL_APIC_VECTOR \
1183         thermal_interrupt smp_thermal_interrupt
1184 #endif
1185
1186 #ifdef CONFIG_SMP
1187 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1188         call_function_single_interrupt smp_call_function_single_interrupt
1189 apicinterrupt CALL_FUNCTION_VECTOR \
1190         call_function_interrupt smp_call_function_interrupt
1191 apicinterrupt RESCHEDULE_VECTOR \
1192         reschedule_interrupt smp_reschedule_interrupt
1193 #endif
1194
1195 apicinterrupt ERROR_APIC_VECTOR \
1196         error_interrupt smp_error_interrupt
1197 apicinterrupt SPURIOUS_APIC_VECTOR \
1198         spurious_interrupt smp_spurious_interrupt
1199
1200 #ifdef CONFIG_IRQ_WORK
1201 apicinterrupt IRQ_WORK_VECTOR \
1202         irq_work_interrupt smp_irq_work_interrupt
1203 #endif
1204
1205 /*
1206  * Exception entry points.
1207  */
1208 .macro zeroentry sym do_sym
1209 ENTRY(\sym)
1210         INTR_FRAME
1211         ASM_CLAC
1212         PARAVIRT_ADJUST_EXCEPTION_FRAME
1213         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1214         subq $ORIG_RAX-R15, %rsp
1215         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1216         call error_entry
1217         DEFAULT_FRAME 0
1218         movq %rsp,%rdi          /* pt_regs pointer */
1219         xorl %esi,%esi          /* no error code */
1220         call \do_sym
1221         jmp error_exit          /* %ebx: no swapgs flag */
1222         CFI_ENDPROC
1223 END(\sym)
1224 .endm
1225
1226 .macro paranoidzeroentry sym do_sym
1227 ENTRY(\sym)
1228         INTR_FRAME
1229         ASM_CLAC
1230         PARAVIRT_ADJUST_EXCEPTION_FRAME
1231         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1232         subq $ORIG_RAX-R15, %rsp
1233         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1234         call save_paranoid
1235         TRACE_IRQS_OFF
1236         movq %rsp,%rdi          /* pt_regs pointer */
1237         xorl %esi,%esi          /* no error code */
1238         call \do_sym
1239         jmp paranoid_exit       /* %ebx: no swapgs flag */
1240         CFI_ENDPROC
1241 END(\sym)
1242 .endm
1243
1244 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1245 .macro paranoidzeroentry_ist sym do_sym ist
1246 ENTRY(\sym)
1247         INTR_FRAME
1248         ASM_CLAC
1249         PARAVIRT_ADJUST_EXCEPTION_FRAME
1250         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1251         subq $ORIG_RAX-R15, %rsp
1252         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1253         call save_paranoid
1254         TRACE_IRQS_OFF_DEBUG
1255         movq %rsp,%rdi          /* pt_regs pointer */
1256         xorl %esi,%esi          /* no error code */
1257         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1258         call \do_sym
1259         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1260         jmp paranoid_exit       /* %ebx: no swapgs flag */
1261         CFI_ENDPROC
1262 END(\sym)
1263 .endm
1264
1265 .macro errorentry sym do_sym
1266 ENTRY(\sym)
1267         XCPT_FRAME
1268         ASM_CLAC
1269         PARAVIRT_ADJUST_EXCEPTION_FRAME
1270         subq $ORIG_RAX-R15, %rsp
1271         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1272         call error_entry
1273         DEFAULT_FRAME 0
1274         movq %rsp,%rdi                  /* pt_regs pointer */
1275         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1276         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1277         call \do_sym
1278         jmp error_exit                  /* %ebx: no swapgs flag */
1279         CFI_ENDPROC
1280 END(\sym)
1281 .endm
1282
1283         /* error code is on the stack already */
1284 .macro paranoiderrorentry sym do_sym
1285 ENTRY(\sym)
1286         XCPT_FRAME
1287         ASM_CLAC
1288         PARAVIRT_ADJUST_EXCEPTION_FRAME
1289         subq $ORIG_RAX-R15, %rsp
1290         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1291         call save_paranoid
1292         DEFAULT_FRAME 0
1293         TRACE_IRQS_OFF
1294         movq %rsp,%rdi                  /* pt_regs pointer */
1295         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1296         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1297         call \do_sym
1298         jmp paranoid_exit               /* %ebx: no swapgs flag */
1299         CFI_ENDPROC
1300 END(\sym)
1301 .endm
1302
1303 zeroentry divide_error do_divide_error
1304 zeroentry overflow do_overflow
1305 zeroentry bounds do_bounds
1306 zeroentry invalid_op do_invalid_op
1307 zeroentry device_not_available do_device_not_available
1308 paranoiderrorentry double_fault do_double_fault
1309 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1310 errorentry invalid_TSS do_invalid_TSS
1311 errorentry segment_not_present do_segment_not_present
1312 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1313 zeroentry coprocessor_error do_coprocessor_error
1314 errorentry alignment_check do_alignment_check
1315 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1316
1317
1318         /* Reload gs selector with exception handling */
1319         /* edi:  new selector */
1320 ENTRY(native_load_gs_index)
1321         CFI_STARTPROC
1322         pushfq_cfi
1323         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1324         SWAPGS
1325 gs_change:
1326         movl %edi,%gs
1327 2:      mfence          /* workaround */
1328         SWAPGS
1329         popfq_cfi
1330         ret
1331         CFI_ENDPROC
1332 END(native_load_gs_index)
1333
1334         _ASM_EXTABLE(gs_change,bad_gs)
1335         .section .fixup,"ax"
1336         /* running with kernelgs */
1337 bad_gs:
1338         SWAPGS                  /* switch back to user gs */
1339         xorl %eax,%eax
1340         movl %eax,%gs
1341         jmp  2b
1342         .previous
1343
1344 /* Call softirq on interrupt stack. Interrupts are off. */
1345 ENTRY(call_softirq)
1346         CFI_STARTPROC
1347         pushq_cfi %rbp
1348         CFI_REL_OFFSET rbp,0
1349         mov  %rsp,%rbp
1350         CFI_DEF_CFA_REGISTER rbp
1351         incl PER_CPU_VAR(irq_count)
1352         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1353         push  %rbp                      # backlink for old unwinder
1354         call __do_softirq
1355         leaveq
1356         CFI_RESTORE             rbp
1357         CFI_DEF_CFA_REGISTER    rsp
1358         CFI_ADJUST_CFA_OFFSET   -8
1359         decl PER_CPU_VAR(irq_count)
1360         ret
1361         CFI_ENDPROC
1362 END(call_softirq)
1363
1364 #ifdef CONFIG_XEN
1365 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1366
1367 /*
1368  * A note on the "critical region" in our callback handler.
1369  * We want to avoid stacking callback handlers due to events occurring
1370  * during handling of the last event. To do this, we keep events disabled
1371  * until we've done all processing. HOWEVER, we must enable events before
1372  * popping the stack frame (can't be done atomically) and so it would still
1373  * be possible to get enough handler activations to overflow the stack.
1374  * Although unlikely, bugs of that kind are hard to track down, so we'd
1375  * like to avoid the possibility.
1376  * So, on entry to the handler we detect whether we interrupted an
1377  * existing activation in its critical region -- if so, we pop the current
1378  * activation and restart the handler using the previous one.
1379  */
1380 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1381         CFI_STARTPROC
1382 /*
1383  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1384  * see the correct pointer to the pt_regs
1385  */
1386         movq %rdi, %rsp            # we don't return, adjust the stack frame
1387         CFI_ENDPROC
1388         DEFAULT_FRAME
1389 11:     incl PER_CPU_VAR(irq_count)
1390         movq %rsp,%rbp
1391         CFI_DEF_CFA_REGISTER rbp
1392         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1393         pushq %rbp                      # backlink for old unwinder
1394         call xen_evtchn_do_upcall
1395         popq %rsp
1396         CFI_DEF_CFA_REGISTER rsp
1397         decl PER_CPU_VAR(irq_count)
1398         jmp  error_exit
1399         CFI_ENDPROC
1400 END(xen_do_hypervisor_callback)
1401
1402 /*
1403  * Hypervisor uses this for application faults while it executes.
1404  * We get here for two reasons:
1405  *  1. Fault while reloading DS, ES, FS or GS
1406  *  2. Fault while executing IRET
1407  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1408  * registers that could be reloaded and zeroed the others.
1409  * Category 2 we fix up by killing the current process. We cannot use the
1410  * normal Linux return path in this case because if we use the IRET hypercall
1411  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1412  * We distinguish between categories by comparing each saved segment register
1413  * with its current contents: any discrepancy means we in category 1.
1414  */
1415 ENTRY(xen_failsafe_callback)
1416         INTR_FRAME 1 (6*8)
1417         /*CFI_REL_OFFSET gs,GS*/
1418         /*CFI_REL_OFFSET fs,FS*/
1419         /*CFI_REL_OFFSET es,ES*/
1420         /*CFI_REL_OFFSET ds,DS*/
1421         CFI_REL_OFFSET r11,8
1422         CFI_REL_OFFSET rcx,0
1423         movw %ds,%cx
1424         cmpw %cx,0x10(%rsp)
1425         CFI_REMEMBER_STATE
1426         jne 1f
1427         movw %es,%cx
1428         cmpw %cx,0x18(%rsp)
1429         jne 1f
1430         movw %fs,%cx
1431         cmpw %cx,0x20(%rsp)
1432         jne 1f
1433         movw %gs,%cx
1434         cmpw %cx,0x28(%rsp)
1435         jne 1f
1436         /* All segments match their saved values => Category 2 (Bad IRET). */
1437         movq (%rsp),%rcx
1438         CFI_RESTORE rcx
1439         movq 8(%rsp),%r11
1440         CFI_RESTORE r11
1441         addq $0x30,%rsp
1442         CFI_ADJUST_CFA_OFFSET -0x30
1443         pushq_cfi $0    /* RIP */
1444         pushq_cfi %r11
1445         pushq_cfi %rcx
1446         jmp general_protection
1447         CFI_RESTORE_STATE
1448 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1449         movq (%rsp),%rcx
1450         CFI_RESTORE rcx
1451         movq 8(%rsp),%r11
1452         CFI_RESTORE r11
1453         addq $0x30,%rsp
1454         CFI_ADJUST_CFA_OFFSET -0x30
1455         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1456         SAVE_ALL
1457         jmp error_exit
1458         CFI_ENDPROC
1459 END(xen_failsafe_callback)
1460
1461 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1462         xen_hvm_callback_vector xen_evtchn_do_upcall
1463
1464 #endif /* CONFIG_XEN */
1465
1466 #if IS_ENABLED(CONFIG_HYPERV)
1467 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1468         hyperv_callback_vector hyperv_vector_handler
1469 #endif /* CONFIG_HYPERV */
1470
1471 /*
1472  * Some functions should be protected against kprobes
1473  */
1474         .pushsection .kprobes.text, "ax"
1475
1476 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1477 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1478 paranoiderrorentry stack_segment do_stack_segment
1479 #ifdef CONFIG_XEN
1480 zeroentry xen_debug do_debug
1481 zeroentry xen_int3 do_int3
1482 errorentry xen_stack_segment do_stack_segment
1483 #endif
1484 errorentry general_protection do_general_protection
1485 errorentry page_fault do_page_fault
1486 #ifdef CONFIG_KVM_GUEST
1487 errorentry async_page_fault do_async_page_fault
1488 #endif
1489 #ifdef CONFIG_X86_MCE
1490 paranoidzeroentry machine_check *machine_check_vector(%rip)
1491 #endif
1492
1493         /*
1494          * "Paranoid" exit path from exception stack.
1495          * Paranoid because this is used by NMIs and cannot take
1496          * any kernel state for granted.
1497          * We don't do kernel preemption checks here, because only
1498          * NMI should be common and it does not enable IRQs and
1499          * cannot get reschedule ticks.
1500          *
1501          * "trace" is 0 for the NMI handler only, because irq-tracing
1502          * is fundamentally NMI-unsafe. (we cannot change the soft and
1503          * hard flags at once, atomically)
1504          */
1505
1506         /* ebx: no swapgs flag */
1507 ENTRY(paranoid_exit)
1508         DEFAULT_FRAME
1509         DISABLE_INTERRUPTS(CLBR_NONE)
1510         TRACE_IRQS_OFF_DEBUG
1511         testl %ebx,%ebx                         /* swapgs needed? */
1512         jnz paranoid_restore
1513         testl $3,CS(%rsp)
1514         jnz   paranoid_userspace
1515 paranoid_swapgs:
1516         TRACE_IRQS_IRETQ 0
1517         SWAPGS_UNSAFE_STACK
1518         RESTORE_ALL 8
1519         jmp irq_return
1520 paranoid_restore:
1521         TRACE_IRQS_IRETQ_DEBUG 0
1522         RESTORE_ALL 8
1523         jmp irq_return
1524 paranoid_userspace:
1525         GET_THREAD_INFO(%rcx)
1526         movl TI_flags(%rcx),%ebx
1527         andl $_TIF_WORK_MASK,%ebx
1528         jz paranoid_swapgs
1529         movq %rsp,%rdi                  /* &pt_regs */
1530         call sync_regs
1531         movq %rax,%rsp                  /* switch stack for scheduling */
1532         testl $_TIF_NEED_RESCHED,%ebx
1533         jnz paranoid_schedule
1534         movl %ebx,%edx                  /* arg3: thread flags */
1535         TRACE_IRQS_ON
1536         ENABLE_INTERRUPTS(CLBR_NONE)
1537         xorl %esi,%esi                  /* arg2: oldset */
1538         movq %rsp,%rdi                  /* arg1: &pt_regs */
1539         call do_notify_resume
1540         DISABLE_INTERRUPTS(CLBR_NONE)
1541         TRACE_IRQS_OFF
1542         jmp paranoid_userspace
1543 paranoid_schedule:
1544         TRACE_IRQS_ON
1545         ENABLE_INTERRUPTS(CLBR_ANY)
1546         SCHEDULE_USER
1547         DISABLE_INTERRUPTS(CLBR_ANY)
1548         TRACE_IRQS_OFF
1549         jmp paranoid_userspace
1550         CFI_ENDPROC
1551 END(paranoid_exit)
1552
1553 /*
1554  * Exception entry point. This expects an error code/orig_rax on the stack.
1555  * returns in "no swapgs flag" in %ebx.
1556  */
1557 ENTRY(error_entry)
1558         XCPT_FRAME
1559         CFI_ADJUST_CFA_OFFSET 15*8
1560         /* oldrax contains error code */
1561         cld
1562         movq_cfi rdi, RDI+8
1563         movq_cfi rsi, RSI+8
1564         movq_cfi rdx, RDX+8
1565         movq_cfi rcx, RCX+8
1566         movq_cfi rax, RAX+8
1567         movq_cfi  r8,  R8+8
1568         movq_cfi  r9,  R9+8
1569         movq_cfi r10, R10+8
1570         movq_cfi r11, R11+8
1571         movq_cfi rbx, RBX+8
1572         movq_cfi rbp, RBP+8
1573         movq_cfi r12, R12+8
1574         movq_cfi r13, R13+8
1575         movq_cfi r14, R14+8
1576         movq_cfi r15, R15+8
1577         xorl %ebx,%ebx
1578         testl $3,CS+8(%rsp)
1579         je error_kernelspace
1580 error_swapgs:
1581         SWAPGS
1582 error_sti:
1583         TRACE_IRQS_OFF
1584         ret
1585
1586 /*
1587  * There are two places in the kernel that can potentially fault with
1588  * usergs. Handle them here. The exception handlers after iret run with
1589  * kernel gs again, so don't set the user space flag. B stepping K8s
1590  * sometimes report an truncated RIP for IRET exceptions returning to
1591  * compat mode. Check for these here too.
1592  */
1593 error_kernelspace:
1594         incl %ebx
1595         leaq irq_return(%rip),%rcx
1596         cmpq %rcx,RIP+8(%rsp)
1597         je error_swapgs
1598         movl %ecx,%eax  /* zero extend */
1599         cmpq %rax,RIP+8(%rsp)
1600         je bstep_iret
1601         cmpq $gs_change,RIP+8(%rsp)
1602         je error_swapgs
1603         jmp error_sti
1604
1605 bstep_iret:
1606         /* Fix truncated RIP */
1607         movq %rcx,RIP+8(%rsp)
1608         jmp error_swapgs
1609         CFI_ENDPROC
1610 END(error_entry)
1611
1612
1613 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1614 ENTRY(error_exit)
1615         DEFAULT_FRAME
1616         movl %ebx,%eax
1617         RESTORE_REST
1618         DISABLE_INTERRUPTS(CLBR_NONE)
1619         TRACE_IRQS_OFF
1620         GET_THREAD_INFO(%rcx)
1621         testl %eax,%eax
1622         jne retint_kernel
1623         LOCKDEP_SYS_EXIT_IRQ
1624         movl TI_flags(%rcx),%edx
1625         movl $_TIF_WORK_MASK,%edi
1626         andl %edi,%edx
1627         jnz retint_careful
1628         jmp retint_swapgs
1629         CFI_ENDPROC
1630 END(error_exit)
1631
1632 /*
1633  * Test if a given stack is an NMI stack or not.
1634  */
1635         .macro test_in_nmi reg stack nmi_ret normal_ret
1636         cmpq %\reg, \stack
1637         ja \normal_ret
1638         subq $EXCEPTION_STKSZ, %\reg
1639         cmpq %\reg, \stack
1640         jb \normal_ret
1641         jmp \nmi_ret
1642         .endm
1643
1644         /* runs on exception stack */
1645 ENTRY(nmi)
1646         INTR_FRAME
1647         PARAVIRT_ADJUST_EXCEPTION_FRAME
1648         /*
1649          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1650          * the iretq it performs will take us out of NMI context.
1651          * This means that we can have nested NMIs where the next
1652          * NMI is using the top of the stack of the previous NMI. We
1653          * can't let it execute because the nested NMI will corrupt the
1654          * stack of the previous NMI. NMI handlers are not re-entrant
1655          * anyway.
1656          *
1657          * To handle this case we do the following:
1658          *  Check the a special location on the stack that contains
1659          *  a variable that is set when NMIs are executing.
1660          *  The interrupted task's stack is also checked to see if it
1661          *  is an NMI stack.
1662          *  If the variable is not set and the stack is not the NMI
1663          *  stack then:
1664          *    o Set the special variable on the stack
1665          *    o Copy the interrupt frame into a "saved" location on the stack
1666          *    o Copy the interrupt frame into a "copy" location on the stack
1667          *    o Continue processing the NMI
1668          *  If the variable is set or the previous stack is the NMI stack:
1669          *    o Modify the "copy" location to jump to the repeate_nmi
1670          *    o return back to the first NMI
1671          *
1672          * Now on exit of the first NMI, we first clear the stack variable
1673          * The NMI stack will tell any nested NMIs at that point that it is
1674          * nested. Then we pop the stack normally with iret, and if there was
1675          * a nested NMI that updated the copy interrupt stack frame, a
1676          * jump will be made to the repeat_nmi code that will handle the second
1677          * NMI.
1678          */
1679
1680         /* Use %rdx as out temp variable throughout */
1681         pushq_cfi %rdx
1682         CFI_REL_OFFSET rdx, 0
1683
1684         /*
1685          * If %cs was not the kernel segment, then the NMI triggered in user
1686          * space, which means it is definitely not nested.
1687          */
1688         cmpl $__KERNEL_CS, 16(%rsp)
1689         jne first_nmi
1690
1691         /*
1692          * Check the special variable on the stack to see if NMIs are
1693          * executing.
1694          */
1695         cmpl $1, -8(%rsp)
1696         je nested_nmi
1697
1698         /*
1699          * Now test if the previous stack was an NMI stack.
1700          * We need the double check. We check the NMI stack to satisfy the
1701          * race when the first NMI clears the variable before returning.
1702          * We check the variable because the first NMI could be in a
1703          * breakpoint routine using a breakpoint stack.
1704          */
1705         lea 6*8(%rsp), %rdx
1706         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1707         CFI_REMEMBER_STATE
1708
1709 nested_nmi:
1710         /*
1711          * Do nothing if we interrupted the fixup in repeat_nmi.
1712          * It's about to repeat the NMI handler, so we are fine
1713          * with ignoring this one.
1714          */
1715         movq $repeat_nmi, %rdx
1716         cmpq 8(%rsp), %rdx
1717         ja 1f
1718         movq $end_repeat_nmi, %rdx
1719         cmpq 8(%rsp), %rdx
1720         ja nested_nmi_out
1721
1722 1:
1723         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1724         leaq -1*8(%rsp), %rdx
1725         movq %rdx, %rsp
1726         CFI_ADJUST_CFA_OFFSET 1*8
1727         leaq -10*8(%rsp), %rdx
1728         pushq_cfi $__KERNEL_DS
1729         pushq_cfi %rdx
1730         pushfq_cfi
1731         pushq_cfi $__KERNEL_CS
1732         pushq_cfi $repeat_nmi
1733
1734         /* Put stack back */
1735         addq $(6*8), %rsp
1736         CFI_ADJUST_CFA_OFFSET -6*8
1737
1738 nested_nmi_out:
1739         popq_cfi %rdx
1740         CFI_RESTORE rdx
1741
1742         /* No need to check faults here */
1743         INTERRUPT_RETURN
1744
1745         CFI_RESTORE_STATE
1746 first_nmi:
1747         /*
1748          * Because nested NMIs will use the pushed location that we
1749          * stored in rdx, we must keep that space available.
1750          * Here's what our stack frame will look like:
1751          * +-------------------------+
1752          * | original SS             |
1753          * | original Return RSP     |
1754          * | original RFLAGS         |
1755          * | original CS             |
1756          * | original RIP            |
1757          * +-------------------------+
1758          * | temp storage for rdx    |
1759          * +-------------------------+
1760          * | NMI executing variable  |
1761          * +-------------------------+
1762          * | copied SS               |
1763          * | copied Return RSP       |
1764          * | copied RFLAGS           |
1765          * | copied CS               |
1766          * | copied RIP              |
1767          * +-------------------------+
1768          * | Saved SS                |
1769          * | Saved Return RSP        |
1770          * | Saved RFLAGS            |
1771          * | Saved CS                |
1772          * | Saved RIP               |
1773          * +-------------------------+
1774          * | pt_regs                 |
1775          * +-------------------------+
1776          *
1777          * The saved stack frame is used to fix up the copied stack frame
1778          * that a nested NMI may change to make the interrupted NMI iret jump
1779          * to the repeat_nmi. The original stack frame and the temp storage
1780          * is also used by nested NMIs and can not be trusted on exit.
1781          */
1782         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1783         movq (%rsp), %rdx
1784         CFI_RESTORE rdx
1785
1786         /* Set the NMI executing variable on the stack. */
1787         pushq_cfi $1
1788
1789         /*
1790          * Leave room for the "copied" frame
1791          */
1792         subq $(5*8), %rsp
1793         CFI_ADJUST_CFA_OFFSET 5*8
1794
1795         /* Copy the stack frame to the Saved frame */
1796         .rept 5
1797         pushq_cfi 11*8(%rsp)
1798         .endr
1799         CFI_DEF_CFA_OFFSET SS+8-RIP
1800
1801         /* Everything up to here is safe from nested NMIs */
1802
1803         /*
1804          * If there was a nested NMI, the first NMI's iret will return
1805          * here. But NMIs are still enabled and we can take another
1806          * nested NMI. The nested NMI checks the interrupted RIP to see
1807          * if it is between repeat_nmi and end_repeat_nmi, and if so
1808          * it will just return, as we are about to repeat an NMI anyway.
1809          * This makes it safe to copy to the stack frame that a nested
1810          * NMI will update.
1811          */
1812 repeat_nmi:
1813         /*
1814          * Update the stack variable to say we are still in NMI (the update
1815          * is benign for the non-repeat case, where 1 was pushed just above
1816          * to this very stack slot).
1817          */
1818         movq $1, 10*8(%rsp)
1819
1820         /* Make another copy, this one may be modified by nested NMIs */
1821         addq $(10*8), %rsp
1822         CFI_ADJUST_CFA_OFFSET -10*8
1823         .rept 5
1824         pushq_cfi -6*8(%rsp)
1825         .endr
1826         subq $(5*8), %rsp
1827         CFI_DEF_CFA_OFFSET SS+8-RIP
1828 end_repeat_nmi:
1829
1830         /*
1831          * Everything below this point can be preempted by a nested
1832          * NMI if the first NMI took an exception and reset our iret stack
1833          * so that we repeat another NMI.
1834          */
1835         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1836         subq $ORIG_RAX-R15, %rsp
1837         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1838         /*
1839          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1840          * as we should not be calling schedule in NMI context.
1841          * Even with normal interrupts enabled. An NMI should not be
1842          * setting NEED_RESCHED or anything that normal interrupts and
1843          * exceptions might do.
1844          */
1845         call save_paranoid
1846         DEFAULT_FRAME 0
1847
1848         /*
1849          * Save off the CR2 register. If we take a page fault in the NMI then
1850          * it could corrupt the CR2 value. If the NMI preempts a page fault
1851          * handler before it was able to read the CR2 register, and then the
1852          * NMI itself takes a page fault, the page fault that was preempted
1853          * will read the information from the NMI page fault and not the
1854          * origin fault. Save it off and restore it if it changes.
1855          * Use the r12 callee-saved register.
1856          */
1857         movq %cr2, %r12
1858
1859         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1860         movq %rsp,%rdi
1861         movq $-1,%rsi
1862         call do_nmi
1863
1864         /* Did the NMI take a page fault? Restore cr2 if it did */
1865         movq %cr2, %rcx
1866         cmpq %rcx, %r12
1867         je 1f
1868         movq %r12, %cr2
1869 1:
1870
1871         testl %ebx,%ebx                         /* swapgs needed? */
1872         jnz nmi_restore
1873 nmi_swapgs:
1874         SWAPGS_UNSAFE_STACK
1875 nmi_restore:
1876         /* Pop the extra iret frame at once */
1877         RESTORE_ALL 6*8
1878
1879         /* Clear the NMI executing stack variable */
1880         movq $0, 5*8(%rsp)
1881         jmp irq_return
1882         CFI_ENDPROC
1883 END(nmi)
1884
1885 ENTRY(ignore_sysret)
1886         CFI_STARTPROC
1887         mov $-ENOSYS,%eax
1888         sysret
1889         CFI_ENDPROC
1890 END(ignore_sysret)
1891
1892 /*
1893  * End of kprobes section
1894  */
1895         .popsection