dpdk: add support for v2.1.0
[cascardo/ovs.git] / acinclude.m4
1 # -*- autoconf -*-
2
3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
4 #
5 # Licensed under the Apache License, Version 2.0 (the "License");
6 # you may not use this file except in compliance with the License.
7 # You may obtain a copy of the License at:
8 #
9 #     http://www.apache.org/licenses/LICENSE-2.0
10 #
11 # Unless required by applicable law or agreed to in writing, software
12 # distributed under the License is distributed on an "AS IS" BASIS,
13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14 # See the License for the specific language governing permissions and
15 # limitations under the License.
16
17 dnl OVS_ENABLE_WERROR
18 AC_DEFUN([OVS_ENABLE_WERROR],
19   [AC_ARG_ENABLE(
20      [Werror],
21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
22      [], [enable_Werror=no])
23    AC_CONFIG_COMMANDS_PRE(
24      [if test "X$enable_Werror" = Xyes; then
25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
26       fi])])
27
28 dnl OVS_CHECK_LINUX
29 dnl
30 dnl Configure linux kernel source tree 
31 AC_DEFUN([OVS_CHECK_LINUX], [
32   AC_ARG_WITH([linux],
33               [AC_HELP_STRING([--with-linux=/path/to/linux],
34                               [Specify the Linux kernel build directory])])
35   AC_ARG_WITH([linux-source],
36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
37                               [Specify the Linux kernel source directory
38                                (usually figured out automatically from build
39                                directory)])])
40
41   # Deprecated equivalents to --with-linux, --with-linux-source.
42   AC_ARG_WITH([l26])
43   AC_ARG_WITH([l26-source])
44
45   if test X"$with_linux" != X; then
46     KBUILD=$with_linux
47   elif test X"$with_l26" != X; then
48     KBUILD=$with_l26
49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
50   else
51     KBUILD=
52   fi
53
54   if test X"$KBUILD" != X; then
55     if test X"$with_linux_source" != X; then
56       KSRC=$with_linux_source
57     elif test X"$with_l26_source" != X; then
58       KSRC=$with_l26_source
59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
60     else
61       KSRC=
62     fi
63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
65   fi
66
67   if test -n "$KBUILD"; then
68     KBUILD=`eval echo "$KBUILD"`
69     case $KBUILD in
70         /*) ;;
71         *) KBUILD=`pwd`/$KBUILD ;;
72     esac
73
74     # The build directory is what the user provided.
75     # Make sure that it exists.
76     AC_MSG_CHECKING([for Linux build directory])
77     if test -d "$KBUILD"; then
78         AC_MSG_RESULT([$KBUILD])
79         AC_SUBST(KBUILD)
80     else
81         AC_MSG_RESULT([no])
82         AC_ERROR([source dir $KBUILD doesn't exist])
83     fi
84
85     # Debian breaks kernel headers into "source" header and "build" headers.
86     # We want the source headers, but $KBUILD gives us the "build" headers.
87     # Use heuristics to find the source headers.
88     AC_MSG_CHECKING([for Linux source directory])
89     if test -n "$KSRC"; then
90       KSRC=`eval echo "$KSRC"`
91       case $KSRC in
92           /*) ;;
93           *) KSRC=`pwd`/$KSRC ;;
94       esac
95       if test ! -e $KSRC/include/linux/kernel.h; then
96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
97       fi
98     else
99       KSRC=$KBUILD
100       if test ! -e $KSRC/include/linux/kernel.h; then
101         # Debian kernel build Makefiles tend to include a line of the form:
102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
103         # First try to extract the source directory from this line.
104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
105         if test ! -e "$KSRC"/include/linux/kernel.h; then
106           # Didn't work.  Fall back to name-based heuristics that used to work.
107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
108             */build)
109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
110               ;; # (
111             *)
112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
113               ;;
114           esac
115         fi
116       fi
117       if test ! -e "$KSRC"/include/linux/kernel.h; then
118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
119       fi
120     fi
121     AC_MSG_RESULT([$KSRC])
122
123     AC_MSG_CHECKING([for kernel version])
124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
127     if test X"$version" = X || test X"$patchlevel" = X; then
128        AC_ERROR([cannot determine kernel version])
129     elif test X"$sublevel" = X; then
130        kversion=$version.$patchlevel
131     else
132        kversion=$version.$patchlevel.$sublevel
133     fi
134     AC_MSG_RESULT([$kversion])
135
136     if test "$version" -ge 4; then
137        if test "$version" = 4 && test "$patchlevel" -le 0; then
138           : # Linux 4.x
139        else
140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.0.x is not supported (please refer to the FAQ for advice)])
141        fi
142     elif test "$version" = 3; then
143        : # Linux 3.x
144     else
145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
147        else
148          : # Linux 2.6.x
149        fi
150     fi
151     if (test ! -e "$KBUILD"/include/linux/version.h && \
152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
156     fi
157     OVS_CHECK_LINUX_COMPAT
158   fi
159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
160 ])
161
162 dnl OVS_CHECK_DPDK
163 dnl
164 dnl Configure DPDK source tree
165 AC_DEFUN([OVS_CHECK_DPDK], [
166   AC_ARG_WITH([dpdk],
167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
168                               [Specify the DPDK build directory])])
169
170   if test X"$with_dpdk" != X; then
171     RTE_SDK=$with_dpdk
172
173     DPDK_INCLUDE=$RTE_SDK/include
174     DPDK_LIB_DIR=$RTE_SDK/lib
175     DPDK_LIB="-ldpdk"
176     DPDK_EXTRA_LIB=""
177
178     AC_COMPILE_IFELSE(
179       [AC_LANG_PROGRAM([#include <$RTE_SDK/include/rte_config.h>
180 #if !RTE_LIBRTE_VHOST_USER
181 #error
182 #endif], [])],
183                     [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
184                          DPDK_EXTRA_LIB="-lfuse"])
185
186     ovs_save_CFLAGS="$CFLAGS"
187     ovs_save_LDFLAGS="$LDFLAGS"
188     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
189     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
190
191     # On some systems we have to add -ldl to link with dpdk
192     #
193     # This code, at first, tries to link without -ldl (""),
194     # then adds it and tries again.
195     # Before each attempt the search cache must be unset,
196     # otherwise autoconf will stick with the old result
197
198     found=false
199     save_LIBS=$LIBS
200     for extras in "" "-ldl"; do
201         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
202         AC_LINK_IFELSE(
203            [AC_LANG_PROGRAM([#include <rte_config.h>
204                              #include <rte_eal.h>],
205                             [int rte_argc; char ** rte_argv;
206                              rte_eal_init(rte_argc, rte_argv);])],
207            [found=true])
208         if $found; then
209             break
210         fi
211     done
212     if $found; then :; else
213         AC_MSG_ERROR([cannot link with dpdk])
214     fi
215     CFLAGS="$ovs_save_CFLAGS"
216     LDFLAGS="$ovs_save_LDFLAGS"
217     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
218     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
219
220     # DPDK pmd drivers are not linked unless --whole-archive is used.
221     #
222     # This happens because the rest of the DPDK code doesn't use any symbol in
223     # the pmd driver objects, and the drivers register themselves using an
224     # __attribute__((constructor)) function.
225     #
226     # These options are specified inside a single -Wl directive to prevent
227     # autotools from reordering them.
228     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
229     AC_SUBST([DPDK_vswitchd_LDFLAGS])
230     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
231
232   else
233     RTE_SDK=
234   fi
235
236   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
237 ])
238
239 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
240 dnl
241 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
242 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
243 dnl <REGEX> translated to uppercase.
244 AC_DEFUN([OVS_GREP_IFELSE], [
245   AC_MSG_CHECKING([whether $2 matches in $1])
246   if test -f $1; then
247     grep '$2' $1 >/dev/null 2>&1
248     status=$?
249     case $status in
250       0) 
251         AC_MSG_RESULT([yes])
252         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
253         ;;
254       1) 
255         AC_MSG_RESULT([no])
256         $4
257         ;;
258       *) 
259         AC_MSG_ERROR([grep exited with status $status])
260         ;;
261     esac
262   else
263     AC_MSG_RESULT([file not found])
264     $4
265   fi
266 ])
267
268 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
269 dnl
270 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
271 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
272 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
273 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
274 dnl translated to uppercase.
275 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
276   AC_MSG_CHECKING([whether $2 has member $3 in $1])
277   if test -f $1; then
278     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
279     status=$?
280     case $status in
281       0)
282         AC_MSG_RESULT([yes])
283         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
284         ;;
285       1)
286         AC_MSG_RESULT([no])
287         $5
288         ;;
289       *)
290         AC_MSG_ERROR([grep exited with status $status])
291         ;;
292     esac
293   else
294     AC_MSG_RESULT([file not found])
295     $5
296   fi
297 ])
298
299 dnl OVS_DEFINE(NAME)
300 dnl
301 dnl Defines NAME to 1 in kcompat.h.
302 AC_DEFUN([OVS_DEFINE], [
303   echo '#define $1 1' >> datapath/linux/kcompat.h.new
304 ])
305
306 dnl OVS_CHECK_LINUX_COMPAT
307 dnl
308 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
309 dnl the directory in $KBUILD.
310 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
311   rm -f datapath/linux/kcompat.h.new
312   mkdir -p datapath/linux
313   : > datapath/linux/kcompat.h.new
314
315   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
316                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
317
318   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
319   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
320
321   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
322   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
323
324   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
325
326   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
327   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
328   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
329                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
330   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
331                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
332   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment])
333
334   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
335   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
336   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
337   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
338   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
339   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
340   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
341   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_rx_handler_register])
342   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_extended])
343   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [rx_handler_func_t.*pskb],
344                   [OVS_DEFINE([HAVE_RX_HANDLER_PSKB])])
345   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
346                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
347
348   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
349
350   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
351                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
352                                    [rcu_read_lock_held])])
353   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
354   
355   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
356   # is necessary because some versions of this header remove the
357   # member but retain the kerneldoc comment that describes it (which
358   # starts with @).  The brackets must be doubled because of m4
359   # quoting rules.
360   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
361                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
362   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
363   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
364   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
365                   [OVS_DEFINE([HAVE_U16_RXHASH])])
366   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
367                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
368   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], 
369                   [skb_copy_from_linear_data_offset])
370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
371                   [skb_reset_tail_pointer])
372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
373   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
374                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
375   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
376                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
377   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
378                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
379   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
380   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
381   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
382   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
383   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
384   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
385   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
386   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
387   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
388   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
389                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
390   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
391                   [OVS_DEFINE([HAVE_L4_RXHASH])])
392   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
393   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
394   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
395
396   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
397                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
398   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
399                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
400   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
401                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
402
403   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
404   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
405
406   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
407   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
408   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
409   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
410   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
411                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
412   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
413   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
414                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
415
416   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
417                         [genl_multicast_group], [id])
418
419   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
420   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
421   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
422   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
423   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
424   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
425   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
426   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
427
428   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
429
430   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
431                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
432   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
433   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
434
435
436   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
437
438   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
439                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
440   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
441                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
442   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
443                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
444                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
445   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
446   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
447   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
448                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
449   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
450                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
451   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
452                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
453   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
454                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
455
456   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
457                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
458
459   if cmp -s datapath/linux/kcompat.h.new \
460             datapath/linux/kcompat.h >/dev/null 2>&1; then
461     rm datapath/linux/kcompat.h.new
462   else
463     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
464   fi
465 ])
466
467 dnl Checks for net/if_packet.h.
468 AC_DEFUN([OVS_CHECK_IF_PACKET],
469   [AC_CHECK_HEADER([net/if_packet.h],
470                    [HAVE_IF_PACKET=yes],
471                    [HAVE_IF_PACKET=no])
472    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
473    if test "$HAVE_IF_PACKET" = yes; then
474       AC_DEFINE([HAVE_IF_PACKET], [1],
475                 [Define to 1 if net/if_packet.h is available.])
476    fi])
477
478 dnl Checks for net/if_dl.h.
479 dnl
480 dnl (We use this as a proxy for checking whether we're building on FreeBSD
481 dnl or NetBSD.)
482 AC_DEFUN([OVS_CHECK_IF_DL],
483   [AC_CHECK_HEADER([net/if_dl.h],
484                    [HAVE_IF_DL=yes],
485                    [HAVE_IF_DL=no])
486    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
487    if test "$HAVE_IF_DL" = yes; then
488       AC_DEFINE([HAVE_IF_DL], [1],
489                 [Define to 1 if net/if_dl.h is available.])
490
491       # On these platforms we use libpcap to access network devices.
492       AC_SEARCH_LIBS([pcap_open_live], [pcap])
493    fi])
494
495 dnl Checks for buggy strtok_r.
496 dnl
497 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
498 dnl with optimization that can cause segfaults:
499 dnl
500 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
501 AC_DEFUN([OVS_CHECK_STRTOK_R],
502   [AC_CACHE_CHECK(
503      [whether strtok_r macro segfaults on some inputs],
504      [ovs_cv_strtok_r_bug],
505      [AC_RUN_IFELSE(
506         [AC_LANG_PROGRAM([#include <stdio.h>
507                           #include <string.h>
508                          ],
509                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
510                            /* Assume bug is present, because relatively minor
511                               changes in compiler settings (e.g. optimization
512                               level) can make it crop up. */
513                            return 1;
514                            #else
515                            char string[] = ":::";
516                            char *save_ptr = (char *) 0xc0ffee;
517                            char *token1, *token2;
518                            token1 = strtok_r(string, ":", &save_ptr);
519                            token2 = strtok_r(NULL, ":", &save_ptr);
520                            freopen ("/dev/null", "w", stdout);
521                            printf ("%s %s\n", token1, token2);
522                            return 0;
523                            #endif
524                           ]])],
525         [ovs_cv_strtok_r_bug=no],
526         [ovs_cv_strtok_r_bug=yes],
527         [ovs_cv_strtok_r_bug=yes])])
528    if test $ovs_cv_strtok_r_bug = yes; then
529      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
530                [Define if strtok_r macro segfaults on some inputs])
531    fi
532 ])
533
534 dnl ----------------------------------------------------------------------
535 dnl These macros are from GNU PSPP, with the following original license:
536 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
537 dnl This file is free software; the Free Software Foundation
538 dnl gives unlimited permission to copy and/or distribute it,
539 dnl with or without modifications, as long as this notice is preserved.
540
541 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
542   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
543   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name], 
544     [ovs_save_CFLAGS="$CFLAGS"
545      dnl Include -Werror in the compiler options, because without -Werror
546      dnl clang's GCC-compatible compiler driver does not return a failure
547      dnl exit status even though it complains about options it does not
548      dnl understand.
549      dnl
550      dnl Also, check stderr as gcc exits with status 0 for options
551      dnl rejected at getopt level.
552      dnl    % touch /tmp/a.c
553      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
554      dnl    gcc: unrecognized option '-Qunused-arguments'
555      dnl    0
556      dnl    %
557      CFLAGS="$CFLAGS $WERROR $1"
558      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
559      CFLAGS="$ovs_save_CFLAGS"])
560   if test $ovs_cv_name = yes; then
561     m4_if([$2], [], [:], [$2])
562   else
563     m4_if([$3], [], [:], [$3])
564   fi
565 ])
566
567 dnl OVS_CHECK_WERROR
568 dnl
569 dnl Check whether the C compiler accepts -Werror.
570 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
571 AC_DEFUN([OVS_CHECK_WERROR],
572   [WERROR=
573    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
574
575 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
576 dnl Check whether the given C compiler OPTION is accepted.
577 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
578 AC_DEFUN([OVS_CHECK_CC_OPTION],
579   [AC_REQUIRE([OVS_CHECK_WERROR])
580    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
581
582 dnl OVS_ENABLE_OPTION([OPTION])
583 dnl Check whether the given C compiler OPTION is accepted.
584 dnl If so, add it to WARNING_FLAGS.
585 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
586 AC_DEFUN([OVS_ENABLE_OPTION], 
587   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
588    AC_SUBST([WARNING_FLAGS])])
589
590 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
591 dnl Check whether the given C compiler OPTION is accepted.
592 dnl If so, enable the given Automake CONDITIONAL.
593
594 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
595 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
596   [OVS_CHECK_CC_OPTION(
597     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
598    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
599 dnl ----------------------------------------------------------------------
600
601 dnl Check for too-old XenServer.
602 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
603   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
604     [if test -e /etc/redhat-release; then
605        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
606      fi
607      if test -z "$ovs_cv_xsversion"; then
608        ovs_cv_xsversion=none
609      fi])
610   case $ovs_cv_xsversion in
611     none)
612       ;;
613
614     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
615     [[6-9]]* |                           dnl XenServer 6 or later
616     5.[[7-9]]* |                         dnl XenServer 5.7 or later
617     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
618     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
619     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
620       ;;
621
622     *)
623       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
624       ;;
625   esac])
626
627 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
628 dnl
629 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
630 dnl Runs 'if-true' if so, 'if-false' otherwise.
631 AC_DEFUN([OVS_CHECK_MAKE_IF],
632   [AC_CACHE_CHECK(
633      [whether ${MAKE-make} has GNU make \$(if) extension],
634      [ovs_cv_gnu_make_if],
635      [cat <<'EOF' > conftest.mk
636 conftest.out:
637         echo $(if x,y,z) > conftest.out
638 .PHONY: all
639 EOF
640       rm -f conftest.out
641       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
642       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
643       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
644       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
645       result=`cat conftest.out`
646       rm -f conftest.mk conftest.out
647       if test "X$result" = "Xy"; then
648         ovs_cv_gnu_make_if=yes
649       else
650         ovs_cv_gnu_make_if=no
651       fi])])
652
653 dnl OVS_CHECK_GNU_MAKE
654 dnl
655 dnl Checks whether make is GNU make (because Linux kernel Makefiles
656 dnl only work with GNU make).
657 AC_DEFUN([OVS_CHECK_GNU_MAKE],
658   [AC_CACHE_CHECK(
659      [whether ${MAKE-make} is GNU make],
660      [ovs_cv_gnu_make],
661      [rm -f conftest.out
662       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
663       ${MAKE-make} --version >conftest.out 2>&1
664       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
665       result=`cat conftest.out`
666       rm -f conftest.mk conftest.out
667
668       case $result in # (
669         GNU*) ovs_cv_gnu_make=yes ;; # (
670         *) ovs_cv_gnu_make=no ;;
671       esac])
672    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
673
674 dnl OVS_CHECK_SPARSE_TARGET
675 dnl
676 dnl The "cgcc" script from "sparse" isn't very good at detecting the
677 dnl target for which the code is being built.  This helps it out.
678 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
679   [AC_CACHE_CHECK(
680     [target hint for cgcc],
681     [ac_cv_sparse_target],
682     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
683        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
684        [x86_64-*], [ac_cv_sparse_target=x86_64],
685        [ac_cv_sparse_target=other])])
686    AS_CASE([$ac_cv_sparse_target],
687      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
688      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
689      [SPARSEFLAGS= CGCCFLAGS=])
690    AC_SUBST([SPARSEFLAGS])
691    AC_SUBST([CGCCFLAGS])])
692
693 dnl OVS_SPARSE_EXTRA_INCLUDES
694 dnl
695 dnl The cgcc script from "sparse" does not search gcc's default
696 dnl search path. Get the default search path from GCC and pass
697 dnl them to sparse.
698 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
699     AC_SUBST([SPARSE_EXTRA_INCLUDES],
700            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
701
702 dnl OVS_ENABLE_SPARSE
703 AC_DEFUN([OVS_ENABLE_SPARSE],
704   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
705    AC_REQUIRE([OVS_CHECK_MAKE_IF])
706    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
707    : ${SPARSE=sparse}
708    AC_SUBST([SPARSE])
709    AC_CONFIG_COMMANDS_PRE(
710      [if test $ovs_cv_gnu_make_if = yes; then
711         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
712       fi])])
713
714 dnl OVS_PTHREAD_SET_NAME
715 dnl
716 dnl This checks for three known variants of pthreads functions for setting
717 dnl the name of the current thread:
718 dnl
719 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
720 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
721 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
722 dnl
723 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
724 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
725 dnl provide to it.
726 dnl
727 dnl This macro defines:
728 dnl
729 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
730 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
731 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
732 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
733   [AC_CHECK_FUNCS([pthread_set_name_np])
734    if test $ac_cv_func_pthread_set_name_np != yes; then
735      AC_CACHE_CHECK(
736        [for pthread_setname_np() variant],
737        [ovs_cv_pthread_setname_np],
738        [AC_LINK_IFELSE(
739          [AC_LANG_PROGRAM([#include <pthread.h>
740   ], [pthread_setname_np(pthread_self(), "name");])],
741          [ovs_cv_pthread_setname_np=glibc],
742          [AC_LINK_IFELSE(
743            [AC_LANG_PROGRAM([#include <pthread.h>
744 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
745            [ovs_cv_pthread_setname_np=netbsd],
746            [ovs_cv_pthread_setname_np=none])])])
747      case $ovs_cv_pthread_setname_np in # (
748        glibc)
749           AC_DEFINE(
750             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
751             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
752           ;; # (
753        netbsd)
754           AC_DEFINE(
755             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
756             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
757           ;;
758      esac
759    fi])
760
761 dnl OVS_CHECK_LINUX_HOST.
762 dnl
763 dnl Checks whether we're building for a Linux host, based on the presence of
764 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
765 dnl LINUX based on the result.
766 AC_DEFUN([OVS_CHECK_LINUX_HOST],
767   [AC_CACHE_CHECK(
768      [whether __linux__ is defined],
769      [ovs_cv_linux],
770      [AC_COMPILE_IFELSE(
771         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
772         [ovs_cv_linux=true],
773         [ovs_cv_linux=false])])
774    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])