acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-ldpdk"
 176     DPDK_EXTRA_LIB=""
 177     RTE_SDK_FULL=`readlink -f $RTE_SDK`
 178
 179     AC_COMPILE_IFELSE(
 180       [AC_LANG_PROGRAM([#include <$RTE_SDK_FULL/include/rte_config.h>
 181 #if !RTE_LIBRTE_VHOST_USER
 182 #error
 183 #endif], [])],
 184                     [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 185                          DPDK_EXTRA_LIB="-lfuse"])
 186
 187     ovs_save_CFLAGS="$CFLAGS"
 188     ovs_save_LDFLAGS="$LDFLAGS"
 189     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 190     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 191
 192     # On some systems we have to add -ldl to link with dpdk
 193     #
 194     # This code, at first, tries to link without -ldl (""),
 195     # then adds it and tries again.
 196     # Before each attempt the search cache must be unset,
 197     # otherwise autoconf will stick with the old result
 198
 199     found=false
 200     save_LIBS=$LIBS
 201     for extras in "" "-ldl"; do
 202         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 203         AC_LINK_IFELSE(
 204            [AC_LANG_PROGRAM([#include <rte_config.h>
 205                              #include <rte_eal.h>],
 206                             [int rte_argc; char ** rte_argv;
 207                              rte_eal_init(rte_argc, rte_argv);])],
 208            [found=true])
 209         if $found; then
 210             break
 211         fi
 212     done
 213     if $found; then :; else
 214         AC_MSG_ERROR([cannot link with dpdk])
 215     fi
 216     CFLAGS="$ovs_save_CFLAGS"
 217     LDFLAGS="$ovs_save_LDFLAGS"
 218     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 219     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 220
 221     # DPDK pmd drivers are not linked unless --whole-archive is used.
 222     #
 223     # This happens because the rest of the DPDK code doesn't use any symbol in
 224     # the pmd driver objects, and the drivers register themselves using an
 225     # __attribute__((constructor)) function.
 226     #
 227     # These options are specified inside a single -Wl directive to prevent
 228     # autotools from reordering them.
 229     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 230     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 231     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 232
 233   else
 234     RTE_SDK=
 235   fi
 236
 237   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 238 ])
 239
 240 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 241 dnl
 242 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 243 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 244 dnl <REGEX> translated to uppercase.
 245 AC_DEFUN([OVS_GREP_IFELSE], [
 246   AC_MSG_CHECKING([whether $2 matches in $1])
 247   if test -f $1; then
 248     grep '$2' $1 >/dev/null 2>&1
 249     status=$?
 250     case $status in
 251       0)
 252         AC_MSG_RESULT([yes])
 253         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 254         ;;
 255       1)
 256         AC_MSG_RESULT([no])
 257         $4
 258         ;;
 259       *)
 260         AC_MSG_ERROR([grep exited with status $status])
 261         ;;
 262     esac
 263   else
 264     AC_MSG_RESULT([file not found])
 265     $4
 266   fi
 267 ])
 268
 269 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 270 dnl
 271 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 272 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 273 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 274 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 275 dnl translated to uppercase.
 276 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 277   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 278   if test -f $1; then
 279     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 280     status=$?
 281     case $status in
 282       0)
 283         AC_MSG_RESULT([yes])
 284         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 285         ;;
 286       1)
 287         AC_MSG_RESULT([no])
 288         $5
 289         ;;
 290       *)
 291         AC_MSG_ERROR([grep exited with status $status])
 292         ;;
 293     esac
 294   else
 295     AC_MSG_RESULT([file not found])
 296     $5
 297   fi
 298 ])
 299
 300 dnl OVS_DEFINE(NAME)
 301 dnl
 302 dnl Defines NAME to 1 in kcompat.h.
 303 AC_DEFUN([OVS_DEFINE], [
 304   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 305 ])
 306
 307 dnl OVS_CHECK_LINUX_COMPAT
 308 dnl
 309 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 310 dnl the directory in $KBUILD.
 311 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 312   rm -f datapath/linux/kcompat.h.new
 313   mkdir -p datapath/linux
 314   : > datapath/linux/kcompat.h.new
 315
 316   echo '#include <linux/version.h>
 317 #ifndef RHEL_RELEASE_CODE
 318 #define RHEL_RELEASE_CODE 0
 319 #define RHEL_RELEASE_VERSION(a, b) 0
 320 #endif' >> datapath/linux/kcompat.h.new
 321
 322   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 323                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 324
 325   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 326                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 327   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 328
 329   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 331
 332   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 333   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 334
 335   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 336   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 337   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 339   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 340
 341   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 342   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 343   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 344                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 345   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 346                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 347
 348   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 349                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 350   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_do_fragment])
 351   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment])
 352   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 353   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 354                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 355   OVS_GREP_IFELSE([$KSRC/include/net/dst_metadata.h], [metadata_dst])
 356
 357   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 358                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 359   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 360   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 361   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 366   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_rx_handler_register])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_extended])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [rx_handler_func_t.*pskb],
 371                   [OVS_DEFINE([HAVE_RX_HANDLER_PSKB])])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 373                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 374   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 376                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 377   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 378
 379   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 380   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 381   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 382                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 383
 384   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 385                   [tmpl_alloc.*conntrack_zone],
 386                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 387
 388   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 389   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 390
 391   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 392   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 393   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 394                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 395   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 396
 397   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 398                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 399                                    [rcu_read_lock_held])])
 400   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 401
 402   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 403   # is necessary because some versions of this header remove the
 404   # member but retain the kerneldoc comment that describes it (which
 405   # starts with @).  The brackets must be doubled because of m4
 406   # quoting rules.
 407   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 408                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 409   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 410   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 411   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_mac_header])
 412   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_network_header])
 413   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 415                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 417   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 418                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 419   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 420                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 421   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 422                   [skb_copy_from_linear_data_offset])
 423   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 424                   [skb_reset_tail_pointer])
 425   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 426   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 427                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 428   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 429                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 430   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 431                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 432   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 433   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 434   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 435   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 436   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 437   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 438   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 439   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 440   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 441   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 442                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 443   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 444                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 445   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 446   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 447   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 448
 449   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 450                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 451   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 452                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 453   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 454                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 455
 456   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 457   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 458
 459   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 460
 461   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 462   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 463   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 464   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 465   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 466                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 467   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 468   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 469                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 470
 471   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 472                         [genl_multicast_group], [id])
 473   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 474
 475   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 476   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 477   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 478   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 479   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 480                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 481
 482   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 483   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 484   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 485   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 486   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 487   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 488   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 489
 490   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 491
 492   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 493                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 494   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 497
 498   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 499
 500   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 501                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 502   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 503                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 504   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [VXLAN_HF_RCO])
 505   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 506                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 507                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 508   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 509   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 510   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 511   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [ipv6_v6only],
 512                   [OVS_DEFINE([HAVE_UDP_TUNNEL_IPV6])])
 513
 514   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 515                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 516   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 517                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 518
 519   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 520                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 521
 522   if test "$version" = 4 && test "$patchlevel" -le 2; then
 523         OVS_DEFINE([OVS_FRAGMENT_BACKPORT])
 524   elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 525         OVS_DEFINE([OVS_FRAGMENT_BACKPORT])
 526   fi
 527
 528   if cmp -s datapath/linux/kcompat.h.new \
 529             datapath/linux/kcompat.h >/dev/null 2>&1; then
 530     rm datapath/linux/kcompat.h.new
 531   else
 532     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 533   fi
 534 ])
 535
 536 dnl Checks for net/if_packet.h.
 537 AC_DEFUN([OVS_CHECK_IF_PACKET],
 538   [AC_CHECK_HEADER([net/if_packet.h],
 539                    [HAVE_IF_PACKET=yes],
 540                    [HAVE_IF_PACKET=no])
 541    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 542    if test "$HAVE_IF_PACKET" = yes; then
 543       AC_DEFINE([HAVE_IF_PACKET], [1],
 544                 [Define to 1 if net/if_packet.h is available.])
 545    fi])
 546
 547 dnl Checks for net/if_dl.h.
 548 dnl
 549 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 550 dnl or NetBSD.)
 551 AC_DEFUN([OVS_CHECK_IF_DL],
 552   [AC_CHECK_HEADER([net/if_dl.h],
 553                    [HAVE_IF_DL=yes],
 554                    [HAVE_IF_DL=no])
 555    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 556    if test "$HAVE_IF_DL" = yes; then
 557       AC_DEFINE([HAVE_IF_DL], [1],
 558                 [Define to 1 if net/if_dl.h is available.])
 559
 560       # On these platforms we use libpcap to access network devices.
 561       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 562    fi])
 563
 564 dnl Checks for buggy strtok_r.
 565 dnl
 566 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 567 dnl with optimization that can cause segfaults:
 568 dnl
 569 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 570 AC_DEFUN([OVS_CHECK_STRTOK_R],
 571   [AC_CACHE_CHECK(
 572      [whether strtok_r macro segfaults on some inputs],
 573      [ovs_cv_strtok_r_bug],
 574      [AC_RUN_IFELSE(
 575         [AC_LANG_PROGRAM([#include <stdio.h>
 576                           #include <string.h>
 577                          ],
 578                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 579                            /* Assume bug is present, because relatively minor
 580                               changes in compiler settings (e.g. optimization
 581                               level) can make it crop up. */
 582                            return 1;
 583                            #else
 584                            char string[] = ":::";
 585                            char *save_ptr = (char *) 0xc0ffee;
 586                            char *token1, *token2;
 587                            token1 = strtok_r(string, ":", &save_ptr);
 588                            token2 = strtok_r(NULL, ":", &save_ptr);
 589                            freopen ("/dev/null", "w", stdout);
 590                            printf ("%s %s\n", token1, token2);
 591                            return 0;
 592                            #endif
 593                           ]])],
 594         [ovs_cv_strtok_r_bug=no],
 595         [ovs_cv_strtok_r_bug=yes],
 596         [ovs_cv_strtok_r_bug=yes])])
 597    if test $ovs_cv_strtok_r_bug = yes; then
 598      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 599                [Define if strtok_r macro segfaults on some inputs])
 600    fi
 601 ])
 602
 603 dnl ----------------------------------------------------------------------
 604 dnl These macros are from GNU PSPP, with the following original license:
 605 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 606 dnl This file is free software; the Free Software Foundation
 607 dnl gives unlimited permission to copy and/or distribute it,
 608 dnl with or without modifications, as long as this notice is preserved.
 609
 610 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 611   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 612   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 613     [ovs_save_CFLAGS="$CFLAGS"
 614      dnl Include -Werror in the compiler options, because without -Werror
 615      dnl clang's GCC-compatible compiler driver does not return a failure
 616      dnl exit status even though it complains about options it does not
 617      dnl understand.
 618      dnl
 619      dnl Also, check stderr as gcc exits with status 0 for options
 620      dnl rejected at getopt level.
 621      dnl    % touch /tmp/a.c
 622      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 623      dnl    gcc: unrecognized option '-Qunused-arguments'
 624      dnl    0
 625      dnl    %
 626      CFLAGS="$CFLAGS $WERROR $1"
 627      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 628      CFLAGS="$ovs_save_CFLAGS"])
 629   if test $ovs_cv_name = yes; then
 630     m4_if([$2], [], [:], [$2])
 631   else
 632     m4_if([$3], [], [:], [$3])
 633   fi
 634 ])
 635
 636 dnl OVS_CHECK_WERROR
 637 dnl
 638 dnl Check whether the C compiler accepts -Werror.
 639 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 640 AC_DEFUN([OVS_CHECK_WERROR],
 641   [WERROR=
 642    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 643
 644 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 645 dnl Check whether the given C compiler OPTION is accepted.
 646 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 647 AC_DEFUN([OVS_CHECK_CC_OPTION],
 648   [AC_REQUIRE([OVS_CHECK_WERROR])
 649    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 650
 651 dnl OVS_ENABLE_OPTION([OPTION])
 652 dnl Check whether the given C compiler OPTION is accepted.
 653 dnl If so, add it to WARNING_FLAGS.
 654 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 655 AC_DEFUN([OVS_ENABLE_OPTION],
 656   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 657    AC_SUBST([WARNING_FLAGS])])
 658
 659 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 660 dnl Check whether the given C compiler OPTION is accepted.
 661 dnl If so, enable the given Automake CONDITIONAL.
 662
 663 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 664 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 665   [OVS_CHECK_CC_OPTION(
 666     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 667    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 668 dnl ----------------------------------------------------------------------
 669
 670 dnl Check for too-old XenServer.
 671 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 672   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 673     [if test -e /etc/redhat-release; then
 674        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 675      fi
 676      if test -z "$ovs_cv_xsversion"; then
 677        ovs_cv_xsversion=none
 678      fi])
 679   case $ovs_cv_xsversion in
 680     none)
 681       ;;
 682
 683     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 684     [[6-9]]* |                           dnl XenServer 6 or later
 685     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 686     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 687     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 688     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 689       ;;
 690
 691     *)
 692       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 693       ;;
 694   esac])
 695
 696 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 697 dnl
 698 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 699 dnl Runs 'if-true' if so, 'if-false' otherwise.
 700 AC_DEFUN([OVS_CHECK_MAKE_IF],
 701   [AC_CACHE_CHECK(
 702      [whether ${MAKE-make} has GNU make \$(if) extension],
 703      [ovs_cv_gnu_make_if],
 704      [cat <<'EOF' > conftest.mk
 705 conftest.out:
 706         echo $(if x,y,z) > conftest.out
 707 .PHONY: all
 708 EOF
 709       rm -f conftest.out
 710       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 711       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 712       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 713       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 714       result=`cat conftest.out`
 715       rm -f conftest.mk conftest.out
 716       if test "X$result" = "Xy"; then
 717         ovs_cv_gnu_make_if=yes
 718       else
 719         ovs_cv_gnu_make_if=no
 720       fi])])
 721
 722 dnl OVS_CHECK_GNU_MAKE
 723 dnl
 724 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 725 dnl only work with GNU make).
 726 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 727   [AC_CACHE_CHECK(
 728      [whether ${MAKE-make} is GNU make],
 729      [ovs_cv_gnu_make],
 730      [rm -f conftest.out
 731       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 732       ${MAKE-make} --version >conftest.out 2>&1
 733       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 734       result=`cat conftest.out`
 735       rm -f conftest.mk conftest.out
 736
 737       case $result in # (
 738         GNU*) ovs_cv_gnu_make=yes ;; # (
 739         *) ovs_cv_gnu_make=no ;;
 740       esac])
 741    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 742
 743 dnl OVS_CHECK_SPARSE_TARGET
 744 dnl
 745 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 746 dnl target for which the code is being built.  This helps it out.
 747 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 748   [AC_CACHE_CHECK(
 749     [target hint for cgcc],
 750     [ac_cv_sparse_target],
 751     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 752        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 753        [x86_64-*], [ac_cv_sparse_target=x86_64],
 754        [ac_cv_sparse_target=other])])
 755    AS_CASE([$ac_cv_sparse_target],
 756      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 757      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 758      [SPARSEFLAGS= CGCCFLAGS=])
 759    AC_SUBST([SPARSEFLAGS])
 760    AC_SUBST([CGCCFLAGS])])
 761
 762 dnl OVS_SPARSE_EXTRA_INCLUDES
 763 dnl
 764 dnl The cgcc script from "sparse" does not search gcc's default
 765 dnl search path. Get the default search path from GCC and pass
 766 dnl them to sparse.
 767 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 768     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 769            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 770
 771 dnl OVS_ENABLE_SPARSE
 772 AC_DEFUN([OVS_ENABLE_SPARSE],
 773   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 774    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 775    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 776    : ${SPARSE=sparse}
 777    AC_SUBST([SPARSE])
 778    AC_CONFIG_COMMANDS_PRE(
 779      [if test $ovs_cv_gnu_make_if = yes; then
 780         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 781       fi])])
 782
 783 dnl OVS_PTHREAD_SET_NAME
 784 dnl
 785 dnl This checks for three known variants of pthreads functions for setting
 786 dnl the name of the current thread:
 787 dnl
 788 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 789 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 790 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 791 dnl
 792 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 793 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 794 dnl provide to it.
 795 dnl
 796 dnl This macro defines:
 797 dnl
 798 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 799 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 800 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 801 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 802   [AC_CHECK_FUNCS([pthread_set_name_np])
 803    if test $ac_cv_func_pthread_set_name_np != yes; then
 804      AC_CACHE_CHECK(
 805        [for pthread_setname_np() variant],
 806        [ovs_cv_pthread_setname_np],
 807        [AC_LINK_IFELSE(
 808          [AC_LANG_PROGRAM([#include <pthread.h>
 809   ], [pthread_setname_np(pthread_self(), "name");])],
 810          [ovs_cv_pthread_setname_np=glibc],
 811          [AC_LINK_IFELSE(
 812            [AC_LANG_PROGRAM([#include <pthread.h>
 813 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 814            [ovs_cv_pthread_setname_np=netbsd],
 815            [ovs_cv_pthread_setname_np=none])])])
 816      case $ovs_cv_pthread_setname_np in # (
 817        glibc)
 818           AC_DEFINE(
 819             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 820             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 821           ;; # (
 822        netbsd)
 823           AC_DEFINE(
 824             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 825             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 826           ;;
 827      esac
 828    fi])
 829
 830 dnl OVS_CHECK_LINUX_HOST.
 831 dnl
 832 dnl Checks whether we're building for a Linux host, based on the presence of
 833 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 834 dnl LINUX based on the result.
 835 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 836   [AC_CACHE_CHECK(
 837      [whether __linux__ is defined],
 838      [ovs_cv_linux],
 839      [AC_COMPILE_IFELSE(
 840         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 841         [ovs_cv_linux=true],
 842         [ovs_cv_linux=false])])
 843    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])