acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 0; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.0.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-lintel_dpdk"
 176     DPDK_EXTRA_LIB="-lfuse"
 177
 178     ovs_save_CFLAGS="$CFLAGS"
 179     ovs_save_LDFLAGS="$LDFLAGS"
 180     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 181     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 182
 183     # On some systems we have to add -ldl to link with dpdk
 184     #
 185     # This code, at first, tries to link without -ldl (""),
 186     # then adds it and tries again.
 187     # Before each attempt the search cache must be unset,
 188     # otherwise autoconf will stick with the old result
 189
 190     found=false
 191     save_LIBS=$LIBS
 192     for extras in "" "-ldl"; do
 193         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 194         AC_LINK_IFELSE(
 195            [AC_LANG_PROGRAM([#include <rte_config.h>
 196                              #include <rte_eal.h>],
 197                             [int rte_argc; char ** rte_argv;
 198                              rte_eal_init(rte_argc, rte_argv);])],
 199            [found=true])
 200         if $found; then
 201             break
 202         fi
 203     done
 204     if $found; then :; else
 205         AC_MSG_ERROR([cannot link with dpdk])
 206     fi
 207     CFLAGS="$ovs_save_CFLAGS"
 208     LDFLAGS="$ovs_save_LDFLAGS"
 209     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 210     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 211
 212     # DPDK pmd drivers are not linked unless --whole-archive is used.
 213     #
 214     # This happens because the rest of the DPDK code doesn't use any symbol in
 215     # the pmd driver objects, and the drivers register themselves using an
 216     # __attribute__((constructor)) function.
 217     #
 218     # These options are specified inside a single -Wl directive to prevent
 219     # autotools from reordering them.
 220     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 221     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 222     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 223   else
 224     RTE_SDK=
 225   fi
 226
 227   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 228 ])
 229
 230 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 231 dnl
 232 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 233 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 234 dnl <REGEX> translated to uppercase.
 235 AC_DEFUN([OVS_GREP_IFELSE], [
 236   AC_MSG_CHECKING([whether $2 matches in $1])
 237   if test -f $1; then
 238     grep '$2' $1 >/dev/null 2>&1
 239     status=$?
 240     case $status in
 241       0)
 242         AC_MSG_RESULT([yes])
 243         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 244         ;;
 245       1)
 246         AC_MSG_RESULT([no])
 247         $4
 248         ;;
 249       *)
 250         AC_MSG_ERROR([grep exited with status $status])
 251         ;;
 252     esac
 253   else
 254     AC_MSG_RESULT([file not found])
 255     $4
 256   fi
 257 ])
 258
 259 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 260 dnl
 261 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 262 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 263 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 264 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 265 dnl translated to uppercase.
 266 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 267   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 268   if test -f $1; then
 269     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3'
 270     status=$?
 271     case $status in
 272       0)
 273         AC_MSG_RESULT([yes])
 274         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 275         ;;
 276       1)
 277         AC_MSG_RESULT([no])
 278         $5
 279         ;;
 280       *)
 281         AC_MSG_ERROR([grep exited with status $status])
 282         ;;
 283     esac
 284   else
 285     AC_MSG_RESULT([file not found])
 286     $5
 287   fi
 288 ])
 289
 290 dnl OVS_DEFINE(NAME)
 291 dnl
 292 dnl Defines NAME to 1 in kcompat.h.
 293 AC_DEFUN([OVS_DEFINE], [
 294   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 295 ])
 296
 297 dnl OVS_CHECK_LINUX_COMPAT
 298 dnl
 299 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 300 dnl the directory in $KBUILD.
 301 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 302   rm -f datapath/linux/kcompat.h.new
 303   mkdir -p datapath/linux
 304   : > datapath/linux/kcompat.h.new
 305
 306   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 307                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 308
 309   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 310   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 311
 312   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 313   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 314
 315   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 316
 317   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 318   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 319                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 320   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 321                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 322
 323   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 331                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 334
 335   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 336                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 337                                    [rcu_read_lock_held])])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 339
 340   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 341   # is necessary because some versions of this header remove the
 342   # member but retain the kerneldoc comment that describes it (which
 343   # starts with @).  The brackets must be doubled because of m4
 344   # quoting rules.
 345   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 346                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 347   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 348   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 349   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 350                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 351   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 352                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 353   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 354                   [skb_copy_from_linear_data_offset])
 355   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 356                   [skb_reset_tail_pointer])
 357   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 358   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 359                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 360   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 361                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 363                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 366   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 374                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 376   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 377   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 378   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 379
 380   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 381                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 382   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 383                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 384   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 385                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 386
 387   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 388   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 389
 390   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 391   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 392   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 393   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 394   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 395                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 396   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 397   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 398                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 399
 400   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 401                         [genl_multicast_group], [id])
 402
 403   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 404   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 405   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 406   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 407   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 408   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 409   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 410   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 411
 412   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 413
 414   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 415                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 417   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 418
 419
 420   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 421
 422   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 423                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 424   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 425                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 426   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 427                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 428                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 429   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 430   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 431   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 432                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 433   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
 434                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
 435   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
 436                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
 437   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 438                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 439
 440   if cmp -s datapath/linux/kcompat.h.new \
 441             datapath/linux/kcompat.h >/dev/null 2>&1; then
 442     rm datapath/linux/kcompat.h.new
 443   else
 444     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 445   fi
 446 ])
 447
 448 dnl Checks for net/if_packet.h.
 449 AC_DEFUN([OVS_CHECK_IF_PACKET],
 450   [AC_CHECK_HEADER([net/if_packet.h],
 451                    [HAVE_IF_PACKET=yes],
 452                    [HAVE_IF_PACKET=no])
 453    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 454    if test "$HAVE_IF_PACKET" = yes; then
 455       AC_DEFINE([HAVE_IF_PACKET], [1],
 456                 [Define to 1 if net/if_packet.h is available.])
 457    fi])
 458
 459 dnl Checks for net/if_dl.h.
 460 dnl
 461 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 462 dnl or NetBSD.)
 463 AC_DEFUN([OVS_CHECK_IF_DL],
 464   [AC_CHECK_HEADER([net/if_dl.h],
 465                    [HAVE_IF_DL=yes],
 466                    [HAVE_IF_DL=no])
 467    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 468    if test "$HAVE_IF_DL" = yes; then
 469       AC_DEFINE([HAVE_IF_DL], [1],
 470                 [Define to 1 if net/if_dl.h is available.])
 471
 472       # On these platforms we use libpcap to access network devices.
 473       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 474    fi])
 475
 476 dnl Checks for buggy strtok_r.
 477 dnl
 478 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 479 dnl with optimization that can cause segfaults:
 480 dnl
 481 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 482 AC_DEFUN([OVS_CHECK_STRTOK_R],
 483   [AC_CACHE_CHECK(
 484      [whether strtok_r macro segfaults on some inputs],
 485      [ovs_cv_strtok_r_bug],
 486      [AC_RUN_IFELSE(
 487         [AC_LANG_PROGRAM([#include <stdio.h>
 488                           #include <string.h>
 489                          ],
 490                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 491                            /* Assume bug is present, because relatively minor
 492                               changes in compiler settings (e.g. optimization
 493                               level) can make it crop up. */
 494                            return 1;
 495                            #else
 496                            char string[] = ":::";
 497                            char *save_ptr = (char *) 0xc0ffee;
 498                            char *token1, *token2;
 499                            token1 = strtok_r(string, ":", &save_ptr);
 500                            token2 = strtok_r(NULL, ":", &save_ptr);
 501                            freopen ("/dev/null", "w", stdout);
 502                            printf ("%s %s\n", token1, token2);
 503                            return 0;
 504                            #endif
 505                           ]])],
 506         [ovs_cv_strtok_r_bug=no],
 507         [ovs_cv_strtok_r_bug=yes],
 508         [ovs_cv_strtok_r_bug=yes])])
 509    if test $ovs_cv_strtok_r_bug = yes; then
 510      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 511                [Define if strtok_r macro segfaults on some inputs])
 512    fi
 513 ])
 514
 515 dnl ----------------------------------------------------------------------
 516 dnl These macros are from GNU PSPP, with the following original license:
 517 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 518 dnl This file is free software; the Free Software Foundation
 519 dnl gives unlimited permission to copy and/or distribute it,
 520 dnl with or without modifications, as long as this notice is preserved.
 521
 522 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 523   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 524   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 525     [ovs_save_CFLAGS="$CFLAGS"
 526      dnl Include -Werror in the compiler options, because without -Werror
 527      dnl clang's GCC-compatible compiler driver does not return a failure
 528      dnl exit status even though it complains about options it does not
 529      dnl understand.
 530      dnl
 531      dnl Also, check stderr as gcc exits with status 0 for options
 532      dnl rejected at getopt level.
 533      dnl    % touch /tmp/a.c
 534      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 535      dnl    gcc: unrecognized option '-Qunused-arguments'
 536      dnl    0
 537      dnl    %
 538      CFLAGS="$CFLAGS $WERROR $1"
 539      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 540      CFLAGS="$ovs_save_CFLAGS"])
 541   if test $ovs_cv_name = yes; then
 542     m4_if([$2], [], [:], [$2])
 543   else
 544     m4_if([$3], [], [:], [$3])
 545   fi
 546 ])
 547
 548 dnl OVS_CHECK_WERROR
 549 dnl
 550 dnl Check whether the C compiler accepts -Werror.
 551 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 552 AC_DEFUN([OVS_CHECK_WERROR],
 553   [WERROR=
 554    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 555
 556 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 557 dnl Check whether the given C compiler OPTION is accepted.
 558 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 559 AC_DEFUN([OVS_CHECK_CC_OPTION],
 560   [AC_REQUIRE([OVS_CHECK_WERROR])
 561    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 562
 563 dnl OVS_ENABLE_OPTION([OPTION])
 564 dnl Check whether the given C compiler OPTION is accepted.
 565 dnl If so, add it to WARNING_FLAGS.
 566 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 567 AC_DEFUN([OVS_ENABLE_OPTION],
 568   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 569    AC_SUBST([WARNING_FLAGS])])
 570
 571 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 572 dnl Check whether the given C compiler OPTION is accepted.
 573 dnl If so, enable the given Automake CONDITIONAL.
 574
 575 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 576 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 577   [OVS_CHECK_CC_OPTION(
 578     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 579    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 580 dnl ----------------------------------------------------------------------
 581
 582 dnl Check for too-old XenServer.
 583 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 584   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 585     [if test -e /etc/redhat-release; then
 586        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 587      fi
 588      if test -z "$ovs_cv_xsversion"; then
 589        ovs_cv_xsversion=none
 590      fi])
 591   case $ovs_cv_xsversion in
 592     none)
 593       ;;
 594
 595     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 596     [[6-9]]* |                           dnl XenServer 6 or later
 597     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 598     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 599     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 600     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 601       ;;
 602
 603     *)
 604       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 605       ;;
 606   esac])
 607
 608 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 609 dnl
 610 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 611 dnl Runs 'if-true' if so, 'if-false' otherwise.
 612 AC_DEFUN([OVS_CHECK_MAKE_IF],
 613   [AC_CACHE_CHECK(
 614      [whether ${MAKE-make} has GNU make \$(if) extension],
 615      [ovs_cv_gnu_make_if],
 616      [cat <<'EOF' > conftest.mk
 617 conftest.out:
 618         echo $(if x,y,z) > conftest.out
 619 .PHONY: all
 620 EOF
 621       rm -f conftest.out
 622       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 623       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 624       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 625       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 626       result=`cat conftest.out`
 627       rm -f conftest.mk conftest.out
 628       if test "X$result" = "Xy"; then
 629         ovs_cv_gnu_make_if=yes
 630       else
 631         ovs_cv_gnu_make_if=no
 632       fi])])
 633
 634 dnl OVS_CHECK_GNU_MAKE
 635 dnl
 636 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 637 dnl only work with GNU make).
 638 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 639   [AC_CACHE_CHECK(
 640      [whether ${MAKE-make} is GNU make],
 641      [ovs_cv_gnu_make],
 642      [rm -f conftest.out
 643       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 644       ${MAKE-make} --version >conftest.out 2>&1
 645       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 646       result=`cat conftest.out`
 647       rm -f conftest.mk conftest.out
 648
 649       case $result in # (
 650         GNU*) ovs_cv_gnu_make=yes ;; # (
 651         *) ovs_cv_gnu_make=no ;;
 652       esac])
 653    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 654
 655 dnl OVS_CHECK_SPARSE_TARGET
 656 dnl
 657 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 658 dnl target for which the code is being built.  This helps it out.
 659 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 660   [AC_CACHE_CHECK(
 661     [target hint for cgcc],
 662     [ac_cv_sparse_target],
 663     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 664        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 665        [x86_64-*], [ac_cv_sparse_target=x86_64],
 666        [ac_cv_sparse_target=other])])
 667    AS_CASE([$ac_cv_sparse_target],
 668      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 669      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 670      [SPARSEFLAGS= CGCCFLAGS=])
 671    AC_SUBST([SPARSEFLAGS])
 672    AC_SUBST([CGCCFLAGS])])
 673
 674 dnl OVS_SPARSE_EXTRA_INCLUDES
 675 dnl
 676 dnl The cgcc script from "sparse" does not search gcc's default
 677 dnl search path. Get the default search path from GCC and pass
 678 dnl them to sparse.
 679 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 680     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 681            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 682
 683 dnl OVS_ENABLE_SPARSE
 684 AC_DEFUN([OVS_ENABLE_SPARSE],
 685   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 686    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 687    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 688    : ${SPARSE=sparse}
 689    AC_SUBST([SPARSE])
 690    AC_CONFIG_COMMANDS_PRE(
 691      [if test $ovs_cv_gnu_make_if = yes; then
 692         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 693       fi])])
 694
 695 dnl OVS_PTHREAD_SET_NAME
 696 dnl
 697 dnl This checks for three known variants of pthreads functions for setting
 698 dnl the name of the current thread:
 699 dnl
 700 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 701 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 702 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 703 dnl
 704 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 705 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 706 dnl provide to it.
 707 dnl
 708 dnl This macro defines:
 709 dnl
 710 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 711 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 712 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 713 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 714   [AC_CHECK_FUNCS([pthread_set_name_np])
 715    if test $ac_cv_func_pthread_set_name_np != yes; then
 716      AC_CACHE_CHECK(
 717        [for pthread_setname_np() variant],
 718        [ovs_cv_pthread_setname_np],
 719        [AC_LINK_IFELSE(
 720          [AC_LANG_PROGRAM([#include <pthread.h>
 721   ], [pthread_setname_np(pthread_self(), "name");])],
 722          [ovs_cv_pthread_setname_np=glibc],
 723          [AC_LINK_IFELSE(
 724            [AC_LANG_PROGRAM([#include <pthread.h>
 725 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 726            [ovs_cv_pthread_setname_np=netbsd],
 727            [ovs_cv_pthread_setname_np=none])])])
 728      case $ovs_cv_pthread_setname_np in # (
 729        glibc)
 730           AC_DEFINE(
 731             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 732             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 733           ;; # (
 734        netbsd)
 735           AC_DEFINE(
 736             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 737             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 738           ;;
 739      esac
 740    fi])
 741
 742 dnl OVS_CHECK_LINUX_HOST.
 743 dnl
 744 dnl Checks whether we're building for a Linux host, based on the presence of
 745 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 746 dnl LINUX based on the result.
 747 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 748   [AC_CACHE_CHECK(
 749      [whether __linux__ is defined],
 750      [ovs_cv_linux],
 751      [AC_COMPILE_IFELSE(
 752         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 753         [ovs_cv_linux=true],
 754         [ovs_cv_linux=false])])
 755    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])