acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 0; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.0.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-lintel_dpdk"
 176     DPDK_EXTRA_LIB="-lfuse"
 177
 178     ovs_save_CFLAGS="$CFLAGS"
 179     ovs_save_LDFLAGS="$LDFLAGS"
 180     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 181     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 182
 183     # On some systems we have to add -ldl to link with dpdk
 184     #
 185     # This code, at first, tries to link without -ldl (""),
 186     # then adds it and tries again.
 187     # Before each attempt the search cache must be unset,
 188     # otherwise autoconf will stick with the old result
 189
 190     found=false
 191     save_LIBS=$LIBS
 192     for extras in "" "-ldl"; do
 193         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 194         AC_LINK_IFELSE(
 195            [AC_LANG_PROGRAM([#include <rte_config.h>
 196                              #include <rte_eal.h>],
 197                             [int rte_argc; char ** rte_argv;
 198                              rte_eal_init(rte_argc, rte_argv);])],
 199            [found=true])
 200         if $found; then
 201             break
 202         fi
 203     done
 204     if $found; then :; else
 205         AC_MSG_ERROR([cannot link with dpdk])
 206     fi
 207     CFLAGS="$ovs_save_CFLAGS"
 208     LDFLAGS="$ovs_save_LDFLAGS"
 209     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 210     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 211
 212     # DPDK pmd drivers are not linked unless --whole-archive is used.
 213     #
 214     # This happens because the rest of the DPDK code doesn't use any symbol in
 215     # the pmd driver objects, and the drivers register themselves using an
 216     # __attribute__((constructor)) function.
 217     #
 218     # These options are specified inside a single -Wl directive to prevent
 219     # autotools from reordering them.
 220     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 221     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 222     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 223   else
 224     RTE_SDK=
 225   fi
 226
 227   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 228 ])
 229
 230 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 231 dnl
 232 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 233 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 234 dnl <REGEX> translated to uppercase.
 235 AC_DEFUN([OVS_GREP_IFELSE], [
 236   AC_MSG_CHECKING([whether $2 matches in $1])
 237   if test -f $1; then
 238     grep '$2' $1 >/dev/null 2>&1
 239     status=$?
 240     case $status in
 241       0)
 242         AC_MSG_RESULT([yes])
 243         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 244         ;;
 245       1)
 246         AC_MSG_RESULT([no])
 247         $4
 248         ;;
 249       *)
 250         AC_MSG_ERROR([grep exited with status $status])
 251         ;;
 252     esac
 253   else
 254     AC_MSG_RESULT([file not found])
 255     $4
 256   fi
 257 ])
 258
 259 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 260 dnl
 261 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 262 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 263 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 264 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 265 dnl translated to uppercase.
 266 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 267   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 268   if test -f $1; then
 269     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3'
 270     status=$?
 271     case $status in
 272       0)
 273         AC_MSG_RESULT([yes])
 274         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 275         ;;
 276       1)
 277         AC_MSG_RESULT([no])
 278         $5
 279         ;;
 280       *)
 281         AC_MSG_ERROR([grep exited with status $status])
 282         ;;
 283     esac
 284   else
 285     AC_MSG_RESULT([file not found])
 286     $5
 287   fi
 288 ])
 289
 290 dnl OVS_DEFINE(NAME)
 291 dnl
 292 dnl Defines NAME to 1 in kcompat.h.
 293 AC_DEFUN([OVS_DEFINE], [
 294   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 295 ])
 296
 297 dnl OVS_CHECK_LINUX_COMPAT
 298 dnl
 299 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 300 dnl the directory in $KBUILD.
 301 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 302   rm -f datapath/linux/kcompat.h.new
 303   mkdir -p datapath/linux
 304   : > datapath/linux/kcompat.h.new
 305
 306   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 307                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 308
 309   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 310   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 311
 312   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 313   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 314
 315   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 316
 317   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 318   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 319                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 320   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 321                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 322
 323   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 331                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 334
 335   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 336                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 337                                    [rcu_read_lock_held])])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 339
 340   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 341   # is necessary because some versions of this header remove the
 342   # member but retain the kerneldoc comment that describes it (which
 343   # starts with @).  The brackets must be doubled because of m4
 344   # quoting rules.
 345   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 346                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 347   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 348   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 349                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 350   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 351                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 352   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 353                   [skb_copy_from_linear_data_offset])
 354   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 355                   [skb_reset_tail_pointer])
 356   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 357   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 358                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 359   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 360                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 361   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 362                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 366   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 373                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 374   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 376   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 377   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 378
 379   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 380                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 381   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 382                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 383   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 384                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 385
 386   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 387   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 388
 389   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 390   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 391   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 392   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 393   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 394                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 395   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 396   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 397                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 398
 399   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 400                         [genl_multicast_group], [id])
 401
 402   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 403   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 404   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 405   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 406   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 407   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 408   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 409   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 410
 411   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 412
 413   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 414                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 415   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 417
 418
 419   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 420
 421   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 422                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 423   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 424                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 425   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 426                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 427                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 428   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 429   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 430   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 431                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 432   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
 433                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
 434   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
 435                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
 436   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 437                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 438
 439   if cmp -s datapath/linux/kcompat.h.new \
 440             datapath/linux/kcompat.h >/dev/null 2>&1; then
 441     rm datapath/linux/kcompat.h.new
 442   else
 443     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 444   fi
 445 ])
 446
 447 dnl Checks for net/if_packet.h.
 448 AC_DEFUN([OVS_CHECK_IF_PACKET],
 449   [AC_CHECK_HEADER([net/if_packet.h],
 450                    [HAVE_IF_PACKET=yes],
 451                    [HAVE_IF_PACKET=no])
 452    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 453    if test "$HAVE_IF_PACKET" = yes; then
 454       AC_DEFINE([HAVE_IF_PACKET], [1],
 455                 [Define to 1 if net/if_packet.h is available.])
 456    fi])
 457
 458 dnl Checks for net/if_dl.h.
 459 dnl
 460 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 461 dnl or NetBSD.)
 462 AC_DEFUN([OVS_CHECK_IF_DL],
 463   [AC_CHECK_HEADER([net/if_dl.h],
 464                    [HAVE_IF_DL=yes],
 465                    [HAVE_IF_DL=no])
 466    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 467    if test "$HAVE_IF_DL" = yes; then
 468       AC_DEFINE([HAVE_IF_DL], [1],
 469                 [Define to 1 if net/if_dl.h is available.])
 470
 471       # On these platforms we use libpcap to access network devices.
 472       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 473    fi])
 474
 475 dnl Checks for buggy strtok_r.
 476 dnl
 477 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 478 dnl with optimization that can cause segfaults:
 479 dnl
 480 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 481 AC_DEFUN([OVS_CHECK_STRTOK_R],
 482   [AC_CACHE_CHECK(
 483      [whether strtok_r macro segfaults on some inputs],
 484      [ovs_cv_strtok_r_bug],
 485      [AC_RUN_IFELSE(
 486         [AC_LANG_PROGRAM([#include <stdio.h>
 487                           #include <string.h>
 488                          ],
 489                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 490                            /* Assume bug is present, because relatively minor
 491                               changes in compiler settings (e.g. optimization
 492                               level) can make it crop up. */
 493                            return 1;
 494                            #else
 495                            char string[] = ":::";
 496                            char *save_ptr = (char *) 0xc0ffee;
 497                            char *token1, *token2;
 498                            token1 = strtok_r(string, ":", &save_ptr);
 499                            token2 = strtok_r(NULL, ":", &save_ptr);
 500                            freopen ("/dev/null", "w", stdout);
 501                            printf ("%s %s\n", token1, token2);
 502                            return 0;
 503                            #endif
 504                           ]])],
 505         [ovs_cv_strtok_r_bug=no],
 506         [ovs_cv_strtok_r_bug=yes],
 507         [ovs_cv_strtok_r_bug=yes])])
 508    if test $ovs_cv_strtok_r_bug = yes; then
 509      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 510                [Define if strtok_r macro segfaults on some inputs])
 511    fi
 512 ])
 513
 514 dnl ----------------------------------------------------------------------
 515 dnl These macros are from GNU PSPP, with the following original license:
 516 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 517 dnl This file is free software; the Free Software Foundation
 518 dnl gives unlimited permission to copy and/or distribute it,
 519 dnl with or without modifications, as long as this notice is preserved.
 520
 521 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 522   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 523   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 524     [ovs_save_CFLAGS="$CFLAGS"
 525      dnl Include -Werror in the compiler options, because without -Werror
 526      dnl clang's GCC-compatible compiler driver does not return a failure
 527      dnl exit status even though it complains about options it does not
 528      dnl understand.
 529      dnl
 530      dnl Also, check stderr as gcc exits with status 0 for options
 531      dnl rejected at getopt level.
 532      dnl    % touch /tmp/a.c
 533      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 534      dnl    gcc: unrecognized option '-Qunused-arguments'
 535      dnl    0
 536      dnl    %
 537      CFLAGS="$CFLAGS $WERROR $1"
 538      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 539      CFLAGS="$ovs_save_CFLAGS"])
 540   if test $ovs_cv_name = yes; then
 541     m4_if([$2], [], [:], [$2])
 542   else
 543     m4_if([$3], [], [:], [$3])
 544   fi
 545 ])
 546
 547 dnl OVS_CHECK_WERROR
 548 dnl
 549 dnl Check whether the C compiler accepts -Werror.
 550 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 551 AC_DEFUN([OVS_CHECK_WERROR],
 552   [WERROR=
 553    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 554
 555 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 556 dnl Check whether the given C compiler OPTION is accepted.
 557 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 558 AC_DEFUN([OVS_CHECK_CC_OPTION],
 559   [AC_REQUIRE([OVS_CHECK_WERROR])
 560    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 561
 562 dnl OVS_ENABLE_OPTION([OPTION])
 563 dnl Check whether the given C compiler OPTION is accepted.
 564 dnl If so, add it to WARNING_FLAGS.
 565 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 566 AC_DEFUN([OVS_ENABLE_OPTION],
 567   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 568    AC_SUBST([WARNING_FLAGS])])
 569
 570 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 571 dnl Check whether the given C compiler OPTION is accepted.
 572 dnl If so, enable the given Automake CONDITIONAL.
 573
 574 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 575 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 576   [OVS_CHECK_CC_OPTION(
 577     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 578    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 579 dnl ----------------------------------------------------------------------
 580
 581 dnl Check for too-old XenServer.
 582 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 583   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 584     [if test -e /etc/redhat-release; then
 585        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 586      fi
 587      if test -z "$ovs_cv_xsversion"; then
 588        ovs_cv_xsversion=none
 589      fi])
 590   case $ovs_cv_xsversion in
 591     none)
 592       ;;
 593
 594     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 595     [[6-9]]* |                           dnl XenServer 6 or later
 596     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 597     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 598     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 599     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 600       ;;
 601
 602     *)
 603       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 604       ;;
 605   esac])
 606
 607 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 608 dnl
 609 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 610 dnl Runs 'if-true' if so, 'if-false' otherwise.
 611 AC_DEFUN([OVS_CHECK_MAKE_IF],
 612   [AC_CACHE_CHECK(
 613      [whether ${MAKE-make} has GNU make \$(if) extension],
 614      [ovs_cv_gnu_make_if],
 615      [cat <<'EOF' > conftest.mk
 616 conftest.out:
 617         echo $(if x,y,z) > conftest.out
 618 .PHONY: all
 619 EOF
 620       rm -f conftest.out
 621       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 622       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 623       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 624       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 625       result=`cat conftest.out`
 626       rm -f conftest.mk conftest.out
 627       if test "X$result" = "Xy"; then
 628         ovs_cv_gnu_make_if=yes
 629       else
 630         ovs_cv_gnu_make_if=no
 631       fi])])
 632
 633 dnl OVS_CHECK_GNU_MAKE
 634 dnl
 635 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 636 dnl only work with GNU make).
 637 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 638   [AC_CACHE_CHECK(
 639      [whether ${MAKE-make} is GNU make],
 640      [ovs_cv_gnu_make],
 641      [rm -f conftest.out
 642       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 643       ${MAKE-make} --version >conftest.out 2>&1
 644       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 645       result=`cat conftest.out`
 646       rm -f conftest.mk conftest.out
 647
 648       case $result in # (
 649         GNU*) ovs_cv_gnu_make=yes ;; # (
 650         *) ovs_cv_gnu_make=no ;;
 651       esac])
 652    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 653
 654 dnl OVS_CHECK_SPARSE_TARGET
 655 dnl
 656 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 657 dnl target for which the code is being built.  This helps it out.
 658 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 659   [AC_CACHE_CHECK(
 660     [target hint for cgcc],
 661     [ac_cv_sparse_target],
 662     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 663        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 664        [x86_64-*], [ac_cv_sparse_target=x86_64],
 665        [ac_cv_sparse_target=other])])
 666    AS_CASE([$ac_cv_sparse_target],
 667      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 668      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 669      [SPARSEFLAGS= CGCCFLAGS=])
 670    AC_SUBST([SPARSEFLAGS])
 671    AC_SUBST([CGCCFLAGS])])
 672
 673 dnl OVS_SPARSE_EXTRA_INCLUDES
 674 dnl
 675 dnl The cgcc script from "sparse" does not search gcc's default
 676 dnl search path. Get the default search path from GCC and pass
 677 dnl them to sparse.
 678 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 679     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 680            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 681
 682 dnl OVS_ENABLE_SPARSE
 683 AC_DEFUN([OVS_ENABLE_SPARSE],
 684   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 685    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 686    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 687    : ${SPARSE=sparse}
 688    AC_SUBST([SPARSE])
 689    AC_CONFIG_COMMANDS_PRE(
 690      [if test $ovs_cv_gnu_make_if = yes; then
 691         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 692       fi])])
 693
 694 dnl OVS_PTHREAD_SET_NAME
 695 dnl
 696 dnl This checks for three known variants of pthreads functions for setting
 697 dnl the name of the current thread:
 698 dnl
 699 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 700 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 701 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 702 dnl
 703 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 704 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 705 dnl provide to it.
 706 dnl
 707 dnl This macro defines:
 708 dnl
 709 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 710 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 711 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 712 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 713   [AC_CHECK_FUNCS([pthread_set_name_np])
 714    if test $ac_cv_func_pthread_set_name_np != yes; then
 715      AC_CACHE_CHECK(
 716        [for pthread_setname_np() variant],
 717        [ovs_cv_pthread_setname_np],
 718        [AC_LINK_IFELSE(
 719          [AC_LANG_PROGRAM([#include <pthread.h>
 720   ], [pthread_setname_np(pthread_self(), "name");])],
 721          [ovs_cv_pthread_setname_np=glibc],
 722          [AC_LINK_IFELSE(
 723            [AC_LANG_PROGRAM([#include <pthread.h>
 724 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 725            [ovs_cv_pthread_setname_np=netbsd],
 726            [ovs_cv_pthread_setname_np=none])])])
 727      case $ovs_cv_pthread_setname_np in # (
 728        glibc)
 729           AC_DEFINE(
 730             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 731             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 732           ;; # (
 733        netbsd)
 734           AC_DEFINE(
 735             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 736             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 737           ;;
 738      esac
 739    fi])
 740
 741 dnl OVS_CHECK_LINUX_HOST.
 742 dnl
 743 dnl Checks whether we're building for a Linux host, based on the presence of
 744 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 745 dnl LINUX based on the result.
 746 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 747   [AC_CACHE_CHECK(
 748      [whether __linux__ is defined],
 749      [ovs_cv_linux],
 750      [AC_COMPILE_IFELSE(
 751         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 752         [ovs_cv_linux=true],
 753         [ovs_cv_linux=false])])
 754    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])