acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 19; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.19.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIB="-lintel_dpdk"
 174     DPDK_EXTRA_LIB="-lfuse"
 175
 176     ovs_save_CFLAGS="$CFLAGS"
 177     ovs_save_LDFLAGS="$LDFLAGS"
 178     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 179     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 180
 181     # On some systems we have to add -ldl to link with dpdk
 182     #
 183     # This code, at first, tries to link without -ldl (""),
 184     # then adds it and tries again.
 185     # Before each attempt the search cache must be unset,
 186     # otherwise autoconf will stick with the old result
 187
 188     found=false
 189     save_LIBS=$LIBS
 190     for extras in "" "-ldl"; do
 191         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 192         AC_LINK_IFELSE(
 193            [AC_LANG_PROGRAM([#include <rte_config.h>
 194                              #include <rte_eal.h>],
 195                             [int rte_argc; char ** rte_argv;
 196                              rte_eal_init(rte_argc, rte_argv);])],
 197            [found=true])
 198         if $found; then
 199             break
 200         fi
 201     done
 202     if $found; then :; else
 203         AC_MSG_ERROR([cannot link with dpdk])
 204     fi
 205     CFLAGS="$ovs_save_CFLAGS"
 206     LDFLAGS="$ovs_save_LDFLAGS"
 207     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 208     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 209
 210     # DPDK pmd drivers are not linked unless --whole-archive is used.
 211     #
 212     # This happens because the rest of the DPDK code doesn't use any symbol in
 213     # the pmd driver objects, and the drivers register themselves using an
 214     # __attribute__((constructor)) function.
 215     #
 216     # These options are specified inside a single -Wl directive to prevent
 217     # autotools from reordering them.
 218     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 219     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 220     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 221   else
 222     RTE_SDK=
 223   fi
 224
 225   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 226 ])
 227
 228 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 229 dnl
 230 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 231 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 232 dnl <REGEX> translated to uppercase.
 233 AC_DEFUN([OVS_GREP_IFELSE], [
 234   AC_MSG_CHECKING([whether $2 matches in $1])
 235   if test -f $1; then
 236     grep '$2' $1 >/dev/null 2>&1
 237     status=$?
 238     case $status in
 239       0)
 240         AC_MSG_RESULT([yes])
 241         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 242         ;;
 243       1)
 244         AC_MSG_RESULT([no])
 245         $4
 246         ;;
 247       *)
 248         AC_MSG_ERROR([grep exited with status $status])
 249         ;;
 250     esac
 251   else
 252     AC_MSG_RESULT([file not found])
 253     $4
 254   fi
 255 ])
 256
 257 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 258 dnl
 259 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 260 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 261 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 262 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 263 dnl translated to uppercase.
 264 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 265   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 266   if test -f $1; then
 267     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3'
 268     status=$?
 269     case $status in
 270       0)
 271         AC_MSG_RESULT([yes])
 272         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 273         ;;
 274       1)
 275         AC_MSG_RESULT([no])
 276         $5
 277         ;;
 278       *)
 279         AC_MSG_ERROR([grep exited with status $status])
 280         ;;
 281     esac
 282   else
 283     AC_MSG_RESULT([file not found])
 284     $5
 285   fi
 286 ])
 287
 288 dnl OVS_DEFINE(NAME)
 289 dnl
 290 dnl Defines NAME to 1 in kcompat.h.
 291 AC_DEFUN([OVS_DEFINE], [
 292   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 293 ])
 294
 295 dnl OVS_CHECK_LINUX_COMPAT
 296 dnl
 297 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 298 dnl the directory in $KBUILD.
 299 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 300   rm -f datapath/linux/kcompat.h.new
 301   mkdir -p datapath/linux
 302   : > datapath/linux/kcompat.h.new
 303
 304   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 305                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 306
 307   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 308   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 309
 310   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 311   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 312
 313   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 314
 315   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 316   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 317                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 318   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 319                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 320
 321   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 322   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 323   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 324   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 329                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 330
 331   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 334                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 335                                    [rcu_read_lock_held])])
 336   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 337
 338   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 339   # is necessary because some versions of this header remove the
 340   # member but retain the kerneldoc comment that describes it (which
 341   # starts with @).  The brackets must be doubled because of m4
 342   # quoting rules.
 343   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 344                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 345   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 346   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 347                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 348   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 349                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 350   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 351                   [skb_copy_from_linear_data_offset])
 352   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 353                   [skb_reset_tail_pointer])
 354   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 355   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 356                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 357   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 358                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 359   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 360                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 361   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 366   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 371                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 374   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 376
 377   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 378                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 379   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 380                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 381   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 382                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 383
 384   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 385   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 386
 387   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 388   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 389   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 390   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 391   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 392                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 393   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 394   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 395                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 396
 397   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 398                         [genl_multicast_group], [id])
 399
 400   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 401   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 402   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 403   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 404   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 405   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 406   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 407   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 408
 409   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 410
 411   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 412                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 413   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 415
 416
 417   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 418
 419   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 420                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 421   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 422                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 423   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 424                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 425                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 426   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 427   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 428   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 429                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 430   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
 431                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
 432   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
 433                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
 434   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 435                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 436
 437   if cmp -s datapath/linux/kcompat.h.new \
 438             datapath/linux/kcompat.h >/dev/null 2>&1; then
 439     rm datapath/linux/kcompat.h.new
 440   else
 441     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 442   fi
 443 ])
 444
 445 dnl Checks for net/if_packet.h.
 446 AC_DEFUN([OVS_CHECK_IF_PACKET],
 447   [AC_CHECK_HEADER([net/if_packet.h],
 448                    [HAVE_IF_PACKET=yes],
 449                    [HAVE_IF_PACKET=no])
 450    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 451    if test "$HAVE_IF_PACKET" = yes; then
 452       AC_DEFINE([HAVE_IF_PACKET], [1],
 453                 [Define to 1 if net/if_packet.h is available.])
 454    fi])
 455
 456 dnl Checks for net/if_dl.h.
 457 dnl
 458 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 459 dnl or NetBSD.)
 460 AC_DEFUN([OVS_CHECK_IF_DL],
 461   [AC_CHECK_HEADER([net/if_dl.h],
 462                    [HAVE_IF_DL=yes],
 463                    [HAVE_IF_DL=no])
 464    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 465    if test "$HAVE_IF_DL" = yes; then
 466       AC_DEFINE([HAVE_IF_DL], [1],
 467                 [Define to 1 if net/if_dl.h is available.])
 468
 469       # On these platforms we use libpcap to access network devices.
 470       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 471    fi])
 472
 473 dnl Checks for buggy strtok_r.
 474 dnl
 475 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 476 dnl with optimization that can cause segfaults:
 477 dnl
 478 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 479 AC_DEFUN([OVS_CHECK_STRTOK_R],
 480   [AC_CACHE_CHECK(
 481      [whether strtok_r macro segfaults on some inputs],
 482      [ovs_cv_strtok_r_bug],
 483      [AC_RUN_IFELSE(
 484         [AC_LANG_PROGRAM([#include <stdio.h>
 485                           #include <string.h>
 486                          ],
 487                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 488                            /* Assume bug is present, because relatively minor
 489                               changes in compiler settings (e.g. optimization
 490                               level) can make it crop up. */
 491                            return 1;
 492                            #else
 493                            char string[] = ":::";
 494                            char *save_ptr = (char *) 0xc0ffee;
 495                            char *token1, *token2;
 496                            token1 = strtok_r(string, ":", &save_ptr);
 497                            token2 = strtok_r(NULL, ":", &save_ptr);
 498                            freopen ("/dev/null", "w", stdout);
 499                            printf ("%s %s\n", token1, token2);
 500                            return 0;
 501                            #endif
 502                           ]])],
 503         [ovs_cv_strtok_r_bug=no],
 504         [ovs_cv_strtok_r_bug=yes],
 505         [ovs_cv_strtok_r_bug=yes])])
 506    if test $ovs_cv_strtok_r_bug = yes; then
 507      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 508                [Define if strtok_r macro segfaults on some inputs])
 509    fi
 510 ])
 511
 512 dnl ----------------------------------------------------------------------
 513 dnl These macros are from GNU PSPP, with the following original license:
 514 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 515 dnl This file is free software; the Free Software Foundation
 516 dnl gives unlimited permission to copy and/or distribute it,
 517 dnl with or without modifications, as long as this notice is preserved.
 518
 519 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 520   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 521   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 522     [ovs_save_CFLAGS="$CFLAGS"
 523      dnl Include -Werror in the compiler options, because without -Werror
 524      dnl clang's GCC-compatible compiler driver does not return a failure
 525      dnl exit status even though it complains about options it does not
 526      dnl understand.
 527      dnl
 528      dnl Also, check stderr as gcc exits with status 0 for options
 529      dnl rejected at getopt level.
 530      dnl    % touch /tmp/a.c
 531      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 532      dnl    gcc: unrecognized option '-Qunused-arguments'
 533      dnl    0
 534      dnl    %
 535      CFLAGS="$CFLAGS $WERROR $1"
 536      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 537      CFLAGS="$ovs_save_CFLAGS"])
 538   if test $ovs_cv_name = yes; then
 539     m4_if([$2], [], [:], [$2])
 540   else
 541     m4_if([$3], [], [:], [$3])
 542   fi
 543 ])
 544
 545 dnl OVS_CHECK_WERROR
 546 dnl
 547 dnl Check whether the C compiler accepts -Werror.
 548 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 549 AC_DEFUN([OVS_CHECK_WERROR],
 550   [WERROR=
 551    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 552
 553 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 554 dnl Check whether the given C compiler OPTION is accepted.
 555 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 556 AC_DEFUN([OVS_CHECK_CC_OPTION],
 557   [AC_REQUIRE([OVS_CHECK_WERROR])
 558    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 559
 560 dnl OVS_ENABLE_OPTION([OPTION])
 561 dnl Check whether the given C compiler OPTION is accepted.
 562 dnl If so, add it to WARNING_FLAGS.
 563 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 564 AC_DEFUN([OVS_ENABLE_OPTION],
 565   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 566    AC_SUBST([WARNING_FLAGS])])
 567
 568 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 569 dnl Check whether the given C compiler OPTION is accepted.
 570 dnl If so, enable the given Automake CONDITIONAL.
 571
 572 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 573 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 574   [OVS_CHECK_CC_OPTION(
 575     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 576    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 577 dnl ----------------------------------------------------------------------
 578
 579 dnl Check for too-old XenServer.
 580 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 581   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 582     [if test -e /etc/redhat-release; then
 583        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 584      fi
 585      if test -z "$ovs_cv_xsversion"; then
 586        ovs_cv_xsversion=none
 587      fi])
 588   case $ovs_cv_xsversion in
 589     none)
 590       ;;
 591
 592     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 593     [[6-9]]* |                           dnl XenServer 6 or later
 594     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 595     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 596     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 597     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 598       ;;
 599
 600     *)
 601       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 602       ;;
 603   esac])
 604
 605 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 606 dnl
 607 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 608 dnl Runs 'if-true' if so, 'if-false' otherwise.
 609 AC_DEFUN([OVS_CHECK_MAKE_IF],
 610   [AC_CACHE_CHECK(
 611      [whether ${MAKE-make} has GNU make \$(if) extension],
 612      [ovs_cv_gnu_make_if],
 613      [cat <<'EOF' > conftest.mk
 614 conftest.out:
 615         echo $(if x,y,z) > conftest.out
 616 .PHONY: all
 617 EOF
 618       rm -f conftest.out
 619       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 620       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 621       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 622       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 623       result=`cat conftest.out`
 624       rm -f conftest.mk conftest.out
 625       if test "X$result" = "Xy"; then
 626         ovs_cv_gnu_make_if=yes
 627       else
 628         ovs_cv_gnu_make_if=no
 629       fi])])
 630
 631 dnl OVS_CHECK_GNU_MAKE
 632 dnl
 633 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 634 dnl only work with GNU make).
 635 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 636   [AC_CACHE_CHECK(
 637      [whether ${MAKE-make} is GNU make],
 638      [ovs_cv_gnu_make],
 639      [rm -f conftest.out
 640       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 641       ${MAKE-make} --version >conftest.out 2>&1
 642       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 643       result=`cat conftest.out`
 644       rm -f conftest.mk conftest.out
 645
 646       case $result in # (
 647         GNU*) ovs_cv_gnu_make=yes ;; # (
 648         *) ovs_cv_gnu_make=no ;;
 649       esac])
 650    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 651
 652 dnl OVS_CHECK_SPARSE_TARGET
 653 dnl
 654 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 655 dnl target for which the code is being built.  This helps it out.
 656 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 657   [AC_CACHE_CHECK(
 658     [target hint for cgcc],
 659     [ac_cv_sparse_target],
 660     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 661        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 662        [x86_64-*], [ac_cv_sparse_target=x86_64],
 663        [ac_cv_sparse_target=other])])
 664    AS_CASE([$ac_cv_sparse_target],
 665      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 666      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 667      [SPARSEFLAGS= CGCCFLAGS=])
 668    AC_SUBST([SPARSEFLAGS])
 669    AC_SUBST([CGCCFLAGS])])
 670
 671 dnl OVS_SPARSE_EXTRA_INCLUDES
 672 dnl
 673 dnl The cgcc script from "sparse" does not search gcc's default
 674 dnl search path. Get the default search path from GCC and pass
 675 dnl them to sparse.
 676 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 677     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 678            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 679
 680 dnl OVS_ENABLE_SPARSE
 681 AC_DEFUN([OVS_ENABLE_SPARSE],
 682   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 683    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 684    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 685    : ${SPARSE=sparse}
 686    AC_SUBST([SPARSE])
 687    AC_CONFIG_COMMANDS_PRE(
 688      [if test $ovs_cv_gnu_make_if = yes; then
 689         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 690       fi])])
 691
 692 dnl OVS_PTHREAD_SET_NAME
 693 dnl
 694 dnl This checks for three known variants of pthreads functions for setting
 695 dnl the name of the current thread:
 696 dnl
 697 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 698 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 699 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 700 dnl
 701 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 702 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 703 dnl provide to it.
 704 dnl
 705 dnl This macro defines:
 706 dnl
 707 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 708 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 709 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 710 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 711   [AC_CHECK_FUNCS([pthread_set_name_np])
 712    if test $ac_cv_func_pthread_set_name_np != yes; then
 713      AC_CACHE_CHECK(
 714        [for pthread_setname_np() variant],
 715        [ovs_cv_pthread_setname_np],
 716        [AC_LINK_IFELSE(
 717          [AC_LANG_PROGRAM([#include <pthread.h>
 718   ], [pthread_setname_np(pthread_self(), "name");])],
 719          [ovs_cv_pthread_setname_np=glibc],
 720          [AC_LINK_IFELSE(
 721            [AC_LANG_PROGRAM([#include <pthread.h>
 722 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 723            [ovs_cv_pthread_setname_np=netbsd],
 724            [ovs_cv_pthread_setname_np=none])])])
 725      case $ovs_cv_pthread_setname_np in # (
 726        glibc)
 727           AC_DEFINE(
 728             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 729             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 730           ;; # (
 731        netbsd)
 732           AC_DEFINE(
 733             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 734             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 735           ;;
 736      esac
 737    fi])
 738
 739 dnl OVS_CHECK_LINUX_HOST.
 740 dnl
 741 dnl Checks whether we're building for a Linux host, based on the presence of
 742 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 743 dnl LINUX based on the result.
 744 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 745   [AC_CACHE_CHECK(
 746      [whether __linux__ is defined],
 747      [ovs_cv_linux],
 748      [AC_COMPILE_IFELSE(
 749         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 750         [ovs_cv_linux=true],
 751         [ovs_cv_linux=false])])
 752    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])