acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 14; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.14.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIB=-lintel_dpdk
 174
 175     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 176     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 177
 178     # On some systems we have to add -ldl to link with dpdk
 179     #
 180     # This code, at first, tries to link without -ldl (""),
 181     # then adds it and tries again.
 182     # Before each attempt the search cache must be unset,
 183     # otherwise autoconf will stick with the old result
 184
 185     found=false
 186     save_LIBS=$LIBS
 187     for extras in "" "-ldl"; do
 188         LIBS="$DPDK_LIB $extras $save_LIBS"
 189         AC_LINK_IFELSE(
 190            [AC_LANG_PROGRAM([#include <rte_config.h>
 191                              #include <rte_eal.h>],
 192                             [int rte_argc; char ** rte_argv;
 193                              rte_eal_init(rte_argc, rte_argv);])],
 194            [found=true])
 195         if $found; then
 196             break
 197         fi
 198     done
 199     if $found; then :; else
 200         AC_MSG_ERROR([cannot link with dpdk])
 201     fi
 202
 203     # DPDK 1.7.0 pmd drivers are not linked unless --whole-archive is used.
 204     #
 205     # This happens because the rest of the DPDK code doesn't use any symbol in
 206     # the pmd driver objects, and the drivers register themselves using an
 207     # __attribute__((constructor)) function.
 208     #
 209     # These options are specified inside a single -Wl directive to prevent
 210     # autotools from reordering them.
 211     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 212     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 213     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 214   else
 215     RTE_SDK=
 216   fi
 217
 218   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 219 ])
 220
 221 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 222 dnl
 223 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 224 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 225 dnl <REGEX> translated to uppercase.
 226 AC_DEFUN([OVS_GREP_IFELSE], [
 227   AC_MSG_CHECKING([whether $2 matches in $1])
 228   if test -f $1; then
 229     grep '$2' $1 >/dev/null 2>&1
 230     status=$?
 231     case $status in
 232       0)
 233         AC_MSG_RESULT([yes])
 234         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 235         ;;
 236       1)
 237         AC_MSG_RESULT([no])
 238         $4
 239         ;;
 240       *)
 241         AC_MSG_ERROR([grep exited with status $status])
 242         ;;
 243     esac
 244   else
 245     AC_MSG_RESULT([file not found])
 246     $4
 247   fi
 248 ])
 249
 250 dnl OVS_DEFINE(NAME)
 251 dnl
 252 dnl Defines NAME to 1 in kcompat.h.
 253 AC_DEFUN([OVS_DEFINE], [
 254   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 255 ])
 256
 257 AC_DEFUN([OVS_CHECK_LOG2_H], [
 258   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 259   if test -e $KSRC/include/linux/log2.h; then
 260     AC_MSG_RESULT([yes])
 261     OVS_DEFINE([HAVE_LOG2_H])
 262   else
 263     AC_MSG_RESULT([no])
 264   fi
 265 ])
 266
 267 dnl OVS_CHECK_LINUX_COMPAT
 268 dnl
 269 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 270 dnl the directory in $KBUILD.
 271 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 272   rm -f datapath/linux/kcompat.h.new
 273   mkdir -p datapath/linux
 274   : > datapath/linux/kcompat.h.new
 275
 276   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 277                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 278
 279   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 280
 281   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 282   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 283
 284   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 285
 286   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 287   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 288                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 289
 290   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 291   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 292   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 293   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 294   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 295   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 296   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 297
 298   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 299
 300   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 301                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 302                                    [rcu_read_lock_held])])
 303   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 304
 305   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 306   # is necessary because some versions of this header remove the
 307   # member but retain the kerneldoc comment that describes it (which
 308   # starts with @).  The brackets must be doubled because of m4
 309   # quoting rules.
 310   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 311                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 312   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 313   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 314                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 315   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 316                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 317   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 318                   [skb_copy_from_linear_data_offset])
 319   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 320                   [skb_reset_tail_pointer])
 321   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 322   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 323                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 325                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 327                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 332   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 333   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 335   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 336   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 337   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 338
 339   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 340                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 341   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 342                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 343   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 344                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 345
 346   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 347   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 348
 349   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 350   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 351   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 352   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 353   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 354   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 355   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 356
 357   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 358
 359   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 360                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 361
 362   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 363
 364   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 365
 366   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 367                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 368
 369   OVS_CHECK_LOG2_H
 370
 371   if cmp -s datapath/linux/kcompat.h.new \
 372             datapath/linux/kcompat.h >/dev/null 2>&1; then
 373     rm datapath/linux/kcompat.h.new
 374   else
 375     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 376   fi
 377 ])
 378
 379 dnl Checks for net/if_packet.h.
 380 AC_DEFUN([OVS_CHECK_IF_PACKET],
 381   [AC_CHECK_HEADER([net/if_packet.h],
 382                    [HAVE_IF_PACKET=yes],
 383                    [HAVE_IF_PACKET=no])
 384    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 385    if test "$HAVE_IF_PACKET" = yes; then
 386       AC_DEFINE([HAVE_IF_PACKET], [1],
 387                 [Define to 1 if net/if_packet.h is available.])
 388    fi])
 389
 390 dnl Checks for net/if_dl.h.
 391 dnl
 392 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 393 dnl or NetBSD.)
 394 AC_DEFUN([OVS_CHECK_IF_DL],
 395   [AC_CHECK_HEADER([net/if_dl.h],
 396                    [HAVE_IF_DL=yes],
 397                    [HAVE_IF_DL=no])
 398    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 399    if test "$HAVE_IF_DL" = yes; then
 400       AC_DEFINE([HAVE_IF_DL], [1],
 401                 [Define to 1 if net/if_dl.h is available.])
 402
 403       # On these platforms we use libpcap to access network devices.
 404       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 405    fi])
 406
 407 dnl Checks for buggy strtok_r.
 408 dnl
 409 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 410 dnl with optimization that can cause segfaults:
 411 dnl
 412 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 413 AC_DEFUN([OVS_CHECK_STRTOK_R],
 414   [AC_CACHE_CHECK(
 415      [whether strtok_r macro segfaults on some inputs],
 416      [ovs_cv_strtok_r_bug],
 417      [AC_RUN_IFELSE(
 418         [AC_LANG_PROGRAM([#include <stdio.h>
 419                           #include <string.h>
 420                          ],
 421                          [[char string[] = ":::";
 422                            char *save_ptr = (char *) 0xc0ffee;
 423                            char *token1, *token2;
 424                            token1 = strtok_r(string, ":", &save_ptr);
 425                            token2 = strtok_r(NULL, ":", &save_ptr);
 426                            freopen ("/dev/null", "w", stdout);
 427                            printf ("%s %s\n", token1, token2);
 428                            return 0;
 429                           ]])],
 430         [ovs_cv_strtok_r_bug=no],
 431         [ovs_cv_strtok_r_bug=yes],
 432         [ovs_cv_strtok_r_bug=yes])])
 433    if test $ovs_cv_strtok_r_bug = yes; then
 434      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 435                [Define if strtok_r macro segfaults on some inputs])
 436    fi
 437 ])
 438
 439 dnl ----------------------------------------------------------------------
 440 dnl These macros are from GNU PSPP, with the following original license:
 441 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 442 dnl This file is free software; the Free Software Foundation
 443 dnl gives unlimited permission to copy and/or distribute it,
 444 dnl with or without modifications, as long as this notice is preserved.
 445
 446 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 447   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 448   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 449     [ovs_save_CFLAGS="$CFLAGS"
 450      dnl Include -Werror in the compiler options, because without -Werror
 451      dnl clang's GCC-compatible compiler driver does not return a failure
 452      dnl exit status even though it complains about options it does not
 453      dnl understand.
 454      CFLAGS="$CFLAGS $WERROR $1"
 455      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 456      CFLAGS="$ovs_save_CFLAGS"])
 457   if test $ovs_cv_name = yes; then
 458     m4_if([$2], [], [:], [$2])
 459   else
 460     m4_if([$3], [], [:], [$3])
 461   fi
 462 ])
 463
 464 dnl OVS_CHECK_WERROR
 465 dnl
 466 dnl Check whether the C compiler accepts -Werror.
 467 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 468 AC_DEFUN([OVS_CHECK_WERROR],
 469   [WERROR=
 470    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 471
 472 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 473 dnl Check whether the given C compiler OPTION is accepted.
 474 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 475 AC_DEFUN([OVS_CHECK_CC_OPTION],
 476   [AC_REQUIRE([OVS_CHECK_WERROR])
 477    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 478
 479 dnl OVS_ENABLE_OPTION([OPTION])
 480 dnl Check whether the given C compiler OPTION is accepted.
 481 dnl If so, add it to WARNING_FLAGS.
 482 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 483 AC_DEFUN([OVS_ENABLE_OPTION],
 484   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 485    AC_SUBST([WARNING_FLAGS])])
 486
 487 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 488 dnl Check whether the given C compiler OPTION is accepted.
 489 dnl If so, enable the given Automake CONDITIONAL.
 490
 491 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 492 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 493   [OVS_CHECK_CC_OPTION(
 494     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 495    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 496 dnl ----------------------------------------------------------------------
 497
 498 dnl Check for too-old XenServer.
 499 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 500   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 501     [if test -e /etc/redhat-release; then
 502        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 503      fi
 504      if test -z "$ovs_cv_xsversion"; then
 505        ovs_cv_xsversion=none
 506      fi])
 507   case $ovs_cv_xsversion in
 508     none)
 509       ;;
 510
 511     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 512     [[6-9]]* |                           dnl XenServer 6 or later
 513     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 514     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 515     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 516     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 517       ;;
 518
 519     *)
 520       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 521       ;;
 522   esac])
 523
 524 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 525 dnl
 526 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 527 dnl Runs 'if-true' if so, 'if-false' otherwise.
 528 AC_DEFUN([OVS_CHECK_MAKE_IF],
 529   [AC_CACHE_CHECK(
 530      [whether ${MAKE-make} has GNU make \$(if) extension],
 531      [ovs_cv_gnu_make_if],
 532      [cat <<'EOF' > conftest.mk
 533 conftest.out:
 534         echo $(if x,y,z) > conftest.out
 535 .PHONY: all
 536 EOF
 537       rm -f conftest.out
 538       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 539       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 540       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 541       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 542       result=`cat conftest.out`
 543       rm -f conftest.mk conftest.out
 544       if test "X$result" = "Xy"; then
 545         ovs_cv_gnu_make_if=yes
 546       else
 547         ovs_cv_gnu_make_if=no
 548       fi])])
 549
 550 dnl OVS_CHECK_GNU_MAKE
 551 dnl
 552 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 553 dnl only work with GNU make).
 554 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 555   [AC_CACHE_CHECK(
 556      [whether ${MAKE-make} is GNU make],
 557      [ovs_cv_gnu_make],
 558      [rm -f conftest.out
 559       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 560       ${MAKE-make} --version >conftest.out 2>&1
 561       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 562       result=`cat conftest.out`
 563       rm -f conftest.mk conftest.out
 564
 565       case $result in # (
 566         GNU*) ovs_cv_gnu_make=yes ;; # (
 567         *) ovs_cv_gnu_make=no ;;
 568       esac])
 569    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 570
 571 dnl OVS_CHECK_SPARSE_TARGET
 572 dnl
 573 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 574 dnl target for which the code is being built.  This helps it out.
 575 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 576   [AC_CACHE_CHECK(
 577     [target hint for cgcc],
 578     [ac_cv_sparse_target],
 579     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 580        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 581        [x86_64-*], [ac_cv_sparse_target=x86_64],
 582        [ac_cv_sparse_target=other])])
 583    AS_CASE([$ac_cv_sparse_target],
 584      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 585      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 586      [SPARSEFLAGS= CGCCFLAGS=])
 587    AC_SUBST([SPARSEFLAGS])
 588    AC_SUBST([CGCCFLAGS])])
 589
 590 dnl OVS_SPARSE_EXTRA_INCLUDES
 591 dnl
 592 dnl The cgcc script from "sparse" does not search gcc's default
 593 dnl search path. Get the default search path from GCC and pass
 594 dnl them to sparse.
 595 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 596     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 597            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 598
 599 dnl OVS_ENABLE_SPARSE
 600 AC_DEFUN([OVS_ENABLE_SPARSE],
 601   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 602    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 603    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 604    : ${SPARSE=sparse}
 605    AC_SUBST([SPARSE])
 606    AC_CONFIG_COMMANDS_PRE(
 607      [if test $ovs_cv_gnu_make_if = yes; then
 608         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 609       fi])])
 610
 611 dnl OVS_PTHREAD_SET_NAME
 612 dnl
 613 dnl This checks for three known variants of pthreads functions for setting
 614 dnl the name of the current thread:
 615 dnl
 616 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 617 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 618 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 619 dnl
 620 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 621 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 622 dnl provide to it.
 623 dnl
 624 dnl This macro defines:
 625 dnl
 626 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 627 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 628 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 629 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 630   [AC_CHECK_FUNCS([pthread_set_name_np])
 631    if test $ac_cv_func_pthread_set_name_np != yes; then
 632      AC_CACHE_CHECK(
 633        [for pthread_setname_np() variant],
 634        [ovs_cv_pthread_setname_np],
 635        [AC_LINK_IFELSE(
 636          [AC_LANG_PROGRAM([#include <pthread.h>
 637   ], [pthread_setname_np(pthread_self(), "name");])],
 638          [ovs_cv_pthread_setname_np=glibc],
 639          [AC_LINK_IFELSE(
 640            [AC_LANG_PROGRAM([#include <pthread.h>
 641 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 642            [ovs_cv_pthread_setname_np=netbsd],
 643            [ovs_cv_pthread_setname_np=none])])])
 644      case $ovs_cv_pthread_setname_np in # (
 645        glibc)
 646           AC_DEFINE(
 647             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 648             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 649           ;; # (
 650        netbsd)
 651           AC_DEFINE(
 652             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 653             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 654           ;;
 655      esac
 656    fi])
 657
 658 dnl OVS_CHECK_LINUX_HOST.
 659 dnl
 660 dnl Checks whether we're building for a Linux host, based on the presence of
 661 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 662 dnl LINUX based on the result.
 663 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 664   [AC_CACHE_CHECK(
 665      [whether __linux__ is defined],
 666      [ovs_cv_linux],
 667      [AC_COMPILE_IFELSE(
 668         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 669         [ovs_cv_linux=true],
 670         [ovs_cv_linux=false])])
 671    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])