acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 14; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.14.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIB=-lintel_dpdk
 174
 175     ovs_save_CFLAGS="$CFLAGS"
 176     ovs_save_LDFLAGS="$LDFLAGS"
 177     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 178     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 179
 180     # On some systems we have to add -ldl to link with dpdk
 181     #
 182     # This code, at first, tries to link without -ldl (""),
 183     # then adds it and tries again.
 184     # Before each attempt the search cache must be unset,
 185     # otherwise autoconf will stick with the old result
 186
 187     found=false
 188     save_LIBS=$LIBS
 189     for extras in "" "-ldl"; do
 190         LIBS="$DPDK_LIB $extras $save_LIBS"
 191         AC_LINK_IFELSE(
 192            [AC_LANG_PROGRAM([#include <rte_config.h>
 193                              #include <rte_eal.h>],
 194                             [int rte_argc; char ** rte_argv;
 195                              rte_eal_init(rte_argc, rte_argv);])],
 196            [found=true])
 197         if $found; then
 198             break
 199         fi
 200     done
 201     if $found; then :; else
 202         AC_MSG_ERROR([cannot link with dpdk])
 203     fi
 204     CFLAGS="$ovs_save_CFLAGS"
 205     LDFLAGS="$ovs_save_LDFLAGS"
 206     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 207     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 208
 209     # DPDK 1.7.0 pmd drivers are not linked unless --whole-archive is used.
 210     #
 211     # This happens because the rest of the DPDK code doesn't use any symbol in
 212     # the pmd driver objects, and the drivers register themselves using an
 213     # __attribute__((constructor)) function.
 214     #
 215     # These options are specified inside a single -Wl directive to prevent
 216     # autotools from reordering them.
 217     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 218     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 219     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 220   else
 221     RTE_SDK=
 222   fi
 223
 224   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 225 ])
 226
 227 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 228 dnl
 229 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 230 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 231 dnl <REGEX> translated to uppercase.
 232 AC_DEFUN([OVS_GREP_IFELSE], [
 233   AC_MSG_CHECKING([whether $2 matches in $1])
 234   if test -f $1; then
 235     grep '$2' $1 >/dev/null 2>&1
 236     status=$?
 237     case $status in
 238       0)
 239         AC_MSG_RESULT([yes])
 240         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 241         ;;
 242       1)
 243         AC_MSG_RESULT([no])
 244         $4
 245         ;;
 246       *)
 247         AC_MSG_ERROR([grep exited with status $status])
 248         ;;
 249     esac
 250   else
 251     AC_MSG_RESULT([file not found])
 252     $4
 253   fi
 254 ])
 255
 256 dnl OVS_DEFINE(NAME)
 257 dnl
 258 dnl Defines NAME to 1 in kcompat.h.
 259 AC_DEFUN([OVS_DEFINE], [
 260   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 261 ])
 262
 263 AC_DEFUN([OVS_CHECK_LOG2_H], [
 264   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 265   if test -e $KSRC/include/linux/log2.h; then
 266     AC_MSG_RESULT([yes])
 267     OVS_DEFINE([HAVE_LOG2_H])
 268   else
 269     AC_MSG_RESULT([no])
 270   fi
 271 ])
 272
 273 dnl OVS_CHECK_LINUX_COMPAT
 274 dnl
 275 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 276 dnl the directory in $KBUILD.
 277 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 278   rm -f datapath/linux/kcompat.h.new
 279   mkdir -p datapath/linux
 280   : > datapath/linux/kcompat.h.new
 281
 282   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 283                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 284
 285   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 286   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 287
 288   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 289   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 290
 291   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 292
 293   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 294   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 295                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 296
 297   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 298   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 299   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 300   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 301   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 302   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 303   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 304
 305   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 306
 307   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 308                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 309                                    [rcu_read_lock_held])])
 310   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 311
 312   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 313   # is necessary because some versions of this header remove the
 314   # member but retain the kerneldoc comment that describes it (which
 315   # starts with @).  The brackets must be doubled because of m4
 316   # quoting rules.
 317   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 318                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 319   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 320   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 321                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 322   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 323                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 325                   [skb_copy_from_linear_data_offset])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 327                   [skb_reset_tail_pointer])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 330                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 332                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 333   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 334                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 335   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 336   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 337   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 339   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 340   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 341   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 342   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 344   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 345
 346   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 347                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 348   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 349                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 350   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 351                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 352
 353   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 354   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 355
 356   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 357   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 358   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 359   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 360   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 361   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 362   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 363
 364   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 365
 366   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 367                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 368
 369   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 370
 371   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 372                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 373
 374   OVS_CHECK_LOG2_H
 375
 376   if cmp -s datapath/linux/kcompat.h.new \
 377             datapath/linux/kcompat.h >/dev/null 2>&1; then
 378     rm datapath/linux/kcompat.h.new
 379   else
 380     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 381   fi
 382 ])
 383
 384 dnl Checks for net/if_packet.h.
 385 AC_DEFUN([OVS_CHECK_IF_PACKET],
 386   [AC_CHECK_HEADER([net/if_packet.h],
 387                    [HAVE_IF_PACKET=yes],
 388                    [HAVE_IF_PACKET=no])
 389    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 390    if test "$HAVE_IF_PACKET" = yes; then
 391       AC_DEFINE([HAVE_IF_PACKET], [1],
 392                 [Define to 1 if net/if_packet.h is available.])
 393    fi])
 394
 395 dnl Checks for net/if_dl.h.
 396 dnl
 397 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 398 dnl or NetBSD.)
 399 AC_DEFUN([OVS_CHECK_IF_DL],
 400   [AC_CHECK_HEADER([net/if_dl.h],
 401                    [HAVE_IF_DL=yes],
 402                    [HAVE_IF_DL=no])
 403    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 404    if test "$HAVE_IF_DL" = yes; then
 405       AC_DEFINE([HAVE_IF_DL], [1],
 406                 [Define to 1 if net/if_dl.h is available.])
 407
 408       # On these platforms we use libpcap to access network devices.
 409       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 410    fi])
 411
 412 dnl Checks for buggy strtok_r.
 413 dnl
 414 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 415 dnl with optimization that can cause segfaults:
 416 dnl
 417 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 418 AC_DEFUN([OVS_CHECK_STRTOK_R],
 419   [AC_CACHE_CHECK(
 420      [whether strtok_r macro segfaults on some inputs],
 421      [ovs_cv_strtok_r_bug],
 422      [AC_RUN_IFELSE(
 423         [AC_LANG_PROGRAM([#include <stdio.h>
 424                           #include <string.h>
 425                          ],
 426                          [[char string[] = ":::";
 427                            char *save_ptr = (char *) 0xc0ffee;
 428                            char *token1, *token2;
 429                            token1 = strtok_r(string, ":", &save_ptr);
 430                            token2 = strtok_r(NULL, ":", &save_ptr);
 431                            freopen ("/dev/null", "w", stdout);
 432                            printf ("%s %s\n", token1, token2);
 433                            return 0;
 434                           ]])],
 435         [ovs_cv_strtok_r_bug=no],
 436         [ovs_cv_strtok_r_bug=yes],
 437         [ovs_cv_strtok_r_bug=yes])])
 438    if test $ovs_cv_strtok_r_bug = yes; then
 439      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 440                [Define if strtok_r macro segfaults on some inputs])
 441    fi
 442 ])
 443
 444 dnl ----------------------------------------------------------------------
 445 dnl These macros are from GNU PSPP, with the following original license:
 446 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 447 dnl This file is free software; the Free Software Foundation
 448 dnl gives unlimited permission to copy and/or distribute it,
 449 dnl with or without modifications, as long as this notice is preserved.
 450
 451 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 452   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 453   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 454     [ovs_save_CFLAGS="$CFLAGS"
 455      dnl Include -Werror in the compiler options, because without -Werror
 456      dnl clang's GCC-compatible compiler driver does not return a failure
 457      dnl exit status even though it complains about options it does not
 458      dnl understand.
 459      CFLAGS="$CFLAGS $WERROR $1"
 460      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 461      CFLAGS="$ovs_save_CFLAGS"])
 462   if test $ovs_cv_name = yes; then
 463     m4_if([$2], [], [:], [$2])
 464   else
 465     m4_if([$3], [], [:], [$3])
 466   fi
 467 ])
 468
 469 dnl OVS_CHECK_WERROR
 470 dnl
 471 dnl Check whether the C compiler accepts -Werror.
 472 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 473 AC_DEFUN([OVS_CHECK_WERROR],
 474   [WERROR=
 475    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 476
 477 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 478 dnl Check whether the given C compiler OPTION is accepted.
 479 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 480 AC_DEFUN([OVS_CHECK_CC_OPTION],
 481   [AC_REQUIRE([OVS_CHECK_WERROR])
 482    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 483
 484 dnl OVS_ENABLE_OPTION([OPTION])
 485 dnl Check whether the given C compiler OPTION is accepted.
 486 dnl If so, add it to WARNING_FLAGS.
 487 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 488 AC_DEFUN([OVS_ENABLE_OPTION],
 489   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 490    AC_SUBST([WARNING_FLAGS])])
 491
 492 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 493 dnl Check whether the given C compiler OPTION is accepted.
 494 dnl If so, enable the given Automake CONDITIONAL.
 495
 496 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 497 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 498   [OVS_CHECK_CC_OPTION(
 499     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 500    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 501 dnl ----------------------------------------------------------------------
 502
 503 dnl Check for too-old XenServer.
 504 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 505   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 506     [if test -e /etc/redhat-release; then
 507        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 508      fi
 509      if test -z "$ovs_cv_xsversion"; then
 510        ovs_cv_xsversion=none
 511      fi])
 512   case $ovs_cv_xsversion in
 513     none)
 514       ;;
 515
 516     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 517     [[6-9]]* |                           dnl XenServer 6 or later
 518     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 519     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 520     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 521     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 522       ;;
 523
 524     *)
 525       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 526       ;;
 527   esac])
 528
 529 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 530 dnl
 531 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 532 dnl Runs 'if-true' if so, 'if-false' otherwise.
 533 AC_DEFUN([OVS_CHECK_MAKE_IF],
 534   [AC_CACHE_CHECK(
 535      [whether ${MAKE-make} has GNU make \$(if) extension],
 536      [ovs_cv_gnu_make_if],
 537      [cat <<'EOF' > conftest.mk
 538 conftest.out:
 539         echo $(if x,y,z) > conftest.out
 540 .PHONY: all
 541 EOF
 542       rm -f conftest.out
 543       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 544       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 545       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 546       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 547       result=`cat conftest.out`
 548       rm -f conftest.mk conftest.out
 549       if test "X$result" = "Xy"; then
 550         ovs_cv_gnu_make_if=yes
 551       else
 552         ovs_cv_gnu_make_if=no
 553       fi])])
 554
 555 dnl OVS_CHECK_GNU_MAKE
 556 dnl
 557 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 558 dnl only work with GNU make).
 559 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 560   [AC_CACHE_CHECK(
 561      [whether ${MAKE-make} is GNU make],
 562      [ovs_cv_gnu_make],
 563      [rm -f conftest.out
 564       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 565       ${MAKE-make} --version >conftest.out 2>&1
 566       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 567       result=`cat conftest.out`
 568       rm -f conftest.mk conftest.out
 569
 570       case $result in # (
 571         GNU*) ovs_cv_gnu_make=yes ;; # (
 572         *) ovs_cv_gnu_make=no ;;
 573       esac])
 574    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 575
 576 dnl OVS_CHECK_SPARSE_TARGET
 577 dnl
 578 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 579 dnl target for which the code is being built.  This helps it out.
 580 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 581   [AC_CACHE_CHECK(
 582     [target hint for cgcc],
 583     [ac_cv_sparse_target],
 584     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 585        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 586        [x86_64-*], [ac_cv_sparse_target=x86_64],
 587        [ac_cv_sparse_target=other])])
 588    AS_CASE([$ac_cv_sparse_target],
 589      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 590      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 591      [SPARSEFLAGS= CGCCFLAGS=])
 592    AC_SUBST([SPARSEFLAGS])
 593    AC_SUBST([CGCCFLAGS])])
 594
 595 dnl OVS_SPARSE_EXTRA_INCLUDES
 596 dnl
 597 dnl The cgcc script from "sparse" does not search gcc's default
 598 dnl search path. Get the default search path from GCC and pass
 599 dnl them to sparse.
 600 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 601     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 602            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 603
 604 dnl OVS_ENABLE_SPARSE
 605 AC_DEFUN([OVS_ENABLE_SPARSE],
 606   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 607    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 608    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 609    : ${SPARSE=sparse}
 610    AC_SUBST([SPARSE])
 611    AC_CONFIG_COMMANDS_PRE(
 612      [if test $ovs_cv_gnu_make_if = yes; then
 613         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 614       fi])])
 615
 616 dnl OVS_PTHREAD_SET_NAME
 617 dnl
 618 dnl This checks for three known variants of pthreads functions for setting
 619 dnl the name of the current thread:
 620 dnl
 621 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 622 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 623 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 624 dnl
 625 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 626 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 627 dnl provide to it.
 628 dnl
 629 dnl This macro defines:
 630 dnl
 631 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 632 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 633 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 634 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 635   [AC_CHECK_FUNCS([pthread_set_name_np])
 636    if test $ac_cv_func_pthread_set_name_np != yes; then
 637      AC_CACHE_CHECK(
 638        [for pthread_setname_np() variant],
 639        [ovs_cv_pthread_setname_np],
 640        [AC_LINK_IFELSE(
 641          [AC_LANG_PROGRAM([#include <pthread.h>
 642   ], [pthread_setname_np(pthread_self(), "name");])],
 643          [ovs_cv_pthread_setname_np=glibc],
 644          [AC_LINK_IFELSE(
 645            [AC_LANG_PROGRAM([#include <pthread.h>
 646 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 647            [ovs_cv_pthread_setname_np=netbsd],
 648            [ovs_cv_pthread_setname_np=none])])])
 649      case $ovs_cv_pthread_setname_np in # (
 650        glibc)
 651           AC_DEFINE(
 652             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 653             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 654           ;; # (
 655        netbsd)
 656           AC_DEFINE(
 657             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 658             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 659           ;;
 660      esac
 661    fi])
 662
 663 dnl OVS_CHECK_LINUX_HOST.
 664 dnl
 665 dnl Checks whether we're building for a Linux host, based on the presence of
 666 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 667 dnl LINUX based on the result.
 668 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 669   [AC_CACHE_CHECK(
 670      [whether __linux__ is defined],
 671      [ovs_cv_linux],
 672      [AC_COMPILE_IFELSE(
 673         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 674         [ovs_cv_linux=true],
 675         [ovs_cv_linux=false])])
 676    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])