arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - idtentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/percpu.h>
  57 #include <asm/asm.h>
  58 #include <asm/context_tracking.h>
  59 #include <asm/smap.h>
  60 #include <asm/pgtable_types.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72
  73 #ifndef CONFIG_PREEMPT
  74 #define retint_kernel retint_restore_args
  75 #endif
  76
  77 #ifdef CONFIG_PARAVIRT
  78 ENTRY(native_usergs_sysret64)
  79         swapgs
  80         sysretq
  81 ENDPROC(native_usergs_sysret64)
  82 #endif /* CONFIG_PARAVIRT */
  83
  84
  85 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
  88         jnc  1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 /*
  95  * When dynamic function tracer is enabled it will add a breakpoint
  96  * to all locations that it is about to modify, sync CPUs, update
  97  * all the code, sync CPUs, then remove the breakpoints. In this time
  98  * if lockdep is enabled, it might jump back into the debug handler
  99  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 100  *
 101  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 102  * make sure the stack pointer does not get reset back to the top
 103  * of the debug stack, and instead just reuses the current stack.
 104  */
 105 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 106
 107 .macro TRACE_IRQS_OFF_DEBUG
 108         call debug_stack_set_zero
 109         TRACE_IRQS_OFF
 110         call debug_stack_reset
 111 .endm
 112
 113 .macro TRACE_IRQS_ON_DEBUG
 114         call debug_stack_set_zero
 115         TRACE_IRQS_ON
 116         call debug_stack_reset
 117 .endm
 118
 119 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 120         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 121         jnc  1f
 122         TRACE_IRQS_ON_DEBUG
 123 1:
 124 .endm
 125
 126 #else
 127 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 128 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 129 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 130 #endif
 131
 132 /*
 133  * C code is not supposed to know about undefined top of stack. Every time
 134  * a C function with an pt_regs argument is called from the SYSCALL based
 135  * fast path FIXUP_TOP_OF_STACK is needed.
 136  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 137  * manipulation.
 138  */
 139
 140         /* %rsp:at FRAMEEND */
 141         .macro FIXUP_TOP_OF_STACK tmp offset=0
 142         movq PER_CPU_VAR(old_rsp),\tmp
 143         movq \tmp,RSP+\offset(%rsp)
 144         movq $__USER_DS,SS+\offset(%rsp)
 145         movq $__USER_CS,CS+\offset(%rsp)
 146         movq $-1,RCX+\offset(%rsp)
 147         movq R11+\offset(%rsp),\tmp  /* get eflags */
 148         movq \tmp,EFLAGS+\offset(%rsp)
 149         .endm
 150
 151         .macro RESTORE_TOP_OF_STACK tmp offset=0
 152         movq RSP+\offset(%rsp),\tmp
 153         movq \tmp,PER_CPU_VAR(old_rsp)
 154         movq EFLAGS+\offset(%rsp),\tmp
 155         movq \tmp,R11+\offset(%rsp)
 156         .endm
 157
 158         .macro FAKE_STACK_FRAME child_rip
 159         /* push in order ss, rsp, eflags, cs, rip */
 160         xorl %eax, %eax
 161         pushq_cfi $__KERNEL_DS /* ss */
 162         /*CFI_REL_OFFSET        ss,0*/
 163         pushq_cfi %rax /* rsp */
 164         CFI_REL_OFFSET  rsp,0
 165         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 166         /*CFI_REL_OFFSET        rflags,0*/
 167         pushq_cfi $__KERNEL_CS /* cs */
 168         /*CFI_REL_OFFSET        cs,0*/
 169         pushq_cfi \child_rip /* rip */
 170         CFI_REL_OFFSET  rip,0
 171         pushq_cfi %rax /* orig rax */
 172         .endm
 173
 174         .macro UNFAKE_STACK_FRAME
 175         addq $8*6, %rsp
 176         CFI_ADJUST_CFA_OFFSET   -(6*8)
 177         .endm
 178
 179 /*
 180  * initial frame state for interrupts (and exceptions without error code)
 181  */
 182         .macro EMPTY_FRAME start=1 offset=0
 183         .if \start
 184         CFI_STARTPROC simple
 185         CFI_SIGNAL_FRAME
 186         CFI_DEF_CFA rsp,8+\offset
 187         .else
 188         CFI_DEF_CFA_OFFSET 8+\offset
 189         .endif
 190         .endm
 191
 192 /*
 193  * initial frame state for interrupts (and exceptions without error code)
 194  */
 195         .macro INTR_FRAME start=1 offset=0
 196         EMPTY_FRAME \start, SS+8+\offset-RIP
 197         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 198         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 199         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 200         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 201         CFI_REL_OFFSET rip, RIP+\offset-RIP
 202         .endm
 203
 204 /*
 205  * initial frame state for exceptions with error code (and interrupts
 206  * with vector already pushed)
 207  */
 208         .macro XCPT_FRAME start=1 offset=0
 209         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 210         .endm
 211
 212 /*
 213  * frame that enables calling into C.
 214  */
 215         .macro PARTIAL_FRAME start=1 offset=0
 216         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 217         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 218         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 219         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 220         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 221         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 222         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 223         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 224         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 225         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 226         .endm
 227
 228 /*
 229  * frame that enables passing a complete pt_regs to a C function.
 230  */
 231         .macro DEFAULT_FRAME start=1 offset=0
 232         PARTIAL_FRAME \start, R11+\offset-R15
 233         CFI_REL_OFFSET rbx, RBX+\offset
 234         CFI_REL_OFFSET rbp, RBP+\offset
 235         CFI_REL_OFFSET r12, R12+\offset
 236         CFI_REL_OFFSET r13, R13+\offset
 237         CFI_REL_OFFSET r14, R14+\offset
 238         CFI_REL_OFFSET r15, R15+\offset
 239         .endm
 240
 241 /* save partial stack frame */
 242         .macro SAVE_ARGS_IRQ
 243         cld
 244         /* start from rbp in pt_regs and jump over */
 245         movq_cfi rdi, (RDI-RBP)
 246         movq_cfi rsi, (RSI-RBP)
 247         movq_cfi rdx, (RDX-RBP)
 248         movq_cfi rcx, (RCX-RBP)
 249         movq_cfi rax, (RAX-RBP)
 250         movq_cfi  r8,  (R8-RBP)
 251         movq_cfi  r9,  (R9-RBP)
 252         movq_cfi r10, (R10-RBP)
 253         movq_cfi r11, (R11-RBP)
 254
 255         /* Save rbp so that we can unwind from get_irq_regs() */
 256         movq_cfi rbp, 0
 257
 258         /* Save previous stack value */
 259         movq %rsp, %rsi
 260
 261         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 262         testl $3, CS-RBP(%rsi)
 263         je 1f
 264         SWAPGS
 265         /*
 266          * irq_count is used to check if a CPU is already on an interrupt stack
 267          * or not. While this is essentially redundant with preempt_count it is
 268          * a little cheaper to use a separate counter in the PDA (short of
 269          * moving irq_enter into assembly, which would be too much work)
 270          */
 271 1:      incl PER_CPU_VAR(irq_count)
 272         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 273         CFI_DEF_CFA_REGISTER    rsi
 274
 275         /* Store previous stack value */
 276         pushq %rsi
 277         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 278                         0x77 /* DW_OP_breg7 */, 0, \
 279                         0x06 /* DW_OP_deref */, \
 280                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 281                         0x22 /* DW_OP_plus */
 282         /* We entered an interrupt context - irqs are off: */
 283         TRACE_IRQS_OFF
 284         .endm
 285
 286 ENTRY(save_paranoid)
 287         XCPT_FRAME 1 RDI+8
 288         cld
 289         movq %rdi, RDI+8(%rsp)
 290         movq %rsi, RSI+8(%rsp)
 291         movq_cfi rdx, RDX+8
 292         movq_cfi rcx, RCX+8
 293         movq_cfi rax, RAX+8
 294         movq %r8, R8+8(%rsp)
 295         movq %r9, R9+8(%rsp)
 296         movq %r10, R10+8(%rsp)
 297         movq %r11, R11+8(%rsp)
 298         movq_cfi rbx, RBX+8
 299         movq %rbp, RBP+8(%rsp)
 300         movq %r12, R12+8(%rsp)
 301         movq %r13, R13+8(%rsp)
 302         movq %r14, R14+8(%rsp)
 303         movq %r15, R15+8(%rsp)
 304         movl $1,%ebx
 305         movl $MSR_GS_BASE,%ecx
 306         rdmsr
 307         testl %edx,%edx
 308         js 1f   /* negative -> in kernel */
 309         SWAPGS
 310         xorl %ebx,%ebx
 311 1:      ret
 312         CFI_ENDPROC
 313 END(save_paranoid)
 314
 315 /*
 316  * A newly forked process directly context switches into this address.
 317  *
 318  * rdi: prev task we switched from
 319  */
 320 ENTRY(ret_from_fork)
 321         DEFAULT_FRAME
 322
 323         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 324
 325         pushq_cfi $0x0002
 326         popfq_cfi                               # reset kernel eflags
 327
 328         call schedule_tail                      # rdi: 'prev' task parameter
 329
 330         GET_THREAD_INFO(%rcx)
 331
 332         RESTORE_REST
 333
 334         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 335         jz   1f
 336
 337         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 338         jnz  int_ret_from_sys_call
 339
 340         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 341         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 342
 343 1:
 344         subq $REST_SKIP, %rsp   # leave space for volatiles
 345         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 346         movq %rbp, %rdi
 347         call *%rbx
 348         movl $0, RAX(%rsp)
 349         RESTORE_REST
 350         jmp int_ret_from_sys_call
 351         CFI_ENDPROC
 352 END(ret_from_fork)
 353
 354 /*
 355  * System call entry. Up to 6 arguments in registers are supported.
 356  *
 357  * SYSCALL does not save anything on the stack and does not change the
 358  * stack pointer.  However, it does mask the flags register for us, so
 359  * CLD and CLAC are not needed.
 360  */
 361
 362 /*
 363  * Register setup:
 364  * rax  system call number
 365  * rdi  arg0
 366  * rcx  return address for syscall/sysret, C arg3
 367  * rsi  arg1
 368  * rdx  arg2
 369  * r10  arg3    (--> moved to rcx for C)
 370  * r8   arg4
 371  * r9   arg5
 372  * r11  eflags for syscall/sysret, temporary for C
 373  * r12-r15,rbp,rbx saved by C code, not touched.
 374  *
 375  * Interrupts are off on entry.
 376  * Only called from user space.
 377  *
 378  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 379  *      and report it properly in ps. Unfortunately we haven't.
 380  *
 381  * When user can change the frames always force IRET. That is because
 382  * it deals with uncanonical addresses better. SYSRET has trouble
 383  * with them due to bugs in both AMD and Intel CPUs.
 384  */
 385
 386 ENTRY(system_call)
 387         CFI_STARTPROC   simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 390         CFI_REGISTER    rip,rcx
 391         /*CFI_REGISTER  rflags,r11*/
 392         SWAPGS_UNSAFE_STACK
 393         /*
 394          * A hypervisor implementation might want to use a label
 395          * after the swapgs, so that it can do the swapgs
 396          * for the guest and jump here on syscall.
 397          */
 398 GLOBAL(system_call_after_swapgs)
 399
 400         movq    %rsp,PER_CPU_VAR(old_rsp)
 401         movq    PER_CPU_VAR(kernel_stack),%rsp
 402         /*
 403          * No need to follow this irqs off/on section - it's straight
 404          * and short:
 405          */
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407         SAVE_ARGS 8, 0, rax_enosys=1
 408         movq_cfi rax,(ORIG_RAX-ARGOFFSET)
 409         movq  %rcx,RIP-ARGOFFSET(%rsp)
 410         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 411         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 412         jnz tracesys
 413 system_call_fastpath:
 414 #if __SYSCALL_MASK == ~0
 415         cmpq $__NR_syscall_max,%rax
 416 #else
 417         andl $__SYSCALL_MASK,%eax
 418         cmpl $__NR_syscall_max,%eax
 419 #endif
 420         ja ret_from_sys_call  /* and return regs->ax */
 421         movq %r10,%rcx
 422         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 423         movq %rax,RAX-ARGOFFSET(%rsp)
 424 /*
 425  * Syscall return path ending with SYSRET (fast path)
 426  * Has incomplete stack frame and undefined top of stack.
 427  */
 428 ret_from_sys_call:
 429         movl $_TIF_ALLWORK_MASK,%edi
 430         /* edi: flagmask */
 431 sysret_check:
 432         LOCKDEP_SYS_EXIT
 433         DISABLE_INTERRUPTS(CLBR_NONE)
 434         TRACE_IRQS_OFF
 435         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 436         andl %edi,%edx
 437         jnz  sysret_careful
 438         CFI_REMEMBER_STATE
 439         /*
 440          * sysretq will re-enable interrupts:
 441          */
 442         TRACE_IRQS_ON
 443         movq RIP-ARGOFFSET(%rsp),%rcx
 444         CFI_REGISTER    rip,rcx
 445         RESTORE_ARGS 1,-ARG_SKIP,0
 446         /*CFI_REGISTER  rflags,r11*/
 447         movq    PER_CPU_VAR(old_rsp), %rsp
 448         USERGS_SYSRET64
 449
 450         CFI_RESTORE_STATE
 451         /* Handle reschedules */
 452         /* edx: work, edi: workmask */
 453 sysret_careful:
 454         bt $TIF_NEED_RESCHED,%edx
 455         jnc sysret_signal
 456         TRACE_IRQS_ON
 457         ENABLE_INTERRUPTS(CLBR_NONE)
 458         pushq_cfi %rdi
 459         SCHEDULE_USER
 460         popq_cfi %rdi
 461         jmp sysret_check
 462
 463         /* Handle a signal */
 464 sysret_signal:
 465         TRACE_IRQS_ON
 466         ENABLE_INTERRUPTS(CLBR_NONE)
 467 #ifdef CONFIG_AUDITSYSCALL
 468         bt $TIF_SYSCALL_AUDIT,%edx
 469         jc sysret_audit
 470 #endif
 471         /*
 472          * We have a signal, or exit tracing or single-step.
 473          * These all wind up with the iret return path anyway,
 474          * so just join that path right now.
 475          */
 476         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 477         jmp int_check_syscall_exit_work
 478
 479 #ifdef CONFIG_AUDITSYSCALL
 480         /*
 481          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 482          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 483          * masked off.
 484          */
 485 sysret_audit:
 486         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 487         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 488         setbe %al               /* 1 if so, 0 if not */
 489         movzbl %al,%edi         /* zero-extend that into %edi */
 490         call __audit_syscall_exit
 491         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 492         jmp sysret_check
 493 #endif  /* CONFIG_AUDITSYSCALL */
 494
 495         /* Do syscall tracing */
 496 tracesys:
 497         leaq -REST_SKIP(%rsp), %rdi
 498         movq $AUDIT_ARCH_X86_64, %rsi
 499         call syscall_trace_enter_phase1
 500         test %rax, %rax
 501         jnz tracesys_phase2             /* if needed, run the slow path */
 502         LOAD_ARGS 0                     /* else restore clobbered regs */
 503         jmp system_call_fastpath        /*      and return to the fast path */
 504
 505 tracesys_phase2:
 506         SAVE_REST
 507         FIXUP_TOP_OF_STACK %rdi
 508         movq %rsp, %rdi
 509         movq $AUDIT_ARCH_X86_64, %rsi
 510         movq %rax,%rdx
 511         call syscall_trace_enter_phase2
 512
 513         /*
 514          * Reload arg registers from stack in case ptrace changed them.
 515          * We don't reload %rax because syscall_trace_entry_phase2() returned
 516          * the value it wants us to use in the table lookup.
 517          */
 518         LOAD_ARGS ARGOFFSET, 1
 519         RESTORE_REST
 520 #if __SYSCALL_MASK == ~0
 521         cmpq $__NR_syscall_max,%rax
 522 #else
 523         andl $__SYSCALL_MASK,%eax
 524         cmpl $__NR_syscall_max,%eax
 525 #endif
 526         ja   int_ret_from_sys_call      /* RAX(%rsp) is already set */
 527         movq %r10,%rcx  /* fixup for C */
 528         call *sys_call_table(,%rax,8)
 529         movq %rax,RAX-ARGOFFSET(%rsp)
 530         /* Use IRET because user could have changed frame */
 531
 532 /*
 533  * Syscall return path ending with IRET.
 534  * Has correct top of stack, but partial stack frame.
 535  */
 536 GLOBAL(int_ret_from_sys_call)
 537         DISABLE_INTERRUPTS(CLBR_NONE)
 538         TRACE_IRQS_OFF
 539         movl $_TIF_ALLWORK_MASK,%edi
 540         /* edi: mask to check */
 541 GLOBAL(int_with_check)
 542         LOCKDEP_SYS_EXIT_IRQ
 543         GET_THREAD_INFO(%rcx)
 544         movl TI_flags(%rcx),%edx
 545         andl %edi,%edx
 546         jnz   int_careful
 547         andl    $~TS_COMPAT,TI_status(%rcx)
 548         jmp   retint_swapgs
 549
 550         /* Either reschedule or signal or syscall exit tracking needed. */
 551         /* First do a reschedule test. */
 552         /* edx: work, edi: workmask */
 553 int_careful:
 554         bt $TIF_NEED_RESCHED,%edx
 555         jnc  int_very_careful
 556         TRACE_IRQS_ON
 557         ENABLE_INTERRUPTS(CLBR_NONE)
 558         pushq_cfi %rdi
 559         SCHEDULE_USER
 560         popq_cfi %rdi
 561         DISABLE_INTERRUPTS(CLBR_NONE)
 562         TRACE_IRQS_OFF
 563         jmp int_with_check
 564
 565         /* handle signals and tracing -- both require a full stack frame */
 566 int_very_careful:
 567         TRACE_IRQS_ON
 568         ENABLE_INTERRUPTS(CLBR_NONE)
 569 int_check_syscall_exit_work:
 570         SAVE_REST
 571         /* Check for syscall exit trace */
 572         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 573         jz int_signal
 574         pushq_cfi %rdi
 575         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 576         call syscall_trace_leave
 577         popq_cfi %rdi
 578         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 579         jmp int_restore_rest
 580
 581 int_signal:
 582         testl $_TIF_DO_NOTIFY_MASK,%edx
 583         jz 1f
 584         movq %rsp,%rdi          # &ptregs -> arg1
 585         xorl %esi,%esi          # oldset -> arg2
 586         call do_notify_resume
 587 1:      movl $_TIF_WORK_MASK,%edi
 588 int_restore_rest:
 589         RESTORE_REST
 590         DISABLE_INTERRUPTS(CLBR_NONE)
 591         TRACE_IRQS_OFF
 592         jmp int_with_check
 593         CFI_ENDPROC
 594 END(system_call)
 595
 596         .macro FORK_LIKE func
 597 ENTRY(stub_\func)
 598         CFI_STARTPROC
 599         popq    %r11                    /* save return address */
 600         PARTIAL_FRAME 0
 601         SAVE_REST
 602         pushq   %r11                    /* put it back on stack */
 603         FIXUP_TOP_OF_STACK %r11, 8
 604         DEFAULT_FRAME 0 8               /* offset 8: return address */
 605         call sys_\func
 606         RESTORE_TOP_OF_STACK %r11, 8
 607         ret $REST_SKIP          /* pop extended registers */
 608         CFI_ENDPROC
 609 END(stub_\func)
 610         .endm
 611
 612         .macro FIXED_FRAME label,func
 613 ENTRY(\label)
 614         CFI_STARTPROC
 615         PARTIAL_FRAME 0 8               /* offset 8: return address */
 616         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 617         call \func
 618         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 619         ret
 620         CFI_ENDPROC
 621 END(\label)
 622         .endm
 623
 624         FORK_LIKE  clone
 625         FORK_LIKE  fork
 626         FORK_LIKE  vfork
 627         FIXED_FRAME stub_iopl, sys_iopl
 628
 629 ENTRY(ptregscall_common)
 630         DEFAULT_FRAME 1 8       /* offset 8: return address */
 631         RESTORE_TOP_OF_STACK %r11, 8
 632         movq_cfi_restore R15+8, r15
 633         movq_cfi_restore R14+8, r14
 634         movq_cfi_restore R13+8, r13
 635         movq_cfi_restore R12+8, r12
 636         movq_cfi_restore RBP+8, rbp
 637         movq_cfi_restore RBX+8, rbx
 638         ret $REST_SKIP          /* pop extended registers */
 639         CFI_ENDPROC
 640 END(ptregscall_common)
 641
 642 ENTRY(stub_execve)
 643         CFI_STARTPROC
 644         addq $8, %rsp
 645         PARTIAL_FRAME 0
 646         SAVE_REST
 647         FIXUP_TOP_OF_STACK %r11
 648         call sys_execve
 649         movq %rax,RAX(%rsp)
 650         RESTORE_REST
 651         jmp int_ret_from_sys_call
 652         CFI_ENDPROC
 653 END(stub_execve)
 654
 655 /*
 656  * sigreturn is special because it needs to restore all registers on return.
 657  * This cannot be done with SYSRET, so use the IRET return path instead.
 658  */
 659 ENTRY(stub_rt_sigreturn)
 660         CFI_STARTPROC
 661         addq $8, %rsp
 662         PARTIAL_FRAME 0
 663         SAVE_REST
 664         FIXUP_TOP_OF_STACK %r11
 665         call sys_rt_sigreturn
 666         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 667         RESTORE_REST
 668         jmp int_ret_from_sys_call
 669         CFI_ENDPROC
 670 END(stub_rt_sigreturn)
 671
 672 #ifdef CONFIG_X86_X32_ABI
 673 ENTRY(stub_x32_rt_sigreturn)
 674         CFI_STARTPROC
 675         addq $8, %rsp
 676         PARTIAL_FRAME 0
 677         SAVE_REST
 678         FIXUP_TOP_OF_STACK %r11
 679         call sys32_x32_rt_sigreturn
 680         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 681         RESTORE_REST
 682         jmp int_ret_from_sys_call
 683         CFI_ENDPROC
 684 END(stub_x32_rt_sigreturn)
 685
 686 ENTRY(stub_x32_execve)
 687         CFI_STARTPROC
 688         addq $8, %rsp
 689         PARTIAL_FRAME 0
 690         SAVE_REST
 691         FIXUP_TOP_OF_STACK %r11
 692         call compat_sys_execve
 693         RESTORE_TOP_OF_STACK %r11
 694         movq %rax,RAX(%rsp)
 695         RESTORE_REST
 696         jmp int_ret_from_sys_call
 697         CFI_ENDPROC
 698 END(stub_x32_execve)
 699
 700 #endif
 701
 702 /*
 703  * Build the entry stubs and pointer table with some assembler magic.
 704  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 705  * single cache line on all modern x86 implementations.
 706  */
 707         .section .init.rodata,"a"
 708 ENTRY(interrupt)
 709         .section .entry.text
 710         .p2align 5
 711         .p2align CONFIG_X86_L1_CACHE_SHIFT
 712 ENTRY(irq_entries_start)
 713         INTR_FRAME
 714 vector=FIRST_EXTERNAL_VECTOR
 715 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 716         .balign 32
 717   .rept 7
 718     .if vector < NR_VECTORS
 719       .if vector <> FIRST_EXTERNAL_VECTOR
 720         CFI_ADJUST_CFA_OFFSET -8
 721       .endif
 722 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 723       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 724         jmp 2f
 725       .endif
 726       .previous
 727         .quad 1b
 728       .section .entry.text
 729 vector=vector+1
 730     .endif
 731   .endr
 732 2:      jmp common_interrupt
 733 .endr
 734         CFI_ENDPROC
 735 END(irq_entries_start)
 736
 737 .previous
 738 END(interrupt)
 739 .previous
 740
 741 /*
 742  * Interrupt entry/exit.
 743  *
 744  * Interrupt entry points save only callee clobbered registers in fast path.
 745  *
 746  * Entry runs with interrupts off.
 747  */
 748
 749 /* 0(%rsp): ~(interrupt number) */
 750         .macro interrupt func
 751         /* reserve pt_regs for scratch regs and rbp */
 752         subq $ORIG_RAX-RBP, %rsp
 753         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 754         SAVE_ARGS_IRQ
 755         call \func
 756         .endm
 757
 758         /*
 759          * The interrupt stubs push (~vector+0x80) onto the stack and
 760          * then jump to common_interrupt.
 761          */
 762         .p2align CONFIG_X86_L1_CACHE_SHIFT
 763 common_interrupt:
 764         XCPT_FRAME
 765         ASM_CLAC
 766         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 767         interrupt do_IRQ
 768         /* 0(%rsp): old_rsp-ARGOFFSET */
 769 ret_from_intr:
 770         DISABLE_INTERRUPTS(CLBR_NONE)
 771         TRACE_IRQS_OFF
 772         decl PER_CPU_VAR(irq_count)
 773
 774         /* Restore saved previous stack */
 775         popq %rsi
 776         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 777         leaq ARGOFFSET-RBP(%rsi), %rsp
 778         CFI_DEF_CFA_REGISTER    rsp
 779         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 780
 781 exit_intr:
 782         GET_THREAD_INFO(%rcx)
 783         testl $3,CS-ARGOFFSET(%rsp)
 784         je retint_kernel
 785
 786         /* Interrupt came from user space */
 787         /*
 788          * Has a correct top of stack, but a partial stack frame
 789          * %rcx: thread info. Interrupts off.
 790          */
 791 retint_with_reschedule:
 792         movl $_TIF_WORK_MASK,%edi
 793 retint_check:
 794         LOCKDEP_SYS_EXIT_IRQ
 795         movl TI_flags(%rcx),%edx
 796         andl %edi,%edx
 797         CFI_REMEMBER_STATE
 798         jnz  retint_careful
 799
 800 retint_swapgs:          /* return to user-space */
 801         /*
 802          * The iretq could re-enable interrupts:
 803          */
 804         DISABLE_INTERRUPTS(CLBR_ANY)
 805         TRACE_IRQS_IRETQ
 806         SWAPGS
 807         jmp restore_args
 808
 809 retint_restore_args:    /* return to kernel space */
 810         DISABLE_INTERRUPTS(CLBR_ANY)
 811         /*
 812          * The iretq could re-enable interrupts:
 813          */
 814         TRACE_IRQS_IRETQ
 815 restore_args:
 816         RESTORE_ARGS 1,8,1
 817
 818 irq_return:
 819         INTERRUPT_RETURN
 820
 821 ENTRY(native_iret)
 822         /*
 823          * Are we returning to a stack segment from the LDT?  Note: in
 824          * 64-bit mode SS:RSP on the exception stack is always valid.
 825          */
 826 #ifdef CONFIG_X86_ESPFIX64
 827         testb $4,(SS-RIP)(%rsp)
 828         jnz native_irq_return_ldt
 829 #endif
 830
 831 .global native_irq_return_iret
 832 native_irq_return_iret:
 833         /*
 834          * This may fault.  Non-paranoid faults on return to userspace are
 835          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 836          * Double-faults due to espfix64 are handled in do_double_fault.
 837          * Other faults here are fatal.
 838          */
 839         iretq
 840
 841 #ifdef CONFIG_X86_ESPFIX64
 842 native_irq_return_ldt:
 843         pushq_cfi %rax
 844         pushq_cfi %rdi
 845         SWAPGS
 846         movq PER_CPU_VAR(espfix_waddr),%rdi
 847         movq %rax,(0*8)(%rdi)   /* RAX */
 848         movq (2*8)(%rsp),%rax   /* RIP */
 849         movq %rax,(1*8)(%rdi)
 850         movq (3*8)(%rsp),%rax   /* CS */
 851         movq %rax,(2*8)(%rdi)
 852         movq (4*8)(%rsp),%rax   /* RFLAGS */
 853         movq %rax,(3*8)(%rdi)
 854         movq (6*8)(%rsp),%rax   /* SS */
 855         movq %rax,(5*8)(%rdi)
 856         movq (5*8)(%rsp),%rax   /* RSP */
 857         movq %rax,(4*8)(%rdi)
 858         andl $0xffff0000,%eax
 859         popq_cfi %rdi
 860         orq PER_CPU_VAR(espfix_stack),%rax
 861         SWAPGS
 862         movq %rax,%rsp
 863         popq_cfi %rax
 864         jmp native_irq_return_iret
 865 #endif
 866
 867         /* edi: workmask, edx: work */
 868 retint_careful:
 869         CFI_RESTORE_STATE
 870         bt    $TIF_NEED_RESCHED,%edx
 871         jnc   retint_signal
 872         TRACE_IRQS_ON
 873         ENABLE_INTERRUPTS(CLBR_NONE)
 874         pushq_cfi %rdi
 875         SCHEDULE_USER
 876         popq_cfi %rdi
 877         GET_THREAD_INFO(%rcx)
 878         DISABLE_INTERRUPTS(CLBR_NONE)
 879         TRACE_IRQS_OFF
 880         jmp retint_check
 881
 882 retint_signal:
 883         testl $_TIF_DO_NOTIFY_MASK,%edx
 884         jz    retint_swapgs
 885         TRACE_IRQS_ON
 886         ENABLE_INTERRUPTS(CLBR_NONE)
 887         SAVE_REST
 888         movq $-1,ORIG_RAX(%rsp)
 889         xorl %esi,%esi          # oldset
 890         movq %rsp,%rdi          # &pt_regs
 891         call do_notify_resume
 892         RESTORE_REST
 893         DISABLE_INTERRUPTS(CLBR_NONE)
 894         TRACE_IRQS_OFF
 895         GET_THREAD_INFO(%rcx)
 896         jmp retint_with_reschedule
 897
 898 #ifdef CONFIG_PREEMPT
 899         /* Returning to kernel space. Check if we need preemption */
 900         /* rcx:  threadinfo. interrupts off. */
 901 ENTRY(retint_kernel)
 902         cmpl $0,PER_CPU_VAR(__preempt_count)
 903         jnz  retint_restore_args
 904         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 905         jnc  retint_restore_args
 906         call preempt_schedule_irq
 907         jmp exit_intr
 908 #endif
 909         CFI_ENDPROC
 910 END(common_interrupt)
 911
 912 /*
 913  * APIC interrupts.
 914  */
 915 .macro apicinterrupt3 num sym do_sym
 916 ENTRY(\sym)
 917         INTR_FRAME
 918         ASM_CLAC
 919         pushq_cfi $~(\num)
 920 .Lcommon_\sym:
 921         interrupt \do_sym
 922         jmp ret_from_intr
 923         CFI_ENDPROC
 924 END(\sym)
 925 .endm
 926
 927 #ifdef CONFIG_TRACING
 928 #define trace(sym) trace_##sym
 929 #define smp_trace(sym) smp_trace_##sym
 930
 931 .macro trace_apicinterrupt num sym
 932 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
 933 .endm
 934 #else
 935 .macro trace_apicinterrupt num sym do_sym
 936 .endm
 937 #endif
 938
 939 .macro apicinterrupt num sym do_sym
 940 apicinterrupt3 \num \sym \do_sym
 941 trace_apicinterrupt \num \sym
 942 .endm
 943
 944 #ifdef CONFIG_SMP
 945 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
 946         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 947 apicinterrupt3 REBOOT_VECTOR \
 948         reboot_interrupt smp_reboot_interrupt
 949 #endif
 950
 951 #ifdef CONFIG_X86_UV
 952 apicinterrupt3 UV_BAU_MESSAGE \
 953         uv_bau_message_intr1 uv_bau_message_interrupt
 954 #endif
 955 apicinterrupt LOCAL_TIMER_VECTOR \
 956         apic_timer_interrupt smp_apic_timer_interrupt
 957 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 958         x86_platform_ipi smp_x86_platform_ipi
 959
 960 #ifdef CONFIG_HAVE_KVM
 961 apicinterrupt3 POSTED_INTR_VECTOR \
 962         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
 963 #endif
 964
 965 #ifdef CONFIG_X86_MCE_THRESHOLD
 966 apicinterrupt THRESHOLD_APIC_VECTOR \
 967         threshold_interrupt smp_threshold_interrupt
 968 #endif
 969
 970 #ifdef CONFIG_X86_THERMAL_VECTOR
 971 apicinterrupt THERMAL_APIC_VECTOR \
 972         thermal_interrupt smp_thermal_interrupt
 973 #endif
 974
 975 #ifdef CONFIG_SMP
 976 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
 977         call_function_single_interrupt smp_call_function_single_interrupt
 978 apicinterrupt CALL_FUNCTION_VECTOR \
 979         call_function_interrupt smp_call_function_interrupt
 980 apicinterrupt RESCHEDULE_VECTOR \
 981         reschedule_interrupt smp_reschedule_interrupt
 982 #endif
 983
 984 apicinterrupt ERROR_APIC_VECTOR \
 985         error_interrupt smp_error_interrupt
 986 apicinterrupt SPURIOUS_APIC_VECTOR \
 987         spurious_interrupt smp_spurious_interrupt
 988
 989 #ifdef CONFIG_IRQ_WORK
 990 apicinterrupt IRQ_WORK_VECTOR \
 991         irq_work_interrupt smp_irq_work_interrupt
 992 #endif
 993
 994 /*
 995  * Exception entry points.
 996  */
 997 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
 998
 999 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
1000 ENTRY(\sym)
1001         /* Sanity check */
1002         .if \shift_ist != -1 && \paranoid == 0
1003         .error "using shift_ist requires paranoid=1"
1004         .endif
1005
1006         .if \has_error_code
1007         XCPT_FRAME
1008         .else
1009         INTR_FRAME
1010         .endif
1011
1012         ASM_CLAC
1013         PARAVIRT_ADJUST_EXCEPTION_FRAME
1014
1015         .ifeq \has_error_code
1016         pushq_cfi $-1                   /* ORIG_RAX: no syscall to restart */
1017         .endif
1018
1019         subq $ORIG_RAX-R15, %rsp
1020         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1021
1022         .if \paranoid
1023         call save_paranoid
1024         .else
1025         call error_entry
1026         .endif
1027
1028         DEFAULT_FRAME 0
1029
1030         .if \paranoid
1031         .if \shift_ist != -1
1032         TRACE_IRQS_OFF_DEBUG            /* reload IDT in case of recursion */
1033         .else
1034         TRACE_IRQS_OFF
1035         .endif
1036         .endif
1037
1038         movq %rsp,%rdi                  /* pt_regs pointer */
1039
1040         .if \has_error_code
1041         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1042         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1043         .else
1044         xorl %esi,%esi                  /* no error code */
1045         .endif
1046
1047         .if \shift_ist != -1
1048         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1049         .endif
1050
1051         call \do_sym
1052
1053         .if \shift_ist != -1
1054         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1055         .endif
1056
1057         .if \paranoid
1058         jmp paranoid_exit               /* %ebx: no swapgs flag */
1059         .else
1060         jmp error_exit                  /* %ebx: no swapgs flag */
1061         .endif
1062
1063         CFI_ENDPROC
1064 END(\sym)
1065 .endm
1066
1067 #ifdef CONFIG_TRACING
1068 .macro trace_idtentry sym do_sym has_error_code:req
1069 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
1070 idtentry \sym \do_sym has_error_code=\has_error_code
1071 .endm
1072 #else
1073 .macro trace_idtentry sym do_sym has_error_code:req
1074 idtentry \sym \do_sym has_error_code=\has_error_code
1075 .endm
1076 #endif
1077
1078 idtentry divide_error do_divide_error has_error_code=0
1079 idtentry overflow do_overflow has_error_code=0
1080 idtentry bounds do_bounds has_error_code=0
1081 idtentry invalid_op do_invalid_op has_error_code=0
1082 idtentry device_not_available do_device_not_available has_error_code=0
1083 idtentry double_fault do_double_fault has_error_code=1 paranoid=1
1084 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1085 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1086 idtentry segment_not_present do_segment_not_present has_error_code=1
1087 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1088 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1089 idtentry alignment_check do_alignment_check has_error_code=1
1090 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1091
1092
1093         /* Reload gs selector with exception handling */
1094         /* edi:  new selector */
1095 ENTRY(native_load_gs_index)
1096         CFI_STARTPROC
1097         pushfq_cfi
1098         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1099         SWAPGS
1100 gs_change:
1101         movl %edi,%gs
1102 2:      mfence          /* workaround */
1103         SWAPGS
1104         popfq_cfi
1105         ret
1106         CFI_ENDPROC
1107 END(native_load_gs_index)
1108
1109         _ASM_EXTABLE(gs_change,bad_gs)
1110         .section .fixup,"ax"
1111         /* running with kernelgs */
1112 bad_gs:
1113         SWAPGS                  /* switch back to user gs */
1114         xorl %eax,%eax
1115         movl %eax,%gs
1116         jmp  2b
1117         .previous
1118
1119 /* Call softirq on interrupt stack. Interrupts are off. */
1120 ENTRY(do_softirq_own_stack)
1121         CFI_STARTPROC
1122         pushq_cfi %rbp
1123         CFI_REL_OFFSET rbp,0
1124         mov  %rsp,%rbp
1125         CFI_DEF_CFA_REGISTER rbp
1126         incl PER_CPU_VAR(irq_count)
1127         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1128         push  %rbp                      # backlink for old unwinder
1129         call __do_softirq
1130         leaveq
1131         CFI_RESTORE             rbp
1132         CFI_DEF_CFA_REGISTER    rsp
1133         CFI_ADJUST_CFA_OFFSET   -8
1134         decl PER_CPU_VAR(irq_count)
1135         ret
1136         CFI_ENDPROC
1137 END(do_softirq_own_stack)
1138
1139 #ifdef CONFIG_XEN
1140 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1141
1142 /*
1143  * A note on the "critical region" in our callback handler.
1144  * We want to avoid stacking callback handlers due to events occurring
1145  * during handling of the last event. To do this, we keep events disabled
1146  * until we've done all processing. HOWEVER, we must enable events before
1147  * popping the stack frame (can't be done atomically) and so it would still
1148  * be possible to get enough handler activations to overflow the stack.
1149  * Although unlikely, bugs of that kind are hard to track down, so we'd
1150  * like to avoid the possibility.
1151  * So, on entry to the handler we detect whether we interrupted an
1152  * existing activation in its critical region -- if so, we pop the current
1153  * activation and restart the handler using the previous one.
1154  */
1155 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1156         CFI_STARTPROC
1157 /*
1158  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1159  * see the correct pointer to the pt_regs
1160  */
1161         movq %rdi, %rsp            # we don't return, adjust the stack frame
1162         CFI_ENDPROC
1163         DEFAULT_FRAME
1164 11:     incl PER_CPU_VAR(irq_count)
1165         movq %rsp,%rbp
1166         CFI_DEF_CFA_REGISTER rbp
1167         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1168         pushq %rbp                      # backlink for old unwinder
1169         call xen_evtchn_do_upcall
1170         popq %rsp
1171         CFI_DEF_CFA_REGISTER rsp
1172         decl PER_CPU_VAR(irq_count)
1173         jmp  error_exit
1174         CFI_ENDPROC
1175 END(xen_do_hypervisor_callback)
1176
1177 /*
1178  * Hypervisor uses this for application faults while it executes.
1179  * We get here for two reasons:
1180  *  1. Fault while reloading DS, ES, FS or GS
1181  *  2. Fault while executing IRET
1182  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1183  * registers that could be reloaded and zeroed the others.
1184  * Category 2 we fix up by killing the current process. We cannot use the
1185  * normal Linux return path in this case because if we use the IRET hypercall
1186  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1187  * We distinguish between categories by comparing each saved segment register
1188  * with its current contents: any discrepancy means we in category 1.
1189  */
1190 ENTRY(xen_failsafe_callback)
1191         INTR_FRAME 1 (6*8)
1192         /*CFI_REL_OFFSET gs,GS*/
1193         /*CFI_REL_OFFSET fs,FS*/
1194         /*CFI_REL_OFFSET es,ES*/
1195         /*CFI_REL_OFFSET ds,DS*/
1196         CFI_REL_OFFSET r11,8
1197         CFI_REL_OFFSET rcx,0
1198         movw %ds,%cx
1199         cmpw %cx,0x10(%rsp)
1200         CFI_REMEMBER_STATE
1201         jne 1f
1202         movw %es,%cx
1203         cmpw %cx,0x18(%rsp)
1204         jne 1f
1205         movw %fs,%cx
1206         cmpw %cx,0x20(%rsp)
1207         jne 1f
1208         movw %gs,%cx
1209         cmpw %cx,0x28(%rsp)
1210         jne 1f
1211         /* All segments match their saved values => Category 2 (Bad IRET). */
1212         movq (%rsp),%rcx
1213         CFI_RESTORE rcx
1214         movq 8(%rsp),%r11
1215         CFI_RESTORE r11
1216         addq $0x30,%rsp
1217         CFI_ADJUST_CFA_OFFSET -0x30
1218         pushq_cfi $0    /* RIP */
1219         pushq_cfi %r11
1220         pushq_cfi %rcx
1221         jmp general_protection
1222         CFI_RESTORE_STATE
1223 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1224         movq (%rsp),%rcx
1225         CFI_RESTORE rcx
1226         movq 8(%rsp),%r11
1227         CFI_RESTORE r11
1228         addq $0x30,%rsp
1229         CFI_ADJUST_CFA_OFFSET -0x30
1230         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1231         SAVE_ALL
1232         jmp error_exit
1233         CFI_ENDPROC
1234 END(xen_failsafe_callback)
1235
1236 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1237         xen_hvm_callback_vector xen_evtchn_do_upcall
1238
1239 #endif /* CONFIG_XEN */
1240
1241 #if IS_ENABLED(CONFIG_HYPERV)
1242 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1243         hyperv_callback_vector hyperv_vector_handler
1244 #endif /* CONFIG_HYPERV */
1245
1246 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1247 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1248 idtentry stack_segment do_stack_segment has_error_code=1
1249 #ifdef CONFIG_XEN
1250 idtentry xen_debug do_debug has_error_code=0
1251 idtentry xen_int3 do_int3 has_error_code=0
1252 idtentry xen_stack_segment do_stack_segment has_error_code=1
1253 #endif
1254 idtentry general_protection do_general_protection has_error_code=1
1255 trace_idtentry page_fault do_page_fault has_error_code=1
1256 #ifdef CONFIG_KVM_GUEST
1257 idtentry async_page_fault do_async_page_fault has_error_code=1
1258 #endif
1259 #ifdef CONFIG_X86_MCE
1260 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1261 #endif
1262
1263         /*
1264          * "Paranoid" exit path from exception stack.
1265          * Paranoid because this is used by NMIs and cannot take
1266          * any kernel state for granted.
1267          * We don't do kernel preemption checks here, because only
1268          * NMI should be common and it does not enable IRQs and
1269          * cannot get reschedule ticks.
1270          *
1271          * "trace" is 0 for the NMI handler only, because irq-tracing
1272          * is fundamentally NMI-unsafe. (we cannot change the soft and
1273          * hard flags at once, atomically)
1274          */
1275
1276         /* ebx: no swapgs flag */
1277 ENTRY(paranoid_exit)
1278         DEFAULT_FRAME
1279         DISABLE_INTERRUPTS(CLBR_NONE)
1280         TRACE_IRQS_OFF_DEBUG
1281         testl %ebx,%ebx                         /* swapgs needed? */
1282         jnz paranoid_restore
1283         testl $3,CS(%rsp)
1284         jnz   paranoid_userspace
1285 paranoid_swapgs:
1286         TRACE_IRQS_IRETQ 0
1287         SWAPGS_UNSAFE_STACK
1288         RESTORE_ALL 8
1289         jmp irq_return
1290 paranoid_restore:
1291         TRACE_IRQS_IRETQ_DEBUG 0
1292         RESTORE_ALL 8
1293         jmp irq_return
1294 paranoid_userspace:
1295         GET_THREAD_INFO(%rcx)
1296         movl TI_flags(%rcx),%ebx
1297         andl $_TIF_WORK_MASK,%ebx
1298         jz paranoid_swapgs
1299         movq %rsp,%rdi                  /* &pt_regs */
1300         call sync_regs
1301         movq %rax,%rsp                  /* switch stack for scheduling */
1302         testl $_TIF_NEED_RESCHED,%ebx
1303         jnz paranoid_schedule
1304         movl %ebx,%edx                  /* arg3: thread flags */
1305         TRACE_IRQS_ON
1306         ENABLE_INTERRUPTS(CLBR_NONE)
1307         xorl %esi,%esi                  /* arg2: oldset */
1308         movq %rsp,%rdi                  /* arg1: &pt_regs */
1309         call do_notify_resume
1310         DISABLE_INTERRUPTS(CLBR_NONE)
1311         TRACE_IRQS_OFF
1312         jmp paranoid_userspace
1313 paranoid_schedule:
1314         TRACE_IRQS_ON
1315         ENABLE_INTERRUPTS(CLBR_ANY)
1316         SCHEDULE_USER
1317         DISABLE_INTERRUPTS(CLBR_ANY)
1318         TRACE_IRQS_OFF
1319         jmp paranoid_userspace
1320         CFI_ENDPROC
1321 END(paranoid_exit)
1322
1323 /*
1324  * Exception entry point. This expects an error code/orig_rax on the stack.
1325  * returns in "no swapgs flag" in %ebx.
1326  */
1327 ENTRY(error_entry)
1328         XCPT_FRAME
1329         CFI_ADJUST_CFA_OFFSET 15*8
1330         /* oldrax contains error code */
1331         cld
1332         movq %rdi, RDI+8(%rsp)
1333         movq %rsi, RSI+8(%rsp)
1334         movq %rdx, RDX+8(%rsp)
1335         movq %rcx, RCX+8(%rsp)
1336         movq %rax, RAX+8(%rsp)
1337         movq  %r8,  R8+8(%rsp)
1338         movq  %r9,  R9+8(%rsp)
1339         movq %r10, R10+8(%rsp)
1340         movq %r11, R11+8(%rsp)
1341         movq_cfi rbx, RBX+8
1342         movq %rbp, RBP+8(%rsp)
1343         movq %r12, R12+8(%rsp)
1344         movq %r13, R13+8(%rsp)
1345         movq %r14, R14+8(%rsp)
1346         movq %r15, R15+8(%rsp)
1347         xorl %ebx,%ebx
1348         testl $3,CS+8(%rsp)
1349         je error_kernelspace
1350 error_swapgs:
1351         SWAPGS
1352 error_sti:
1353         TRACE_IRQS_OFF
1354         ret
1355
1356 /*
1357  * There are two places in the kernel that can potentially fault with
1358  * usergs. Handle them here.  B stepping K8s sometimes report a
1359  * truncated RIP for IRET exceptions returning to compat mode. Check
1360  * for these here too.
1361  */
1362 error_kernelspace:
1363         CFI_REL_OFFSET rcx, RCX+8
1364         incl %ebx
1365         leaq native_irq_return_iret(%rip),%rcx
1366         cmpq %rcx,RIP+8(%rsp)
1367         je error_bad_iret
1368         movl %ecx,%eax  /* zero extend */
1369         cmpq %rax,RIP+8(%rsp)
1370         je bstep_iret
1371         cmpq $gs_change,RIP+8(%rsp)
1372         je error_swapgs
1373         jmp error_sti
1374
1375 bstep_iret:
1376         /* Fix truncated RIP */
1377         movq %rcx,RIP+8(%rsp)
1378         /* fall through */
1379
1380 error_bad_iret:
1381         SWAPGS
1382         mov %rsp,%rdi
1383         call fixup_bad_iret
1384         mov %rax,%rsp
1385         decl %ebx       /* Return to usergs */
1386         jmp error_sti
1387         CFI_ENDPROC
1388 END(error_entry)
1389
1390
1391 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1392 ENTRY(error_exit)
1393         DEFAULT_FRAME
1394         movl %ebx,%eax
1395         RESTORE_REST
1396         DISABLE_INTERRUPTS(CLBR_NONE)
1397         TRACE_IRQS_OFF
1398         GET_THREAD_INFO(%rcx)
1399         testl %eax,%eax
1400         jne retint_kernel
1401         LOCKDEP_SYS_EXIT_IRQ
1402         movl TI_flags(%rcx),%edx
1403         movl $_TIF_WORK_MASK,%edi
1404         andl %edi,%edx
1405         jnz retint_careful
1406         jmp retint_swapgs
1407         CFI_ENDPROC
1408 END(error_exit)
1409
1410 /*
1411  * Test if a given stack is an NMI stack or not.
1412  */
1413         .macro test_in_nmi reg stack nmi_ret normal_ret
1414         cmpq %\reg, \stack
1415         ja \normal_ret
1416         subq $EXCEPTION_STKSZ, %\reg
1417         cmpq %\reg, \stack
1418         jb \normal_ret
1419         jmp \nmi_ret
1420         .endm
1421
1422         /* runs on exception stack */
1423 ENTRY(nmi)
1424         INTR_FRAME
1425         PARAVIRT_ADJUST_EXCEPTION_FRAME
1426         /*
1427          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1428          * the iretq it performs will take us out of NMI context.
1429          * This means that we can have nested NMIs where the next
1430          * NMI is using the top of the stack of the previous NMI. We
1431          * can't let it execute because the nested NMI will corrupt the
1432          * stack of the previous NMI. NMI handlers are not re-entrant
1433          * anyway.
1434          *
1435          * To handle this case we do the following:
1436          *  Check the a special location on the stack that contains
1437          *  a variable that is set when NMIs are executing.
1438          *  The interrupted task's stack is also checked to see if it
1439          *  is an NMI stack.
1440          *  If the variable is not set and the stack is not the NMI
1441          *  stack then:
1442          *    o Set the special variable on the stack
1443          *    o Copy the interrupt frame into a "saved" location on the stack
1444          *    o Copy the interrupt frame into a "copy" location on the stack
1445          *    o Continue processing the NMI
1446          *  If the variable is set or the previous stack is the NMI stack:
1447          *    o Modify the "copy" location to jump to the repeate_nmi
1448          *    o return back to the first NMI
1449          *
1450          * Now on exit of the first NMI, we first clear the stack variable
1451          * The NMI stack will tell any nested NMIs at that point that it is
1452          * nested. Then we pop the stack normally with iret, and if there was
1453          * a nested NMI that updated the copy interrupt stack frame, a
1454          * jump will be made to the repeat_nmi code that will handle the second
1455          * NMI.
1456          */
1457
1458         /* Use %rdx as out temp variable throughout */
1459         pushq_cfi %rdx
1460         CFI_REL_OFFSET rdx, 0
1461
1462         /*
1463          * If %cs was not the kernel segment, then the NMI triggered in user
1464          * space, which means it is definitely not nested.
1465          */
1466         cmpl $__KERNEL_CS, 16(%rsp)
1467         jne first_nmi
1468
1469         /*
1470          * Check the special variable on the stack to see if NMIs are
1471          * executing.
1472          */
1473         cmpl $1, -8(%rsp)
1474         je nested_nmi
1475
1476         /*
1477          * Now test if the previous stack was an NMI stack.
1478          * We need the double check. We check the NMI stack to satisfy the
1479          * race when the first NMI clears the variable before returning.
1480          * We check the variable because the first NMI could be in a
1481          * breakpoint routine using a breakpoint stack.
1482          */
1483         lea 6*8(%rsp), %rdx
1484         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1485         CFI_REMEMBER_STATE
1486
1487 nested_nmi:
1488         /*
1489          * Do nothing if we interrupted the fixup in repeat_nmi.
1490          * It's about to repeat the NMI handler, so we are fine
1491          * with ignoring this one.
1492          */
1493         movq $repeat_nmi, %rdx
1494         cmpq 8(%rsp), %rdx
1495         ja 1f
1496         movq $end_repeat_nmi, %rdx
1497         cmpq 8(%rsp), %rdx
1498         ja nested_nmi_out
1499
1500 1:
1501         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1502         leaq -1*8(%rsp), %rdx
1503         movq %rdx, %rsp
1504         CFI_ADJUST_CFA_OFFSET 1*8
1505         leaq -10*8(%rsp), %rdx
1506         pushq_cfi $__KERNEL_DS
1507         pushq_cfi %rdx
1508         pushfq_cfi
1509         pushq_cfi $__KERNEL_CS
1510         pushq_cfi $repeat_nmi
1511
1512         /* Put stack back */
1513         addq $(6*8), %rsp
1514         CFI_ADJUST_CFA_OFFSET -6*8
1515
1516 nested_nmi_out:
1517         popq_cfi %rdx
1518         CFI_RESTORE rdx
1519
1520         /* No need to check faults here */
1521         INTERRUPT_RETURN
1522
1523         CFI_RESTORE_STATE
1524 first_nmi:
1525         /*
1526          * Because nested NMIs will use the pushed location that we
1527          * stored in rdx, we must keep that space available.
1528          * Here's what our stack frame will look like:
1529          * +-------------------------+
1530          * | original SS             |
1531          * | original Return RSP     |
1532          * | original RFLAGS         |
1533          * | original CS             |
1534          * | original RIP            |
1535          * +-------------------------+
1536          * | temp storage for rdx    |
1537          * +-------------------------+
1538          * | NMI executing variable  |
1539          * +-------------------------+
1540          * | copied SS               |
1541          * | copied Return RSP       |
1542          * | copied RFLAGS           |
1543          * | copied CS               |
1544          * | copied RIP              |
1545          * +-------------------------+
1546          * | Saved SS                |
1547          * | Saved Return RSP        |
1548          * | Saved RFLAGS            |
1549          * | Saved CS                |
1550          * | Saved RIP               |
1551          * +-------------------------+
1552          * | pt_regs                 |
1553          * +-------------------------+
1554          *
1555          * The saved stack frame is used to fix up the copied stack frame
1556          * that a nested NMI may change to make the interrupted NMI iret jump
1557          * to the repeat_nmi. The original stack frame and the temp storage
1558          * is also used by nested NMIs and can not be trusted on exit.
1559          */
1560         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1561         movq (%rsp), %rdx
1562         CFI_RESTORE rdx
1563
1564         /* Set the NMI executing variable on the stack. */
1565         pushq_cfi $1
1566
1567         /*
1568          * Leave room for the "copied" frame
1569          */
1570         subq $(5*8), %rsp
1571         CFI_ADJUST_CFA_OFFSET 5*8
1572
1573         /* Copy the stack frame to the Saved frame */
1574         .rept 5
1575         pushq_cfi 11*8(%rsp)
1576         .endr
1577         CFI_DEF_CFA_OFFSET SS+8-RIP
1578
1579         /* Everything up to here is safe from nested NMIs */
1580
1581         /*
1582          * If there was a nested NMI, the first NMI's iret will return
1583          * here. But NMIs are still enabled and we can take another
1584          * nested NMI. The nested NMI checks the interrupted RIP to see
1585          * if it is between repeat_nmi and end_repeat_nmi, and if so
1586          * it will just return, as we are about to repeat an NMI anyway.
1587          * This makes it safe to copy to the stack frame that a nested
1588          * NMI will update.
1589          */
1590 repeat_nmi:
1591         /*
1592          * Update the stack variable to say we are still in NMI (the update
1593          * is benign for the non-repeat case, where 1 was pushed just above
1594          * to this very stack slot).
1595          */
1596         movq $1, 10*8(%rsp)
1597
1598         /* Make another copy, this one may be modified by nested NMIs */
1599         addq $(10*8), %rsp
1600         CFI_ADJUST_CFA_OFFSET -10*8
1601         .rept 5
1602         pushq_cfi -6*8(%rsp)
1603         .endr
1604         subq $(5*8), %rsp
1605         CFI_DEF_CFA_OFFSET SS+8-RIP
1606 end_repeat_nmi:
1607
1608         /*
1609          * Everything below this point can be preempted by a nested
1610          * NMI if the first NMI took an exception and reset our iret stack
1611          * so that we repeat another NMI.
1612          */
1613         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1614         subq $ORIG_RAX-R15, %rsp
1615         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1616         /*
1617          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1618          * as we should not be calling schedule in NMI context.
1619          * Even with normal interrupts enabled. An NMI should not be
1620          * setting NEED_RESCHED or anything that normal interrupts and
1621          * exceptions might do.
1622          */
1623         call save_paranoid
1624         DEFAULT_FRAME 0
1625
1626         /*
1627          * Save off the CR2 register. If we take a page fault in the NMI then
1628          * it could corrupt the CR2 value. If the NMI preempts a page fault
1629          * handler before it was able to read the CR2 register, and then the
1630          * NMI itself takes a page fault, the page fault that was preempted
1631          * will read the information from the NMI page fault and not the
1632          * origin fault. Save it off and restore it if it changes.
1633          * Use the r12 callee-saved register.
1634          */
1635         movq %cr2, %r12
1636
1637         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1638         movq %rsp,%rdi
1639         movq $-1,%rsi
1640         call do_nmi
1641
1642         /* Did the NMI take a page fault? Restore cr2 if it did */
1643         movq %cr2, %rcx
1644         cmpq %rcx, %r12
1645         je 1f
1646         movq %r12, %cr2
1647 1:
1648
1649         testl %ebx,%ebx                         /* swapgs needed? */
1650         jnz nmi_restore
1651 nmi_swapgs:
1652         SWAPGS_UNSAFE_STACK
1653 nmi_restore:
1654         /* Pop the extra iret frame at once */
1655         RESTORE_ALL 6*8
1656
1657         /* Clear the NMI executing stack variable */
1658         movq $0, 5*8(%rsp)
1659         jmp irq_return
1660         CFI_ENDPROC
1661 END(nmi)
1662
1663 ENTRY(ignore_sysret)
1664         CFI_STARTPROC
1665         mov $-ENOSYS,%eax
1666         sysret
1667         CFI_ENDPROC
1668 END(ignore_sysret)
1669