arch/x86/vdso/vdso-layout.lds.S

   1 #include <asm/vdso.h>
   2
   3 /*
   4  * Linker script for vDSO.  This is an ELF shared object prelinked to
   5  * its virtual address, and with only one read-only segment.
   6  * This script controls its layout.
   7  */
   8
   9 #if defined(BUILD_VDSO64)
  10 # define SHDR_SIZE 64
  11 #elif defined(BUILD_VDSO32) || defined(BUILD_VDSOX32)
  12 # define SHDR_SIZE 40
  13 #else
  14 # error unknown VDSO target
  15 #endif
  16
  17 #define NUM_FAKE_SHDRS 13
  18
  19 SECTIONS
  20 {
  21         . = SIZEOF_HEADERS;
  22
  23         .hash           : { *(.hash) }                  :text
  24         .gnu.hash       : { *(.gnu.hash) }
  25         .dynsym         : { *(.dynsym) }
  26         .dynstr         : { *(.dynstr) }
  27         .gnu.version    : { *(.gnu.version) }
  28         .gnu.version_d  : { *(.gnu.version_d) }
  29         .gnu.version_r  : { *(.gnu.version_r) }
  30
  31         .dynamic        : { *(.dynamic) }               :text   :dynamic
  32
  33         .rodata         : {
  34                 *(.rodata*)
  35                 *(.data*)
  36                 *(.sdata*)
  37                 *(.got.plt) *(.got)
  38                 *(.gnu.linkonce.d.*)
  39                 *(.bss*)
  40                 *(.dynbss*)
  41                 *(.gnu.linkonce.b.*)
  42
  43                 /*
  44                  * Ideally this would live in a C file, but that won't
  45                  * work cleanly for x32 until we start building the x32
  46                  * C code using an x32 toolchain.
  47                  */
  48                 VDSO_FAKE_SECTION_TABLE_START = .;
  49                 . = . + NUM_FAKE_SHDRS * SHDR_SIZE;
  50                 VDSO_FAKE_SECTION_TABLE_END = .;
  51         }                                               :text
  52
  53         .fake_shstrtab  : { *(.fake_shstrtab) }         :text
  54
  55
  56         .note           : { *(.note.*) }                :text   :note
  57
  58         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  59         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  60
  61
  62         /*
  63          * Text is well-separated from actual data: there's plenty of
  64          * stuff that isn't used at runtime in between.
  65          */
  66
  67         .text           : { *(.text*) }                 :text   =0x90909090,
  68
  69         /*
  70          * At the end so that eu-elflint stays happy when vdso2c strips
  71          * these.  A better implementation would avoid allocating space
  72          * for these.
  73          */
  74         .altinstructions        : { *(.altinstructions) }       :text
  75         .altinstr_replacement   : { *(.altinstr_replacement) }  :text
  76
  77         /*
  78          * The remainder of the vDSO consists of special pages that are
  79          * shared between the kernel and userspace.  It needs to be at the
  80          * end so that it doesn't overlap the mapping of the actual
  81          * vDSO image.
  82          */
  83
  84         . = ALIGN(PAGE_SIZE);
  85         vvar_page = .;
  86
  87         /* Place all vvars at the offsets in asm/vvar.h. */
  88 #define EMIT_VVAR(name, offset) vvar_ ## name = vvar_page + offset;
  89 #define __VVAR_KERNEL_LDS
  90 #include <asm/vvar.h>
  91 #undef __VVAR_KERNEL_LDS
  92 #undef EMIT_VVAR
  93
  94         . = vvar_page + PAGE_SIZE;
  95
  96         hpet_page = .;
  97         . = . + PAGE_SIZE;
  98
  99         . = ALIGN(PAGE_SIZE);
 100         end_mapping = .;
 101
 102         /DISCARD/ : {
 103                 *(.discard)
 104                 *(.discard.*)
 105                 *(__bug_table)
 106         }
 107 }
 108
 109 /*
 110  * Very old versions of ld do not recognize this name token; use the constant.
 111  */
 112 #define PT_GNU_EH_FRAME 0x6474e550
 113
 114 /*
 115  * We must supply the ELF program headers explicitly to get just one
 116  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 117  */
 118 PHDRS
 119 {
 120         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
 121         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
 122         note            PT_NOTE         FLAGS(4);               /* PF_R */
 123         eh_frame_hdr    PT_GNU_EH_FRAME;
 124 }