arch/x86/realmode/rm/trampoline_64.S

   1 /*
   2  *
   3  *      Trampoline.S    Derived from Setup.S by Linus Torvalds
   4  *
   5  *      4 Jan 1997 Michael Chastain: changed to gnu as.
   6  *      15 Sept 2005 Eric Biederman: 64bit PIC support
   7  *
   8  *      Entry: CS:IP point to the start of our code, we are
   9  *      in real mode with no stack, but the rest of the
  10  *      trampoline page to make our stack and everything else
  11  *      is a mystery.
  12  *
  13  *      On entry to trampoline_data, the processor is in real mode
  14  *      with 16-bit addressing and 16-bit data.  CS has some value
  15  *      and IP is zero.  Thus, data addresses need to be absolute
  16  *      (no relocation) and are taken with regard to r_base.
  17  *
  18  *      With the addition of trampoline_level4_pgt this code can
  19  *      now enter a 64bit kernel that lives at arbitrary 64bit
  20  *      physical addresses.
  21  *
  22  *      If you work on this file, check the object module with objdump
  23  *      --full-contents --reloc to make sure there are no relocation
  24  *      entries.
  25  */
  26
  27 #include <linux/linkage.h>
  28 #include <linux/init.h>
  29 #include <asm/pgtable_types.h>
  30 #include <asm/page_types.h>
  31 #include <asm/msr.h>
  32 #include <asm/segment.h>
  33 #include <asm/processor-flags.h>
  34 #include "realmode.h"
  35
  36         .text
  37         .balign PAGE_SIZE
  38         .code16
  39
  40 ENTRY(trampoline_data)
  41         cli                     # We should be safe anyway
  42         wbinvd
  43
  44         LJMPW_RM(1f)
  45 1:
  46         mov     %cs, %ax        # Code and data in the same place
  47         mov     %ax, %ds
  48         mov     %ax, %es
  49         mov     %ax, %ss
  50
  51         movl    $0xA5A5A5A5, trampoline_status
  52         # write marker for master knows we're running
  53
  54         # Setup stack
  55         movw    $trampoline_stack_end, %sp
  56
  57         call    verify_cpu              # Verify the cpu supports long mode
  58         testl   %eax, %eax              # Check for return code
  59         jnz     no_longmode
  60
  61         /*
  62          * GDT tables in non default location kernel can be beyond 16MB and
  63          * lgdt will not be able to load the address as in real mode default
  64          * operand size is 16bit. Use lgdtl instead to force operand size
  65          * to 32 bit.
  66          */
  67
  68         lidtl   tidt    # load idt with 0, 0
  69         lgdtl   tgdt    # load gdt with whatever is appropriate
  70
  71         mov     $X86_CR0_PE, %ax        # protected mode (PE) bit
  72         lmsw    %ax                     # into protected mode
  73
  74         # flush prefetch and jump to startup_32
  75         ljmpl   $__KERNEL32_CS, $pa_startup_32
  76
  77 no_longmode:
  78         hlt
  79         jmp no_longmode
  80 #include "../kernel/verify_cpu.S"
  81
  82         .section ".text32","ax"
  83         .code32
  84         .balign 4
  85 ENTRY(startup_32)
  86         movl    $__KERNEL_DS, %eax      # Initialize the %ds segment register
  87         movl    %eax, %ds
  88
  89         movl    $X86_CR4_PAE, %eax
  90         movl    %eax, %cr4              # Enable PAE mode
  91
  92         movl    pa_startup_64_smp, %esi
  93         movl    pa_startup_64_smp_high, %edi
  94
  95                                         # Setup trampoline 4 level pagetables
  96         leal    pa_trampoline_level4_pgt, %eax
  97         movl    %eax, %cr3
  98
  99         movl    $MSR_EFER, %ecx
 100         movl    $(1 << _EFER_LME), %eax # Enable Long Mode
 101         xorl    %edx, %edx
 102         wrmsr
 103
 104         # Enable paging and in turn activate Long Mode
 105         # Enable protected mode
 106         movl    $(X86_CR0_PG | X86_CR0_PE), %eax
 107         movl    %eax, %cr0
 108
 109         /*
 110          * At this point we're in long mode but in 32bit compatibility mode
 111          * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
 112          * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
 113          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 114          */
 115         ljmpl   $__KERNEL_CS, $pa_startup_64
 116
 117         .section ".text64","ax"
 118         .code64
 119         .balign 4
 120 ENTRY(startup_64)
 121         # Now jump into the kernel using virtual addresses
 122         movl    %edi, %eax
 123         shlq    $32, %rax
 124         addl    %esi, %eax
 125         jmp     *%rax
 126
 127         .section ".rodata","a"
 128         .balign 16
 129 tidt:
 130         .word   0                       # idt limit = 0
 131         .word   0, 0                    # idt base = 0L
 132
 133         # Duplicate the global descriptor table
 134         # so the kernel can live anywhere
 135         .balign 4
 136         .globl tgdt
 137 tgdt:
 138         .short  tgdt_end - tgdt         # gdt limit
 139         .long   pa_tgdt
 140         .short  0
 141         .quad   0x00cf9b000000ffff      # __KERNEL32_CS
 142         .quad   0x00af9b000000ffff      # __KERNEL_CS
 143         .quad   0x00cf93000000ffff      # __KERNEL_DS
 144 tgdt_end:
 145
 146         .data
 147         .balign 4
 148 GLOBAL(trampoline_status)
 149         .long   0
 150
 151 trampoline_stack:
 152         .org 0x1000
 153 trampoline_stack_end:
 154
 155         .globl  level3_ident_pgt
 156         .globl  level3_kernel_pgt
 157 GLOBAL(trampoline_level4_pgt)
 158         level3_ident_pgt:       .quad   0
 159         .fill 510,8,0
 160         level3_kernel_pgt:      .quad   0
 161
 162         .globl  startup_64_smp
 163         .globl  startup_64_smp_high
 164 startup_64_smp:         .long 0
 165 startup_64_smp_high:    .long 0