arch/x86/power/hibernate_asm_64.S

   1 /*
   2  * Hibernation support for x86-64
   3  *
   4  * Distribute under GPLv2.
   5  *
   6  * Copyright 2007 Rafael J. Wysocki <rjw@sisk.pl>
   7  * Copyright 2005 Andi Kleen <ak@suse.de>
   8  * Copyright 2004 Pavel Machek <pavel@suse.cz>
   9  *
  10  * swsusp_arch_resume must not use any stack or any nonlocal variables while
  11  * copying pages:
  12  *
  13  * Its rewriting one kernel image with another. What is stack in "old"
  14  * image could very well be data page in "new" image, and overwriting
  15  * your own stack under you is bad idea.
  16  */
  17
  18         .text
  19 #include <linux/linkage.h>
  20 #include <asm/segment.h>
  21 #include <asm/page_types.h>
  22 #include <asm/asm-offsets.h>
  23 #include <asm/processor-flags.h>
  24 #include <asm/frame.h>
  25
  26 ENTRY(swsusp_arch_suspend)
  27         FRAME_BEGIN
  28         movq    $saved_context, %rax
  29         movq    %rsp, pt_regs_sp(%rax)
  30         movq    %rbp, pt_regs_bp(%rax)
  31         movq    %rsi, pt_regs_si(%rax)
  32         movq    %rdi, pt_regs_di(%rax)
  33         movq    %rbx, pt_regs_bx(%rax)
  34         movq    %rcx, pt_regs_cx(%rax)
  35         movq    %rdx, pt_regs_dx(%rax)
  36         movq    %r8, pt_regs_r8(%rax)
  37         movq    %r9, pt_regs_r9(%rax)
  38         movq    %r10, pt_regs_r10(%rax)
  39         movq    %r11, pt_regs_r11(%rax)
  40         movq    %r12, pt_regs_r12(%rax)
  41         movq    %r13, pt_regs_r13(%rax)
  42         movq    %r14, pt_regs_r14(%rax)
  43         movq    %r15, pt_regs_r15(%rax)
  44         pushfq
  45         popq    pt_regs_flags(%rax)
  46
  47         /* save the address of restore_registers */
  48         movq    $restore_registers, %rax
  49         movq    %rax, restore_jump_address(%rip)
  50         /* save cr3 */
  51         movq    %cr3, %rax
  52         movq    %rax, restore_cr3(%rip)
  53
  54         call swsusp_save
  55         FRAME_END
  56         ret
  57 ENDPROC(swsusp_arch_suspend)
  58
  59 ENTRY(restore_image)
  60         /* switch to temporary page tables */
  61         movq    $__PAGE_OFFSET, %rdx
  62         movq    temp_level4_pgt(%rip), %rax
  63         subq    %rdx, %rax
  64         movq    %rax, %cr3
  65         /* Flush TLB */
  66         movq    mmu_cr4_features(%rip), %rax
  67         movq    %rax, %rdx
  68         andq    $~(X86_CR4_PGE), %rdx
  69         movq    %rdx, %cr4;  # turn off PGE
  70         movq    %cr3, %rcx;  # flush TLB
  71         movq    %rcx, %cr3;
  72         movq    %rax, %cr4;  # turn PGE back on
  73
  74         /* prepare to jump to the image kernel */
  75         movq    restore_jump_address(%rip), %rax
  76         movq    restore_cr3(%rip), %rbx
  77
  78         /* prepare to copy image data to their original locations */
  79         movq    restore_pblist(%rip), %rdx
  80         movq    relocated_restore_code(%rip), %rcx
  81         jmpq    *%rcx
  82
  83         /* code below has been relocated to a safe page */
  84 ENTRY(core_restore_code)
  85 .Lloop:
  86         testq   %rdx, %rdx
  87         jz      .Ldone
  88
  89         /* get addresses from the pbe and copy the page */
  90         movq    pbe_address(%rdx), %rsi
  91         movq    pbe_orig_address(%rdx), %rdi
  92         movq    $(PAGE_SIZE >> 3), %rcx
  93         rep
  94         movsq
  95
  96         /* progress to the next pbe */
  97         movq    pbe_next(%rdx), %rdx
  98         jmp     .Lloop
  99 .Ldone:
 100         /* jump to the restore_registers address from the image header */
 101         jmpq    *%rax
 102         /*
 103          * NOTE: This assumes that the boot kernel's text mapping covers the
 104          * image kernel's page containing restore_registers and the address of
 105          * this page is the same as in the image kernel's text mapping (it
 106          * should always be true, because the text mapping is linear, starting
 107          * from 0, and is supposed to cover the entire kernel text for every
 108          * kernel).
 109          *
 110          * code below belongs to the image kernel
 111          */
 112
 113 ENTRY(restore_registers)
 114         FRAME_BEGIN
 115         /* go back to the original page tables */
 116         movq    %rbx, %cr3
 117
 118         /* Flush TLB, including "global" things (vmalloc) */
 119         movq    mmu_cr4_features(%rip), %rax
 120         movq    %rax, %rdx
 121         andq    $~(X86_CR4_PGE), %rdx
 122         movq    %rdx, %cr4;  # turn off PGE
 123         movq    %cr3, %rcx;  # flush TLB
 124         movq    %rcx, %cr3
 125         movq    %rax, %cr4;  # turn PGE back on
 126
 127         /* We don't restore %rax, it must be 0 anyway */
 128         movq    $saved_context, %rax
 129         movq    pt_regs_sp(%rax), %rsp
 130         movq    pt_regs_bp(%rax), %rbp
 131         movq    pt_regs_si(%rax), %rsi
 132         movq    pt_regs_di(%rax), %rdi
 133         movq    pt_regs_bx(%rax), %rbx
 134         movq    pt_regs_cx(%rax), %rcx
 135         movq    pt_regs_dx(%rax), %rdx
 136         movq    pt_regs_r8(%rax), %r8
 137         movq    pt_regs_r9(%rax), %r9
 138         movq    pt_regs_r10(%rax), %r10
 139         movq    pt_regs_r11(%rax), %r11
 140         movq    pt_regs_r12(%rax), %r12
 141         movq    pt_regs_r13(%rax), %r13
 142         movq    pt_regs_r14(%rax), %r14
 143         movq    pt_regs_r15(%rax), %r15
 144         pushq   pt_regs_flags(%rax)
 145         popfq
 146
 147         /* Saved in save_processor_state. */
 148         lgdt    saved_context_gdt_desc(%rax)
 149
 150         xorq    %rax, %rax
 151
 152         /* tell the hibernation core that we've just restored the memory */
 153         movq    %rax, in_suspend(%rip)
 154
 155         FRAME_END
 156         ret
 157 ENDPROC(restore_registers)