acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 0; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.0.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-lintel_dpdk"
 176     DPDK_EXTRA_LIB="-lfuse"
 177
 178     ovs_save_CFLAGS="$CFLAGS"
 179     ovs_save_LDFLAGS="$LDFLAGS"
 180     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 181     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 182
 183     # On some systems we have to add -ldl to link with dpdk
 184     #
 185     # This code, at first, tries to link without -ldl (""),
 186     # then adds it and tries again.
 187     # Before each attempt the search cache must be unset,
 188     # otherwise autoconf will stick with the old result
 189
 190     found=false
 191     save_LIBS=$LIBS
 192     for extras in "" "-ldl"; do
 193         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 194         AC_LINK_IFELSE(
 195            [AC_LANG_PROGRAM([#include <rte_config.h>
 196                              #include <rte_eal.h>],
 197                             [int rte_argc; char ** rte_argv;
 198                              rte_eal_init(rte_argc, rte_argv);])],
 199            [found=true])
 200         if $found; then
 201             break
 202         fi
 203     done
 204     if $found; then :; else
 205         AC_MSG_ERROR([cannot link with dpdk])
 206     fi
 207     CFLAGS="$ovs_save_CFLAGS"
 208     LDFLAGS="$ovs_save_LDFLAGS"
 209     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 210     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 211
 212     # DPDK pmd drivers are not linked unless --whole-archive is used.
 213     #
 214     # This happens because the rest of the DPDK code doesn't use any symbol in
 215     # the pmd driver objects, and the drivers register themselves using an
 216     # __attribute__((constructor)) function.
 217     #
 218     # These options are specified inside a single -Wl directive to prevent
 219     # autotools from reordering them.
 220     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 221     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 222     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 223
 224     OVS_GREP_IFELSE([$RTE_SDK/include/rte_config.h], [define RTE_LIBRTE_VHOST_USER 1],
 225                     [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])])
 226   else
 227     RTE_SDK=
 228   fi
 229
 230   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 231 ])
 232
 233 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 234 dnl
 235 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 236 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 237 dnl <REGEX> translated to uppercase.
 238 AC_DEFUN([OVS_GREP_IFELSE], [
 239   AC_MSG_CHECKING([whether $2 matches in $1])
 240   if test -f $1; then
 241     grep '$2' $1 >/dev/null 2>&1
 242     status=$?
 243     case $status in
 244       0)
 245         AC_MSG_RESULT([yes])
 246         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 247         ;;
 248       1)
 249         AC_MSG_RESULT([no])
 250         $4
 251         ;;
 252       *)
 253         AC_MSG_ERROR([grep exited with status $status])
 254         ;;
 255     esac
 256   else
 257     AC_MSG_RESULT([file not found])
 258     $4
 259   fi
 260 ])
 261
 262 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 263 dnl
 264 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 265 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 266 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 267 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 268 dnl translated to uppercase.
 269 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 270   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 271   if test -f $1; then
 272     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3'
 273     status=$?
 274     case $status in
 275       0)
 276         AC_MSG_RESULT([yes])
 277         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 278         ;;
 279       1)
 280         AC_MSG_RESULT([no])
 281         $5
 282         ;;
 283       *)
 284         AC_MSG_ERROR([grep exited with status $status])
 285         ;;
 286     esac
 287   else
 288     AC_MSG_RESULT([file not found])
 289     $5
 290   fi
 291 ])
 292
 293 dnl OVS_DEFINE(NAME)
 294 dnl
 295 dnl Defines NAME to 1 in kcompat.h.
 296 AC_DEFUN([OVS_DEFINE], [
 297   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 298 ])
 299
 300 dnl OVS_CHECK_LINUX_COMPAT
 301 dnl
 302 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 303 dnl the directory in $KBUILD.
 304 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 305   rm -f datapath/linux/kcompat.h.new
 306   mkdir -p datapath/linux
 307   : > datapath/linux/kcompat.h.new
 308
 309   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 310                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 311
 312   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 313   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 314
 315   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 316   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 317
 318   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 319
 320   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 321   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 322                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 323   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 324                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 325
 326   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 332   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 333   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 334                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 335
 336   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 337
 338   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 339                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 340                                    [rcu_read_lock_held])])
 341   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 342
 343   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 344   # is necessary because some versions of this header remove the
 345   # member but retain the kerneldoc comment that describes it (which
 346   # starts with @).  The brackets must be doubled because of m4
 347   # quoting rules.
 348   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 349                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 350   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 351   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 352   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 353                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 354   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 355                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 356   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 357                   [skb_copy_from_linear_data_offset])
 358   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 359                   [skb_reset_tail_pointer])
 360   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 361   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 362                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 364                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 366                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 374   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 376   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 377                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 378   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 379   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 380   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 381   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 382
 383   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 384                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 385   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 386                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 387   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 388                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 389
 390   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 391   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 392
 393   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 394   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 395   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 396   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 397   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 398                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 399   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 400   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 401                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 402
 403   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 404                         [genl_multicast_group], [id])
 405
 406   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 407   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 408   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 409   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 410   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 411   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 412   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 413   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 414
 415   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 416
 417   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 418                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 419   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 420   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 421
 422
 423   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 424
 425   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 426                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 427   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 428                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 429   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 430                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 431                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 432   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 433   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 434   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 435                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 436   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
 437                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
 438   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
 439                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
 440   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 441                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 442
 443   if cmp -s datapath/linux/kcompat.h.new \
 444             datapath/linux/kcompat.h >/dev/null 2>&1; then
 445     rm datapath/linux/kcompat.h.new
 446   else
 447     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 448   fi
 449 ])
 450
 451 dnl Checks for net/if_packet.h.
 452 AC_DEFUN([OVS_CHECK_IF_PACKET],
 453   [AC_CHECK_HEADER([net/if_packet.h],
 454                    [HAVE_IF_PACKET=yes],
 455                    [HAVE_IF_PACKET=no])
 456    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 457    if test "$HAVE_IF_PACKET" = yes; then
 458       AC_DEFINE([HAVE_IF_PACKET], [1],
 459                 [Define to 1 if net/if_packet.h is available.])
 460    fi])
 461
 462 dnl Checks for net/if_dl.h.
 463 dnl
 464 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 465 dnl or NetBSD.)
 466 AC_DEFUN([OVS_CHECK_IF_DL],
 467   [AC_CHECK_HEADER([net/if_dl.h],
 468                    [HAVE_IF_DL=yes],
 469                    [HAVE_IF_DL=no])
 470    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 471    if test "$HAVE_IF_DL" = yes; then
 472       AC_DEFINE([HAVE_IF_DL], [1],
 473                 [Define to 1 if net/if_dl.h is available.])
 474
 475       # On these platforms we use libpcap to access network devices.
 476       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 477    fi])
 478
 479 dnl Checks for buggy strtok_r.
 480 dnl
 481 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 482 dnl with optimization that can cause segfaults:
 483 dnl
 484 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 485 AC_DEFUN([OVS_CHECK_STRTOK_R],
 486   [AC_CACHE_CHECK(
 487      [whether strtok_r macro segfaults on some inputs],
 488      [ovs_cv_strtok_r_bug],
 489      [AC_RUN_IFELSE(
 490         [AC_LANG_PROGRAM([#include <stdio.h>
 491                           #include <string.h>
 492                          ],
 493                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 494                            /* Assume bug is present, because relatively minor
 495                               changes in compiler settings (e.g. optimization
 496                               level) can make it crop up. */
 497                            return 1;
 498                            #else
 499                            char string[] = ":::";
 500                            char *save_ptr = (char *) 0xc0ffee;
 501                            char *token1, *token2;
 502                            token1 = strtok_r(string, ":", &save_ptr);
 503                            token2 = strtok_r(NULL, ":", &save_ptr);
 504                            freopen ("/dev/null", "w", stdout);
 505                            printf ("%s %s\n", token1, token2);
 506                            return 0;
 507                            #endif
 508                           ]])],
 509         [ovs_cv_strtok_r_bug=no],
 510         [ovs_cv_strtok_r_bug=yes],
 511         [ovs_cv_strtok_r_bug=yes])])
 512    if test $ovs_cv_strtok_r_bug = yes; then
 513      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 514                [Define if strtok_r macro segfaults on some inputs])
 515    fi
 516 ])
 517
 518 dnl ----------------------------------------------------------------------
 519 dnl These macros are from GNU PSPP, with the following original license:
 520 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 521 dnl This file is free software; the Free Software Foundation
 522 dnl gives unlimited permission to copy and/or distribute it,
 523 dnl with or without modifications, as long as this notice is preserved.
 524
 525 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 526   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 527   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 528     [ovs_save_CFLAGS="$CFLAGS"
 529      dnl Include -Werror in the compiler options, because without -Werror
 530      dnl clang's GCC-compatible compiler driver does not return a failure
 531      dnl exit status even though it complains about options it does not
 532      dnl understand.
 533      dnl
 534      dnl Also, check stderr as gcc exits with status 0 for options
 535      dnl rejected at getopt level.
 536      dnl    % touch /tmp/a.c
 537      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 538      dnl    gcc: unrecognized option '-Qunused-arguments'
 539      dnl    0
 540      dnl    %
 541      CFLAGS="$CFLAGS $WERROR $1"
 542      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 543      CFLAGS="$ovs_save_CFLAGS"])
 544   if test $ovs_cv_name = yes; then
 545     m4_if([$2], [], [:], [$2])
 546   else
 547     m4_if([$3], [], [:], [$3])
 548   fi
 549 ])
 550
 551 dnl OVS_CHECK_WERROR
 552 dnl
 553 dnl Check whether the C compiler accepts -Werror.
 554 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 555 AC_DEFUN([OVS_CHECK_WERROR],
 556   [WERROR=
 557    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 558
 559 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 560 dnl Check whether the given C compiler OPTION is accepted.
 561 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 562 AC_DEFUN([OVS_CHECK_CC_OPTION],
 563   [AC_REQUIRE([OVS_CHECK_WERROR])
 564    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 565
 566 dnl OVS_ENABLE_OPTION([OPTION])
 567 dnl Check whether the given C compiler OPTION is accepted.
 568 dnl If so, add it to WARNING_FLAGS.
 569 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 570 AC_DEFUN([OVS_ENABLE_OPTION],
 571   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 572    AC_SUBST([WARNING_FLAGS])])
 573
 574 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 575 dnl Check whether the given C compiler OPTION is accepted.
 576 dnl If so, enable the given Automake CONDITIONAL.
 577
 578 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 579 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 580   [OVS_CHECK_CC_OPTION(
 581     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 582    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 583 dnl ----------------------------------------------------------------------
 584
 585 dnl Check for too-old XenServer.
 586 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 587   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 588     [if test -e /etc/redhat-release; then
 589        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 590      fi
 591      if test -z "$ovs_cv_xsversion"; then
 592        ovs_cv_xsversion=none
 593      fi])
 594   case $ovs_cv_xsversion in
 595     none)
 596       ;;
 597
 598     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 599     [[6-9]]* |                           dnl XenServer 6 or later
 600     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 601     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 602     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 603     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 604       ;;
 605
 606     *)
 607       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 608       ;;
 609   esac])
 610
 611 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 612 dnl
 613 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 614 dnl Runs 'if-true' if so, 'if-false' otherwise.
 615 AC_DEFUN([OVS_CHECK_MAKE_IF],
 616   [AC_CACHE_CHECK(
 617      [whether ${MAKE-make} has GNU make \$(if) extension],
 618      [ovs_cv_gnu_make_if],
 619      [cat <<'EOF' > conftest.mk
 620 conftest.out:
 621         echo $(if x,y,z) > conftest.out
 622 .PHONY: all
 623 EOF
 624       rm -f conftest.out
 625       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 626       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 627       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 628       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 629       result=`cat conftest.out`
 630       rm -f conftest.mk conftest.out
 631       if test "X$result" = "Xy"; then
 632         ovs_cv_gnu_make_if=yes
 633       else
 634         ovs_cv_gnu_make_if=no
 635       fi])])
 636
 637 dnl OVS_CHECK_GNU_MAKE
 638 dnl
 639 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 640 dnl only work with GNU make).
 641 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 642   [AC_CACHE_CHECK(
 643      [whether ${MAKE-make} is GNU make],
 644      [ovs_cv_gnu_make],
 645      [rm -f conftest.out
 646       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 647       ${MAKE-make} --version >conftest.out 2>&1
 648       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 649       result=`cat conftest.out`
 650       rm -f conftest.mk conftest.out
 651
 652       case $result in # (
 653         GNU*) ovs_cv_gnu_make=yes ;; # (
 654         *) ovs_cv_gnu_make=no ;;
 655       esac])
 656    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 657
 658 dnl OVS_CHECK_SPARSE_TARGET
 659 dnl
 660 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 661 dnl target for which the code is being built.  This helps it out.
 662 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 663   [AC_CACHE_CHECK(
 664     [target hint for cgcc],
 665     [ac_cv_sparse_target],
 666     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 667        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 668        [x86_64-*], [ac_cv_sparse_target=x86_64],
 669        [ac_cv_sparse_target=other])])
 670    AS_CASE([$ac_cv_sparse_target],
 671      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 672      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 673      [SPARSEFLAGS= CGCCFLAGS=])
 674    AC_SUBST([SPARSEFLAGS])
 675    AC_SUBST([CGCCFLAGS])])
 676
 677 dnl OVS_SPARSE_EXTRA_INCLUDES
 678 dnl
 679 dnl The cgcc script from "sparse" does not search gcc's default
 680 dnl search path. Get the default search path from GCC and pass
 681 dnl them to sparse.
 682 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 683     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 684            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 685
 686 dnl OVS_ENABLE_SPARSE
 687 AC_DEFUN([OVS_ENABLE_SPARSE],
 688   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 689    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 690    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 691    : ${SPARSE=sparse}
 692    AC_SUBST([SPARSE])
 693    AC_CONFIG_COMMANDS_PRE(
 694      [if test $ovs_cv_gnu_make_if = yes; then
 695         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 696       fi])])
 697
 698 dnl OVS_PTHREAD_SET_NAME
 699 dnl
 700 dnl This checks for three known variants of pthreads functions for setting
 701 dnl the name of the current thread:
 702 dnl
 703 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 704 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 705 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 706 dnl
 707 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 708 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 709 dnl provide to it.
 710 dnl
 711 dnl This macro defines:
 712 dnl
 713 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 714 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 715 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 716 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 717   [AC_CHECK_FUNCS([pthread_set_name_np])
 718    if test $ac_cv_func_pthread_set_name_np != yes; then
 719      AC_CACHE_CHECK(
 720        [for pthread_setname_np() variant],
 721        [ovs_cv_pthread_setname_np],
 722        [AC_LINK_IFELSE(
 723          [AC_LANG_PROGRAM([#include <pthread.h>
 724   ], [pthread_setname_np(pthread_self(), "name");])],
 725          [ovs_cv_pthread_setname_np=glibc],
 726          [AC_LINK_IFELSE(
 727            [AC_LANG_PROGRAM([#include <pthread.h>
 728 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 729            [ovs_cv_pthread_setname_np=netbsd],
 730            [ovs_cv_pthread_setname_np=none])])])
 731      case $ovs_cv_pthread_setname_np in # (
 732        glibc)
 733           AC_DEFINE(
 734             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 735             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 736           ;; # (
 737        netbsd)
 738           AC_DEFINE(
 739             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 740             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 741           ;;
 742      esac
 743    fi])
 744
 745 dnl OVS_CHECK_LINUX_HOST.
 746 dnl
 747 dnl Checks whether we're building for a Linux host, based on the presence of
 748 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 749 dnl LINUX based on the result.
 750 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 751   [AC_CACHE_CHECK(
 752      [whether __linux__ is defined],
 753      [ovs_cv_linux],
 754      [AC_COMPILE_IFELSE(
 755         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 756         [ovs_cv_linux=true],
 757         [ovs_cv_linux=false])])
 758    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])