acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-ldpdk"
 176     DPDK_EXTRA_LIB=""
 177     RTE_SDK_FULL=`readlink -f $RTE_SDK`
 178
 179     AC_COMPILE_IFELSE(
 180       [AC_LANG_PROGRAM([#include <$RTE_SDK_FULL/include/rte_config.h>
 181 #if !RTE_LIBRTE_VHOST_USER
 182 #error
 183 #endif], [])],
 184                     [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 185                          DPDK_EXTRA_LIB="-lfuse"])
 186
 187     ovs_save_CFLAGS="$CFLAGS"
 188     ovs_save_LDFLAGS="$LDFLAGS"
 189     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 190     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 191
 192     # On some systems we have to add -ldl to link with dpdk
 193     #
 194     # This code, at first, tries to link without -ldl (""),
 195     # then adds it and tries again.
 196     # Before each attempt the search cache must be unset,
 197     # otherwise autoconf will stick with the old result
 198
 199     found=false
 200     save_LIBS=$LIBS
 201     for extras in "" "-ldl"; do
 202         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 203         AC_LINK_IFELSE(
 204            [AC_LANG_PROGRAM([#include <rte_config.h>
 205                              #include <rte_eal.h>],
 206                             [int rte_argc; char ** rte_argv;
 207                              rte_eal_init(rte_argc, rte_argv);])],
 208            [found=true])
 209         if $found; then
 210             break
 211         fi
 212     done
 213     if $found; then :; else
 214         AC_MSG_ERROR([cannot link with dpdk])
 215     fi
 216     CFLAGS="$ovs_save_CFLAGS"
 217     LDFLAGS="$ovs_save_LDFLAGS"
 218     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 219     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 220     OVS_ENABLE_OPTION([-mssse3])
 221
 222     # DPDK pmd drivers are not linked unless --whole-archive is used.
 223     #
 224     # This happens because the rest of the DPDK code doesn't use any symbol in
 225     # the pmd driver objects, and the drivers register themselves using an
 226     # __attribute__((constructor)) function.
 227     #
 228     # These options are specified inside a single -Wl directive to prevent
 229     # autotools from reordering them.
 230     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 231     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 232     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 233
 234   else
 235     RTE_SDK=
 236   fi
 237
 238   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 239 ])
 240
 241 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 242 dnl
 243 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 244 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 245 dnl <REGEX> translated to uppercase.
 246 AC_DEFUN([OVS_GREP_IFELSE], [
 247   AC_MSG_CHECKING([whether $2 matches in $1])
 248   if test -f $1; then
 249     grep '$2' $1 >/dev/null 2>&1
 250     status=$?
 251     case $status in
 252       0)
 253         AC_MSG_RESULT([yes])
 254         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 255         ;;
 256       1)
 257         AC_MSG_RESULT([no])
 258         $4
 259         ;;
 260       *)
 261         AC_MSG_ERROR([grep exited with status $status])
 262         ;;
 263     esac
 264   else
 265     AC_MSG_RESULT([file not found])
 266     $4
 267   fi
 268 ])
 269
 270 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 271 dnl
 272 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 273 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 274 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 275 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 276 dnl translated to uppercase.
 277 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 278   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 279   if test -f $1; then
 280     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 281     status=$?
 282     case $status in
 283       0)
 284         AC_MSG_RESULT([yes])
 285         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 286         ;;
 287       1)
 288         AC_MSG_RESULT([no])
 289         $5
 290         ;;
 291       *)
 292         AC_MSG_ERROR([grep exited with status $status])
 293         ;;
 294     esac
 295   else
 296     AC_MSG_RESULT([file not found])
 297     $5
 298   fi
 299 ])
 300
 301 dnl OVS_DEFINE(NAME)
 302 dnl
 303 dnl Defines NAME to 1 in kcompat.h.
 304 AC_DEFUN([OVS_DEFINE], [
 305   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 306 ])
 307
 308 dnl OVS_CHECK_LINUX_COMPAT
 309 dnl
 310 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 311 dnl the directory in $KBUILD.
 312 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 313   rm -f datapath/linux/kcompat.h.new
 314   mkdir -p datapath/linux
 315   : > datapath/linux/kcompat.h.new
 316
 317   echo '#include <linux/version.h>
 318 #ifndef RHEL_RELEASE_CODE
 319 #define RHEL_RELEASE_CODE 0
 320 #define RHEL_RELEASE_VERSION(a, b) 0
 321 #endif' >> datapath/linux/kcompat.h.new
 322
 323   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 324                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 325
 326   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 327                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 328   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 329
 330   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 335
 336   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 337   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 339   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 340   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 341
 342   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 344   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 345                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 346   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 347                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 348
 349   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 350                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 351   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_do_fragment])
 352   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment])
 353   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 354   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 355                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 356   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 357                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 358   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 359                         [frags_work])
 360   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 361                         [rwlock])
 362
 363   OVS_GREP_IFELSE([$KSRC/include/net/dst_metadata.h], [metadata_dst])
 364
 365   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 366                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 374   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 376   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_rx_handler_register])
 377   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_extended])
 378   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [rx_handler_func_t.*pskb],
 379                   [OVS_DEFINE([HAVE_RX_HANDLER_PSKB])])
 380   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 381                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 382   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 383   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 384                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 385   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 386
 387   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 388   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 389   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 390                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 391   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 392                         [fragment], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 393
 394   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 395                   [tmpl_alloc.*conntrack_zone],
 396                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 397   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 398                   [nf_ct_zone_init])
 399   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 400                   [nf_connlabels_get])
 401
 402   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 403   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 404
 405   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 406   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 407   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 408                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 409   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 410
 411   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 412                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 413                                    [rcu_read_lock_held])])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 415
 416   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 417   # is necessary because some versions of this header remove the
 418   # member but retain the kerneldoc comment that describes it (which
 419   # starts with @).  The brackets must be doubled because of m4
 420   # quoting rules.
 421   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 422                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 423   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 424   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 425   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_mac_header])
 426   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_network_header])
 427   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 428   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 429                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 430   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 431   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 432                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 433   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 434                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 435   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 436                   [skb_copy_from_linear_data_offset])
 437   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 438                   [skb_reset_tail_pointer])
 439   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 440   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 441                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 442   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 443                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 444   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 445                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 446   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 447   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 448   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 449   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 450   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 451   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 452   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 453   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 454   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 455   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 456                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 457   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 458                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 459   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 460   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 461   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 462
 463   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 464                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 465   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 466                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 467   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 468                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 469
 470   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 471   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 472
 473   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 474
 475   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 476   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 477   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 478   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 479   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 480                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 481   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 482   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 483                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 484
 485   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 486                         [genl_multicast_group], [id])
 487   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 488
 489   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 490   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 491   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 492   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 493   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 494   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 495                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 496   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 497                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 498
 499   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 500   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 501   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 502   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 503   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 504   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 505   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 506   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 507                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 508
 509   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 510
 511   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 512                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 513   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 514   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 515   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 516
 517   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 518
 519   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 520                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 521   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 522                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 523   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [VXLAN_HF_RCO])
 524   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 525                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 526                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 527   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 528   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 529   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 530   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [ipv6_v6only],
 531                   [OVS_DEFINE([HAVE_UDP_TUNNEL_IPV6])])
 532
 533   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 534                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 535   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 536                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 537
 538   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 539                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 540
 541   if test "$version" = 4 && test "$patchlevel" -le 2; then
 542         OVS_DEFINE([OVS_FRAGMENT_BACKPORT])
 543   elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 544         OVS_DEFINE([OVS_FRAGMENT_BACKPORT])
 545   fi
 546
 547   if cmp -s datapath/linux/kcompat.h.new \
 548             datapath/linux/kcompat.h >/dev/null 2>&1; then
 549     rm datapath/linux/kcompat.h.new
 550   else
 551     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 552   fi
 553 ])
 554
 555 dnl Checks for net/if_packet.h.
 556 AC_DEFUN([OVS_CHECK_IF_PACKET],
 557   [AC_CHECK_HEADER([net/if_packet.h],
 558                    [HAVE_IF_PACKET=yes],
 559                    [HAVE_IF_PACKET=no])
 560    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 561    if test "$HAVE_IF_PACKET" = yes; then
 562       AC_DEFINE([HAVE_IF_PACKET], [1],
 563                 [Define to 1 if net/if_packet.h is available.])
 564    fi])
 565
 566 dnl Checks for net/if_dl.h.
 567 dnl
 568 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 569 dnl or NetBSD.)
 570 AC_DEFUN([OVS_CHECK_IF_DL],
 571   [AC_CHECK_HEADER([net/if_dl.h],
 572                    [HAVE_IF_DL=yes],
 573                    [HAVE_IF_DL=no])
 574    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 575    if test "$HAVE_IF_DL" = yes; then
 576       AC_DEFINE([HAVE_IF_DL], [1],
 577                 [Define to 1 if net/if_dl.h is available.])
 578
 579       # On these platforms we use libpcap to access network devices.
 580       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 581    fi])
 582
 583 dnl Checks for buggy strtok_r.
 584 dnl
 585 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 586 dnl with optimization that can cause segfaults:
 587 dnl
 588 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 589 AC_DEFUN([OVS_CHECK_STRTOK_R],
 590   [AC_CACHE_CHECK(
 591      [whether strtok_r macro segfaults on some inputs],
 592      [ovs_cv_strtok_r_bug],
 593      [AC_RUN_IFELSE(
 594         [AC_LANG_PROGRAM([#include <stdio.h>
 595                           #include <string.h>
 596                          ],
 597                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 598                            /* Assume bug is present, because relatively minor
 599                               changes in compiler settings (e.g. optimization
 600                               level) can make it crop up. */
 601                            return 1;
 602                            #else
 603                            char string[] = ":::";
 604                            char *save_ptr = (char *) 0xc0ffee;
 605                            char *token1, *token2;
 606                            token1 = strtok_r(string, ":", &save_ptr);
 607                            token2 = strtok_r(NULL, ":", &save_ptr);
 608                            freopen ("/dev/null", "w", stdout);
 609                            printf ("%s %s\n", token1, token2);
 610                            return 0;
 611                            #endif
 612                           ]])],
 613         [ovs_cv_strtok_r_bug=no],
 614         [ovs_cv_strtok_r_bug=yes],
 615         [ovs_cv_strtok_r_bug=yes])])
 616    if test $ovs_cv_strtok_r_bug = yes; then
 617      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 618                [Define if strtok_r macro segfaults on some inputs])
 619    fi
 620 ])
 621
 622 dnl ----------------------------------------------------------------------
 623 dnl These macros are from GNU PSPP, with the following original license:
 624 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 625 dnl This file is free software; the Free Software Foundation
 626 dnl gives unlimited permission to copy and/or distribute it,
 627 dnl with or without modifications, as long as this notice is preserved.
 628
 629 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 630   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 631   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 632     [ovs_save_CFLAGS="$CFLAGS"
 633      dnl Include -Werror in the compiler options, because without -Werror
 634      dnl clang's GCC-compatible compiler driver does not return a failure
 635      dnl exit status even though it complains about options it does not
 636      dnl understand.
 637      dnl
 638      dnl Also, check stderr as gcc exits with status 0 for options
 639      dnl rejected at getopt level.
 640      dnl    % touch /tmp/a.c
 641      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 642      dnl    gcc: unrecognized option '-Qunused-arguments'
 643      dnl    0
 644      dnl    %
 645      CFLAGS="$CFLAGS $WERROR $1"
 646      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 647      CFLAGS="$ovs_save_CFLAGS"])
 648   if test $ovs_cv_name = yes; then
 649     m4_if([$2], [], [:], [$2])
 650   else
 651     m4_if([$3], [], [:], [$3])
 652   fi
 653 ])
 654
 655 dnl OVS_CHECK_WERROR
 656 dnl
 657 dnl Check whether the C compiler accepts -Werror.
 658 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 659 AC_DEFUN([OVS_CHECK_WERROR],
 660   [WERROR=
 661    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 662
 663 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 664 dnl Check whether the given C compiler OPTION is accepted.
 665 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 666 AC_DEFUN([OVS_CHECK_CC_OPTION],
 667   [AC_REQUIRE([OVS_CHECK_WERROR])
 668    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 669
 670 dnl OVS_ENABLE_OPTION([OPTION])
 671 dnl Check whether the given C compiler OPTION is accepted.
 672 dnl If so, add it to WARNING_FLAGS.
 673 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 674 AC_DEFUN([OVS_ENABLE_OPTION],
 675   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 676    AC_SUBST([WARNING_FLAGS])])
 677
 678 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 679 dnl Check whether the given C compiler OPTION is accepted.
 680 dnl If so, enable the given Automake CONDITIONAL.
 681
 682 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 683 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 684   [OVS_CHECK_CC_OPTION(
 685     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 686    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 687 dnl ----------------------------------------------------------------------
 688
 689 dnl Check for too-old XenServer.
 690 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 691   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 692     [if test -e /etc/redhat-release; then
 693        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 694      fi
 695      if test -z "$ovs_cv_xsversion"; then
 696        ovs_cv_xsversion=none
 697      fi])
 698   case $ovs_cv_xsversion in
 699     none)
 700       ;;
 701
 702     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 703     [[6-9]]* |                           dnl XenServer 6 or later
 704     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 705     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 706     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 707     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 708       ;;
 709
 710     *)
 711       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 712       ;;
 713   esac])
 714
 715 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 716 dnl
 717 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 718 dnl Runs 'if-true' if so, 'if-false' otherwise.
 719 AC_DEFUN([OVS_CHECK_MAKE_IF],
 720   [AC_CACHE_CHECK(
 721      [whether ${MAKE-make} has GNU make \$(if) extension],
 722      [ovs_cv_gnu_make_if],
 723      [cat <<'EOF' > conftest.mk
 724 conftest.out:
 725         echo $(if x,y,z) > conftest.out
 726 .PHONY: all
 727 EOF
 728       rm -f conftest.out
 729       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 730       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 731       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 732       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 733       result=`cat conftest.out`
 734       rm -f conftest.mk conftest.out
 735       if test "X$result" = "Xy"; then
 736         ovs_cv_gnu_make_if=yes
 737       else
 738         ovs_cv_gnu_make_if=no
 739       fi])])
 740
 741 dnl OVS_CHECK_GNU_MAKE
 742 dnl
 743 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 744 dnl only work with GNU make).
 745 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 746   [AC_CACHE_CHECK(
 747      [whether ${MAKE-make} is GNU make],
 748      [ovs_cv_gnu_make],
 749      [rm -f conftest.out
 750       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 751       ${MAKE-make} --version >conftest.out 2>&1
 752       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 753       result=`cat conftest.out`
 754       rm -f conftest.mk conftest.out
 755
 756       case $result in # (
 757         GNU*) ovs_cv_gnu_make=yes ;; # (
 758         *) ovs_cv_gnu_make=no ;;
 759       esac])
 760    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 761
 762 dnl OVS_CHECK_SPARSE_TARGET
 763 dnl
 764 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 765 dnl target for which the code is being built.  This helps it out.
 766 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 767   [AC_CACHE_CHECK(
 768     [target hint for cgcc],
 769     [ac_cv_sparse_target],
 770     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 771        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 772        [x86_64-*], [ac_cv_sparse_target=x86_64],
 773        [ac_cv_sparse_target=other])])
 774    AS_CASE([$ac_cv_sparse_target],
 775      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 776      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 777      [SPARSEFLAGS= CGCCFLAGS=])
 778    AC_SUBST([SPARSEFLAGS])
 779    AC_SUBST([CGCCFLAGS])])
 780
 781 dnl OVS_SPARSE_EXTRA_INCLUDES
 782 dnl
 783 dnl The cgcc script from "sparse" does not search gcc's default
 784 dnl search path. Get the default search path from GCC and pass
 785 dnl them to sparse.
 786 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 787     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 788            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 789
 790 dnl OVS_ENABLE_SPARSE
 791 AC_DEFUN([OVS_ENABLE_SPARSE],
 792   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 793    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 794    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 795    : ${SPARSE=sparse}
 796    AC_SUBST([SPARSE])
 797    AC_CONFIG_COMMANDS_PRE(
 798      [if test $ovs_cv_gnu_make_if = yes; then
 799         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 800       fi])])
 801
 802 dnl OVS_PTHREAD_SET_NAME
 803 dnl
 804 dnl This checks for three known variants of pthreads functions for setting
 805 dnl the name of the current thread:
 806 dnl
 807 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 808 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 809 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 810 dnl
 811 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 812 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 813 dnl provide to it.
 814 dnl
 815 dnl This macro defines:
 816 dnl
 817 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 818 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 819 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 820 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 821   [AC_CHECK_FUNCS([pthread_set_name_np])
 822    if test $ac_cv_func_pthread_set_name_np != yes; then
 823      AC_CACHE_CHECK(
 824        [for pthread_setname_np() variant],
 825        [ovs_cv_pthread_setname_np],
 826        [AC_LINK_IFELSE(
 827          [AC_LANG_PROGRAM([#include <pthread.h>
 828   ], [pthread_setname_np(pthread_self(), "name");])],
 829          [ovs_cv_pthread_setname_np=glibc],
 830          [AC_LINK_IFELSE(
 831            [AC_LANG_PROGRAM([#include <pthread.h>
 832 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 833            [ovs_cv_pthread_setname_np=netbsd],
 834            [ovs_cv_pthread_setname_np=none])])])
 835      case $ovs_cv_pthread_setname_np in # (
 836        glibc)
 837           AC_DEFINE(
 838             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 839             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 840           ;; # (
 841        netbsd)
 842           AC_DEFINE(
 843             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 844             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 845           ;;
 846      esac
 847    fi])
 848
 849 dnl OVS_CHECK_LINUX_HOST.
 850 dnl
 851 dnl Checks whether we're building for a Linux host, based on the presence of
 852 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 853 dnl LINUX based on the result.
 854 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 855   [AC_CACHE_CHECK(
 856      [whether __linux__ is defined],
 857      [ovs_cv_linux],
 858      [AC_COMPILE_IFELSE(
 859         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 860         [ovs_cv_linux=true],
 861         [ovs_cv_linux=false])])
 862    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])