acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 14; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.14.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173
 174     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 175     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 176
 177     # On some systems we have to add -ldl to link with dpdk
 178     #
 179     # This code, at first, tries to link without -ldl (""),
 180     # then adds it and tries again.
 181     # Before each attempt the search cache must be unset,
 182     # otherwise autoconf will stick with the old result
 183
 184     found=false
 185     save_LIBS=$LIBS
 186     for extras in "" "-ldl"; do
 187         LIBS="-lintel_dpdk $extras $save_LIBS"
 188         AC_LINK_IFELSE(
 189            [AC_LANG_PROGRAM([#include <rte_config.h>
 190                              #include <rte_eal.h>],
 191                             [int rte_argc; char ** rte_argv;
 192                              rte_eal_init(rte_argc, rte_argv);])],
 193            [found=true])
 194         if $found; then
 195             break
 196         fi
 197     done
 198     if $found; then :; else
 199         AC_MSG_ERROR([cannot link with dpdk])
 200     fi
 201
 202     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 203   else
 204     RTE_SDK=
 205   fi
 206
 207   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 208 ])
 209
 210 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 211 dnl
 212 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 213 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 214 dnl <REGEX> translated to uppercase.
 215 AC_DEFUN([OVS_GREP_IFELSE], [
 216   AC_MSG_CHECKING([whether $2 matches in $1])
 217   if test -f $1; then
 218     grep '$2' $1 >/dev/null 2>&1
 219     status=$?
 220     case $status in
 221       0)
 222         AC_MSG_RESULT([yes])
 223         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 224         ;;
 225       1)
 226         AC_MSG_RESULT([no])
 227         $4
 228         ;;
 229       *)
 230         AC_MSG_ERROR([grep exited with status $status])
 231         ;;
 232     esac
 233   else
 234     AC_MSG_RESULT([file not found])
 235     $4
 236   fi
 237 ])
 238
 239 dnl OVS_DEFINE(NAME)
 240 dnl
 241 dnl Defines NAME to 1 in kcompat.h.
 242 AC_DEFUN([OVS_DEFINE], [
 243   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 244 ])
 245
 246 AC_DEFUN([OVS_CHECK_LOG2_H], [
 247   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 248   if test -e $KSRC/include/linux/log2.h; then
 249     AC_MSG_RESULT([yes])
 250     OVS_DEFINE([HAVE_LOG2_H])
 251   else
 252     AC_MSG_RESULT([no])
 253   fi
 254 ])
 255
 256 dnl OVS_CHECK_LINUX_COMPAT
 257 dnl
 258 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 259 dnl the directory in $KBUILD.
 260 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 261   rm -f datapath/linux/kcompat.h.new
 262   mkdir -p datapath/linux
 263   : > datapath/linux/kcompat.h.new
 264
 265   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 266                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 267
 268   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 269
 270   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 271   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 272
 273   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 274
 275   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 276
 277   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 278   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 279   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 280   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 281   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 282   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 283   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 284
 285   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 286
 287   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 288                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 289                                    [rcu_read_lock_held])])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 291
 292   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 293   # is necessary because some versions of this header remove the
 294   # member but retain the kerneldoc comment that describes it (which
 295   # starts with @).  The brackets must be doubled because of m4
 296   # quoting rules.
 297   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 298                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 299   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 300   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 301                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 302   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 303                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 304   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 305                   [skb_copy_from_linear_data_offset])
 306   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 307                   [skb_reset_tail_pointer])
 308   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 309   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 310                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 311   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 312                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 313   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 314                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 315   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 316   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 317   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 318   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 319   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 320   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 321   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 322   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 323   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 325
 326   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 327                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 329                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 330   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 331                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 334   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 335
 336   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 337   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 338   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 339   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 340   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 341   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 342   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 343
 344   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 345
 346   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 347                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 348
 349   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 350
 351   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 352                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 353
 354   OVS_CHECK_LOG2_H
 355
 356   if cmp -s datapath/linux/kcompat.h.new \
 357             datapath/linux/kcompat.h >/dev/null 2>&1; then
 358     rm datapath/linux/kcompat.h.new
 359   else
 360     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 361   fi
 362 ])
 363
 364 dnl Checks for net/if_packet.h.
 365 AC_DEFUN([OVS_CHECK_IF_PACKET],
 366   [AC_CHECK_HEADER([net/if_packet.h],
 367                    [HAVE_IF_PACKET=yes],
 368                    [HAVE_IF_PACKET=no])
 369    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 370    if test "$HAVE_IF_PACKET" = yes; then
 371       AC_DEFINE([HAVE_IF_PACKET], [1],
 372                 [Define to 1 if net/if_packet.h is available.])
 373    fi])
 374
 375 dnl Checks for net/if_dl.h.
 376 dnl
 377 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 378 dnl or NetBSD.)
 379 AC_DEFUN([OVS_CHECK_IF_DL],
 380   [AC_CHECK_HEADER([net/if_dl.h],
 381                    [HAVE_IF_DL=yes],
 382                    [HAVE_IF_DL=no])
 383    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 384    if test "$HAVE_IF_DL" = yes; then
 385       AC_DEFINE([HAVE_IF_DL], [1],
 386                 [Define to 1 if net/if_dl.h is available.])
 387
 388       # On these platforms we use libpcap to access network devices.
 389       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 390    fi])
 391
 392 dnl Checks for buggy strtok_r.
 393 dnl
 394 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 395 dnl with optimization that can cause segfaults:
 396 dnl
 397 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 398 AC_DEFUN([OVS_CHECK_STRTOK_R],
 399   [AC_CACHE_CHECK(
 400      [whether strtok_r macro segfaults on some inputs],
 401      [ovs_cv_strtok_r_bug],
 402      [AC_RUN_IFELSE(
 403         [AC_LANG_PROGRAM([#include <stdio.h>
 404                           #include <string.h>
 405                          ],
 406                          [[char string[] = ":::";
 407                            char *save_ptr = (char *) 0xc0ffee;
 408                            char *token1, *token2;
 409                            token1 = strtok_r(string, ":", &save_ptr);
 410                            token2 = strtok_r(NULL, ":", &save_ptr);
 411                            freopen ("/dev/null", "w", stdout);
 412                            printf ("%s %s\n", token1, token2);
 413                            return 0;
 414                           ]])],
 415         [ovs_cv_strtok_r_bug=no],
 416         [ovs_cv_strtok_r_bug=yes],
 417         [ovs_cv_strtok_r_bug=yes])])
 418    if test $ovs_cv_strtok_r_bug = yes; then
 419      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 420                [Define if strtok_r macro segfaults on some inputs])
 421    fi
 422 ])
 423
 424 dnl ----------------------------------------------------------------------
 425 dnl These macros are from GNU PSPP, with the following original license:
 426 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 427 dnl This file is free software; the Free Software Foundation
 428 dnl gives unlimited permission to copy and/or distribute it,
 429 dnl with or without modifications, as long as this notice is preserved.
 430
 431 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 432   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 433   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 434     [ovs_save_CFLAGS="$CFLAGS"
 435      dnl Include -Werror in the compiler options, because without -Werror
 436      dnl clang's GCC-compatible compiler driver does not return a failure
 437      dnl exit status even though it complains about options it does not
 438      dnl understand.
 439      CFLAGS="$CFLAGS $WERROR $1"
 440      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 441      CFLAGS="$ovs_save_CFLAGS"])
 442   if test $ovs_cv_name = yes; then
 443     m4_if([$2], [], [:], [$2])
 444   else
 445     m4_if([$3], [], [:], [$3])
 446   fi
 447 ])
 448
 449 dnl OVS_CHECK_WERROR
 450 dnl
 451 dnl Check whether the C compiler accepts -Werror.
 452 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 453 AC_DEFUN([OVS_CHECK_WERROR],
 454   [WERROR=
 455    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 456
 457 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 458 dnl Check whether the given C compiler OPTION is accepted.
 459 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 460 AC_DEFUN([OVS_CHECK_CC_OPTION],
 461   [AC_REQUIRE([OVS_CHECK_WERROR])
 462    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 463
 464 dnl OVS_ENABLE_OPTION([OPTION])
 465 dnl Check whether the given C compiler OPTION is accepted.
 466 dnl If so, add it to WARNING_FLAGS.
 467 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 468 AC_DEFUN([OVS_ENABLE_OPTION],
 469   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 470    AC_SUBST([WARNING_FLAGS])])
 471
 472 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 473 dnl Check whether the given C compiler OPTION is accepted.
 474 dnl If so, enable the given Automake CONDITIONAL.
 475
 476 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 477 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 478   [OVS_CHECK_CC_OPTION(
 479     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 480    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 481 dnl ----------------------------------------------------------------------
 482
 483 dnl Check for too-old XenServer.
 484 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 485   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 486     [if test -e /etc/redhat-release; then
 487        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 488      fi
 489      if test -z "$ovs_cv_xsversion"; then
 490        ovs_cv_xsversion=none
 491      fi])
 492   case $ovs_cv_xsversion in
 493     none)
 494       ;;
 495
 496     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 497     [[6-9]]* |                           dnl XenServer 6 or later
 498     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 499     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 500     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 501     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 502       ;;
 503
 504     *)
 505       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 506       ;;
 507   esac])
 508
 509 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 510 dnl
 511 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 512 dnl Runs 'if-true' if so, 'if-false' otherwise.
 513 AC_DEFUN([OVS_CHECK_MAKE_IF],
 514   [AC_CACHE_CHECK(
 515      [whether ${MAKE-make} has GNU make \$(if) extension],
 516      [ovs_cv_gnu_make_if],
 517      [cat <<'EOF' > conftest.mk
 518 conftest.out:
 519         echo $(if x,y,z) > conftest.out
 520 .PHONY: all
 521 EOF
 522       rm -f conftest.out
 523       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 524       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 525       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 526       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 527       result=`cat conftest.out`
 528       rm -f conftest.mk conftest.out
 529       if test "X$result" = "Xy"; then
 530         ovs_cv_gnu_make_if=yes
 531       else
 532         ovs_cv_gnu_make_if=no
 533       fi])])
 534
 535 dnl OVS_CHECK_GNU_MAKE
 536 dnl
 537 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 538 dnl only work with GNU make).
 539 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 540   [AC_CACHE_CHECK(
 541      [whether ${MAKE-make} is GNU make],
 542      [ovs_cv_gnu_make],
 543      [rm -f conftest.out
 544       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 545       ${MAKE-make} --version >conftest.out 2>&1
 546       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 547       result=`cat conftest.out`
 548       rm -f conftest.mk conftest.out
 549
 550       case $result in # (
 551         GNU*) ovs_cv_gnu_make=yes ;; # (
 552         *) ovs_cv_gnu_make=no ;;
 553       esac])
 554    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 555
 556 dnl OVS_CHECK_SPARSE_TARGET
 557 dnl
 558 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 559 dnl target for which the code is being built.  This helps it out.
 560 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 561   [AC_CACHE_CHECK(
 562     [target hint for cgcc],
 563     [ac_cv_sparse_target],
 564     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 565        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 566        [x86_64-*], [ac_cv_sparse_target=x86_64],
 567        [ac_cv_sparse_target=other])])
 568    AS_CASE([$ac_cv_sparse_target],
 569      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 570      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 571      [SPARSEFLAGS= CGCCFLAGS=])
 572    AC_SUBST([SPARSEFLAGS])
 573    AC_SUBST([CGCCFLAGS])])
 574
 575 dnl OVS_SPARSE_EXTRA_INCLUDES
 576 dnl
 577 dnl The cgcc script from "sparse" does not search gcc's default
 578 dnl search path. Get the default search path from GCC and pass
 579 dnl them to sparse.
 580 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 581     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 582            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 583
 584 dnl OVS_ENABLE_SPARSE
 585 AC_DEFUN([OVS_ENABLE_SPARSE],
 586   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 587    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 588    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 589    : ${SPARSE=sparse}
 590    AC_SUBST([SPARSE])
 591    AC_CONFIG_COMMANDS_PRE(
 592      [if test $ovs_cv_gnu_make_if = yes; then
 593         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 594       fi])])
 595
 596 dnl OVS_PTHREAD_SET_NAME
 597 dnl
 598 dnl This checks for three known variants of pthreads functions for setting
 599 dnl the name of the current thread:
 600 dnl
 601 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 602 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 603 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 604 dnl
 605 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 606 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 607 dnl provide to it.
 608 dnl
 609 dnl This macro defines:
 610 dnl
 611 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 612 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 613 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 614 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 615   [AC_CHECK_FUNCS([pthread_set_name_np])
 616    if test $ac_cv_func_pthread_set_name_np != yes; then
 617      AC_CACHE_CHECK(
 618        [for pthread_setname_np() variant],
 619        [ovs_cv_pthread_setname_np],
 620        [AC_LINK_IFELSE(
 621          [AC_LANG_PROGRAM([#include <pthread.h>
 622   ], [pthread_setname_np(pthread_self(), "name");])],
 623          [ovs_cv_pthread_setname_np=glibc],
 624          [AC_LINK_IFELSE(
 625            [AC_LANG_PROGRAM([#include <pthread.h>
 626 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 627            [ovs_cv_pthread_setname_np=netbsd],
 628            [ovs_cv_pthread_setname_np=none])])])
 629      case $ovs_cv_pthread_setname_np in # (
 630        glibc)
 631           AC_DEFINE(
 632             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 633             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 634           ;; # (
 635        netbsd)
 636           AC_DEFINE(
 637             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 638             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 639           ;;
 640      esac
 641    fi])
 642
 643 dnl OVS_CHECK_LINUX_HOST.
 644 dnl
 645 dnl Checks whether we're building for a Linux host, based on the presence of
 646 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 647 dnl LINUX based on the result.
 648 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 649   [AC_CACHE_CHECK(
 650      [whether __linux__ is defined],
 651      [ovs_cv_linux],
 652      [AC_COMPILE_IFELSE(
 653         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 654         [ovs_cv_linux=true],
 655         [ovs_cv_linux=false])])
 656    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])