acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 19; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.19.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIB="-lintel_dpdk"
 174     DPDK_EXTRA_LIB="-lfuse"
 175
 176     ovs_save_CFLAGS="$CFLAGS"
 177     ovs_save_LDFLAGS="$LDFLAGS"
 178     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 179     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 180
 181     # On some systems we have to add -ldl to link with dpdk
 182     #
 183     # This code, at first, tries to link without -ldl (""),
 184     # then adds it and tries again.
 185     # Before each attempt the search cache must be unset,
 186     # otherwise autoconf will stick with the old result
 187
 188     found=false
 189     save_LIBS=$LIBS
 190     for extras in "" "-ldl"; do
 191         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 192         AC_LINK_IFELSE(
 193            [AC_LANG_PROGRAM([#include <rte_config.h>
 194                              #include <rte_eal.h>],
 195                             [int rte_argc; char ** rte_argv;
 196                              rte_eal_init(rte_argc, rte_argv);])],
 197            [found=true])
 198         if $found; then
 199             break
 200         fi
 201     done
 202     if $found; then :; else
 203         AC_MSG_ERROR([cannot link with dpdk])
 204     fi
 205     CFLAGS="$ovs_save_CFLAGS"
 206     LDFLAGS="$ovs_save_LDFLAGS"
 207     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 208     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 209
 210     # DPDK pmd drivers are not linked unless --whole-archive is used.
 211     #
 212     # This happens because the rest of the DPDK code doesn't use any symbol in
 213     # the pmd driver objects, and the drivers register themselves using an
 214     # __attribute__((constructor)) function.
 215     #
 216     # These options are specified inside a single -Wl directive to prevent
 217     # autotools from reordering them.
 218     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 219     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 220     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 221   else
 222     RTE_SDK=
 223   fi
 224
 225   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 226 ])
 227
 228 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 229 dnl
 230 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 231 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 232 dnl <REGEX> translated to uppercase.
 233 AC_DEFUN([OVS_GREP_IFELSE], [
 234   AC_MSG_CHECKING([whether $2 matches in $1])
 235   if test -f $1; then
 236     grep '$2' $1 >/dev/null 2>&1
 237     status=$?
 238     case $status in
 239       0)
 240         AC_MSG_RESULT([yes])
 241         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 242         ;;
 243       1)
 244         AC_MSG_RESULT([no])
 245         $4
 246         ;;
 247       *)
 248         AC_MSG_ERROR([grep exited with status $status])
 249         ;;
 250     esac
 251   else
 252     AC_MSG_RESULT([file not found])
 253     $4
 254   fi
 255 ])
 256
 257 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 258 dnl
 259 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 260 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 261 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 262 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 263 dnl translated to uppercase.
 264 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 265   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 266   if test -f $1; then
 267     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3'
 268     status=$?
 269     case $status in
 270       0)
 271         AC_MSG_RESULT([yes])
 272         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 273         ;;
 274       1)
 275         AC_MSG_RESULT([no])
 276         $5
 277         ;;
 278       *)
 279         AC_MSG_ERROR([grep exited with status $status])
 280         ;;
 281     esac
 282   else
 283     AC_MSG_RESULT([file not found])
 284     $5
 285   fi
 286 ])
 287
 288 dnl OVS_DEFINE(NAME)
 289 dnl
 290 dnl Defines NAME to 1 in kcompat.h.
 291 AC_DEFUN([OVS_DEFINE], [
 292   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 293 ])
 294
 295 dnl OVS_CHECK_LINUX_COMPAT
 296 dnl
 297 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 298 dnl the directory in $KBUILD.
 299 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 300   rm -f datapath/linux/kcompat.h.new
 301   mkdir -p datapath/linux
 302   : > datapath/linux/kcompat.h.new
 303
 304   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 305                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 306
 307   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 308   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 309
 310   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 311   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 312
 313   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 314
 315   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 316   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 317                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 318   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 319                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 320
 321   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 322   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 323   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 328
 329   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 330
 331   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 332                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 333                                    [rcu_read_lock_held])])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 335
 336   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 337   # is necessary because some versions of this header remove the
 338   # member but retain the kerneldoc comment that describes it (which
 339   # starts with @).  The brackets must be doubled because of m4
 340   # quoting rules.
 341   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 342                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 344   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 345                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 346   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 347                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 348   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 349                   [skb_copy_from_linear_data_offset])
 350   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 351                   [skb_reset_tail_pointer])
 352   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 353   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 354                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 355   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 356                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 357   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 358                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 359   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 360   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 361   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 366   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 369                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 374
 375   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 376                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 377   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 378                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 379   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 380                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 381
 382   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 383   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 384
 385   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 386   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 387   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 388   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 389   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 390                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 391   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 392   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 393                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 394
 395   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 396                         [genl_multicast_group], [id])
 397
 398   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 399   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 400   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 401   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 402   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 403   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 404   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 405   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 406
 407   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 408
 409   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 410                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 411   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 412   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 413
 414
 415   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 416
 417   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 418                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 419   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 420                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 421   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 422                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 423                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 424   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 425   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 426   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 427                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 428   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
 429                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
 430   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
 431                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
 432   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 433                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 434
 435   if cmp -s datapath/linux/kcompat.h.new \
 436             datapath/linux/kcompat.h >/dev/null 2>&1; then
 437     rm datapath/linux/kcompat.h.new
 438   else
 439     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 440   fi
 441 ])
 442
 443 dnl Checks for net/if_packet.h.
 444 AC_DEFUN([OVS_CHECK_IF_PACKET],
 445   [AC_CHECK_HEADER([net/if_packet.h],
 446                    [HAVE_IF_PACKET=yes],
 447                    [HAVE_IF_PACKET=no])
 448    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 449    if test "$HAVE_IF_PACKET" = yes; then
 450       AC_DEFINE([HAVE_IF_PACKET], [1],
 451                 [Define to 1 if net/if_packet.h is available.])
 452    fi])
 453
 454 dnl Checks for net/if_dl.h.
 455 dnl
 456 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 457 dnl or NetBSD.)
 458 AC_DEFUN([OVS_CHECK_IF_DL],
 459   [AC_CHECK_HEADER([net/if_dl.h],
 460                    [HAVE_IF_DL=yes],
 461                    [HAVE_IF_DL=no])
 462    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 463    if test "$HAVE_IF_DL" = yes; then
 464       AC_DEFINE([HAVE_IF_DL], [1],
 465                 [Define to 1 if net/if_dl.h is available.])
 466
 467       # On these platforms we use libpcap to access network devices.
 468       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 469    fi])
 470
 471 dnl Checks for buggy strtok_r.
 472 dnl
 473 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 474 dnl with optimization that can cause segfaults:
 475 dnl
 476 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 477 AC_DEFUN([OVS_CHECK_STRTOK_R],
 478   [AC_CACHE_CHECK(
 479      [whether strtok_r macro segfaults on some inputs],
 480      [ovs_cv_strtok_r_bug],
 481      [AC_RUN_IFELSE(
 482         [AC_LANG_PROGRAM([#include <stdio.h>
 483                           #include <string.h>
 484                          ],
 485                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 486                            /* Assume bug is present, because relatively minor
 487                               changes in compiler settings (e.g. optimization
 488                               level) can make it crop up. */
 489                            return 1;
 490                            #else
 491                            char string[] = ":::";
 492                            char *save_ptr = (char *) 0xc0ffee;
 493                            char *token1, *token2;
 494                            token1 = strtok_r(string, ":", &save_ptr);
 495                            token2 = strtok_r(NULL, ":", &save_ptr);
 496                            freopen ("/dev/null", "w", stdout);
 497                            printf ("%s %s\n", token1, token2);
 498                            return 0;
 499                            #endif
 500                           ]])],
 501         [ovs_cv_strtok_r_bug=no],
 502         [ovs_cv_strtok_r_bug=yes],
 503         [ovs_cv_strtok_r_bug=yes])])
 504    if test $ovs_cv_strtok_r_bug = yes; then
 505      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 506                [Define if strtok_r macro segfaults on some inputs])
 507    fi
 508 ])
 509
 510 dnl ----------------------------------------------------------------------
 511 dnl These macros are from GNU PSPP, with the following original license:
 512 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 513 dnl This file is free software; the Free Software Foundation
 514 dnl gives unlimited permission to copy and/or distribute it,
 515 dnl with or without modifications, as long as this notice is preserved.
 516
 517 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 518   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 519   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 520     [ovs_save_CFLAGS="$CFLAGS"
 521      dnl Include -Werror in the compiler options, because without -Werror
 522      dnl clang's GCC-compatible compiler driver does not return a failure
 523      dnl exit status even though it complains about options it does not
 524      dnl understand.
 525      dnl
 526      dnl Also, check stderr as gcc exits with status 0 for options
 527      dnl rejected at getopt level.
 528      dnl    % touch /tmp/a.c
 529      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 530      dnl    gcc: unrecognized option '-Qunused-arguments'
 531      dnl    0
 532      dnl    %
 533      CFLAGS="$CFLAGS $WERROR $1"
 534      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 535      CFLAGS="$ovs_save_CFLAGS"])
 536   if test $ovs_cv_name = yes; then
 537     m4_if([$2], [], [:], [$2])
 538   else
 539     m4_if([$3], [], [:], [$3])
 540   fi
 541 ])
 542
 543 dnl OVS_CHECK_WERROR
 544 dnl
 545 dnl Check whether the C compiler accepts -Werror.
 546 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 547 AC_DEFUN([OVS_CHECK_WERROR],
 548   [WERROR=
 549    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 550
 551 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 552 dnl Check whether the given C compiler OPTION is accepted.
 553 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 554 AC_DEFUN([OVS_CHECK_CC_OPTION],
 555   [AC_REQUIRE([OVS_CHECK_WERROR])
 556    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 557
 558 dnl OVS_ENABLE_OPTION([OPTION])
 559 dnl Check whether the given C compiler OPTION is accepted.
 560 dnl If so, add it to WARNING_FLAGS.
 561 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 562 AC_DEFUN([OVS_ENABLE_OPTION],
 563   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 564    AC_SUBST([WARNING_FLAGS])])
 565
 566 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 567 dnl Check whether the given C compiler OPTION is accepted.
 568 dnl If so, enable the given Automake CONDITIONAL.
 569
 570 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 571 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 572   [OVS_CHECK_CC_OPTION(
 573     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 574    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 575 dnl ----------------------------------------------------------------------
 576
 577 dnl Check for too-old XenServer.
 578 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 579   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 580     [if test -e /etc/redhat-release; then
 581        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 582      fi
 583      if test -z "$ovs_cv_xsversion"; then
 584        ovs_cv_xsversion=none
 585      fi])
 586   case $ovs_cv_xsversion in
 587     none)
 588       ;;
 589
 590     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 591     [[6-9]]* |                           dnl XenServer 6 or later
 592     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 593     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 594     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 595     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 596       ;;
 597
 598     *)
 599       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 600       ;;
 601   esac])
 602
 603 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 604 dnl
 605 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 606 dnl Runs 'if-true' if so, 'if-false' otherwise.
 607 AC_DEFUN([OVS_CHECK_MAKE_IF],
 608   [AC_CACHE_CHECK(
 609      [whether ${MAKE-make} has GNU make \$(if) extension],
 610      [ovs_cv_gnu_make_if],
 611      [cat <<'EOF' > conftest.mk
 612 conftest.out:
 613         echo $(if x,y,z) > conftest.out
 614 .PHONY: all
 615 EOF
 616       rm -f conftest.out
 617       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 618       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 619       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 620       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 621       result=`cat conftest.out`
 622       rm -f conftest.mk conftest.out
 623       if test "X$result" = "Xy"; then
 624         ovs_cv_gnu_make_if=yes
 625       else
 626         ovs_cv_gnu_make_if=no
 627       fi])])
 628
 629 dnl OVS_CHECK_GNU_MAKE
 630 dnl
 631 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 632 dnl only work with GNU make).
 633 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 634   [AC_CACHE_CHECK(
 635      [whether ${MAKE-make} is GNU make],
 636      [ovs_cv_gnu_make],
 637      [rm -f conftest.out
 638       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 639       ${MAKE-make} --version >conftest.out 2>&1
 640       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 641       result=`cat conftest.out`
 642       rm -f conftest.mk conftest.out
 643
 644       case $result in # (
 645         GNU*) ovs_cv_gnu_make=yes ;; # (
 646         *) ovs_cv_gnu_make=no ;;
 647       esac])
 648    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 649
 650 dnl OVS_CHECK_SPARSE_TARGET
 651 dnl
 652 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 653 dnl target for which the code is being built.  This helps it out.
 654 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 655   [AC_CACHE_CHECK(
 656     [target hint for cgcc],
 657     [ac_cv_sparse_target],
 658     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 659        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 660        [x86_64-*], [ac_cv_sparse_target=x86_64],
 661        [ac_cv_sparse_target=other])])
 662    AS_CASE([$ac_cv_sparse_target],
 663      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 664      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 665      [SPARSEFLAGS= CGCCFLAGS=])
 666    AC_SUBST([SPARSEFLAGS])
 667    AC_SUBST([CGCCFLAGS])])
 668
 669 dnl OVS_SPARSE_EXTRA_INCLUDES
 670 dnl
 671 dnl The cgcc script from "sparse" does not search gcc's default
 672 dnl search path. Get the default search path from GCC and pass
 673 dnl them to sparse.
 674 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 675     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 676            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 677
 678 dnl OVS_ENABLE_SPARSE
 679 AC_DEFUN([OVS_ENABLE_SPARSE],
 680   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 681    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 682    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 683    : ${SPARSE=sparse}
 684    AC_SUBST([SPARSE])
 685    AC_CONFIG_COMMANDS_PRE(
 686      [if test $ovs_cv_gnu_make_if = yes; then
 687         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 688       fi])])
 689
 690 dnl OVS_PTHREAD_SET_NAME
 691 dnl
 692 dnl This checks for three known variants of pthreads functions for setting
 693 dnl the name of the current thread:
 694 dnl
 695 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 696 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 697 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 698 dnl
 699 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 700 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 701 dnl provide to it.
 702 dnl
 703 dnl This macro defines:
 704 dnl
 705 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 706 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 707 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 708 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 709   [AC_CHECK_FUNCS([pthread_set_name_np])
 710    if test $ac_cv_func_pthread_set_name_np != yes; then
 711      AC_CACHE_CHECK(
 712        [for pthread_setname_np() variant],
 713        [ovs_cv_pthread_setname_np],
 714        [AC_LINK_IFELSE(
 715          [AC_LANG_PROGRAM([#include <pthread.h>
 716   ], [pthread_setname_np(pthread_self(), "name");])],
 717          [ovs_cv_pthread_setname_np=glibc],
 718          [AC_LINK_IFELSE(
 719            [AC_LANG_PROGRAM([#include <pthread.h>
 720 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 721            [ovs_cv_pthread_setname_np=netbsd],
 722            [ovs_cv_pthread_setname_np=none])])])
 723      case $ovs_cv_pthread_setname_np in # (
 724        glibc)
 725           AC_DEFINE(
 726             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 727             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 728           ;; # (
 729        netbsd)
 730           AC_DEFINE(
 731             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 732             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 733           ;;
 734      esac
 735    fi])
 736
 737 dnl OVS_CHECK_LINUX_HOST.
 738 dnl
 739 dnl Checks whether we're building for a Linux host, based on the presence of
 740 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 741 dnl LINUX based on the result.
 742 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 743   [AC_CACHE_CHECK(
 744      [whether __linux__ is defined],
 745      [ovs_cv_linux],
 746      [AC_COMPILE_IFELSE(
 747         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 748         [ovs_cv_linux=true],
 749         [ovs_cv_linux=false])])
 750    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])